Funciones financieras, tercera parte
CUPON.DIAS
Devuelve el número de días del período actual de interés que incluye la fecha de liquidación.
Sintaxis
CUPON.DIAS(Liquidación; Vencimiento; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en la que vence el título (expira).
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
Ejemplo
Un títuloes comprado en 25-1-2001; la fecha de vencimiento es el 15-11-2001. Los intereses se pagarán cada medio año (frecuencia es 2). Con un cálculo diario (base 3), ¿cuántos días hay en el período de interés en el que caiga la fecha de liquidación?
=CUPON.DIAS("2001-01-25"; "2001-11-15"; 2; 3) devuelve 181.
CUPON.DIAS.L1
Devuelve el número de días desde el primer día de pago de intereses de un título hasta la fecha de liquidación.
Sintaxis
CUPON.DIAS.L1(Liquidación; Vencimiento; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
Frecuencia es la cantidad de pagos de interés al año (1, 2 o 4).
Ejemplo
Se compra un título el 25-1-2001; la fecha de vencimiento es el 15-11-2001. Los intereses se pagarán cada medio año (frecuencia es 2). Con un cálculo diario (base 3) ¿Cuántos días existen en este?
=CUPON.DIAS.L1("2001-01-25"; "2001-11-15"; 2; 3) devuelve 71.
CUPON.DIAS.L2
Devuelve el número de días desde la fecha de liquidación hasta la siguiente fecha de interés.
Sintaxis
CUPON.DIAS.L2(Liquidación; Vencimiento; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
Ejemplo
Se compra un título el 25-1-2001; la fecha de vencimiento es el 15-11-2001. Los intereses se pagarán cada medio año (frecuencia es 2). Con un cálculo diario (base 3), ¿cuántos días quedan hasta el próximo pago de intereses?
=CUPON.DIAS.L2("2001-01-25"; "2001-11-15"; 2; 3) devuelve 110.
CUPON.FECHA.L1
Devuelve la fecha de interés anterior a la fecha de liquidación. Asigna al resultado formato de fecha.
Sintaxis
CUPON.FECHA.L1(Liquidación; Vencimiento; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
Frecuencia es la cantidad de pagos de interés al año (1, 2 o 4).
Ejemplo
Se compra un título el 25-1-2001; la fecha de vencimiento es el 15-11-2001. Los intereses se pagarán cada medio año (frecuencia es 2). Con un cálculo diario (base 3), ¿cuál fue la fecha de interés antes de la compra?
=CUPON.FECHA.L1("2001-01-25"; "2001-11-15"; 2; 3) devuelve 2000-15-11.
CUPON.FECHA.L2
Devuelve la fecha del primer interés después de la fecha de liquidación. Asigna al resultado formato de fecha.
Sintaxis
CUPON.FECHA.L2(Liquidación; Vencimiento; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
Ejemplo
Se compra un título el 25-1-2001; la fecha de vencimiento es el 15-11-2001. Los intereses se pagan cada medio año (frecuencia es 2). Con un cálculo diario (Base 3), ¿cuándo es el próximo plazo?
=CUPON.FECHA.L2("2001-01-25"; "2001-11-15"; 2; 3) devuelve 2001-05-15.
CUPON.NUM
Devuelve el número de cupones (pagos de interés) entre la fecha de liquidación y la fecha de vencimiento.
Sintaxis
CUPON.NUM(Liquidación; Vencimiento; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
Frecuencia es la cantidad de pagos de interés al año (1, 2 o 4).
Ejemplo
Se compra un título el 25-1-2001; la fecha de vencimiento es el 15-11-2001. Los intereses se pagarán cada medio año (frecuencia es 2). Con un cálculo diario (base 3) ¿Cuántos plazos de intereses existen?
=CUPON.NUM("2001-01-25"; "2001-11-15"; 2; 3) devuelve 2.
DVS
Devuelve la depreciación de un activo en un período especifico o parcial según el método geométrico decreciente.
Sintaxis
DVS(Costo; Salvamento; Vida; S; Fin; Factor; SinCambio)
Costo es el valor inicial de un activo.
Salvamento es el valor de un activo al final de la amortización.
Vida es la duración de la depreciación del activo.
S es el comienzo de la depreciación. Deberá consignarse en la misma unidad de fecha que la duración.
Final es el finalde la depreciación.
Factor (opcional) es el factor de depreciación. Factor = 2 es el doble de la tasa de depreciación.
SinCambio es un parámetro opcional. SinCambio = 0 (predeterminado) indica que se cambiará a una depreciación lineal; SinCambio = 1 evita que se efectúe el cambio.
En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» se pueden omitir siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.
Ejemplo
A cuánto asciende la amortización aritméticamente degresiva en plazos dobles para un espacio de tiempo periódico determinado si el valor de adquisición es 35000 unidades monetarias y el valor residual, 7500 unidades monetarias. El tiempo de uso es de tres años. Se calcula la amortización del período 10 al 20.
=DVS(35000;7500;36;10;20;2) = 8603,80 unidades de moneda. La depreciación durante el período comprendido entre el 10º y el 20º período es de 8603,80 unidades monetarias.
INT.RENDIMIENTO
Calcula el tipo de interés que resulta del beneficio (rendimiento) generado por una inversión.
Sintaxis
INT.RENDIMIENTO(P; VA; VF)
P es el número de períodos necesarios para el cálculo de la tasa de interés.
VA es el valor actual. El valor en efectivo es el depósito de efectivo o el valor en efectivo actual de un subsidio en beneficio. Como es un valor de depósito debe ser introducido un valor positivo; el depósito no debe ser 0 o <0.
VF determina lo que se desea como el valor en efectivo del depósito.
Ejemplo
Para cuatro períodos (años) y un valor efectivo de 7 500 unidades monetarias, la tasa de interés del rendimiento se calculará si el valor futuro es de 10 000 unidades monetarias.
=INT.RENDIMIENTO(4;7500;10000) = 7,46 %
El interés debe ascender al 7,46 % para que las 7500 unidades monetarias se conviertan en 10000.
NPER
Calcula el número de períodos de pago de una inversión con pagos periodicos constantes y una tasa de interés constante.
Sintaxis
NPER(Tasa; Pago; VA; VF; Tipo)
Tasa define el tipo de interés periódico.
Pago es la renta constante pagada en cada período.
VA es el valor actual (en efectivo) en una secuencia de pagos.
VF (opcional) es el valor futuro, el cual se alcanza al final del último periodo.
Tipo (opcional) es la fecha de vencimiento del pago, al comienzo o al final del período.
En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» se pueden omitir siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.
Ejemplo
¿Cuántos períodos comprende un espacio de tiempo para el pago si el tipo de interés es del 6%, el pago periódico 153,75 unidades monetarias y el valor efectivo actual, 2600 unidades monetarias?
=NPER(6%;153,75;2600) = -12,02. El período de pago cubre 12,02 períodos.
PAGOINT
Calcula la amortización periódica de una inversión con pagos regulares y un interés constante.
Sintaxis
PAGOINT(Tasa; Periodo; NPer; VP; VF; Tipo)
Tasa define el tipo de interés periódico.
Periodo indica el periodo para el que se calcula el interés compuesto. Periodo=NPER cuando se calcula el interés compuesto del último periodo.
NPer es el número total de períodos, durante los cuales la anualidad se paga.
VA es el valor actual en efectivo en una secuencia de pagos.
VF (opcional) es el valor deseado (valor futuro) al final de los períodos.
Tipo define el vencimiento de los pagos periódicos.
Ejemplo
¿Cuál es el interés del quinto período (año) si el interés constante se define en el 5% y el valor efectivo es de 15000 unidades monetarias? El espacio de tiempo del pago periódico es de siete años.
=PAGOINT(5%;5;7;15000) = -352,97 unidades monetarias. El interés compuesto durante el quinto período (año) es 352,97 unidades monetarias.
PRECIO.PER.IRREGULAR.1
Calcula el precio de 100 unidades monetarias por valor de un título, si la fecha del primer interés es irregular.
Sintaxis
PRECIO.PER.IRREGULAR.1(Liquidación; Vencimiento; Emisión; PrimerCupón; Tasa; Rendimiento; Redención; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha cuando el título vence (expira).
Emisión es la fecha de emisión del título.
PrimerCupón es la fecha del primer interés del título.
Tasa es la tasa anual de interés.
Rendimeinto es la ganancia anual del título.
Redención es el valor de redención del título por cada 100 unidades monetarias de valor nominal.
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
PRECIO.PER.IRREGULAR.2
Calcula el precio de 100 unidades monetarias por valor de un título, si la fecha del último interés es irregular.
Sintaxis
PRECIO.PER.IRREGULAR.2(Liquidación; Vencimiento; ÚltimoInterés; Tasa; Rendimiento; Redención; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
PrimerInterés es la fecha del primer interés del título.
Tasa es la tasa anual de interés.
Rendimeinto es la ganancia anual del título.
Redención es el valor de redención del título por cada 100 unidades monetarias de valor nominal.
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
Ejemplo
Fecha de liquidación: 7 de febrero de 1999, fecha de vencimiento: 15 de junio de 1999, último plazo de interés: 15 de octubre de 1998. Tasa de interés: 3,75 por ciento, rédito: 4,05 por ciento, valor de devolución: 100 unidades de moneda, frecuencia de los pagos: cada medio año = 2, base: = 0
El precio por 100 unidades monetarias por el valor del título, cuando tiene una última fecha de interés irregular, se calcula como sigue:
=PRECIO.PER.IRREGULAR.1("1999-02-07";"1999-06-15";"1998-10-15"; 0,0375; 0,0405;100;2;0) devuelve 99,87829.
RENDTO.PER.IRREGULAR.1
Calcula el rendimiento de un título si la fecha del primer interés es irregular.
Sintaxis
RENDTO.PER.IRREGULAR.1(Liquidación; Vencimiento; Emisión; PrimerCupón; Tasa; Precio; Redención; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
Emisión es la fecha de emisión del título.
PrimerInterés es la fecha del primer interés del título.
Tasa es la tasa anual de interés.
Precio es el precio del título.
Redención es el valor de redención del título por cada 100 unidades monetarias de valor nominal.
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
RENDTO.PER.IRREGULAR.2
Calcula el rendimiento de un título si la fecha del último interés es irregular.
Sintaxis
RENDTO.PER.IRREGULAR.2(Liquidación; Vencimiento; ÚltimoInteres; Tasa; Precio; Redención; Frecuencia; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en que vence el título (expira).
PrimerInterés es la fecha del primer interés del título.
Tasa es la tasa anual de interés.
Precio es el precio del título.
Redención es el valor de redención del título por cada 100 unidades monetarias de valor nominal.
Frecuencia es el número de pagos de interés por año (1, 2 o 4).
Ejemplo
Fecha de liquidación: 20 de abril de 1999, fecha de vencimiento: 15 de junio de 1999, último plazo de intereses: 15 de octubre de 1998. Tasa de interés: 3,75 por ciento, cotización: 99,875 unidades monetarias, valor de devolución: 100 unidades monetarias, frecuencia de los pagos: semestral = 2, base: = 0
El rédito del valor que tiene un último plazo de interés irregular se calcula de esta forma:
=RENDTO.PER.IRREGULAR.2("1999-04-20";"1999-06-15"; "1998-10-15"; 0,0375; 99,875; 100;2;0) devuelve 0,044873 o 4,4873%.
TASA
Calcula el tipo de interés constante de una anualidad.
Sintaxis
TASA(NPer; Pago; VA; VF; Tipo; Valor estimado)
NPer es el número total de períodos durante los cuales se efectúan los pagos (período de pago).
Pago es el pago constante (anualidad) pagado durante cada período.
VA es el valor efectivo en la serie de pagos.
VF (opcional) define el valor futuro, una vez finalizados los períodos de pago.
Tipo (opcional) es la fecha de vencimiento de los periódicos de pago, al comienzo o al final de un período.
Valor estimado (opcional) determina el valor estimado del intereses del cálculo interactivo.
En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» se pueden omitir siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.
Ejemplo
Cuál es el tipo de interés constante para un espacio de tiempo de 3 períodos si se pagan regularmente 10 unidades monetarias y el valor efectivo actual es de 900 unidades monetarias
=TASA(3;-10;900) = −75,63 %. La tasa de interés es, por tanto, del 75,63 %.
TASA.INT
Calcula la tasa de interés anual que resulta cuando se compra un título (u otro artículo) a un valor de inversión y se vende a un valor de amortización. No se paga interés.
Sintaxis
TASA.INT(Liquidación; Vencimiento; Inversión; Redención; Base)
Liquidación es la fecha de compra del título.
Vencimiento es la fecha en la que se vende el título.
Inversión es el precio de compra.
Redención es el precio de venta.
Ejemplo
Se compra un cuadro el 15-01-1990 por 1 millón y se vende el 05-05-2002 por 2 millones. La base es diariamente calculada (Base = 3). ¿A cuánto asciende la tasa de interés anual?
=TASA.INT("1990-01-15"; "2002-05-05"; 1000000; 2000000; 3) devuelve 8,12%.
TIR.NO.PER
Calcula el interés interno de una serie de pagos no periódicos. El cálculo se basa en un esquema de 365 días al año, y omite los años bisiestos.
Si los pagos ocurren en intervalos regulares, utilice la función TIR.
Sintaxis
TIR.NO.PER(Valores; Fechas; Valor_estimado)
Valores y Fechas se refieren a una serie de pagos y la serie de valores de fecha asociados. El primer par de fechas define el inicio del plan de pago. Todos los demás valores de fecha deben ser posteriores, pero no necesitan estar en un orden. La serie de valores debe contener al menos un valor negativo y uno positivo (ingresos y depósitos).
Valor estimado (opcional) es un valor estimado que puede ser ingresado para la tasa interna de retorno. El valor predeterminado es 10%.
Ejemplo
Calcular el tipo de interés interno para los siguientes cinco pagos:
A |
B |
C |
|
1 |
2001-01-01 |
10000 |
Recibido |
2 |
2001-01-02 |
2000 |
Depositado |
3 |
2001-03-15 |
2500 |
|
4 |
2001-05-12 |
5000 |
|
5 |
2001-08-10 |
1000 |
=TIR.NO.PER(B1:B5; A1:A5; 0,1) devuelve 0,1828.
VF
Calcula el valor final de una inversión con pagos constantes y a un tipo de interés constante (valor futuro).
Sintaxis
VF(Tasa; NPer; Pago; VA; Tipo)
Tasa define el tipo de interés periódico.
NPer es la cantidad total de periodos de pagos (periodo de pago).
Pago es la renta pagada regularmente por periodo.
VA (opcional) es el valor en efectivo (actual) de una inversión.
Tipo (opcional) define si el pago se debe al principio o al final de un período.
En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» se pueden omitir siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.
Ejemplo
¿Cuál es el valor final de una inversión si el tipo de interés es del 4% y el pago se efectúa en cuotas periódicas de 750 unidades monetarias durante dos años? La inversión tiene un valor actual de 2500 unidades monetarias.
=VF(4%;2;750;2500) = -4234.00 unidades monetarias. El valor al final de la inversión es 4234,00 unidades monetarias.
VF.PLAN
Calcula el valor acumulado del capital inicial para una serie de tipos de interés de variación periódica.
Sintaxis
VF.PLAN(Principal; Plan)
Principal es la capital inicial.
Plan es una serie de tasas de intereses, por ejemplo, como un rango H3:H5 o como una Lista (ver ejemplo).
Ejemplo
Se invirtieron 1000 unidades monetarias por un periodo de tres años. Los intereses anuales son 3%, 4% y 5%. ¿Cuál es el valor tras tres años?
=VF.PLAN(1000;{0,03;0,04;0,05}) devuelve 1124,76.
VNA.NO.PER
Calcula el valor del capital (valor neto actual) de una serie de pagos que ocurren en fechas distintas. El cálculo se basa en un esquema de 365 días por año, omitiendo los años bisiestos.
Si los pagos ocurren en intervalos regulares, utilice la función VNA.
Sintaxis
VNA.NO.PER(Tasa; Valores; Fechas)
Tasa es la tasa interna de retorno para los pagos.
Valores y Fechas se refieren a una serie de pagos y la serie de valores de fecha asociados. El primer par de fechas define el inicio del plan de pago. Todos los demás valores de fecha deben ser posteriores, pero no necesitan estar en un orden. La serie de valores debe contener al menos un valor negativo y uno positivo (ingresos y depósitos).
Ejemplo
Calcular el valor del capital para los cinco pagos nombrados más arriba con un interés interno del 6%:
=VNA.NO.PER(0,06;B1:B5;A1:A5) devuelve 323,02.