তথ্য ফাংশন
এই শ্রেণীতে পরিসংখ্যান ফাংশন রয়েছে।
কিছু উদাহরণের জন্য ফাংশনের বর্ণনায় নিম্নবর্ণিত সারণির ডাটা ভিত্তি হিসাবে ব্যবহার করা হয়:
C |
D |
|
2 |
x মান |
y মান |
3 |
-5 |
-3 |
4 |
-2 |
0 |
5 |
-1 |
1 |
6 |
0 |
3 |
7 |
2 |
4 |
8 |
4 |
6 |
9 |
6 |
8 |
CELL
ঘরের ঠিকানা, বিন্যাস বা বিষয়বস্তুর তথ্য প্রদান করে।
সিনট্যাক্স
CELL("InfoType"; Reference)
InfoType হলো অক্ষরের স্ট্রিং, যা তথ্যের ধরন উল্লেখ করে। অক্ষর স্ট্রিং সর্বদা ইংরেজীতে থাকে। বড় হাতের বা ছোট হাতের অক্ষর হলো ঐচ্ছিক।
InfoType |
অর্থ |
COL |
উল্লেখিত কলামের সংখ্যা প্রদান করে। =CELL("COL";D2) ৪ প্রদান করে। |
ROW |
উল্লেখিত সারির সংখ্যা প্রদান করে। =CELL("ROW";D2) ২ প্রদান করে। |
SHEET |
উল্লেখিত শীটের সংখ্যা প্রদান করে। =CELL("Sheet";Sheet3.D2) ৩ প্রদান করে। |
ADDRESS |
উল্লেখিত ঘরের সম্পূর্ণ ঠিকানা প্রদান করে। =CELL("ADDRESS";D2) $D$2 প্রদান করে। =CELL("ADDRESS";Sheet3.D2) $Sheet3.$D$2 প্রদান করে। =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.$D$2. |
FILENAME |
উল্লেখিত ঘরের ফাইলের নাম এবং শীট সংখ্যা প্রদান করে। =CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1. |
COORD |
Returns the complete cell address in Lotus™ notation. =CELL("COORD"; D2) $A:$D$2 প্রদান করে। =CELL("COORD"; Sheet3.D2) $C:$D$2 প্রদান করে। |
CONTENTS |
উল্লেখিত ঘরের বিষয়বস্তু কোনো বিন্যাস ছাড়াই প্রদান করে। |
TYPE |
ঘরের বিষয়বস্তুর ধরন প্রদান করে। b = ফাঁকা। শূন্য ঘর l = লেবেল। টেক্সট, টেক্সট হিসেবে সূত্রের ফলাফল v = মান। মান, সংখ্যা হিসেবে সূত্রের ফলাফল |
WIDTH |
রেফারেন্সকৃত কলামের প্রস্থ প্রদান করে। একক হলো শূন্যের (০) সংখ্যা, যা পূর্বনির্ধারিত টেক্সট এবং পূর্বনির্ধারিত আকারে কলামের উপযুক্ত। |
PREFIX |
রেফারেন্সকৃত ঘরের প্রান্তিককরণ প্রদান করে। ' = বাম প্রান্তিক বা বাম-উভয়প্রান্তিক " = ডান প্রান্তিক ^ = কেন্দ্রস্থিত \\ = পুনরাবৃত্তকরণ (বর্তমানে নিষ্ক্রিয়) |
PROTECT |
ঘরের জন্য ঘর সংরক্ষণের অবস্থা প্রদান করে। ১ = ঘর সংরক্ষিত ০ = ঘর সংরক্ষিত নয় |
FORMAT |
একটি অক্ষর স্ট্রিং প্রদান করে, যা সংখ্যার বিন্যাস নির্দেশ করে। , = সহস্র বিভাজক যুক্ত সংখ্যা F = সহস্র বিভাজক ব্যতীত সংখ্যা C = মুদ্রার বিন্যাস S = সূচকীয় উপস্থাপন, উদাহরণস্বরূপ, 1.234+E56 P = শতকরা হার উপরের ফরম্যাটে, দশমিক বিভাজকের পরে দশমিক স্থান সংখ্যা একটি সংখ্যা হিসাবে প্রদান করা হয়েছে। উদাহরণ: #,##০.০ সংখ্যা বিন্যাস ১ প্রদান করে এবং ০০.০০০% সংখ্যা বিন্যাস P3 প্রদান করে। D1 = MMM-D-YY, MM-D-YY এবং অনুরূপ ফরম্যাট D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = অন্য সব ফরম্যাট - (বিয়োগ) শেষে = ঋণাত্মক সংখ্যা রং দিয়ে বিন্যাসিত () (বন্ধনী) শেষে = ফরম্যাট কোডে একটি শুরু বন্ধনী রয়েছে |
COLOR |
যদি ঋণাত্মক মান রং দিয়ে বিন্যাসিত থাকে, 1 প্রদান করে, অন্যথায় 0। |
PARENTHESES |
যদি ফরম্যাট কোডে শুরু বন্ধনী ( থাকে, 1 প্রদান করে, অন্যথায় 0। |
রেফারেন্স (অপশনের তালিকা) হলো এমন ঘরের অবস্থান, যা পরীক্ষা করা হবে। যদি রেফারেন্স একটি পরিসর হয়, ঘরটি পরিসরের উপরের বাম দিকে সরে যায়। যদি রেফারেন্স অনুপস্থিত থাকে, LibreOffice ক্যালক ঘরের অবস্থান ব্যবহার করে, যেটিতে সূত্রের অবস্থান চিহ্নিত করা হয়। মাইক্রোসফ্ট এক্সেল এমন ঘরের রেফারেন্স ব্যবহার করে, যেটিতে কার্সার অবস্থিত থাকে।
CURRENT
সূত্রটি মূল্যায়ন করার তারিখে এই ফাংশনটি ফলাফল প্রদান করে যার এইটি একটি অংশ (অন্য কথায় যতক্ষন ফলাফলটি মূল্যায়ন করার হয়)। এইটির প্রধান ব্যবহার হলো ঘর উপাদানের উপর নির্ভরশীল একটি ঘরের নির্বাচিত শৈলী প্রয়োগ করার জন্য STYLE() ফাংশনটির সাথে একত্রে করা হয়।
সিনট্যাক্স
CURRENT()
উদাহরণ
=১+২+CURRENT()
এই উদাহরণটি ৬ প্রদান করে থাকে। সূত্রটি বাম থকে ডানে: ১+২ সমান ৩, CURRENT() সংঘটনের তারিখে ফলাফল প্রদান করে গণনা করা হয়; CURRENT() এর ফলাফল ৩ যা প্রকৃত ফল ৩ এর সাথে যোগ করে ৬ হয়।
=A2+B2+STYLE(IF(CURRENT()>10;”Red”;”Default”))
উদাহরণটি A2+B2 (এখানে STYLE ০ প্রদান করে) প্রদান করে। যদি যোগফল ১০ অপেক্ষা বড় হয়, ঘরে লাল শৈলী প্রয়োগ করা হয়। আরও ব্যাখ্যার জন্য STYLE ফাংশনটি দেখুন।
="choo"&CURRENT()
এই উদাহরণটি choochoo প্রদান করে থাকে।
FORMULA
সূত্র ঘরের সূত্র টেক্সট স্ট্রিং হিসাবে প্রদর্শন করা হয়।
সিনট্যাক্স
FORMULA(Reference)
reference হলো এমন ঘরের রেফারেন্স যাতে সূত্র রয়েছে।
একটি অবৈধ রেফারেন্স অথবা কোন সূত্র ব্যতীত একটি ঘরে রেফারেন্স ফলাফল হিসেবে একটি ত্রুটি মান #N/A প্রদান করে।
উদাহরণ
যদি A8 ঘরে =SUM(1;2;3) সূত্রটি থাকে তবে
=FORMULA(A8) =SUM(1;2;3) টেক্সট প্রদান করে।
INFO
বর্তমান কর্মক্ষেত্রের পরিবেশ সম্পর্কে সুনির্দিষ্ট তথ্য প্রদান করে। ফাংশনটি একক টেক্সট আর্গুমেন্ট গ্রহণ করে এবং ঐ প্যারামিটারের উপর ভিত্তি করে ডাটা প্রদান করে।
সিনট্যাক্স
INFO("Type")
নিম্নের সারণিটি টেক্সট প্যারামিটার Type এর মান এবং INFO ফাংশনের প্রদান মানের তালিকা তৈরি করে।
"Type" এর মান |
প্রদান মান |
"osversion" |
উপযুক্ততার কারণে, সর্বদা "Windows (32-bit) NT 5.01" |
"system" |
অপারেটিং সিস্টেমের ধরন। |
"release" |
পণ্যের রিলিজ আইডেন্টিফায়ার, উদাহরণস্বরূপ "300m25(Build:9876)" |
"numfile" |
উপযুক্ততার কারণে, সবসময় ১ |
"recalc" |
বর্তমান সূত্রের পুনঃহিসাব মোড, "স্বয়ংক্রিয়" বা "ম্যানুয়াল" (LibreOffice ভাষাতে অনুবাদ করা হয়েছে) |
অন্যান্য স্প্রেডশীট অ্যাপ্লিকেশন Type প্যারামিটারের জন্য আঞ্চলিক মান গ্রহণ করতে পারে, কিন্তু LibreOffice ক্যালক শুধুমাত্র ইংরেজী মান গ্রহণ করবে।
উদাহরণ
=INFO("release") ব্যবহার করতে LibreOffice-এর প্রোডাক্ট রিলিজ নম্বর প্রদান করে।
টেক্সট স্ট্রিং সিস্টেম ধারণকারী D5 ঘর সহ =INFO(D5) অপারেটিং সিস্টেমের ধরন প্রদান করে থাকে।
ISBLANK
যদি একটি ঘরের রেফারেন্স খালি থাকে, TRUE প্রদান করা হয়। ঘরের বিষয়বস্তু ফাঁকা কিনা জানার জন্য এই ফাংশনটি ব্যবহার করা হয়। সূত্র যুক্ত একটি ঘর ফাঁকা নয়।
সিনট্যাক্স
ISBLANK(Value)
Value হলো এমন বিষয়বস্তু, যা পরীক্ষা করা হবে।
উদাহরণ
=ISBLANK(D2) ফলাফল হিসাবে FALSE প্রদান করে।
ISERR
ত্রুটি মান "#N/A" ব্যতীত, ত্রুটি যুক্ত অবস্থার জন্য পরীক্ষা করা হয়, এবং TRUE বা FALSE প্রদান করে।
সিনট্যাক্স
ISERR(Value)
Value হলো এমন যেকোনো মান বা এক্সপ্রেশন, যা #N/A ব্যতীত অন্য কোনো ত্রুটি মান আছে কিনা দেখার জন্য পরীক্ষা করা হয়।
উদাহরণ
=ISERR(C8), যেখানে C8 ঘরে =1/0 থাকে, TRUE প্রদান করে, কারণ ১/০ হলো একটি ত্রুটি।
=ISERR(C9), যেখানে C9 ঘরে =NA() থাকে, FALSE প্রদান করে, কারণ ISERR() #N/A ত্রুটি উপেক্ষা করে।
ISERROR
ত্রুটি মান "#N/A" সহ, ত্রুটি যুক্ত অবস্থার জন্য পরীক্ষা করা হয়, এবং TRUE বা FALSE প্রদান করে
সিনট্যাক্স
ISERROR(Value)
Value হলো এমন মান, যা পরীক্ষা করা হবে বা পরীক্ষার জন্য পাঠানো হয়। যদি কোনো ত্রুটি থাকে ISERROR() TRUE প্রদান করে এবং অন্যথায় FALSE।
উদাহরণ
=ISERROR(C8), যেখানে C8 ঘরে =1/0 রয়েছে, TRUE প্রদান করে, কারণ ১/০ হলো ত্রুটি।
=ISERROR(C9), যেখানে C9 ঘরে =NA() রয়েছে, TRUE প্রদান করে।
ISERROR
Returns the value if the cell does not contains an error value, or the alternative value if it does.
সিনট্যাক্স
IFERROR(Value;Alternate_value)
Value is the value or expression to be returned if it is not equal or results in an error.
Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an error.
উদাহরণ
=ISERROR(C8), যেখানে C8 ঘরে =1/0 রয়েছে, TRUE প্রদান করে, কারণ ১/০ হলো ত্রুটি।
=ISERROR(C8), যেখানে C8 ঘরে =1/0 রয়েছে, TRUE প্রদান করে, কারণ ১/০ হলো ত্রুটি।
ISEVEN
মান যদি জোড় পূর্ণসংখ্যা হয়, TRUE প্রদান করা হয়, বা মান যদি বিজোড় হয়, FALSE প্রদান করা হয়।
সিনট্যাক্স
ISEVEN(Value)
Value হলো এমন মান, যা পরীক্ষা করা হবে।
মান যদি পূর্ণসংখ্যা না হয়, দশমিক বিন্দুর পরবর্তী যেকোনো সংখ্যা বাদ দেয়া হবে। মানের চিহ্নও বাদ দেয়া হবে।
উদাহরণ
=ISEVEN(48) TRUE প্রদান করে
=ISEVEN(33) FALSE প্রদান করে
=ISEVEN(0) TRUE প্রদান করে
=ISEVEN(-2.1) TRUE প্রদান করে
=ISEVEN(3.999) FALSE প্রদান করে
ISEVEN_ADD
জোড় সংখ্যার জন্য পরীক্ষা করা হয়। যদি সংখ্যাটি ২ দ্বারা ভাগ করা হলে একটি পূর্ণ সংখ্যা প্রদান করে, ১ প্রদান করা হয়।
সিনট্যাক্স
ISEVEN_ADD(Number)
Number হলো এমন সংখ্যা যা পরীক্ষা করা হবে।
উদাহরণ
=ISEVEN_ADD(5) ০ প্রদান করে।
=ISEVEN_ADD(A1) ১ প্রদান করে, যদি A1 ঘরে ২ সংখ্যাটি থাকে।
ISFORMULA
যদি কোনো ঘর সূত্র ঘর হয়, TRUE প্রদান করে।
সিনট্যাক্স
ISFORMULA(Reference)
Reference একটি ঘরের রেফারেন্স নির্দেশ করে, যেখানে একটি পরীক্ষা সম্পন্ন করা হবে, যা নির্ধারণ করবে যে এতে সূত্র রয়েছে কিনা।
উদাহরণ
=ISFORMULA(C4) FALSE প্রদান করে, যদি C4 ঘরে ৫ সংখ্যাটি থাকে।
ISLOGICAL
লজিক্যাল মান (TRUE বা FALSE) পরীক্ষা করা হয়।
যদি কোনো ত্রুটি সংঘটিত হয়, ফাংশনটি FALSE প্রদান করে।
সিনট্যাক্স
ISLOGICAL(Value)
যদি Value লজিক্যাল মান (TRUE বা FALSE) হয়, তবে TRUE প্রদান করে, এবং অন্যথায় FALSE প্রদান করে।
উদাহরণ
=ISLOGICAL(99) FALSE প্রদান করে, কারণ ৯৯ হলো একটি সংখ্যা, লজিক্যাল মান নয়।
D4 ঘরের বিষয়বস্তু যাই হোক না কেন, =ISLOGICAL(ISNA(D4)) TRUE প্রদান করে, কারণ ISNA() লজিক্যাল মান প্রদান করে।
ISNA
যদি কোনো ঘরে ত্রুটি মান #N/A (মান বিদ্যমান নেই) থাকে, TRUE প্রদান করে।
যদি কোনো ত্রুটি সংঘটিত হয়, ফাংশনটি FALSE প্রদান করে।
সিনট্যাক্স
ISNA(Value)
Value হলো এমন একটি মান বা এক্সপ্রেশন, যা পরীক্ষা করা হবে।
উদাহরণ
=ISNA(D3) ফলাফল হিসেবে FALSE প্রদান করে।
ISNA
Returns the value if the cell does not contains the #N/A (value not available) error value, or the alternative value if it does.
সিনট্যাক্স
IFNA(Value;Alternate_value)
Value is the value or expression to be returned if it is not equal or results in an #N/A error.
Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an #N/A error.
উদাহরণ
=IFNA(D3;D4) returns the value of D3 if D3 does not result in an #N/A error, or D4 if it does.
ISNONTEXT
যদি ঘরের বিষয়বস্তু টেক্সট বা সংখ্যা হয়, তবে পরীক্ষা করা হয়, এবং যদি বিষয়বস্তু টেক্সট হয়, FALSE প্রদান করে।
যদি কোনো ত্রুটি সংঘটিত হয়, ফাংশনটি TRUE প্রদান করে।
সিনট্যাক্স
ISNONTEXT(Value)
Value হলো এমন যেনোনো মান বা এক্সপ্রেশন, যেখানে একটি পরীক্ষা সম্পন্ন করা হয়, যা নির্ধারণ করে যে এটা টেক্সট বা সংখ্যা বা বুলিয়ান মান কিনা।
উদাহরণ
=ISNONTEXT(D2) FALSE প্রদান করে, যদি D2 ঘরে abcdef টেক্সট থাকে।
=ISNONTEXT(D9) TRUE প্রদান করে, যদি D9 ঘরে ৮ সংখ্যাটি থাকে।
ISNUMBER
যদি মানটি সংখ্যায় উল্লেখ করা হয়, TRUE প্রদান করে।
সিনট্যাক্স
ISNUMBER(Value)
Value হলো এমন যেকোনো এক্সপ্রেশন, যা মানটি সংখ্যা বা টেক্সট কিনা নির্ধারণ করতে পরীক্ষা করা হয়।
উদাহরণ
যদি C3 ঘরে ৪ সংখ্যাটি থাকে, =ISNUMBER(C3) TRUE প্রদান করে।
যদি C2 ঘরে abcdef টেক্সট থাকে, =ISNUMBER(C2) FALSE প্রদান করে।
ISODD
মান যদি বিজোড় হয়, TRUE প্রদান করে, বা সংখ্যাটি যদি জোড় হয়, FALSE প্রদান করে।
সিনট্যাক্স
ISODD(value)
Value হলো এমন মান, যা পরীক্ষা করা হবে।
মান যদি পূর্ণসংখ্যা না হয়, দশমিক বিন্দুর পরবর্তী যেকোনো সংখ্যা বাদ দেয়া হবে। মানের চিহ্নও বাদ দেয়া হবে।
উদাহরণ
=ISODD(33) TRUE প্রদান করে
=ISODD(48) FALSE প্রদান করে
=ISODD(3.999) TRUE প্রদান করে
=ISODD(-3.1) TRUE প্রদান করে
ISODD_ADD
যদি সংখ্যাটি ২ দ্বারা ভাগ করা হলে পূর্ণ সংখ্যা প্রদান না করে, TRUE (1) প্রদান করে।
সিনট্যাক্স
ISODD_ADD(Number)
Number হলো এমন সংখ্যা যা পরীক্ষা করা হবে।
উদাহরণ
=ISODD_ADD(5) 1 প্রদান করে।
ISREF
আরগুমেন্ট যদি রেফারেন্স হয় তবে পরীক্ষা করা হয়। আরগুমেন্ট যদি রেফারেন্স হয় তবে TRUE প্রদান করা হয়, অন্যথায় FALSE প্রদান করে। যখন কোনো রেফারেন্স প্রদান করা হয়, এই ফাংশনটি রেফারেন্সের জন্য মান পরীক্ষা করে না।
সিনট্যাক্স
ISREF(Value)
Value হলো এমন মান, যা রেফারেন্স কিনা পরীক্ষা করা হয়, নির্ধারণ করা হয়।
উদাহরণ
=ISREF(C5) TRUE প্রদান করে কারণ C5 একটি কার্যকর রেফারেন্স।
=ISREF("abcdef") সর্বদা FALSE প্রদান করে কারণ একটি টেক্সট কখনও রেফারেন্স হতে পারে না।
=ISREF(4) FALSE প্রদান করে।
=ISREF(INDIRECT("A6")) TRUE প্রদান করে, কারণ INDIRECT এমন একটি ফাংশন যা রেফারেন্স প্রদান করে।
=ISREF(ADDRESS(1; 1; 2;"Sheet2")) FALSE প্রদান করে, কারণ ADDRESS এমন একটি ফাংশন যা টেক্সট প্রদান করে, যদিও এটা রেফারেন্সের মতো দেখায়।
ISTEXT
যদি ঘরের বিষয়বস্তু টেক্সটে উল্লেখ করা হয়, TRUE প্রদান করে।
যদি কোনো ত্রুটি সংঘটিত হয়, ফাংশনটি FALSE প্রদান করে।
সিনট্যাক্স
ISTEXT(Value)
Value হলো এমন মান, সংখ্যা, বুলিয়ান মান, বা ত্রুটি মান, যা পরীক্ষা করা হবে।
উদাহরণ
যদি D9 ঘরে abcdefটেক্সটি থাকে, =ISTEXT(D9) TRUE প্রদান করে।
যদি C3 ঘরে ৩সংখ্যাটি থাকে, =ISTEXT(C3) FALSE প্রদান করে।
N
Returns the numeric value of the given parameter. Returns 0 if parameter is text or FALSE.
If an error occurs the function returns the error value.
সিনট্যাক্স
N(Value)
Value is the parameter to be converted into a number. N() returns the numeric value if it can. It returns the logical values TRUE and FALSE as 1 and 0 respectively. It returns text as 0.
উদাহরণ
=N(123) ১২৩ প্রদান করে
=N(TRUE) 1 প্রদান করে
=N(FALSE) 0 প্রদান করে
=N("abc") 0 প্রদান করে
=N(১/০) #DIV/0! প্রদান করে
NA
ত্রুটি মান #N/A প্রদান করে।
সিনট্যাক্স
NA()
উদাহরণ
=NA() ঘরের বিষয়বস্তু #N/A এ রূপান্তর করে।
TYPE
Returns the type of value, where 1 = number, 2 = text, 4 = Boolean value, 8 = formula, 16 = error value, 64 = array.
সিনট্যাক্স
TYPE(Value)
Value is a specific value for which the data type is determined.
উদাহরণ (উপরের উদাহরণ সারণি দেখুন)
=TYPE(C2) ফলাফল হিসেবে ২ প্রদান করে।
=TYPE(D9) ফলাফল হিসেবে ১ প্রদান করে।