Gestió de cel·les buides

A les versions anteriors del programari, les cel·les buides es forçaven a un 0 numèric en alguns contextos i a una cadena buida en d'altres, excepte en comparació directa, on =A1=0 i =A1="" donaven CERT si A1 era buida. Ara, les cel·les continuen estant buides fins que s'utilitzen, així que =CONSULTAV(...)=0 i =CONSULTAV(...)="" donen CERT si la consulta retorna una cel·la buida.

Una referència simple a una cel·la buida es mostra amb un 0 numèric però no és necessàriament del tipus numèric; passa el mateix amb les comparacions al treball de la cel·la de referència.

En els exemples següents, A1 conté un nombre, B1 és buida i C1 conté la referència a B1:

A1: 1 B1: <Empty> C1: =B1 (mostra 0)

=B1=0 => CERT

=B1="" => CERT

=C1=0 => CERT

=C1="" => CERT (anteriorment era FALS)

=ESNOMBRE(B1) => FALS

=ESNOMBRE(C1) => FALS (anteriorment era CERT)

=ESNOMBRE(CONSULTAV(1;A1:C1;2)) => FALS (B1)

=ESNOMBRE(CONSULTAV(1;A1:C1;3)) => FALS (C1, anteriorment era CERT)

=ESTEXT(B1) => FALS

=ESTEXT(C1) => FALS

=ESTEXT(CONSULTAV(1;A1:C1;2)) => FALS (B1, anteriorment era CERT)

=ESTEXT(CONSULTAV(1;A1:C1;3)) => FALS (C1)

=ESBUIDA(B1) => CERT

=ESBUIDA(C1) => FALS

=ESBUIDA(CONSULTAV(1;A1:C1;2)) => CERT (B1, anteriorment era FALS)

=ESBUIDA(CONSULTAV(1;A1:C1;3)) => FALS (C1)

A1: <Empty>

B1: =A1 => mostra 0, però només és una referència a una cel·la buida

=ESNOMBRE(A1) => FALS

=ESTEXT(A1) => FALS

=A1=0 => CERT

=A1="" => CERT

=ESNOMBRE(B1) => FALS (Microsoft Excel: CERT)

=ESTEXT(B1) => FALS

=B1=0 => CERT

=B1="" => CERT (Microsoft Excel: FALS)

C1: =CONSULTAV(...) amb resultat d'una cel·la buida => es mostra buida (Microsoft Excel: mostra 0)

=ESNOMBRE(CONSULTAV(...)) => FALS

=ESTEXT(CONSULTAV(...)) => FALS

=ESNOMBRE(C1) => FALS (Microsoft Excel: CERT)

=ESTEXT(C1) => FALS