Funcions d'informació

Aquesta categoria conté les funcions d'informació.

Per a accedir a aquesta ordre...

Insereix - Funció - Categoria Informació


Les dades de la taula següent serveixen com a base d'alguns exemples en les descripcions de funció:

C

D

2

x valor

y valor

3

-5

-3

4

-2

0

5

-1

1

6

0

3

7

2

4

8

4

6

9

6

8


ACTUAL

Aquesta funció retorna el resultat fins al moment de l'avaluació de la fórmula de què forma part (és a dir, el resultat fins al moment en què s'ha fet l'avaluació). El seu ús principal, juntament amb la funció ESTIL(), és aplicar els estils seleccionats a una cel·la en funció dels continguts de la cel·la.

Sintaxi

ACTUAL()

Exemple

=1+2+ACTUAL()

L'exemple retorna 6. La fórmula es calcula d'esquerra a dreta: 1 + 2 igual a 3, i dóna el resultat fins avui quan troba ACTUAL(); per tant, ACTUAL() retorna 3, que s'afegeix al primer 3 i dóna 6.

=A2+B2+ESTIL(SI(ACTUAL()>10;”Vermell”;”Per defecte”))

L'exemple retorna A2 + B2 (ESTIL retorna 0 aquí). Si la suma és superior a 10, s'aplica l'estil Vermell a la cel·la. Vegeu la funció ESTIL per obtenir-ne més informació.

="txu"&ACTUAL()

L'exemple retorna txu-txu.

CEL·LA

Retorna informació sobre l'adreça, la formatació o els continguts d'una cel·la.

Sintaxi

CEL·LA("InfoType"; Referència)

InfoType és la cadena de caràcters que indica el tipus d'informació. La cadena de caràcters sempre és en anglès. Les majúscules i les minúscules són opcionals.

InfoType

Significat

COL

Retorna el nombre de la columna referenciada.

=CEL·LA("COL";D2) retorna 4.

ROW

Retorna el número de la fila referenciada.

=CEL·LA("FILA";D2) retorna 2.

SHEET

Retorna el número del full referenciat.

=CEL·LA("Full";Full3.D2) retorna 3.

ADDRESS

Retorna l'adreça absoluta de la cel·la referenciada.

=CEL·LA("ADREÇA";D2) retorna $D$2.

=CEL·LA("ADREÇA";Full3.D2) retorna $Full3.$D$2.

=CEL·LA("ADREÇA";'X:\dr\test.ods'#$Full1.D2) retorna 'file:///X:/dr/test.ods'#$Full1.$D$2.

FILENAME

Retorna el nom del fitxer i el número de full de la cel·la referenciada.

=CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1.

=CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.

COORD

Returns the complete cell address in Lotus™ notation.

=CEL·LA("COORD"; D2) retorna $A:$D$2.

=CEL·LA("COORD"; Full3.D2) retorna $C:$D$2.

CONTENTS

Retorna els continguts de la cel·la referenciada, sense cap formatació.

TYPE

Retorna el tipus dels continguts de la cel·la.

b = blank. Cel·la buida.

l = label. Text, resultat d'una fórmula en forma de text.

v = valor. Valor, resultat d'una fórmula en forma de nombre.

WIDTH

Retorna l'amplada de la columna referenciada. La unitat correspon al nombre de zeros (0) que caben a la columna, amb la mida i el tipus de lletra per defecte.

PREFIX

Retorna l'alineació de la cel·la referenciada.

' = alineat a l'esquerra

" = alineat a la dreta

^ = centrat

\ = repetitiu (actualment inactiu)

PROTECT

Retorna l'estat de protecció de la cel·la.

1= la cel·la està protegida

0 = la cel·la no està protegida

FORMAT

Retorna una cadena de caràcters que indica el format dels nombres.

, = nombre amb separador de milers

F = nombre sense separador de milers

C = format de moneda

S = representació exponencial, per exemple, 1,234+E56

P = Percentatge

En els formats anteriors, el nombre de posicions decimals després del separador decimal es dóna com a nombre. Exemple: el format de nombre #,##0,0 retorna ,1 i el format de nombre 00,000% retorna P3

D1 = D-MMM-YY, D-MM-YY i formats semblants.

D2 = DD-MM

D3 = MM-YY

D4 = DD-MM-YYYY HH:MM:SS

D5 = MM-DD

D6 = HH:MM:SS AM/PM

D7 = HH:MM AM/PM

D8 = HH:MM:SS

D9 = HH:MM

G = tots els altres formats.

- (Menys) al final = els nombres negatius es formaten en color.

() (parèntesis) al final = hi ha un parèntesi d'obertura en el codi de format.

COLOR

Retorna 1 si els valors negatius tenen format en color; en cas contrari, retorna 0.

PARENTHESES

Retorna 1 si el codi de format conté un parèntesi d'obertura (; en cas contrari, retorna 0.


Referència (llista d'opcions) és la posició de la cel·la que s'ha d'examinar. Si Referència és un interval, la cel·la es mou cap a la part superior esquerra de l'interval. Si manca la Referència, el LibreOffice Calc utilitza la posició de la cel·la on hi ha la fórmula. El Microsoft Excel utilitza la referència de la cel·la on es col·loca el cursor.

ESBUIDA

Retorna CERT si la referència a una cel·la determinada és buida. Aquesta funció s'utilitza per determinar si una cel·la és buida. Una cel·la que conté una fórmula no és buida.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

ESBUIDA(Valor)

Valor és el contingut que s'ha de verificar.

Exemple

=ESBUIDA(D2) retorna FALS com a resultat.

ESERR

Comprova condicions d'error, excepte el valor d'error #N/D, i retorna CERT o FALS.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

ESERR(Valor)

Valor és qualsevol valor o expressió que es verifica per comprovar si hi ha un valor d'error diferent d'#N/D.

Exemple

=ESERR(C8) on la cel·la C8 conté =1/0 retorna CERT, ja que 1/0 és un error.

=ESERR(C9) on la cel·la C9 conté =ND() retorna FALS, ja que ESERR() ignora l'error #N/D.

ESERROR

Comprova si hi ha condicions d'error, incloent-hi el valor d'error #N/D, i retorna CERT o FALS.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

ESERROR(Valor)

Valor és el valor que s'ha de verificar o bé fa referència a aquest valor. ESERROR() retorna CERT si hi ha un error; en cas contrari, retorna FALS.

Exemple

=ESERROR(C8) on la cel·la C8 conté =1/0 retorna CERT perquè 1/0 és un error.

=ESERROR(C9) on la cel·la C9 conté =ND() retorna CERT.

ESFORMULA

Retorna CERT si una cel·la és una cel·la de fórmula.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

ESFORMULA(Referència)

Referència indica la referència a una cel·la que es verificarà per determinar si conté una fórmula.

Exemple

=ESFORMULA(C4) retorna FALS si la cel·la C4 conté el nombre 5.

ESLOGIC

Verifica un valor lògic (CERT o FALS).

Si es produeix un error, la funció retorna FALS.

Sintaxi

ESLOGIC(Valor)

Retorna CERT si Valor és un valor lògic (CERT o FALS); en cas contrari, retorna FALS.

Exemple

=ESLOGIC(99) retorna FALS perquè 99 és un nombre, no pas un valor lògic.

=ESLOGIC(ESND(D4)) retorna CERT independentment de quins siguin els continguts de la cel·la D4, ja que ESND() retorna un valor lògic.

ESND

Retorna CERT si una cel·la conté el valor d'error #N/D (valor no disponible).

Si es produeix un error, la funció retorna FALS.

Sintaxi

ESND(Valor)

Valor és el valor o l'expressió que s'ha de provar.

Exemple

=ESND(D3) retorna FALS com a resultat.

ESNOMBRE

Retorna CERT si el valor fa referència a un nombre.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

ESNOMBRE(Valor)

Valor és l'expressió que s'ha de verificar per determinar si és un nombre o un text.

Exemple

=ESNOMBRE(C3) retorna CERT si la cel·la C3 conté el nombre 4.

=ESNOMBRE(C2) retorna FALS si la cel·la C2 conté el text abcdef.

ESPARELL

Retorna CERT si el valor és un enter parell, o FALS si el valor és senar.

Sintaxi

ESPARELL(Valor)

Valor és el valor que s'ha de comprovar.

Si Valor no és un enter, s'ignoren tots els dígits situats després del punt decimal. També s'ignora el signe de Valor.

Exemple

=ESPARELL(48) retorna CERT.

=ESPARELL(33) retorna FALS.

=ESPARELL(0) retorna CERT.

=ESPARELL(-2,1) retorna CERT.

=ESPARELL(3,999) retorna FALS.

ESPARELL_ADD

Verifica els nombres parells. Retorna 1 si el resultat de dividir el nombre entre 2 és un nombre enter.

Icona de nota

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per obtenir resultats basats en els estàndards internacionals.


Sintaxi

ESPARELL_ADD(Nombre)

Nombre és el nombre que s'ha de provar.

Exemple

=ESPARELL_ADD(5) retorna 0.

=ESPARELL_ADD(A1) retorna 1 si la cel·la A1 conté el nombre 2.

ESREF

Verifica si l'argument és una referència. Retorna CERT si l'argument és una referència; altrament, retorna FALS. Quan s'indica una referència, la funció no examina el valor referenciat.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

ESREF(Valor)

Valor és el valor que s'ha de verificar per determinar si és una referència.

Exemple

=ESREF(C5) retorna el resultat CERT perquè C5 és una referència vàlida.

=ESREF("abcdef") sempre retorna FALS perquè un text mai no pot ser una referència.

=ESREF(4) retorna FALS.

=ESREF(INDIRECTE("A6")) retorna CERT perquè INDIRECTE és una funció que retorna una referència.

=ESREF(ADREÇA(1; 1; 2;"Full2")) retorna FALS perquè ADREÇA és una funció que retorna un text, malgrat que sembli una referència.

ESSENAR

Retorna CERT si el valor és senar; o FALS si el nombre és parell.

Sintaxi

ESSENAR(Valor)

Valor és el valor que s'ha de comprovar.

Si Valor no és un enter, s'ignoren tots els dígits situats després del punt decimal. També s'ignora el signe de Valor.

Exemple

=ESSENAR(33) retorna CERT.

=ESSENAR(48) retorna FALS.

=ESSENAR(3,999) retorna CERT.

=ESSENAR(-3,1) retorna CERT.

ESSENAR_ADD

Retorna CERT (1) si el resultat no és un nombre enter quan es divideix entre 2.

Icona de nota

Les funcions el nom de les quals acaba amb _ADD o _EXCEL 2003 retornen els mateixos resultats que les funcions corresponents del Microsoft Excel 2003 sense el sufix. Utilitzeu les funcions sense sufix per obtenir resultats basats en els estàndards internacionals.


Sintaxi

ESSENAR_ADD(Nombre)

Nombre és el nombre que s'ha de provar.

Exemple

=ESSENAR_ADD(5) retorna 1.

ESTEXT

Retorna CERT si el contingut de la cel·la fa referència a text.

Si es produeix un error, la funció retorna FALS.

Sintaxi

ESTEXT(Valor)

Valor és un valor, un nombre, un valor booleà o un valor d'error que s'ha de verificar.

Exemple

=ESTEXT(D9) retorna CERT si la cel·la D9 conté el text abcdef.

=ESTEXT(C3) retorna FALS si la cel·la C3 conté el nombre 3.

FORMULA

Mostra la fórmula d'una cel·la de fórmula com a cadena de text.

Sintaxi

FORMULA(Referència)

Referència és una referència a una cel·la que conté una fórmula.

Una referència no vàlida o una referència a una cel·la sense fórmula retorna el valor d'error #N/D.

Exemple

Si la cel·la A8 conté la fórmula =SUMA(1;2;3), aleshores

=FORMULA(A8) retorna el text =SUMA(1;2;3).

INFO

Retorna informació específica sobre l'entorn de treball actual. La funció rep un sol argument de text i retorna dades en funció d'aquest paràmetre.

Sintaxi

INFO("Tipus")

A la taula següent es llisten els valors del paràmetre de text Tipus i els valors de retorn de la funció INFO.

Valor de "Tipus"

Valor de retorn

"osversion"

Sempre "Windows (32-bit) NT 5.01", per raons de compatibilitat.

"system"

El tipus de sistema operatiu.
"WNT" per al Microsoft Windows
"LINUX" per al Linux
"SOLARIS" per al Solaris

"release"

Identificador de la versió del producte; per exemple, "300m25(Build:9876)"

"numfile"

Sempre 1, per motius de compatibilitat.

"recalc"

Mode de recàlcul de la fórmula actual, "Automàtic" o "Manual" (traduït en la llengua del LibreOffice)


Icona de nota

És possible que altres aplicacions de full de càlcul acceptin valors traduïts per al paràmetre Tipus, però el LibreOffice Calc només accepta els valors en anglès.


Exemple

=INFO("release") retorna el nombre de versió del LibreOffice que utilitzeu.

=INFO(D5), si la cel·la D5 conté la cadena de text system, retorna el tipus de sistema operatiu.

N

Retorna el valor numèric del paràmetre que s'ha indicat. Retorna 0 si el paràmetre és text o FALS.

Si es produeix un error, la funció retorna el valor d'error.

Sintaxi

N(Valor)

Valor és el paràmetre que s'ha de convertir en un nombre. N() retorna el valor numèric, si és possible. Per als valors lògics CERT i FALS, retorna 1 i 0 respectivament. Per al text, retorna 0.

Exemple

=N(123) retorna 123.

=N(CERT) retorna 1.

=N(FALS) retorna 0.

=N("abc") retorna 0

=N(1/0) retorna #DIV/0!

ND

Retorna el valor d'error #N/D.

Sintaxi

ND()

Exemple

=ND() converteix el contingut de la cel·la en #N/D.

NOESTEXT

Verifica si la cel·la conté text o nombres i, si és text, retorna FALS.

Si es produeix un error, la funció retorna CERT.

Sintaxi

NOESTEXT(Valor)

Valor representa qualsevol valor o expressió que es verifica per comprovar si es tracta d'un text, de nombres o d'un valor booleà.

Exemple

=NOESTEXT(D2) retorna FALS si la cel·la D2 conté el text abcdef.

=NOESTEXT(D9) retorna CERT si la cel·la D9 conté el nombre 8.

SIERROR

Retorna el valor si la cel·la no conté un valor d'error, o el valor alternatiu si el conté.

Sintaxi

SIERROR(Valor;Valor_alternatiu)

Valor és el valor o expressió que es retornarà si no és igual o si produeix un error.

Valor_alternatiu és el valor o expressió que es retornarà si l'expressió o el valor deValor és igual o si produeix un error.

Exemple

=SIERROR(C8;C9) on la cel·la C8 conté =1/0 retorna el valor de C9, perquè 1/0 és un error.

=SIERROR(C8;C9) on la cel·la C8 conté =13 retorna 13, perquè el valor de C8 no és un error.

SIND

Retorna el valor si la cel·la no conté el valor d'error #N/D (valor no disponible), o el valor alternatiu si el conté.

Sintaxi

SIND(Valor;Valor_alternatiu)

Valor és el valor o expressió que es retornarà si no és igual o si produeix un error #N/D.

Valor_alternatiu és el valor o expressió que es retornarà si l'expressió o el valor de Valor és igual o si es produeix un error #N/D.

Exemple

=SIND(D3;D4) retorna el valor de D3 si D3 no conté un error #N/D, o el valor de D4 en cas contrari.

TIPUS

Retorna el tipus de dades d'un valor, on 1 = nombre, 2 = text, 4 = valor booleà, 8 = fórmula, 16 = valor d'error i 64 = matriu.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Sintaxi

TIPUS(Valor)

Valor és un valor específic del qual s'ha de determinar el tipus de dades.

Exemple (vegeu la taula de més amunt)

=TIPUS(C2) retorna 2 com a resultat.

=TIPUS(D9) retorna 1 com a resultat.