Función PROMEDIO.SI

Devuelve la media aritmética de todas las celdas en un intervalo que satisfaga una condición dada. La función PROMEDIO.SI suma todos los resultados que coincidan con la prueba lógica y divide esta suma por la cantidad de valores seleccionados.

Sintaxis

PROMEDIO.SI(Intervalo; Criterio [; Intervalo_promedio])

Intervalo (argumento obligatorio): una matriz, un nombre de intervalo o una etiqueta de columna o fila que contiene los números por promediar o el texto de la condición.

Criterio – argumento requerido. Una condición en el formulario de expresión o en la celda de referencia con una expresión que define que celda debería ser utilizada para calcular la media. La expresión puede contener textos, números, expresiones regulares (si están activadas en las opciones de cálculo) o comodines (si están activados en las opciones de cálculo).

Intervalo_promedio (opcional): el intervalo de valores para calcular la media.

Icono de nota

Observe que si no se especifica Intervalo_promedio, se usará Intervalo para el cálculo del promedio y para el criterio de búsqueda. Si se especifica Intervalo_promedio, Intervalo se utilizará únicamente en la prueba de la condición e Intervalo_promedio en el cálculo del promedio.
El Criterio debe ser una expresión de cadena: en específico, Criterio debe entrecomillarse ("Criterio"), exceptuando los nombres de las funciones, las referencias de celdas y las concatenaciones de cadenas con el operador &.


Icono de nota

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).


Icono de advertencia

Si en el intervalo de valores para calcular la media hay una celda vacía o que contiene texto, la función PROMEDIO.SI la ignorará.
Si todo el intervalo está vacío, contiene solo texto o ninguno de los valores satisfacen la condición (o cualquier combinación de estas circunstancias), la función devolverá el error #¡DIV/0!


Ejemplos

Tenga en cuenta la tabla siguiente

A

B

C

1

Nombre de producto

Ventas

Ingresos

2

lápiz

20

65

3

pluma

35

85

4

cuaderno

20

190

5

libro

17

180

6

estuche

no

no


Icono de advertencia

En todos los ejemplos siguientes, los intervalos utilizados para el cálculo incluyen la fila n.º 6, pero se ignorará debido a que contiene texto.


Icono de advertencia

En todos los cálculos siguientes, los intervalos para el cálculo del promedio contienen la fila n.º 6, pero se ignorará debido a que contiene texto.


Uso simple

=PROMEDIO.SI(B2:B6;"<35")

Calcula el promedio de los valores en el intervalo B2:B6 que sean menores que 35. Devuelve 19 porque la segunda fila no se toma en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;"<"&MAX(B2:B6))

Calcula el promedio de valores del mismo intervalo que son menores que el valor máximo del intervalo. Devuelve 19 porque el valor mayor (la segunda fila) no se tiene en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;">"&K.ESIMO.MENOR(B2:B6;1))

Calcula el promedio de valores del mismo intervalo que son mayores que el primer valor menor del intervalo. Devuelve 25 porque el valor menor (la cuarta fila) no se tiene en cuenta para realizar el cálculo.

Utilizar Intervalo_promedio

=PROMEDIO.SI(B2:B6;"<35";C2:C6)

La función busca qué valores son menores que 35 en el intervalo B2:B6 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Devuelve 145 porque la segunda fila no se tiene en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;">"&MIN(B2:B6);C2:C6)

La función busca qué valores del intervalo B2:B6 son mayores que el valor mínimo del intervalo B2:B6 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Devuelve 113,3 porque la cuarta fila (que contiene el valor mínimo en el intervalo B2:B6) no se tiene en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;"<"&K.ESIMO.MAYOR(B2:B6;2);C2:C6)

La función busca qué valores del intervalo B2:B6 son menores que el segundo valor mayor en el intervalo B2:B6 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Devuelve 180 porque en el cálculo solamente se tiene en cuenta la cuarta fila.

Utilizar expresiones regulares

=PROMEDIO.SI(A2:A6;"pan";B2:B6)

La función busca qué celdas del intervalo A2:A6 contienen solo la palabra «pan» y calcula el promedio de los valores correspondientes del intervalo B2:B6. Devuelve 35 porque solo se tiene en cuenta la segunda fila para realizar el cálculo. La búsqueda se lleva a cabo en el intervalo A2:A6 pero se devuelven los valores del intervalo B2:B6.

=PROMEDIO.SI(A2:A6;"pan.*";B2:B6)

La función busca qué celdas del intervalo A2:A6 comienzan por «pan» terminando con cualquier cantidad de otros caracteres y calcula el promedio de los valores correspondientes del intervalo B2:B6. Devuelve 27,5 porque ahora «panadero» satisface la condición y ambas filas, la primera y la segunda, se tienen en cuenta para realizar el cálculo.

=PROMEDIO.SI(A2:A6;".*libro.*";B2:B6)

La función busca qué celdas del intervalo A2:A6 contienen el término «libro» antecedido y sucedido por cualquier cantidad de caracteres distintos, y calcula el promedio de los valores correspondientes del intervalo B2:B6. Devuelve 18,5 porque solo las filas tercera y cuarta se tienen en cuenta para realizar el cálculo.

Referencia a una celda como criterio

Si se necesita cambiar un criterio fácilmente, se puede especificar en una celda separada y utilizar una referencia a esa celda en la condición de la función PROMEDIO.SI.

=PROMEDIO.SI(A2:A6;".*"&E2&".*";B2:B6)

La función busca qué celdas del intervalo A2:A6 contienen una combinación de caracteres especificada en E2 antecedida y sucedida por cualquier cantidad de caracteres distintos, y calcula el promedio de los valores correspondientes del intervalo B2:B6. Si E2 = libro, la función devuelve 18,5.

=PROMEDIO.SI(B2:B6;"<"&E2;C2:C6)

La función busca qué celdas del intervalo B2:B6 son menores que el valor especificado en E2 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Si E2 = 35, la función devuelve 145.