Fonction MOYENNE.SI

Renvoie la moyenne arithmétique de toutes les cellules d'une plage qui satisfait à une condition donnée. La fonction MOYENNE.SI additionne tous les résultats qui correspondent au test logique et divise cette somme par la quantité de valeurs sélectionnées.

Syntaxe

MOYENNE.SI(plage;critère[;plage_moyenne])

plage - argument requis. Une matrice, un nom d'une plage nommée ou une étiquette de colonne ou de ligne contenant les nombres pour la moyenne ou des nombres ou du texte pour la condition.

critère - argument requis. Une condition sous la forme d'expression ou une référence de cellule avec une expression qui définit quelles cellules doivent être utilisées pour calculer la moyenne. L'expression peut contenir du texte, des nombres, des expressions régulière (si activé dans les options de calcul) ou des caractères génériques (si activés dans les options de calcul).

plage_moyenne - facultatif. C'est une plage de valeurs pour calculer la moyenne.

Icône Remarque

Remarquez que si plage_moyenne n'est pas spécifié, plage est utilisé pour les deux, le calcul de la moyenne et la recherche en fonction de la condition. Si plage_moyenne est spécifié, l'argument plage est utilisé uniquement pour la condition de test, alors que plage_moyenne est utilisé pour le calcul de la moyenne.
Le critère doit être une expression de chaîne entourée de guillemets ("Critère") à l'exception des noms de fonctions, références de cellules et une opération de concaténation des chaînes (&).


Icône Remarque

Cette fonction fait partie du standard Open Document Format for Office Applications (Open Document) Version 1.2 (ISO/IEC 26300:2-2015)


Icône Avertissement

Si une cellule dans une plage de données pour calculer la moyenne est vide ou contient du texte, la fonction MOYENNE.SI ignore cette cellule.
Si la plage entière est vide, contient uniquement du texte ou toutes les valeurs de la plage ne satisfont pas la condition (ou n'importe quelle combinaison de celles-ci), la fonction renvoie l'erreur #DIV/0!


Exemples

Examinez le tableau suivant

A

B

C

1

Nom du produit

Ventes

Chiffre d'affaires

2

crayon

20

65

3

stylo

35

85

4

bloc-notes

20

190

5

livre

17

180

6

trousse

non

non


Icône Avertissement

Dans tous les exemples ci-dessous, les plages de calcul contiennent la ligne #6, qui est ignorée parce qu'elle contient du texte.


Icône Avertissement

Dans tous les calculs ci-dessous, la plage pour le calcul de la moyenne contient la ligne #6, mais elle est ignorée parce qu'elle contient du texte.


Usage simple

=MOYENNE.SI(B2:B6;"<35")

Calcule la moyenne pour les valeurs de la plage B2:B6 qui sont inférieures à 35. Renvoie 19 parce que la seconde ligne ne participe pas au calcul.

=MOYENNE.SI(B2:B6;"<"&MAX(B2:B6))

Calcule la moyenne pour les valeurs de la même plage qui sont inférieure à la valeur maximum de cette plage. Renvoie 19 parce que la valeur la plus grande (la seconde ligne) ne participe pas au calcul.

=MOYENNE.SI(B2:B6;">"&PETITE.VALEUR(B2:B6;1))

Calcule la moyenne pour les valeurs de la même plage qui sont supérieures à la première plus petite valeur de cette plage. Renvoie 25 parce que la première plus petite valeur (la quatrième ligne) ne participe pas au calcul.

Utilisation de plage_moyenne

=MOYENNE.SI(B2:B6;"<35";C2:C6)

Cette fonction recherche quelles valeurs sont inférieures à 35 dans la plage B2:B6 et calcule la moyenne des valeurs correspondantes à partir de la plage C2:C6. Renvoie 145 parce que la seconde ligne ne participe pas au calcul.

=MOYENNE.SI(B2:B6;">"&MIN(B2:B6);C2:C6)

La fonction cherche quelles valeurs de la plage B2:B6 sont supérieurs à la plus petite valeur dans la plage B2:B6 et calcul la moyenne des valeurs correspondantes dans la plage C2:C6. Renvoie 113,3 parce que la quatrième ligne (dans laquelle est la plus petite valeur dans la plage B2:B6) ne participe pas au calcul.

=MOYENNE.SI(B2:B6;"<"&LARGE(B2:B6;2);C2:C6)

La fonction recherche quelles valeurs de la plage B2:B6 sont inférieures à la seconde valeur la plus grand dans la plage B2:B6 et calcul la moyenne des valeurs correspondantes dans la plage C2:C6. Renvoie 180 parce qu'uniquement la quatrième ligne participe au calcul.

Utilisation des expressions régulières

=MOYENNE.SI(A2:A6;"crayon";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 contiennent uniquement le mot “crayon” et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Renvoie 35 parce que uniquement la seconde ligne participe au calcul. La recherche est exécutée dans la plage A2:A6 mais les valeurs sont renvoyées à partir de la plage B2:B6.

=MOYENNE.SI(A2:A6;"crayon.*";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 commence par “crayon” et se finissant avec n'importe quelle quantité d'autres caractères et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Renvoie 27,5 parce que maintenant “crayonner” satisfait aussi la condition et aussi bien la première que la seconde ligne participent au calcul.

=MOYENNE.SI(A2:A6;".*livre.*";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 contiennent “livre” commençant et finissant avec n'importe quelle quantité d'autres caractères et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Renvoie 18,5 parce qu'uniquement les troisièmes et quatrièmes rangs participent au calcul.

Référence à une cellule comme critère

Si vous avez besoin de modifier facilement un critère, vous le spécifiez dans une cellule séparée et utilisez une référence à cette cellule dans la condition de la fonction MOYENNE.SI.

=MOYENNE.SI(A2:A6;".*"&E2&".*";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 contiennent une combinaison de caractères spécifiés dans E2 commençant et finissant par n'importe quelle quantité d'autres caractères et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Si E2=livre, la fonction renvoie 18,5.

=MOYENNE.SI(B2:B6;"<"&E2;C2:C6)

Cette fonction recherche quelles cellules de la plage B2:B6 sont inférieures à la valeur spécifiée dans E2 et calcule la moyenne des valeurs correspondantes à partir de la plage C2:C6. Si E2=35, cette fonction renvoie 145.