Datenbankfunktionen
In diesem Abschnitt werden Funktionen für Daten beschrieben, die in einem Datensatz als einzelne Datenzeile angeordnet sind.
Die Kategorie Datenbank kann mit einer in LibreOffice integrierten Datenbank verwechselt werden. Es besteht jedoch keine Verbindung zwischen einer Datenbank in LibreOffice und der Kategorie Datenbank in LibreOffice Calc.
Beispieldaten:
In einigen der Funktionsbeschreibungen werden die folgenden Daten als Beispiel herangezogen:
Der Bereich A1:E10 enthält die zu Tims Geburtstagsfeier eingeladenen Kinder. Jeder Eintrag umfasst die folgenden Informationen: In Spalte A sehen Sie den Namen, in Spalte B die Klasse, dann das Alter in Jahren, die Entfernung zur Schule in Metern und das Gewicht in Kilogramm.
A |
B |
C |
D |
E |
|
1 |
Name |
Klasse |
Alter |
Schulweg |
Gewicht |
2 |
Andreas |
3 |
9 |
150 |
40 |
3 |
Bettina |
4 |
10 |
1000 |
42 |
4 |
Charles |
3 |
10 |
300 |
51 |
5 |
Daniel |
5 |
11 |
1200 |
48 |
6 |
Eva |
2 |
8 |
650 |
33 |
7 |
Frank |
2 |
7 |
300 |
42 |
8 |
Greta |
1 |
7 |
200 |
36 |
9 |
Harry |
3 |
9 |
1200 |
44 |
10 |
Irene |
2 |
8 |
1000 |
42 |
11 |
|||||
12 |
|||||
13 |
Name |
Klasse |
Alter |
Schulweg |
Gewicht |
14 |
>600 |
||||
15 |
|||||
16 |
DBANZAHL |
5 |
Die Formel in Zelle B16 lautet =DBANZAHL(A1:E10;D1;A13:E14)
Parameter für Datenbankfunktionen:
Diese Parameterdefinitionen gelten für alle Datenbankfunktionen:
Datenbank ist der Zellbereich, der die Datenbank definiert.
Datenbankfeld gibt die Spalte an, wo die Funktion ausgeführt wird, nachdem die Suchkriterien des ersten Parameters angewandt und die Datenzeilen ausgewählt wurden. Datenbankfeld steht nicht mit den Suchkriterien selbst in Beziehung. Für den Parameter Datenbankfeld können Sie einen Bezug auf eine Titelzelle oder eine Zahl eingeben, um die Spalte beginnend mit 1 innerhalb des Datenbankbereichs festzulegen. Um mit dem exakten Spaltenkopfnamen auf eine Spalte zu verweisen, setzen Sie den Spaltenkopf in Anführungszeichen.
Suchkriterien ist der Zellbereich, der Suchkriterien enthält. Wenn Sie mehrere Kriterien in eine Zeile eintragen, werden diese durch UND verbunden. Wenn Sie die Kriterien in verschiedene Zeilen eintragen, werden diese durch ODER verbunden. Leere Zellen im Suchkriterienbereich werden ignoriert.
Wählen Sie LibreOffice - EinstellungenExtras - Optionen... - LibreOffice Calc - Berechnen um zu festzulegen, wie LibreOffice Calc beim Suchen mit identischen Einträgen verfahren soll.
Siehe auch die Wiki-Seite zu Bedingtes Zählen und Summieren.
DBANZAHL
DBANZAHL ermittelt in einer Datenbank die Anzahl der Zeilen (Datensätze), die mit den eingegebenen Suchkriterien übereinstimmen und numerische Werte in der Spalte Datenbankfeld enthalten.
Syntax
DBANZAHL(Datenbank; [Datenbankfeld]; Suchkriterien)
Wenn das Argument Datenbankfeld weggelassen wird, ergibt DBANZAHL die Anzahl aller Datensätze, die den Kriterien genügen. Für den Parameter Datenbankfeld können Sie einen Bezug auf eine Titelzelle oder eine Zahl eingeben, um die Spalte beginnend mit 1 innerhalb des Datenbankbereichs festzulegen. Um mit dem exakten Spaltenkopfnamen auf eine Spalte zu verweisen, setzen Sie den Spaltenkopf in Anführungszeichen.
Beispiel
Im obigen Beispiel soll festgestellt werden, wie viele Kinder einen Schulweg zurücklegen müssen, der länger als 600 Meter ist. Das Ergebnis wird in Zelle B16 gespeichert: Setzen Sie den Cursor in die Zelle B16. Geben Sie die Formel =DBANZAHL(A1:E10;D1;A13:E14) in B16 ein. Der Funktions-Assistent hilft Ihnen beim Eingeben der Bereiche.
Datenbank ist der auszuwertende Datenbereich, einschließlich der Spaltenköpfe: in diesem Falle A1:E10. Datenbankfeld gibt die Spalte für die Suchkriterien an: in diesem Fall die Spalte mit den numerischen Abstandswerten. Suchkriterien ist der Bereich, wo Sie Suchparameter eingeben können: in diesem Falle A13:E14.
Um festzustellen, wie viele Kinder in der zweiten Klasse älter als 7 Jahre sind, löschen Sie den Eintrag >600 in Zelle D14, und geben Sie dann in Zelle B14 unter Klasse 2 und rechts in Zelle C14 >7 ein. Das Ergebnis ist 2. Zwei Kinder in der zweiten Klasse sind älter als 7 Jahre. Da beide Kriterien in der gleichen Zeile stehen, sind sie durch UND verbunden.
DBANZAHL2
DBANZAHL2 ermittelt in einer Datenbank die Anzahl der Zeilen (Datensätze), die mit den eingegebenen Suchkriterien übereinstimmen und die numerische oder alphanumerische Werte enthalten.
Syntax
DBANZAHL2(Datenbank; [Datenbankfeld]; Suchkriterien)
Wenn das Argument Datenbankfeld weggelassen wird, ergibt DBANZAHL2 die Anzahl aller Datensätze, die den Kriterien genügen. Für den Parameter Datenbankfeld können Sie einen Bezug auf eine Titelzelle oder eine Zahl eingeben, um die Spalte beginnend mit 1 innerhalb des Datenbankbereichs festzulegen. Um mit dem exakten Spaltenkopfnamen auf eine Spalte zu verweisen, setzen Sie den Spaltenkopf in Anführungszeichen.
Beispiel
Im obigen Beispiel können Sie ermitteln, wie viele Kinder einen Namen haben, der mit E oder einem nachfolgenden Buchstaben beginnt. Ändern Sie die Formel in B16 in =DBANZAHL2(A1:E10;"Name";A13:E14). Löschen Sie die alten Suchkriterien, und geben Sie unter Name im Feld A14 >=E ein. Das Ergebnis ist 5. Wenn Sie nun alle Zahlenwerte für Greta in Zeile 8 löschen, wird das Ergebnis in 4 geändert. Zeile 8 wird nicht mehr in die Berechnung einbezogen, da sie keine Werte enthält. Der Name Greta ist Text und kein Wert. Beachten Sie, dass der Parameter Datenbankfeld auf eine Spalte verweisen muss, in der Werte enthalten sein können.
DBAUSZUG
DBAUSZUG ergibt den Inhalt der einen Zelle in einer Datenbank, auf die durch die eingegebenen Suchkriterien verwiesen wird. Im Fehlerfall liefert die Funktion entweder #WERT!, wenn keine Zeile gefunden wird, oder Err502, wenn mehr als eine Zelle gefunden wird.
Syntax
DBAUSZUG(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Im obigen Beispiel soll festgestellt werden, in welche Klasse ein Kind geht, dessen Name in die Zelle A14 eingegeben wurde. Die Formel wird in Zelle B16 eingegeben und unterscheidet sich leicht von den vorhergehenden Beispielen, da nur eine Spalte (ein Datenbankfeld) für Datenbankfeld eingegeben werden kann. Geben Sie folgende Formel ein:
=DBAUSZUG(A1:E10;"Klasse";A13:E14)
Wenn Sie in A14 den Namen Frank eingeben, wird als Ergebnis 2 angezeigt. Frank ist ein Schüler der zweiten Klasse. Wenn Sie "Alter" anstelle von "Klasse" eingeben, wird das Alter von Frank angezeigt.
Sie können auch nur den Wert 11 in Zelle C14 eingeben und die anderen Einträge in der Zeile löschen. Bearbeiten Sie die Formel in B16 wie folgt:
=DBAUSZUG(A1:E10;"Name";A13:E14)
Statt nach der Klasse wird jetzt also nach dem Namen gefragt. Sie sehen auch gleich die Antwort: Daniel ist das einzige Kind, das 11 Jahre alt ist.
DBMAX
DBMAX ergibt den Maximalwert einer Zelle (eines Datenfeldes) in einer Datenbank (aller Datensätzen), die den eingegebenen Suchkriterien entsprechen.
Syntax
DBMAX(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Um festzustellen, wie viel das schwerste Kind jeder Klasse wiegt, geben Sie die folgende Formel in B16 ein:
=DBMAX(A1:E10;"Gewicht";A13:E14)
Geben Sie unter Klasse nacheinander 1, 2, 3 und so weiter ein. Nach der Eingabe einer Zahl für eine Klasse wird das Gewicht des schwersten Kindes in der betreffenden Klasse angezeigt.
DBMIN
DBMIN ergibt den Minimalwert einer Zellen (eines Datenfeldes) in einer Datenbank, die den eingegebenen Suchkriterien entsprechen.
Syntax
DBMIN(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Zur Ermittlung des kürzesten Schulwegs unter den Kindern jeder Klasse geben Sie die folgende Formel in B16 ein:
=DBMIN(A1:E10;"Schulweg";A13:E14)
Geben Sie in Zeile 14 unter Klasse nacheinander 1, 2, 3 und so weiter ein. Der kürzeste Schulweg für jede Klasse wird angezeigt.
DBMITTELWERT
DBMITTELWERT ergibt den Mittelwert aller Zellen (der Datenfelder) in allen Zeilen (Datensätzen), die den eingegebenen Suchkriterien entsprechen.
Syntax
DBMITTELWERT(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Um das Durchschnittsgewicht aller Kinder desselben Alters zu ermitteln, geben Sie die folgende Formel in B16 ein:
=DBMITTELWERT(A1:E10;"Gewicht";A13:E14)
Geben Sie in Zeile 14 unter Alter nacheinander 7, 8, 9 und so weiter ein. Das Durchschnittsgewicht aller Kinder desselben Alters wird angezeigt.
DBPRODUKT
DBPRODUKT multipliziert alle Zellen eines Datenbankfeldes in einer Datenbank in allen Zeilen (Datensätzen), die den eingegebenen Suchkriterien entsprechen.
Syntax
DBPRODUKT(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Für unser Geburtstagsbeispiel von oben gibt es keine sinnvolle Anwendung dieser Funktion.
DBSTDABW
DBSTDABW berechnet die Standardabweichung einer Grundgesamtheit, basierend auf einer Stichprobe. Hierzu verwendet die Funktion die Zahlen einer Datenbankspalte, die mit den gegebenen Bedingungen übereinstimmen. Die Datensätze werden wie eine Datenprobe behandelt. Das bedeutet, dass die Kinder im Beispiel einen Durchschnitt aller Kinder darstellen. Beachten Sie hierbei, dass mit Stichproben von weniger als tausend Einzeldaten kein repräsentatives Ergebnis erzielt werden kann.
Syntax
DBSTDABW(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Um die Standardabweichung des Gewichts aller Kinder desselben Alters zu ermitteln, geben Sie die folgende Formel in B16 ein:
=DBSTDABW(A1:E10;"Gewicht";A13:E14)
Geben Sie in Zeile 14 unter Alter nacheinander 7, 8, 9 und so weiter ein. Das angezeigte Ergebnis ist die Standardabweichung des Gewichts aller Kinder dieses Alters.
DBSTDABWN
DBSTDABWN berechnet die Standardabweichung einer Grundgesamtheit auf Grundlage von allen Zellen eines Datenbereichs, die mit dem Suchkriterium übereinstimmen. Die Datensätze dieses Beispiels werden als Grundgesamtheit verwendet.
Syntax
DBSTDABWN(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Um die Standardabweichung des Gewichts aller gleichaltrigen Kinder zu ermitteln, die zu Tims Geburtstagsfeier eingeladen sind, geben Sie die folgende Formel in B16 ein:
=DBSTDABWN(A1:E10;"Gewicht";A13:E14)
Geben Sie in Zeile 14 unter Alter nacheinander 7, 8, 9 und so weiter ein. Das Ergebnis ist die Standardabweichung des Gewichts für alle gleichaltrigen Kinder, deren Gewicht überprüft wurde.
DBSUMME
DBSUMME ergibt die Summe aller Zellen eines Datenbankfeldes in allen Zeilen (Datensätzen), die den eingegebenen Suchkriterien entsprechen.
Syntax
DBSUMME(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Geben Sie die folgende Formel in B16 ein, um die Gesamtlänge der Schulwege alle Kinder der zweiten Klasse zu ermitteln:
=DBSUMME(A1:E10;"Schulweg";A13:E14)
Geben Sie in Zeile 14 unter Klasse 2 ein. Die Summe (1950) der Schulwegstrecken aller Kinder der zweiten Klasse wird angezeigt.
DBVARIANZ
DBVARIANZ ergibt die Varianz aller Zellen eines Datenbankfelds in allen Datensätzen, die den eingegebenen Suchkriterium entsprechen. Die Datensätze des Beispiels werden wie eine Datenprobe behandelt. Beachten Sie hierbei, dass mit Stichproben von weniger als tausend Einzeldaten kein repräsentatives Ergebnis erzielt werden kann.
Syntax
DBVARIANZ(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Um die Varianz des Gewichts aller Kinder desselben Alters zu ermitteln, geben Sie die folgende Formel in B16 ein:
=DBVARIANZ(A1:E10;"Gewicht";A13:E14)
Geben Sie in Zeile 14 unter Alter nacheinander 7, 8, 9 und so weiter ein. Das angezeigte Ergebnis ist die Varianz der Gewichtswerte für alle Kinder dieses Alters.
DBVARIANZEN
DBVARIANZEN liefert die Varianz aller Zellwerte eines Datenbankfelds in allen Datensätzen, die mit dem angegebenen Suchkriterium übereinstimmen. Die Datensätze dieses Beispiels werden als Grundgesamtheit verwendet.
Syntax
DBVARIANZEN(Datenbank; Datenbankfeld; Suchkriterien)
Beispiel
Wie hoch ist die Varianz des Gewichts aller gleichaltrigen Kinder auf Joes Geburtstagsparty? Geben Sie in B16 diese Formel ein:
=DBVARIANZEN(A1:E10;"Gewicht";A13:E14)
Geben Sie in Zeile 14 unter Alter nacheinander 7, 8, 9 und so weiter ein. Die Varianz der Gewichtswerte für alle Kinder dieses Alters, die zur Geburtstagsfeier von Joe kommen, wird angezeigt.