AVERAGEIF function

Emandako irizpide bat betetzen dituen barruti bateko gelaxka guztien batezbesteko aritmetikoa ematen du. AVERAGEIF funtzioak proba logikoekin bat datozen emaitza guztiak batzen ditu eta batuketa hori hautatutako balioen kopuruarekin zatitzen du.

Sintaxia

AVERAGEIF(Barrutia; Irizpidea [; BatezbestekoBarrutia ])

Barrutia (derrigorrezko argumentua). Matrize bat, izendatutako barruti baten izena edo zutabe edo errenkada baten etiketa, batez bestekoa egiteko erabiliko diren zenbakiak edo baldintzaren testua dituena.

Irizpidea (derrigorrezko argumentua). Baldintza bat adierazpen-inprimakian edo adierazpena duen gelaxka baten erreferentzia, batezbestekoa kalkulatzeko zein gelaxka erabiliko diren definitzen duena. Adierazpenak testua, zenbakiak, adierazpen erregularrak (kalkulu-aukeretan gaituta badaude) edo komodinak (kalkulu-aukeretan gaituta badaude) izan ditzake.

BatezbestekoBarrutia (aukerakoa). Batez bestekoa kalkulatzeko erabiliko diren balioen barrutia.

Ohar-ikonoa

Kontuan izan BatezbestekoBarrutia ez bada zehazten, Barrutia erabiliko dela bietan, batezbestekoaren kalkuluan eta baldintzaren araberako bilaketan. Batezbesteko_barrutia zehazten bada, Barrutia baldintza-proban soilik erabiliko da, eta BatezbestekoBarrutia batezbestekoaren kalkuluan.
Irizpidea balioak kate-adierazpen bat izan behar du, eta batez ere, Irizpidea komatxoen artean idatzi behar da ("Irizpidea"), funtzioen izenak, gelaxka-erreferentziak edo kateak lotzeko eragilea (&) direnean salbu.


Ohar-ikonoa

Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.


Abisu-ikonoa

Batezbestekoa kalkulatzeko balio-barrutiko gelaxka bat hutsik badago edo testua badu, AVERAGEIF funtzioak gelaxka hori ez ikusi egingo du.
Barruti osoa hutsik badago, testua soilik badu edo baldintza betetzen ez duten barruti-balioak baditu, funtzioak #DIV/0! errorea emango du.


Adibideak

Begiratu honako taula

A

B

C

1

Produktuaren izena

Salmentak

Diru-sarrerak

2

arkatza

20

65

3

luma

35

85

4

koadernoa

20

190

5

liburua

17

180

6

arkatz-kutxa

ez

ez


Abisu-ikonoa

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.


Abisu-ikonoa

Beheko kalkulu guztietan, batezbestekoa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.


Erabilera sinplea

=AVERAGEIF(B2:B6;"<35")

B2:B6 barrutian 35 baino txikiagoak diren balioen batezbestekoa kalkulatzen du. 19 ematen du, bigarren errenkada ez baita kontuan hartzen kalkuluan.

=AVERAGEIF(B2:B6;"<"&MAX(B2:B6))

Barrutiko balio maximoa baino txikiagoak diren balioen batezbestekoa kalkulatzen du. 19 ematen du, baliorik handiena (bigarren errenkada) ez baita kontuan hartzen kalkuluan.

=AVERAGEIF(B2:B6;">"&SMALL(B2:B6;1))

Barrutiko lehen balio minimoa baino handiagoak diren balioen batezbestekoa kalkulatzen du. 25 ematen du, lehen baliorik txikiena (laugarren errenkada) ez baita kontuan hartzen kalkuluan.

BatezbestekoBarrutia erabiltzea

=AVERAGEIF(B2:B6;"<35";C2:C6)

Funtzioak bilatzen du zein balioak diren 35 baino gutxiago B2:B6 barrutian, eta C2:C6 barrutitik dagozkien balioen batezbestekoa kalkulatzen du. 145 itzultzen du, bigarren errenkadak ez duelako parte hartzen kalkuluan.

=AVERAGEIF(B2:B6;">"&MIN(B2:B6);C2:C6)

Funtzioak bilatzen du B2:B6 barrutiko zein balioak diren B2:B6 barrutiko baliorik txikiena baino handiagoak, eta C2:C6 barrutitik dagozkien balioen batezbestekoa kalkulatzen du. 113,3 itzultzen du, laugarren errenkadak (B2:B6 barrutiko baliorik txikiena duenak) ez duelako parte hartzen kalkuluan.

=AVERAGEIF(B2:B6;"<"&LARGE(B2:B6;2);C2:C6)

Funtzioak bilatzen du B2:B6 barrutiko zein balioak diren B2:B6 barrutiko bigarren baliorik handiena baino txikiagoak, eta C2:C6 barrutitik dagozkien balioen batezbestekoa kalkulatzen du. 180 itzultzen du, laugarren errenkadak soilik hartzen duelako parte kalkuluan.

Adierazpen erregularrak erabiltzea

=AVERAGEIF(A2:A6;"pen";B2:B6)

Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten "pen" hitza, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. 35 ematen du, bigarren errenkadek soilik hartuko duelako parte kalkuluan. Bilaketa A2:A6 barrutian egingo da, baina balioak B2:B6 barrutitik itzuliko dira.

=AVERAGEIF(A2:A6;"pen.*";B2:B6)

Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten "pen" hitza, amaieran beste edozein karaktereren edozein kopuru izanda, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. 27,5 ematen du, "pencil" kateak ere baldintza betetzen duelako, eta horregatik, lehen zein bigarren errenkadek hartuko dutelako parte kalkuluan.

=AVERAGEIF(A2:A6;".*book.*";B2:B6)

Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten "liburu" hitza, hasieran eta amaieran beste edozein karaktereren edozein kopuru izanda, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. 18,5 ematen du, hirugarren eta laugarren errenkadek soilik hartuko dutelako parte kalkuluan.

Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu nahi baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili AVERAGEIF funtzioaren baldintzan.

=AVERAGEIF(A2:A6;".*"&E2&".*";B2:B6)

Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten E2 gelaxkan zehaztutako karaktereen konbinazio bat, hasietan eta amaieran beste edozein karaktereren edozein kopuru izanda, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. E2 = liburu bada, funtzioak 18,5 ematen du.

=AVERAGEIF(B2:B6;"<"&E2;C2:C6)

Funtzioak bilatzen du B2:B6 barrutiko zein gelaxkak E2 gelaxkan zehaztutako balioa baino txikiagoa duten, eta barruti horri C2:C6 barrutian dagozkion balioen batezbestekoa kalkulatzen du. E2 = 35 bada, funtzioak 145 ematen du.