Funktion MAXWENNS
Gibt das Maximum der Werte der Zellen in einem Bereich zurück, die mehrere Bedingungen in mehreren Bereichen erfüllen.
Syntax
MAXWENNS(Funktionsbereich; Bereich 1; Kriterium 1 [ ; Bereich 2; Kriterium 2 [;...]]))
Funktionsbereich (erforderlich). Ist ein Zellbereich, der Name eines benannten Bereichs oder eine Spalten-/Zeilenüberschrift, der/die Werte enthält, für die das Maximum berechnet wird.
Funktionsbereich und Bereich 1, Bereich 2, ... müssen alle dieselbe Größe haben, andernfalls gibt die Funktion den Fehlerwert Err:502 - ungültiges Argument - zurück.
Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.
Die Funktion kann bis zu 255 Argumente verarbeiten, bedeutet, dass Sie 127 Bereiche und Bedingungen angeben können.
Wenn die Zelle WAHR enthält, wird sie wie 1 behandelt, wenn FALSCH, wie 0 (Null).
Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)
Beispiele
Betrachten Sie folgende Tabelle
|
A |
B |
C |
|
|
1 |
Produktname |
Absatz |
Einnahmen |
|
2 |
Buntstift |
20 |
65 |
|
3 |
Stift |
35 |
85 |
|
4 |
Schulbuch |
20 |
190 |
|
5 |
Buch |
17 |
180 |
|
6 |
Buntstift-Set |
nicht |
nicht |
In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.
Einfache Benutzung
=MAXWENNS(B2:B6;B2:B6;"<35")
Berechnet das Maximum der Werte im Bereich B2:B6, die größer oder gleich 20 sind. Ergibt 35, da die fünfte Zeile die Bedingung nicht erfüllt.
=MAXWENNS(C2:C6;B2:B6;">=20";C2:C6;"<90")
Berechnen das Maximum der Werte des Bereichs C2:C6, welche kleiner als 90 sind und deren zugehörige Zellen des Bereichs B2:B6 Werte größer oder gleich 20 enthalten. Gibt 85 zurück, da die vierte und fünfte Zeile mindestens eine Bedingung nicht erfüllen.
Verwendung mit regulären Ausdrücken und verschachtelten Funktionen
=MAXWENNS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))
Berechnet das Maximum der Werte im Bereich C2:C6, die allen Werten im Bereich B2:B6, außer dem Minimum und dem Maximum, entsprechen. Ergibt 190, da nur die vierte Zeile die Bedingungen erfüllt.
=MAXWENNS(C2:C6;A2:A6;".*stift";B2:B6;"<="&MAX(B2:B6))
Berechnet das Maximum der Werte im Bereich C2:C6, deren zugehörige Zellen des Bereichs A2:A6 auf "stift" enden und mit Ausnahme der Zellen des Bereichs B2:B6, die deren Maximum enthalten. Gibt 85 zurück, da nur die dritte Zeile alle Bedingungen erfüllt.
Bezüge zu einer Zelle mit einer Bedingung
Falls Sie eine Bedingung einfach ändern möchten, können Sie diese in einer eigenen Zelle festlegen und einen Bezug zu dieser Zelle in der Bedingung der Funktion MAXWENNS verwenden. Beispielsweise kann die oben stehende Formel wie folgt umgeschrieben werden:
=MAXWENNS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))
Wenn E2 = "stift" ist, ergibt die Funktion 65, da der Bezug zur Zelle derem Inhalt entspricht.
