ARBEITSTAG.INTL

Das Ergebnis ist eine Datumszahl, welche als Datum formatiert werden kann. Sie bekommen das Datum des Tages, welcher eine bestimmte Anzahl an Arbeitstagen vom Startdatum entfernt (vorher oder später) liegt, angezeigt. Es existieren Optionen, um Tage fürs Wochenende und freie Tage festzulegen. Der optionale Parameter (oder eine Zeichenkette) Wochenende kann verwendet werden, um die Tage des Wochenendes festzulegen (beziehungsweise die Nichtarbeitstage einer Woche). Sie können außerdem, ebenfalls optional, eine Liste mit freien Tagen festlegen. Die Tage fürs Wochenende und die freien Tage werden nicht als Arbeitstage gezählt.

Syntax

ARBEITSTAG.INTL(Startdatum; Tage; Wochenende; Freie Tage)

Anfangsdatum ist das Datum, ab dem die Berechnung ausgeführt wird. Wenn das Anfangsdatum ein Arbeitstag ist, wird der Tag in die Berechnung einbezogen. Dies ist erforderlich.

Tage ist die Anzahl von Arbeitstagen. Ein positiver Wert steht für ein Ergebnis nach dem Anfangsdatum, ein negativer Wert steht für ein Ergebnis vor dem Anfangsdatum.

Wochenende ist ein optionaler Parameter – eine Zahl oder eine Zeichenkette, um die Tage der Woche festzulegen, welche Wochenende sind und nicht als Arbeitstage berücksichtigt werden. Wochenende ist eine Zahl oder Zeichenkette, die festlegt, welche Tage Wochenende sind. Zahlwerte für Wochenende legen folgende Tage als Wochenende fest:

Zahl 1 bis 7 für zweitägige Wochenenden und 11 bis 17 für eintägige Wochenenden.

Zahl	Wochenende
1 oder ohne	Samstag und Sonntag
2	Sonntag und Montag
3	Montag und Dienstag
4	Dienstag und Mittwoch
5	Mittwoch und Donnerstag
6	Donnerstag und Freitag
7	Freitag und Samstag
11	Nur Sonntag
12	Nur Montag
13	Nur Dienstag
14	Nur Mittwoch
15	Nur Donnerstag
16	Nur Freitag
17	Nur Samstag

Zeichenketten für Wochenende stellen eine andere Art dar, um die wöchentlichen Nichtarbeitstage festzulegen. Sie muss sieben (7) Zeichen haben – Nullen (0) für Arbeitstage und Einsen (1) für Nichtarbeitstage. Jedes Zeichen stellt einen Tag der Woche dar, beginnend mit Montag. Nur 1 und 0 sind zulässig. "1111111" ist eine ungültige Zeichenkette und sollte nicht verwendet werden. Beispielsweise legt "0000011" Samstag und Sonntag als Nichtarbeitstage fest.

Freie Tage ist eine optionale Liste mit Daten, welche als Nichtarbeitstage zählen. Die Liste kann als Zellbereich angegeben werden.

Beispiel

Welches Datum liegt 20 Arbeitstage nach dem 13. Dezember 2016? Geben Sie das Startdatum in C3 und die Anzahl an Arbeitstagen in D3 ein.

Der Parameter (Zahl) Wochenende kann leer bleiben oder als 1 festgelegt werden, um den Standard für Wochenende (Nichtarbeitstage) zu erhalten – Samstag und Sonntag.

Die Zellen F3 bis J3 enthalten fünf (5) freie Tage für Weihnachten und Neujahr im Datumsformat: 24. Dezember 2016; 25. Dezember 2016; 26. Dezember 2016; 31. Dezember 2016; 1. Januar 2017.

=ARBEITSTAG.INTL(C3;D3;;F3:J3) ergibt 11. Januar 2017 in der Ergebniszelle, beispielsweise D6 (verwenden Sie ein Datumsformat für diese Zelle).

Um Freitag und Samstag als Tage fürs Wochenende festzulegen, verwenden Sie den Parameter 7.

=ARBEITSTAG.INTL(C3;D3;7;F3:J3) ergibt 15. Januar 2017 mit Parameter 7 für Wochenende.

Um Sonntag als einzigen Tag fürs Wochenende festzulegen, verwenden Sie den Parameter 11.

=ARBEITSTAG.INTL(C3;D3;11;F3:J3) ergibt 9. Januar 2017.

Alternativ verwenden Sie die Zeichenkette "0000001" für Sonntag als einzigen Tag fürs Wochenende.

=ARBEITSTAG.INTL(C3;D3;"0000001";F3:J3) ergibt 9. Januar 2017.

Die Funktion kann ohne die beiden optionalen Parameter – Wochenende und Freie Tage – verwendet werden, indem sie leer gelassen werden:

=ARBEITSTAG.INTL(C3;D3) ergibt 10. Januar 2017.

NETTOARBEITSTAGE

NETTOARBEITSTAGE.INTL

ARBEITSTAG

Datumsfunktionen