Testu-funtzioak

Atal honek testu-funtzioen deskribapenak ditu.

ARABIC

Zenbaki erromatarraren balioa kalkulatzen du. Balio-areak 0 eta 3999 artekoa izan behar du.

Sintaxia

ARABIC (Testua)

Testua: zenbaki erromatarra irudikatzen duen testua.

Adibidea

=ARABIC("MXIV"): 1014 ematen du

=ARABIC("MMII"): 2002 ematen du

ASC

ASC funtzioak zabalera osotik zabalera erdira bihurtzen ditu ASCII eta katakana karaktereak. Testu-kate bat emango du.

Ikusi http://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions bihurketa-taula bat kontsultatzeko.

Sintaxia

ASC (Testua)

Testua: bihurtu beharreko karaktereak dituen testua da.

Ikus halaber JIS funtzioa.

BAHTTEXT

Zenbaki bat Thailandierazko testura bihurtzen du, thailandiar moneta-izenak barne.

Sintaxia

BAHTTEXT(Zenbakia)

Zenbakia: edozein zenbaki da. "Baht" zenbakiaren osoko zatiari eransten zaio, eta "Satang", berriz, zenbakiaren dezimal zatiari.

Adibidea

=BAHTTEXT(12,65): Thailandierako karaktereekin idatzitako kate bat ematen du, hauxe esan nahi duena: "Hamabi Baht eta hirurogeita bost Satang".

BASE

Osoko zenbaki positibo bat bestezenbaki-sistema bateko testu bihurtzen du, adierazitako oinarriaren arabera. 0-9 zenbakiak eta A-Z letrak erabiliko dira.

Sintaxia

BASE(Zenbakia; Erroa; [Gutxieneko luzera])

Zenbakia: bihurtu beharreko osoko zenbaki positiboa.

Erroa: zenbaki sistemaren oinarria adierazten du. 2 eta 36 arteko edozein osoko zenbaki positibo izan daiteke.

Gutxieneko luzera (aukerakoa): sortutako karaktere-sekuentziaren gutxieneko luzera zehazten du. Testua ez bada adierazitako gutxieneko luzerara iristen, zeroak gehituko dira karaktere-katearen ezkerraldean.

Adibidea

=BASE(17;10;4): 0017 ematen du sistema hamartarrean.

=BASE(17;2): 10001 ematen du sistema bitarrean.

=BASE(255;16;4): 00FF ematen du sistema hamaseitarrean.

CHAR

Zenbaki bat karaktere bihurtzen du, uneko kode-taularen arabera. Zenbakia bi digituko nahiz hiru digituko osoko zenbakia izan daiteke.

Sintaxia

CHAR(zenbakia)

Zenbakia: karakterearen kode-balioa adierazten duen 1 eta 255 arteko zenbakia.

Adibidea

=CHAR(100): d karakterea ematen du.

="abc" & CHAR(10) & "def" funtzioak lerro-jauziaren karakterea sartzen du katean.

CLEAN

Inprimatzekoak ez diren karaktereak kendu egingo dira katetik.

Sintaxia

CLEAN(testua)

Testua: inprimatzekoak ez diren karaktereak kendu behar zaizkion testua.

CODE

Testu-kate bateko lehen karakterearen zenbakizko kodea ematen du.

Sintaxia

CODE(Testua)

Testua: lehen karakterearen kodea zehaztu behar zaion testua da.

Adibidea

=CODE("Hieronymus") funtzioak 72 ematen du; =CODE("hieroglyphic") funtzioak 104 ematen du.

CONCATENATE

Hainbat testu-kate konbinatzen ditu kate bakar batean.

Sintaxia

CONCATENATE("Testua 1";...;"Testua 30")

Testua 1; Testua 2; ... : kate batean konbinatzeko testu-pasarteak (30 gehienez).

Adibidea

=CONCATENATE("Egun";"on";"Arregi. ";"andrea") funtzioak honako hau ematen du: Egun on Arregi andrea.

DECIMAL

Zenbaki-sistema bateko testua osoko zenbaki positibo bihurtzen du, oinarri gisa ezarritako erroaren arabera. Erroak 2 eta 36 bitartekoa izan behar du. Zuriuneei eta tabulazioei ez ikusi egingo zaie. Testua eremuak ez ditu maiuskulak eta minuskulak bereizten.

Erroa 16 bada, ezkerrean x edo X edo 0x edo 0X gehituko da, eta erantsitako h edo H ez dira kontuan hartuko. Erroa 2 bada, erantsitako b edo B ez dira kontuan hartuko. Zenbaki-sistemari ez dagozkion bestelako karaktereek errorea emango dute.

Sintaxia

DECIMAL(testua; erroa)

Testua: bihurtu beharreko testua. Zenbaki hamaseitar bat, A1 adibidez, eta A1 gelaxkaren erreferentzia desberdintzeko, zenbakia komatxo artean idatzi behar duzu. Adibidez, "A1" edo "FACE".

Erroa: zenbaki sistemaren oinarria adierazten du. 2 eta 36 arteko edozein osoko zenbaki positibo izan daiteke.

Adibidea

=DECIMAL("17";10): 17 ematen du.

=DECIMAL("FACE";16): 64206 ematen du.

=DECIMAL("0101";2): 5 ematen du.

DOLLAR

Zenbaki bat moneta-formatuko kopuru batera bihurtzen du, zehaztutako dezimal kopuruaren arabera biribilduta. Balioa eremuan, sartu monetara bihurtu beharreko zenbakia. Nahiz izanez gero, dezimal kopurua sar dezakezu Dezimalak eremuan. Ez bada baliorik zehazten, moneta-formatuko zenbaki guztiak bi dezimalekin bistaratuko dira.

Sistemaren ezarpenetan ezartzen da moneta-formatua.

Sintaxia

DOLLAR(balioa; dezimalak)

Balioa: zenbaki bat da, zenbaki bat duen gelaxka baten erreferentzia edo zenbaki bat ematen duen formula.

Dezimalak leku dezimalen aukerako kopurua da.

Adibidea

=DOLLAR(255): $255,00 ematen du.

=DOLLAR(367,456;2): $367,46 ematen du. Erabili uneko ezarpen lokalari dagokion dezimalen bereizlea.

EXACT

Bi testu-kate konparatzen ditu, eta TRUE ematen du berdinak baldin badira. Funtzio honek maiuskulak eta minuskulak bereizten ditu.

Sintaxia

EXACT(testua_1;testua_2)

Testua1: konparatzeko lehen testua.

Testua2: konparatzeko bigarren testua.

Adibidea

=EXACT("microsystems";"Microsystems") FALSE itzultzen du.

FIND

Testu-kate batek beste kate baten barruan duen kokapena itzultzen du. Bilaketa non hasi ere defini dezakezu. Bilaketa-terminoa zenbaki bat edo edozein karaktere-kate izan daiteke. Bilaketak maiuskulak eta minuskulak bereizten ditu.

Sintaxia

FIND("BilatzeTestua"; "Testua"; Kokagunea)

Bilatutako_testua: bilatu nahi den testua.

Testua: bilaketa zein testutan egingo den zehazten du.

Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.

Adibidea

=FIND(76;998877665544): 6 ematen du.

FIXED

Zenbakia testu gisa itzultzen du dezimalen eta aukerako milako bereizleen kopuru jakin batekin.

Sintaxia

FIXED(zenbakia; dezimalak; milakoen bereizlerik ez)

Zenbakia: formatua eman beharreko zenbakia.

Dezimalak: bistaratuko den dezimal kopurua.

Milakoen bereizlerik ez (aukerakoa): milakoen bereizlea erabiliko den edo ez zehazten du. Parametroa 0 ez den zenbaki bat bada, milakoen bereizlea kendu egingo da. Parametroa 0 bada edo zehazten ez bada, zure uneko ezarpen lokalaren milakoen bereizleak bistaratuko dira.

Adibidea

=FIXED(1234567,89;3): 1.234.567,890 ematen du testu gisa.

=FIXED(1234567,89;3;1): 1234567,890 ematen du testu-kate gisa.

JIS

JIS funtzioak zabalera erditik zabalera osora bihurtzen ditu ASCII eta katakana karaktereak. Testu-kate bat emango du.

Ikusi http://wiki.documentfoundation.org/Calc/Features/JIS_and_ASC_functions bihurketa-taula bat kontsultatzeko.

Sintaxia

JIS("testua")

Testua: bihurtu beharreko karaktereak dituen testua da.

Ikus halaber ASC funtzioa.

LEFT

Testu-kateko lehen karakterea edo karaktereak ematen ditu.

Sintaxia

LEFT("testua"; zenbakia)

Testua: hasierako hitz partzialak zehazteko testua.

Zenbakia (aukerakoa): hasierako testuaren karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibidea

=LEFT("irteera";3): “irt” ematen du.

LEFTB

DBCS testu-kateko lehen karakterea ematen ditu.

Sintaxia

LEFTB("Testua"; byte_kopurua)

Testua: hasierako hitz partzialak zehazteko testua.

Byte_kopurua (aukerakoa): LEFTB funtzioak aterako dituen karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibideak

LEFTB("中国";1): " " ematen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

LEFTB("中国";2): "中" ematen du (2 bytek DBCS karaktere oso bat osatzen dute).

LEFTB("中国";3): "中 " ematen du (3 bytek DBCS karaktere bat eta erdi osatzen dute; itzulitako azken karakterea zuriune bat izango da).

LEFTB("中国";4): "中国" ematen du (4 bytek bi DBCS karaktere oso egiten dute).

LEFTB("office";3): "off" ematen du (DBCS ez diren 3 karaktere, bakoitza 1 bytekoa).

LEN

Kate baten luzera ematen du, zuriuneak barne.

Sintaxia

LEN("testua")

Testua: luzera zehaztu beharreko testua da.

Adibidea

=LEN("Egun zoragarria"): 15 ematen du.

=LEN(12345,67): 8 ematen du.

LENB

Byte bikoitzeko karaktere multzoko (DBCS) hizkuntzetarako, karaktereak testu-kate batean ordezkatzeko erabiltzen den byte kopurua ematen du.

Sintaxia

LENB("Testua")

Testua: luzera zehaztu beharreko testua da.

Adibideak

LENB("中"): 2 ematen du (2 byte dituen DBCS karaktere bat).

LENB("中国"): 4 ematen du (bakoitzak 2 byte dituen 2 DBCS karaktere).

LENB("office"): 6 ematen du (bakoitzak byte 1 duen eta DBCS ez diren 6 karaktere).

=LENB("Egun zoragarria"): 15 ematen du.

=LENB(12345,67): 8 ematen du.

LOWER

Testu-kateko letra maiuskula guztiak minuskula bihurtzen ditu.

Sintaxia

LOWER("testua")

Testua: bihurtu beharreko testua.

Adibidea

=LOWER("Eguzkia"): eguzkia ematen du.

MID

Testu baten testu-katea ematen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.

Sintaxia

MID("testua"; hasiera; kopurua)

Testua: erauzi beharreko karaktereak dituen testua da.

Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokalekua.

Zenbakia (aukerakoa): testu zatiko karaktere kopurua zehazten du.

Adibidea

=MID("office";2;2): ff ematen du.

MIDB

DBCS testu baten testu-katea itzultzen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.

Sintaxia

MIDB("Testua"; Hasiera; Byte_kopurua)

Testua: erauzi beharreko karaktereak dituen testua da.

Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokalekua.

Byte_kopurua: MIDBk testutik emango duen karaktere kopurua, bytetan, zehazten du.

Adibideak

MIDB("中国";1;0): "" ematen du (0 byte kate huts bat da beti).

MIDB("中国";1;1): " " ematen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

MIDB("中国";1;2): "中" ematen du (2 bytek DBCS karaktere oso bat osatzen dute).

MIDB("中国";1;3): "中 " ematen du (3 byte DBCS karaktere bat eta erdi dira; azken byteak zuriune bat itzultzen du).

MIDB("中国";1;4): "中国" ematen du (4 bytek bi DBCS karaktere oso egiten dute).

MIDB("中国";2;1): " " ematen du (2 byte-kokapena ez dago karaktere baten hasieran DBCS kate batean; zuriune bat itzultzen da).

MIDB("中国";2;2): " " ematen du (2 byte-kokapenak DBCS kateko lehen karakterearen azken erdira apuntatzen du; eskatutako 2 byte-ak, beraz, lehen karakterearen azken erdia eta bigarren karakterearen lehen erdia dira; beraz, 2 zuriune-karaktere itzultzen dira).

MIDB("中国";2;3): " 国" ematen du (2 byte-kokapena ez dago karaktere baten hasieran DBCS kate batean; zuriune bat itzultzen da 2 byte-kokapenerako).

MIDB("中国";3;1): " " ematen du (3 byte-kokapena DBCS kate bateko karaktere baten hasieran dago, baina byte 1 DBCS karaktere baten erdia besterik ez da, eta beraz, zuriune-karaktere bat itzultzen da).

MIDB("中国";3;2): "国" ematen du (3 byte-kokapena DBCS kate bateko karaktere baten hasieran dago, eta 2 byte-k DBCS karaktere bat osatzen dute).

MIDB("office";2;3): "ffi" ematen du (2 byte-kokapena DBCS ez den kate bateko karaktere baten hasieran dago, eta 3 byte, DBCS ez den kate batean, 3 karaktere dira).

PROPER

Testu-kate bateko hitz guztietako lehen letra maiuskulaz ipintzen du.

Sintaxia

PROPER("testua")

Testua: bihurtu beharreko testua.

Adibidea

=PROPER("open office"): Open Office ematen du.

REPLACE

Testu-kate baten zati bat ordezten du beste testu-kate batekin. Funtzio hau karaktereak nahiz zenbakiak ordezteko erabil daiteke (zenbakiak normalean testu bihurtzen dira). Funtzioaren emaitza testu gisa bistaratzen da beti. Gero kalkuluak egin nahi badituzu testu bihurtu den zenbaki batekin, berriro zenbaki bihurtu beharko duzu VALUE funtzioarekin.

Zenbakiak dituen edozein testu komatxoen artean idatzi behar da, ez baduzu nahi zenbaki gisa interpretatu eta automatikoki testu bihurtzea.

Sintaxia

REPLACE("Testua"; Kokagunea; Luzera; "TestuBerria")

Testua: zati bat ordeztuko zaion testua.

Kokagunea: testuaren barruan ordezpen-prozesua hasiko den tokia.

Luzera: Testuan ordeztu beharreko karaktere kopurua.

Testu berria: Testua ordeztuko duen testua.

Adibidea

=REPLACE("1234567";1;1;"444"): "444234567" ematen du. 1 kokalekuko karaktere bat Testu berri osoak ordeztuko du.

REPT

Karaktere-kate bat zehaztutako kopia kopuruarekin errepikatuko du.

Sintaxia

REPT("testua"; kopurua)

Testua: errepikatu beharreko testua.

Kopurua: errepikapenen kopurua.

Emaitza 255 karakterekoa izango da gehienez.

Adibidea

=REPT("Egun on";2): Egun onEgun on ematen du.

RIGHT

Testu baten azkenengo karakterea edo karaktereak itzultzen du.

Sintaxia

RIGHT(testua; kopurua)

Testua: eskuineko zatia zehaztu behar zaion testua.

Kopurua (aukerakoa): testuaren eskuineko zatiko karaktere kopurua.

Adibidea

=RIGHT("Eguzkia";2): ia ematen du.

RIGHTB

Byte bikoitzeko karaktere multzoak (DBCS) dituen testu bateko azken karakterea edo karaktereak ematen ditu.

Sintaxia

RIGHTB("Testua"; Byte_kopurua)

Testua: eskuineko zatia zehaztu behar zaion testua.

Byte_kopurua (aukerakoa): RIGHTB funtzioak erauziko duen karaktere kopurua zehazten du, bytetan oinarrituta.

Adibideak

RIGHTB("中国";1) " " ematen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

RIGHTB("中国";2): "国" ematen du (2 byte-k DBCS karaktere oso bat osatzen dute).

RIGHTB("中国";3): " 国" ematen du (3 byte-k DBCS karaktere baten erdi bat eta DBCS karaktere oso bat osatzen dute; zuriune bat itzultzen da lehen erdirako).

RIGHTB("中国";4): "中国" ematen du (4 byte-k bi DBCS karaktere oso egiten dute).

RIGHTB("office";3): "ice" ematen du (DBCS ez diren 3 karaktere, bakoitza 1 byte-koa).

ROMAN

Zenbaki bat zenbaki erromatar bihurtzen du. Balioak 0 eta 3999 bitartekoa izan behar du; moduek 0 eta 4 bitarteko osoko zenbakiak izan behar dute.

Sintaxia

ROMAN(Zenbakia; Modua)

Zenbakia: zenbaki erromatar bihurtu beharreko zenbakia.

Modua (aukerakoa): sinplifikazio-maila adierazten du. Balioa zenbat eta handiagoa izan, orduan eta handiagoa izango da zenbaki erromatarraren sinplifikazioa.

Adibidea

=ROMAN(999): CMXCIX ematen du

=ROMAN(999;0): CMXCIX ematen du

=ROMAN (999;1): LMVLIV ematen du

=ROMAN(999;2): XMIX ematen du

=ROMAN(999;3): VMIV ematen du

=ROMAN(999;4): IM ematen du

SEARCH

Testu-segmentu batek karaktere-kate batean duen kokalekua ematen du. Nahi izanez gero, bilaketa non hasiko den zehaztu dezakezu. Bilaketa-testua zenbaki bat edo edozein karaktere-sekuentzia izan daiteke. Bilaketak ez ditu maiuskulak eta minuskulak bereizten.

Sintaxia

SEARCH("BilatutakoTestua"; "Testua"; Kokagunea)

Bilatutako_testua: bilatu beharreko testua.

Testua: bilaketa zein testutan egingo den zehazten du.

Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.

Adibidea

=SEARCH(54;998877665544): 10 ematen du.

SUBSTITUTE

Kate bateko testu zaharra testu berriarekin ordezten du.

Sintaxia

SUBSTITUTE(testua; bilatutako_testua; testu berria; agerraldia)

Testua: testu-segmentuak trukatu behar zaizkion testua.

Bilatutako_testua: (hainbat aldiz) ordeztu beharreko testu-segmentua.

Testu berria: testu-segmentua ordeztuko duen testua.

Agerraldia (aukerakoa): bilatutako testuaren zein agerraldi ordeztu behar den zehazten du. Parametro hau agertzen ez bada, agerraldi guztiak ordeztuko dira.

Adibidea

=SUBSTITUTE("123123123";"3";"abc"): 12abc12abc12abc ematen du.

=SUBSTITUTE("123123123";"3";"abc";2): 12312abc123 ematen du.

T

Funtzio honek helburuko testua itzultzen du, edo testu-kate huts bat, helburua testua ez bada.

Sintaxia

T(balioa)

Balioa testu-kate bat da, edo testu-kate bati egiten dio erreferentzia; T-k testu-atea itzultzen du, edo, bestela, testu-kate huts bat.

Adibidea

=T(12345): kate huts bat ematen du.

=T("12345"): 12345 ematen du.

TEXT

Zenbaki bat testu bihurtzen du, emandako formatuaren arabera.

Sintaxia

TEXT(zenbakia; formatua)

Zenbakia: bihurtu beharreko zenbakizko balioa.

Formatua: formatua definitzen duen testua. Gelaxka-formatuan ezarritako hizkuntzaren araberako dezimal eta milakoen bereizleak erabili.

Adibidea

=TEXT(12,34567;"###.##"): 12,35 testua ematen du

=TEXT(12,34567;"000,00"): 012,35 testua ematen du

TRIM

Kate bateko zuriuneak kentzen ditu, zuriune-karaktere bakar bat utziz hitzen artean.

Sintaxia

TRIM("Testua")

Testua zuriuneak kenduko zaizkion testua da.

Adibidea

=TRIM(" kaixo mundua "): 'kaixo mundua' ematen du, aurreko eta atzeko zuriuneak kenduta eta hitzen artean zuriune bakarrak utzita.

UNICHAR

Kode-zenbaki bat Unicode karaktere edota letra bihurtzen du.

Sintaxia

UNICHAR(zenbakia)

Adibidea

=UNICHAR(169): © copyright-karakterea ematen du.

UNICODE

Testu-kate bateko lehen Unicode karakterearen zenbakizko kodea ematen du.

Sintaxia

UNICODE("Testua")

Adibidea

=UNICODE("©"): copyright-karakterearen 169 Unicode zenbakia ematen du.

UPPER

Testua eremuan zehaztutako karaktere-katea maiuskuletara bihurtzen du.

Sintaxia

UPPER(testua)

Testua: maiuskuletara bihurtu nahi dituzun minuskulak.

Adibidea

=UPPER("Egun on"): EGUN ON ematen du.

VALUE

Testu-kate bat zenbaki bihurtzen du.

Sintaxia

DATEVALUE("Testua")

Testua: zenbaki bihurtu beharreko testua.

Adibidea

=VALUE("4321"): 4321 ematen du.