أمثلة برمجية على عناصر التحكم في محرر مربع الحوار

Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)

Dim oLib as Object

Dim oLibDialog as Object

Dim oRuntimeDialog as Object

    If IsMissing(oLibContainer) Then

        oLibContainer = DialogLibraries

    End If

    oLibContainer.LoadLibrary(LibName)

    oLib = oLibContainer.GetByName(Libname)

    oLibDialog = oLib.GetByName(DialogName)

    oRuntimeDialog = CreateUnoDialog(oLibDialog)

    LoadDialog() = oRuntimeDialog

End Function

REM تعريف المتغيرات العالمية

Dim oDialog1 AS Object

Sub StartDialog1

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    oDialog1.Execute()

End Sub

Sub Sample1

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    REM الحصول على نموذج الحوار

    oDialog1Model = oDialog1.Model

    REM عرض نص Label1

    oLabel1 = oDialog1.GetControl("Label1")

    MsgBox oLabel1.Text

    REM تعيين نص جديد لعنصر التحكم Label1

    oLabel1.Text = "ملفات جديدة"

    REM عرض خصائص نموذج عنصر التحكم CheckBox1

    oCheckBox1Model = oDialog1Model.CheckBox1

    MsgBox oCheckBox1Model.Dbg_Properties

    REM تعيين حالة جديدة لـ CheckBox1 لنموذج لعنصر تحكم

    oCheckBox1Model.State = 1

    REM عرض خصائص نموذج عنصر التحكم CommandButton1

    oCMD1Model = oDialog1Model.CommandButton1

    MsgBox oCMD1Model.Dbg_Properties

    REM عرض خصائص نموذج عنصر التحكم CommandButton1

    oCMD1 = oDialog1.GetControl("CommandButton1")

    MsgBox oCMD1.Dbg_Properties

    REM تنفيذ مربع الحوار

    oDialog1.Execute()

End Sub

Sub AddEntry

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    REM يضيف إدخال جديد إلى مربع القائمة

    oDialog1Model = oDialog1.Model

    oListBox = oDialog1.GetControl("ListBox1")

    Dim iCount as integer

    iCount = oListbox.ItemCount

    oListbox.additem("عنصر جديد" & iCount,0)

End Sub

Sub RemoveEntry

    BasicLibraries.LoadLibrary("Tools")

    oDialog1 = LoadDialog("Standard", "Dialog1")

    REM إزالة الإدخال الأول من مربع القائمة

    oDialog1Model = oDialog1.Model

    oListBox = oDialog1.GetControl("ListBox1")

    oListbox.removeitems(0,1)

End Sub