Traitement des cellules vides

Dans les anciennes versions du logiciel, les cellules vides étaient forcées à un 0 numérique dans certains contextes et à des chaînes vides dans d'autres, excepté dans les comparaisons directes ou =A1=0 et =A1="", les deux résultaient en VRAI si A1 était vide. L'état vide est maintenant hérité jusqu'à son utilisation, ainsi =RECHERCHEV(...)=0 et =RECHERCHEV(...)="" renvoient VRAI si la recherche résulte en le renvoi d'une cellule vide.

Une référence simple à une cellule vide est toujours affichée comme 0 numérique mais n'est plus nécessairement de type numérique, ainsi les comparaisons avec les cellules de références fonctionnent aussi comme elles le doivent.

Dans les exemples suivants, A1 contient un nombre, B1 est vide et C1 contient une référence à B1 :

A1: 1 B1: <Empty> C1: =B1 (affiche 0)

=B1=0 => VRAI

=B1="" => VRAI

=C1=0 => VRAI

=C1="" => VRAI (précédemment était FAUX)

=ESTNUM(B1) => FAUX

=ESTNUM(C1) => FAUX (précédemment était VRAI)

=ESTNUM(RECHERCHEV(1;A1:C1;2)) => FAUX (B1)

=ESTNUM(RECHERCHEV(1;A1:C1;3)) => FAUX (C1, précédemment était VRAI)

=ESTTEXTE(B1) => FAUX

=ESTTEXTE(C1) => FAUX

=ESTTEXTE(RECHERCHEV(1;A1:C1;2)) => FAUX (B1, précédemment était VRAI)

=ESTTEXTE(RECHERCHEV(1;A1:C1;3)) => FAUX (C1)

=ESTVIDE(B1) => VRAI

=ESTVIDE(C1) => FAUX

=ESTVIDE(RECHERCHEV(1;A1:C1;2)) => VRAI (B1, précédemment était FAUX)

=ESTVIDE(RECHERCHEV(1;A1:C1;3)) => FAUX (C1)

Icône Remarque

Notez que Microsoft Excel se comporte différemment et renvoie toujours un nombre comme résultat d'une référence à une cellule vide ou d'une cellule de formule qui a pour résultat une cellule vide. Par exemple :


A1: <Empty>

B1: =A1 => affiche 0, mais est juste une référence à une cellule vide

=ISNUM(A1) => FAUX

=ESTTEXTE(A1) => FAUX

=A1=0 => VRAI

=A1="" => VRAI

=ESTNUM(B1) => FAUX (Microsoft-Excel : VRAI)

=ESTTEXTE(B1) => FAUX

=B1=0 => VRAI

=B1="" => VRAI (Microsoft Excel : FAUX)

C1: =RECHERCHEV(...) avec une cellule de résultat vide => affiche vide (Microsoft Excel : affiche 0)

=ESTNUM(RECHERCHEV(...)) => FAUX

=ESTTEXTE(RECHERCHEV(...)) => FAUX

=ESTNUM(C1) => FAUX (Microsoft Excel : VRAI)

=ESTTEXTE(C1) => FAUX