For...Next Statement

Repite les instrucciones que s'atopen nel bloque For...Next un númberu determináu de vegaes.

Sintaxis:

For contador=entamu To final [Step medría]

bloque d'instrucciones

[Exit For]

bloque d'instrucciones

Next [contador]

Variables:

Contador: Contador de bucle al que s'asigna primeramente'l valor de la derecha del signu igual (entamu). Namái les variables numbériques son válides. El contador de bucles aumenta o mengua según la variable Medría hasta que s'algamar el valor final.

Entamu: Variable numbérica que define'l valor inicial de primeres del bucle.

Final: Variable numbérica que define'l valor final cuando termina'l bucle.

Medría: Define'l valor col qu'amontar o decrementar el contador del bucle. Si Amonto nun s'especifica, el contador del bucle amontar en 1. Nesi casu, Final ten de ser mayor qu'Empecipio. Si deseya decrementar el Contador, Final ten de ser inferior a Entamu y Medría tien de tener asignáu un valor negativu.

El bucle For...Next repite toles instrucciones del bucle tantes vegaes como especifiquen los parámetros.

A midida que la variable de contador se decrementa, LibreOffice Basic comprueba si llegóse al valor final. Asina'l contador llega al valor final, el bucle remata automáticamente.

Ye posible añerar instrucciones For...Next. Si nun s'especifica nenguna variable dempués de la instrucción Next, esta Next fai referencia automáticamente a la instrucción For más recién.

Si especifica un medría 0, les instrucciones ente For y Next repitir indefinidamente.

Al realizar la cuenta trás cola variable Contador, LibreOffice Basic comprueba que nun se produza una llena o vacuidad. El bucle termina cuando'l Contador supera a Final (valor de Medría positiva) o ye inferior a Final (valor de Medría negativa).

La instrucción Exit For utilizar pa salir del bucle incondicionalmente. Esta instrucción tien de tar incluyida dientro del bucle For...Next. Use la instrucción If...Then pa comprobar la condición de salida de la forma siguiente:

For...

instrucciones

If condición = Cierta Then Exit For

instrucciones

Siguiente

Nota: En bucles For...Next añeraos, si salar d'un bucle de forma incondicional con Exit For, namái se sale d'un bucle.

Exemplu

L'exemplu siguiente usa dos bucles añeraos pa ordenar una matriz de cadenes con 10 elementos ( sEntry() ) que primero se rellenen con dellos conteníos:

Sub ExampleSort

Dim sEntry(9) As String

Dim iCount As Integer

Dim iCount2 As Integer

Dim sTemp As String

    sEntry(0) = "Xabel"

    sEntry(1) = "Patricia"

    sEntry(2) = "Xuan"

    sEntry(3) = "Tomás"

    sEntry(4) = "Miguel"

    sEntry(5) = "David"

    sEntry(6) = "Catuxa"

    sEntry(7) = "Susana"

    sEntry(8) = "Duvardu"

    sEntry(9) = "Cristina"

    For iCount = 0 To 9

        For iCount2 = iCount + 1 To 9

            If sEntry(iCount) > sEntry(iCount2) Then

                sTemp = sEntry(iCount)

                sEntry(iCount) = sEntry(iCount2)

                sEntry(iCount2) = sTemp

            End If

        Next iCount2

    Next iCount

    For iCount = 0 To 9

        Print sEntry(iCount)

    Next iCount

End Sub