Информационни функции
Тази категория съдържа информационни функции.
Данните в следващата таблица служат за основа за някои от примерите в описанията на функции.
C |
D |
|
2 |
стойност на x |
стойност на y |
3 |
-5 |
-3 |
4 |
-2 |
0 |
5 |
-1 |
1 |
6 |
0 |
3 |
7 |
2 |
4 |
8 |
4 |
6 |
9 |
6 |
8 |
CELL
Връща информация за адреса, форматирането или съдържанието на клетка.
Синтаксис
CELL("ТипИнфрмация"; Обръщение)
ТипИнформация е знаковият низ, задаващ типа на информацията. Той е винаги на английски. Регистърът на буквите няма значение.
ТипИнформация |
Значение |
COL |
Връща номера на колона, посочена чрез обръщение. =CELL("COL";D2) връща 4. |
ROW |
Връща номера на ред, посочен чрез обръщение. =CELL("ROW";D2) връща 2. |
SHEET |
Връща номера на лист, посочен чрез обръщение. =CELL("SHEET";Лист3.D2) връща 3. |
ADDRESS |
Връща абсолютния адрес на клетка, посочена чрез обръщение. =CELL("ADDRESS";D2) връща $D$2. =CELL("ADDRESS";Лист3.D2) връща $Лист3.$D$2. =CELL("ADDRESS";'X:\dr\test.ods'#$Лист1.D2) връща 'file:///X:/dr/test.ods'#$Лист1.$D$2. |
FILENAME |
Връща името на файла и номера на листа на посочената чрез обръщение клетка. =CELL("FILENAME";D2) връща 'file:///X:/dr/own.ods'#$Лист1, ако формулата в текущия документ X:\dr\own.ods се намира в Лист1. =CELL("FILENAME";'X:\dr\test.ods'#$Лист1.D2) връща 'file:///X:/dr/test.ods'#$Лист1. |
COORD |
Връща пълния адрес на клетка във формата на Lotus™. =CELL("COORD"; D2) връща $A:$D$2. =CELL("COORD"; Лист3.D2) връща $C:$D$2. |
CONTENTS |
Връща съдържанието на посочената клетка без форматирането. |
TYPE |
Връща типа на съдържанието на клетка. b = празна клетка (blank) l = текст или текстов резултат от формула (label) v = число или числов резултат от формула (value) |
WIDTH |
Връща ширината на посочената колона като броя нули (0), които могат да се поберат в нея при подразбирания шрифт и размер. |
PREFIX |
Връща подравняването на посочената клетка. ' = подравняване отляво " = подравняване отдясно ^ = центриране \ = повтаряне (не е активно в момента) |
PROTECT |
Връща състоянието на защитата за дадената клетка. 1 = клетката е защитена 0 = клетката не е защитена |
FORMAT |
Връща знаков низ, показващ числовия формат. , = число с разделител на хилядите F = число без разделител на хилядите C = валутен формат S = експоненциално представяне, например 1,234+E56 P = проценти В горните формати броят на дробните позиции се дава като число. Например за числовия формат #,##0.0 се връща низът ,1, а за формата 00.000% – P3. D1 = MMM-D-YY, MM-D-YY и подобни формати D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = всички други формати - (минус) в края = отрицателните числа се форматират с цвят () (скоби) в края = в кода на формат има отваряща скоба |
COLOR |
Връща 1, ако отрицателните стойности са форматирани с цвят, и 0 в противен случай. |
PARENTHESES |
Връща 1, ако кодът на формат съдържа отваряща скоба (, и 0 в противен случай. |
Обръщение (списък с настройки) е позицията на клетката, която да бъде анализирана. Ако Обръщение е област, клетката се премества горе вляво в областта. Ако Обръщение е пропуснато, LibreOffice Calc използва позицията на клетката, в която е разположена формулата. Microsoft Excel използва обръщението на клетката, в която се намира курсорът.
CURRENT
Тази функция връща резултата до момента от изчисляването на формулата, в която участва (с други думи, текущия резултат, до който е стигнало изчисляването). Тя се използва главно в съчетание с функцията STYLE() за прилагане на избрани стилове върху клетка в зависимост от съдържанието й.
Синтаксис
CURRENT()
Пример
=1+2+CURRENT()
Примерът връща 6. Формулата се изчислява от ляво на дясно така: 1 + 2 дава 3 – това е текущият резултат при извикването на CURRENT(); следователно CURRENT() връща 3, което се добавя към оригиналното 3 и дава 6.
=A2+B2+STYLE(IF(CURRENT()>10;"Червен текст";"По подразбиране"))
Примерът връща A2 + B2 (тук STYLE връща 0). Ако сумата е по-голяма от 10, върху клетката се прилага стилът „Червен текст“. Вижте функцията STYLE за допълнителни обяснения.
="ку"&CURRENT()
Примерът връща „куку“.
FORMULA
Показва формулата от клетка с формула като текстов низ.
Синтаксис
FORMULA(Обръщение)
Обръщение е обръщение към клетка, съдържаща формула.
При неправилно обръщение или обръщение към клетка без формула резултатът е стойността за грешка #N/A.
Пример
Ако клетката A8 съдържа формулата =SUM(1;2;3), тогава
=FORMULA(A8) връща текста =SUM(1;2;3).
IFERROR
Връща първата стойност, ако клетката не съдържа стойност за грешка, или алтернативната в противен случай.
Синтаксис
IFERROR(Стойност; Алтернативна_стойност)
Стойност е стойност или израз, който ще бъде върнат, ако ако не е равен на или не дава като резултат стойност за грешка.
Алтернативна_стойност е стойност или израз, който ще бъде върнат, ако изразът или стойността в Стойност е равен на или дава като резултат стойност за грешка.
Пример
=IFERROR(C8; C9), при условие че клетката C8 съдържа =1/0, връща стойността на C9, защото 1/0 е грешка.
=IFERROR(C8; C9), при условие че клетката C8 съдържа 13, връща 13 – стойността на C8, – защото тя не е грешка.
IFNA
Връща първата стойност, ако клетката не съдържа стойността за грешка #N/A (неналична стойност), или алтернативната в противен случай.
Синтаксис
IFNA(Стойност; Алтернативна_стойност)
Стойност е стойност или израз, който ще бъде върнат, ако ако не е равен на или не дава като резултат стойност за грешка #N/A.
Алтернативна_стойност е стойност или израз, който ще бъде върнат, ако изразът или стойността в Стойност е равен на или дава като резултат стойност за грешка #N/A.
Пример
=IFNA(D3; D4) връща стойността на D3, ако D3 не се свежда до грешка #N/A, или D4 в противен случай.
INFO
Връща определена информация за текущата работна среда. Функцията приема единствен текстов аргумент и връща данни в зависимост от стойността му.
Синтаксис
INFO("Тип")
В следващата таблица са изброени стойностите за текстовия параметър Тип и резултатите от функцията INFO.
Стойност на "Тип" |
Връщана стойност |
"osversion" |
Винаги "Windows (32-bit) NT 5.01" за съвместимост. |
"system" |
Тип на операционната система: |
"release" |
Идентификаторът на издание на продукта, например "300m25(Build:9876)" |
"numfile" |
Винаги 1 за съвместимост. |
"recalc" |
Текущият режим на преизчисляване на формули, "Автоматично" или "Ръчно" (локализиран на езика на LibreOffice) |
Други приложения за електронни таблици може да приемат локализирани стойности за параметъра Тип, но LibreOffice Calc приема само стойности на английски.
Пример
=INFO("release") връща номера на издание на използваната инсталация на LibreOffice.
=INFO(D5), ако клетката D5 съдържа текстовия низ system, връща типа на операционната система.
ISBLANK
Връща TRUE, ако обръщението сочи към празна клетка. Тази функция определя дали дадената клетка е празна. Клетка, съдържаща формула, не е празна.
Синтаксис
ISBLANK(Стойност)
Стойност представлява съдържанието, което да бъде проверено.
Пример
=ISBLANK(D2) връща FALSE.
ISERR
Проверява за възникнали грешки с изключение на стойността #N/A и връща TRUE или FALSE.
Синтаксис
ISERR(Стойност)
Стойност е стойност или израз, за който се проверява дали е стойност за грешка, различна от #N/A.
Пример
=ISERR(C8), при условие, че клетката C8 съдържа =1/0, връща TRUE, тъй като 1/0 е грешка.
=ISERR(C9), при условие, че клетката C9 съдържа =NA() връща FALSE, тъй като ISERR() игнорира грешката #N/A.
ISERROR
Проверява за възникнали грешки, включително #N/A, и връща TRUE или FALSE.
Синтаксис
ISERROR(Стойност)
Стойност представлява или посочва стойността, която да бъде проверена. ISERROR() връща TRUE, ако има грешка, и FALSE в противен случай.
Пример
=ISERROR(C8), при условие че клетката C8 съдържа =1/0, връща TRUE, тъй като 1/0 е грешка.
=ISERROR(C9), при условие че клетката C9 съдържа =NA(), връща TRUE.
ISEVEN
Връща TRUE, ако стойността е четно цяло число, и FALSE, ако стойността е нечетна.
Синтаксис
ISODD(Стойност)
Стойност е стойността, която да бъде проверена.
Ако стойността не е цяло число, цифрите след десетичната запетая се игнорират. Знакът на числото също се пренебрегва.
Пример
=ISEVEN(48) връща TRUE
=ISREF(4) връща FALSE
=ISEVEN(0) връща TRUE
=ISEVEN(-2,1) връща TRUE
=ISEVEN(3,999) връща FALSE
ISEVEN_ADD
Проверява за четни числа. Връща 1, ако при делението на числото на две се получава цяло число.
Синтаксис
ISEVEN_ADD(Число)
Число е числото, което да бъде проверено.
Пример
=ISEVEN_ADD(5) връща 0.
=ISEVEN_ADD(A1) връща 1, ако клетката A1 съдържа числото 2.
ISFORMULA
Връща TRUE, ако клетката съдържа формула.
Синтаксис
ISFORMULA(Обръщение)
Обръщение e обръщението към клетка, за която трябва да се провери дали съдържа формула.
Пример
=ISFORMULA(C4) връща FALSE, ако клетката C4 съдържа числото 5.
ISLOGICAL
Проверява за логическа стойност (TRUE илиFALSE).
Ако възникне грешка, функцията връща FALSE.
Синтаксис
ISLOGICAL(Стойност)
Връща TRUE, ако Стойност е логическа стойност (TRUE или FALSE), и FALSE в противен случай.
Пример
=ISLOGICAL(99) връща FALSE, тъй като 99 е число, а не логическа стойност.
=ISLOGICAL(ISNA(D4)) връща TRUE независимо от съдържанието на клетката D4, тъй като ISNA() връща логическа стойност.
ISNA
Връща TRUE, ако клетка съдържа стойността за грешка #N/A (не е налична стойност).
Ако възникне грешка, функцията връща FALSE.
Синтаксис
ISNA(Стойност)
Стойност е стойността или изразът, който да бъде проверен.
Пример
=ISNA(D3) връща FALSE.
ISNONTEXT
Проверява дали съдържанието на клетката е текст или число и връща FALSE, ако съдържанието е текст.
Ако възникне грешка, функцията връща TRUE.
Синтаксис
ISNONTEXT(Стойност)
Стойност е стойност или израз, за който се проверява дали представлява текст, число или логическа стойност.
Пример
=ISNONTEXT(D2) връща FALSE, ако клетката D2 съдържа текста абвгде.
=ISNONTEXT(D9) връща TRUE, ако клетката D9 съдържа числото 8.
ISNUMBER
Връща TRUE, ако стойността представлява или посочва число.
Синтаксис
ISNUMBER(Стойност)
Стойност е израз, за който да се провери дали е число или текст.
Пример
=ISNUMBER(C3) връща TRUE, ако клетката C3 съдържа числото 4.
=ISNUMBER(C2) връща FALSE, ако клетката C2 съдържа текста абвгде.
ISODD
Връща TRUE, ако стойността е нечетна, и FALSE, ако е четна.
Синтаксис
ISODD(Стойност)
Стойност е стойността, която да бъде проверена.
Ако стойността не е цяло число, цифрите след десетичната запетая се игнорират. Знакът на числото също се пренебрегва.
Пример
=ISODD(33) връща TRUE
=ISREF(4) връща FALSE
=ISODD(3,999) връща TRUE
=ISODD(-3,1) връща TRUE
ISODD_ADD
Връща TRUE (1), ако при деление на числото на две не се получава цяло число.
Синтаксис
ISODD_ADD(Число)
Число е числото, което да бъде проверено.
Пример
=ISODD_ADD(5) връща 1.
ISREF
Проверява дали аргументът е обръщение. Връща TRUE, ако аргументът е обръщение, а в противен случай – FALSE. Когато е подадено обръщение, тази функция не обработва стойността на посочената клетка.
Синтаксис
ISREF(Стойност)
Стойност е стойността, за която да се провери дали е обръщение.
Пример
=ISREF(C5) връща резултата TRUE, тъй като C5 е валидно обръщение.
=ISREF("абвгде") винаги връща FALSE, тъй като текст не може да бъде обръщение.
=ISREF(4) връща FALSE.
=ISREF(INDIRECT("A6")) връща TRUE, защото INDIRECT е функция, която връща обръщение.
=ISREF(ADDRESS(1; 1; 2;"Sheet2")) връща FALSE, защото ADDRESS е функция, която връща текст, независимо, че той изглежда като обръщение.
ISTEXT
Връща TRUE, ако съдържанието на клетката е текст.
Ако възникне грешка, функцията връща FALSE.
Синтаксис
ISTEXT(Стойност)
Стойност е стойност, която да бъде проверена и може да бъде число, логическа стойност или стойност за грешка.
Пример
=ISTEXT(D9) връща TRUE, ако клетката D9 съдържа текста абвгде.
=ISTEXT(C3) връща FALSE, ако клетката C3 съдържа числото 3.
N
Връща числовата стойност на дадения параметър. Връща 0, ако параметърът е текст или FALSE.
При възникване на грешка функцията връща стойност за грешка.
Синтаксис
N(Стойност)
Стойност е параметърът, който да бъде превърнат в число. N() връща числовата стойност, ако е възможно. За TRUE и FALSE се връща съответно 1 и 0. За текст се връща 0.
Пример
=N(123) връща 123.
=N(TRUE()) връща 1.
=N(FALSE()) връща 0.
=N("абв") връща 0.
=N(1/0) връща #DIV/0!
NA
Връща стойността за грешка #N/A.
Синтаксис
NA()
Пример
=NA() преобразува съдържанието на клетката в #N/A.
TYPE
Връща типа на дадена стойност, като 1 = число, 2 = текст, 4 = логическа стойност, 8 = формула, 16 = стойност за грешка, 64 = масив.
Синтаксис
TYPE(Стойност)
Стойност е конкретна стойност, за която да се определи типът данни.
Пример (вижте примерната таблица по-горе)
=TYPE(C2) връща 2.
=TYPE(D9) връща 1.