Fonctions de base de données
Cette section présente les fonctions utilisées avec des données organisées sur une seule ligne de données pour chaque enregistrement.
La catégorie Base de données peut être confondue avec la base de données intégrée à LibreOffice. Cependant, il n'y a aucune connexion entre une base de données dans LibreOffice et une catégorie Base de données dans LibreOffice Calc.
Données exemples :
Dans les descriptions de fonction, les données suivantes sont utilisées dans certains exemples :
La plage de cellules A1:E10 indique les enfants invités à la fête d'anniversaire de Rémi. Les informations suivantes sont fournies pour chacune des entrées : la colonne A indique le nom de l'invité, et les colonnes B, C, D et E respectivement sa classe, son âge (en années), la distance entre son domicile et l'école (en mètres) et son poids (en kg).
A |
B |
C |
D |
E |
|
1 |
Nom |
Classe |
Âge |
Distance de l'école |
Poids |
2 |
André |
3 |
9 |
150 |
40 |
3 |
Betty |
4 |
10 |
1000 |
42 |
4 |
Charles |
3 |
10 |
300 |
51 |
5 |
Daniel |
5 |
11 |
1200 |
48 |
6 |
Eva |
2 |
8 |
650 |
33 |
7 |
Mohamed |
2 |
7 |
300 |
42 |
8 |
Aminata |
1 |
7 |
200 |
36 |
9 |
Amir |
3 |
9 |
1200 |
44 |
10 |
Irène |
2 |
8 |
1000 |
42 |
11 |
|||||
12 |
|||||
13 |
Nom |
Classe |
Âge |
Distance de l'école |
Poids |
14 |
>600 |
||||
15 |
|||||
16 |
BDNB |
5 |
La formule figurant dans la cellule B16 est =BDNB(A1:E10;0;A13:E14)
Paramètres des fonctions de base de données :
Les paramètres des différentes fonctions de base de données sont définis comme suit :
base_de_données correspond à la plage de cellules définissant la base de données.
champs_base_de_données spécifie la colonne où la fonction opère après que le critère de recherche du premier paramètre est appliqué et que les lignes de données sont sélectionnées. Ce n'est pas relatif au critère de recherche en lui-même. Pour le paramètre champ_base_de_données, vous pouvez saisir une référence à une cellule d'en-tête ou un nombre pour spécifier la colonne dans la zone de base de données, en commençant par 1. Pour référencer une colonne par le nom de l'en-tête de colonne, placez le nom d'en-tête entre guillemets.
critère_de_recherche est la plage de cellule contenant le critère de recherche. Si vous écrivez plusieurs critères dans une ligne, ils sont connectés par ET. Si vous écrivez les critères sur des lignes différentes, ils sont connectés par OU. Les cellules vides dans la plage de critère de recherche seront ignorées.
Choisissez LibreOffice - PréférencesOutils - Options - LibreOffice Calc - Calculer pour définir comment LibreOffice Calc réagit lors de la recherche de saisies identiques.
Voir également la page de Wiki à propos des Sommes et calculs conditionnels.
BDECARTYPE
La fonction BDECARTYPE calcule, à partir d'un échantillon, l'écart type d'une population donnée. À cet effet, elle utilise les nombres d'une colonne de la base de données qui correspondent aux conditions spécifiées. Les enregistrements sont traités en tant qu'échantillons. Ainsi, les enfants cités dans l'exemple sont considérés comme une coupe transversale de l'ensemble des enfants. Notez que, pour qu'un résultat soit représentatif, l'échantillon doit compter au moins un millier d'éléments.
Syntaxe
BDECARTYPE(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour connaître l'écart type du poids de tous les enfants du même âge dans cet exemple, saisissez la formule suivante dans la cellule B16 :
=BDECARTYPE(A1:E10;"Poids";A13:E14)
À la ligne 14, sous Âge, saisissez 7, 8, 9, et ainsi de suite, l'un après l'autre. Le résultat affiché est la déviation standard du poids de tous les enfants de cet âge.
BDECARTYPEP
BDECARTYPEP calcule l'écart type d'une population donnée à partir de toutes les cellules comprises dans une plage de données correspondant aux critères de recherche. Les enregistrements de l'exemple sont considérés comme constituant une population complète.
Syntaxe
BDECARTYPEP(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour obtenir l'écart type des données de poids de tous les enfants du même âge présents à la fête d'anniversaire de Rémi, saisissez la formule suivante dans la cellule B16 :
=BDECARTYPEP(A1:E10;"Poids";A13:E14)
À la ligne 14, sous Âge, saisissez 7, 8, 9, et ainsi de suite, l'un après l'autre. Le résultat affiché est la déviation standard du poids de tous les enfants du même âge dont le poids a été vérifié.
BDLIRE
BDLIRE renvoie le contenu de la cellule référencée dans une base de données correspondant aux critères de recherche spécifiés. En cas d'erreur, la fonction renvoie soit #VALEUR! (si aucune ligne n'est détectée), soit Err502 (si plusieurs cellules sont détectées).
Syntaxe
BDLIRE(base_de_données;champs_base_de_données;critère_de_recherche)
Exemple
Dans l'exemple ci-dessus (faites défiler vers le haut), nous voulons déterminer à quelle classe appartient un enfant, dont le nom a été saisi dans la cellule A14. La formule est saisie dans la cellule B16 et diffère légèrement du précédent exemple parce qu'une seule colonne (un champ de base de données) peut être saisie pour champ_base_de_données. Saisissez la formule suivante :
=BDLIRE(A1:E10;"Classe";A13:E14)
Saisissez le nom Frank en A14 et vous obtenez le résultat 2. Franck est en classe seconde. Saisissez "Âge" au lieu de "Classe" et vous obtiendrez l'âge de Franck.
Ou saisissez la valeur 11dans la cellule C14 seulement et supprimez les autres saisies dans la ligne. Éditez la formule en B16 comme ci-après :
=BDLIRE(A1:E10;"Nom";A13:E14)
Le système demande maintenant le nom au lieu de la classe. La réponse s'affiche de suite. Daniel est le seul enfant âgé de 11 ans.
BDMAX
BDMAX renvoie le contenu maximal d'une cellule (champ) dans une base de données (tous les enregistrements) correspondant aux conditions de recherche spécifiées.
Syntaxe
BDMAX(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour connaître le poids de l'enfant le plus lourd dans chacune des classes de l'exemple ci-dessus, saisissez la formule suivante dans la cellule B16 :
=BDMAX(A1:E10;"Poids";A13:E14)
Sous Classe, saisissez 1, 2, 3, et ainsi de suite, un après l'autre. Après avoir saisi un numéro de classe, le poids de l'enfant le plus lourd dans cette classe apparaît.
BDMIN
BDMIN renvoie le contenu minimal d'une cellule (champ) dans une base de données correspondant aux critères de recherche spécifiés.
Syntaxe
BDMIN(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour connaître le chemin le plus court entre l'école et le domicile des enfants dans chacune des classes de l'exemple ci-dessus, saisissez la formule suivante dans la cellule B16 :
=BDMIN(A1:E10;"Distance de l'école";A13:E14)
Dans la ligne 14, sous Classe, saisissez 1, 2, 3, et ainsi de suite, un après l'autre. La plus courte distance de l'école pour chaque classe apparaît.
BDMOYENNE
BDMOYENNE renvoie la moyenne des valeurs de toutes les cellules (champs) pour toutes les lignes (enregistrements de la base de données) correspondant aux critères de recherche spécifiés.
Syntaxe
BDMOYENNE(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour connaître le poids moyen de tous les enfants du même âge dans l'exemple ci-dessus, saisissez la formule suivante dans la cellule B16 :
=BDMOYENNE(A1:E10;"Poids";A13:E14)
À la ligne 14, sous Âge, saisissez 7, 8, 9, et ainsi de suite, l'un après l'autre. La moyenne du poids de tous les enfants du même âge apparaît.
BDNB
BDNB compte le nombre de lignes (enregistrements) dans une base de données correspondant aux critères de recherche spécifiés. Cette fonction comporte des valeurs numériques.
Syntaxe
BDNB(base_de_données;[champs_base_de_données];critère_de_recherche)
Si l'argument champ_base_de_données est omis, BDNB renvoie le nombre de tous les enregistrements qui satisfont à critère.Pour le paramètre champ_base_de_données, vous pouvez saisir une référence à une cellule d'en-tête ou un nombre pour spécifier la colonne dans la zone de base de données, en commençant par 1. Pour référencer une colonne par le nom de l'en-tête de colonne, placez le nom d'en-tête entre guillemets.
Exemple
Dans l'exemple ci-dessus (faites défiler vers le haut), nous souhaitons savoir combien d'enfants doivent se déplacer de plus de 600 m de l'école. Le résultat sera stocké dans la cellule B16. Saisissez la formule =BDNB(A1:E10;D1;A13:E14) dans B16. L'assistant Fonction vous aide à saisir les plages.
base_de_données est la plage de données devant être évaluée, incluant ses en-têtes : dans ce cas A1:E10. champs_base_de_données spécifie la colonne pour le critère de recherche : dans ce cas, la colonne avec les valeurs de distance numériques. critère_de_recherche est la plage où vous pouvez saisir les paramètres de recherche : dans ce cas A13:E14.
Pour savoir combien d'enfants de la classe seconde ont plus de 7 ans, supprimez l'entrée >600 dans la cellule D14, saisissez2 dans la cellule B14 sous Classe et saisissez >7 dans la cellule C14 à droite. Le résultat est 2. Deux enfants de la classe seconde ont plus de 7 ans. Comme les deux critères sont sur la même ligne, ils sont connectés par ET.
BDNBVAL
BDNBVAL compte le nombre de lignes (enregistrements) dans une base de données correspondant aux conditions de recherche spécifiées. Cette fonction comporte en outre des valeurs numériques et alphanumériques.
Syntaxe
BDNBVAL(base_de_données; [champ_base_de_données]; critère_de_recherche)
Si l'argument champ_base_de_données est omis, BDNBVAM renvoie le nombre de tous les enregistrements qui satisfont à critère.Pour le paramètre champ_base_de_données, vous pouvez saisir une référence à une cellule d'en-tête ou un nombre pour spécifier la colonne dans la zone de base de données, en commençant par 1. Pour référencer une colonne par le nom de l'en-tête de colonne, placez le nom d'en-tête entre guillemets.
Exemple
Dans l'exemple ci-dessus (faites défiler vers le haut), vous pouvez rechercher le nombre d'enfants dont le prénom commence par E ou une lettre équivalente. Éditez la formule en B16 pour lire =BDNBVAL(A1:E10;"Nom";A13:E14). Supprimez l'ancien critère de recherche et saisissez >=E sous Nom dans le champ A14. Le résultat est 5. Si vous supprimez maintenant toutes les valeurs pour Aminata dans la ligne 8, le résultat est modifié à 4. La ligne 8 n'est plus incluse dans le compte parce qu'elle ne contient plus aucune valeur. Le nom Aminata est du texte, pas une valeur. Remarquez que le paramètre champ_base_de_données doit pointer sur une colonne qui peut contenir des valeurs.
BDPRODUIT
BDPRODUIT multiplie toutes les cellules d'une plage de données dont le contenu correspond aux critères de recherche.
Syntaxe
BDPRODUIT(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Cette fonction ne trouve aucune application pratique dans l'exemple de la fête d'anniversaire ci-dessus.
BDSOMME
BDSOMME renvoie le total de toutes les cellules d'un champ de base de données dans toutes les lignes (enregistrements) remplissant les critères de recherche.
Syntaxe
BDSOMME(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour connaître la longueur que représente le cumul des distances parcourues par chaque enfant de la classe 2 invités à l'anniversaire de Rémi pour aller à l'école, saisissez la formule suivante dans la cellule B16 :
=BDSOMME(A1:E10;"Distance de l'école";A13:E14)
Saisissez 2 à la ligne 14 sous Classe. La somme (1950) des distances de l'école de tous les enfants qui sont en seconde classe est affichée.
BDVAR
BDVAR renvoie la variance de toutes les cellules d'un certain champ de base de données de tous les enregistrements satisfaisant les critères de recherche. Les enregistrements de l'exemple sont traités comme un échantillon de données. Pour qu'un résultat soit représentatif, l'échantillon doit compter au moins un milliers d'éléments.
Syntaxe
BDVAR(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour connaître la variance du poids moyen de tous les enfants du même âge dans l'exemple ci-dessus, saisissez la formule suivante dans la cellule B16 :
=BDVAR(A1:E10;"Poids";A13:E14)
À la ligne 14, sous Âge, saisissez 7, 8, 9, et ainsi de suite, l'un après l'autre. Vous verrez s'afficher la variance des valeurs de poids pour tous les enfants de cet âge.
BDVARP
BDVARP calcule la variance de toutes les valeurs contenues dans les cellules d'un certain champ de base de données de tous les enregistrements satisfaisant les critères de recherche. Les enregistrements de l'exemple sont traités comme une population complète.
Syntaxe
BDVARP(base_de_données;champ_base_de_données;critère_de_recherche)
Exemple
Pour obtenir la variance des données de poids de tous les enfants du même âge présents à la fête d'anniversaire de Rémi, saisissez la formule suivante dans la cellule B16 :
=BDVARP(A1:E10;"Poids";A13:E14)
À la ligne 14, sous Âge, saisissez 7, 8, 9, et ainsi de suite, l'un après l'autre. La variance des valeurs de poids pour tous les enfants de cet âge assistant à la fête d'anniversaire de Rémi s'affiche.