Tühjade lahtrite käsitlemine

Selle tarkvara vanemates versioonides sunniti tühjade lahtrite väärtuseks mõnes kontekstis arv 0 ja mõnes tühi string, v.a otsese võrdlemise puhul, kus =A1=0 ning =A1="" andsid mõlemad tulemuseks TÕENE, kui A1 oli tühi. Nüüd tühjust pärandatakse kuni kasutamiseni, nii et nii =VLOOKUP(...)=0 kui ka =VLOOKUP(...)="" annavad tulemuseks TÕENE, kui päringu tulemuseks oli tühja lahtri tagastamine.

Lihtviide tühjale lahtrile tagastab ka nüüd väärtuse 0, kuid see ei pea tingimata olema arvu vormingus, seetõttu töötavad ka võrdlused viitava lahtriga nii, nagu eeldatakse.

Järgnevates näidetes sisaldab A1 arvu, B1 on tühi ja C1 sisaldab viidet lahtrile B1:

A1: 1 B1: <tühi> C1: =B1 (kuvab 0)

=B1=0 => TÕENE

=B1="" => TÕENE

=C1=0 => TÕENE

=C1="" => TÕENE (varem oli VÄÄR)

=ISNUMBER(B1) => VÄÄR

=ISNUMBER(C1) => VÄÄR (varem oli TÕENE)

=ISNUMBER(VLOOKUP(1;A1:C1;2)) => VÄÄR (B1)

=ISNUMBER(VLOOKUP(1;A1:C1;3)) => VÄÄR (C1, varem oli TÕENE)

=ISTEXT(B1) => VÄÄR

=ISTEXT(C1) => VÄÄR

=ISTEXT(VLOOKUP(1;A1:C1;2)) => VÄÄR (B1, varem oli TÕENE)

=ISTEXT(VLOOKUP(1;A1:C1;3)) => VÄÄR (C1)

=ISBLANK(B1) => TÕENE

=ISBLANK(C1) => VÄÄR

=ISBLANK(VLOOKUP(1;A1:C1;2)) => TÕENE (B1, varem oli VÄÄR)

=ISBLANK(VLOOKUP(1;A1:C1;3)) => VÄÄR (C1)

A1: <tühi>

B1: =A1 => kuvab 0, kuid tegelikult on see lihtsalt viide tühjale lahtrile

=ISNUMBER(A1) => VÄÄR

=ISTEXT(A1) => VÄÄR

=A1=0 => TÕENE

=A1="" => TÕENE

=ISNUMBER(B1) => FALSE (Microsoft Excel: TRUE)

=ISTEXT(B1) => VÄÄR

=B1=0 => TÕENE

=B1="" => TRUE (Microsoft Excel: FALSE)

C1: =VLOOKUP(...) with empty cell result => displays empty (Microsoft Excel: displays 0)

=ISNUMBER(VLOOKUP(...)) => VÄÄR

=ISTEXT(VLOOKUP(...)) => VÄÄR

=ISNUMBER(C1) => FALSE (Microsoft Excel: TRUE)

=ISTEXT(C1) => VÄÄR