Hàm Bảng Tính

Phần này chứa mô tả về các hàm Bảng tính, cùng với mẫu thí dụ.

Để truy cập lệnh này... Chèn > Hàm > (Loại) Bảng tính

[text/scalc/01/func_error_type.xhp#error_type_head not found].

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

ADDRESS

Trả về một địa chỉ ô (tham chiếu) dạng văn bản, tùy theo các số thứ tự hàng/cột đã ghi rõ. Bạn cũng có thể quyết định có nên đọc địa chỉ dưới dạng một địa chỉ tuyệt đối (v.d. $A$1), hoặc dưới dạng một địa chỉ tương đối (A1), hoặc dưới dạng hỗn hợp (A$1 hay $A1). Cũng có thể ghi rõ tên của trang tính.

Để hỗ trợ cho việc dùng chung, cả hai hàm ADDRESS và INDIRECT đều hỗ trợ một tham số tùy chọn cho phép xác lập xem địa chỉ sẽ được điền dưới dạng hay R1C1 hay là kiểu A1 thường dùng.

Trong hàm ADDRESS, tham số này được đưa vào tại vị trí thứ tư, chuyển tham số tùy chọn tên của bảng sang vị trí thứ năm.

Trong hàm INDIRECT, tham số trên được thêm vào tại vị trí số hai.

Trong cả hai hàm, nếu như tham số có giá trị 0 thì kiểu kí hiệu địa chỉ R1C1 sẽ được sử dụng, còn nếu như tham số không xuất hiện hay có giá trị khác 0 thì kiểu kí hiệu A1 sẽ được sử dụng.

Trong trường hợp kí hiệu R1C1, hàm ADDRESS trả về chuỗi địa chỉ sử dụng dấu chấm than '!' làm kí hiệu phân cách tên bảng, còn hàm INDIRECT coi dấu chấm than có tác dụng như trên. Cả hai hàm vẫn sử dụng dấu chấm '.' để phân cách tên bảng với kiểu kí hiệu A1.

Khi mở các tài liệu trong định dạng ODF 1.0/1.1, hàm ADDRESS thường sử dụng vị trí thứ tư cho tên bảng sẽ chuyển sang vị trí thứ năm. Một tham số với với giá trị 1 sẽ được thêm vào vị trí thứ tư thay thế.

Khi lưu một tài liệu theo định dạng ODF 1.0/1.1, nếu hàm ADDRESS có tham số thứ 4, tham số đó sẽ bị gỡ bỏ.

Cú pháp

ADDRESS(Hàng; Cột; Kiểu; A1; "Trang")

Hàng đại diện số thứ tự hàng cho tham chiếu ô

Cột đại diện số thứ tự cột cho tham chiếu ô (số, không phải chữ)

Kiểu xác định kiểu tham chiếu :

1: tuyệt đối ($A$1)

2: kiểu tham chiếu hàng là tuyệt đối; tham chiếu cột là tương đối (A$1)

3: hàng (tương đối); cột (tuyệt đối) ($A1)

4: tương đối (A1)

A1 (optional) - nếu có giá trị là 0 thì kiểu kí hiệu R1C1 sẽ được sử dụng, trái lại nếu như tham số này không có mặt hoặc có giá trị khác 0 thì kiểu kí hiệu A1 sẽ được sử dụng.

Trang đại diện tên của trang tính. Nó phải nằm giữa dấu nháy kép.

Thí dụ :

=ADDRESS(1;1;2;"Trang2") trả về « Trang2.A$1 ».

Nếu ô A1 trong trang tính 2 chứa giá trị -6, bạn có thể tham chiếu gián tiếp đến ô đã tham chiếu dùng một hàm trong B2, bằng cách nhập công thức =ABS(INDIRECT(B2)). Kết quả là giá trị tuyệt đối của tham chiếu ô được ghi rõ trong B2, mà trong trường hợp này là 6.

AREAS

Trả về số phạm vi riêng thuộc về một phạm vi đa mục. Một phạm vi có thể chứa nhiều ô kề nhau, hay một ô riêng lẻ.

Hàm này nhận một đối số duy nhất. Nếu có nhiều vùng, bạn phải bao chúng trong ngoặc đơn bổ sung. Nhiều vùng có thể được nhập bằng cách sử dụng dấu chấm phẩy (;) để chia tách, nhưng sẽ được chuyển đổi tự động sang toán tử dấu ngã (~). Dấu ngã được sử dụng để nối các vùng.

Cú pháp

AREAS(Tham_chiếu)

Tham_chiếu đại diện tham chiếu đến một ô hay phạm vi các ô.

Ví dụ

=AREAS((A1:B3;F2;G1)) trả về 3, vì nó là một tham chiếu tới 3 ô hoặc vùng. Sau khi nhập nó được chuyển thành =AREAS((A1:B3~F2~G1)).

=AREAS(All) trả về 1 nếu bạn đã xác định một vùng tên « Tất cả » dưới Dữ liệu > Xác định Phạm vi.

CHOOSE

Sử dụng một chỉ số để trả về một giá trị từ danh sách chứa đến 30 giá trị.

Cú pháp

CHOOSE(Chỉ_số; Giá_trị1; ...; Giá_trị30)

Chỉ_số là một tham chiếu hay số nằm giữa 1 và 30 mà ngụ ý giá trị nào cần lấy từ danh sách.

Giá_trị1...Giá_trị30 là danh sách các giá trị được nhập vào dạng một tham chiếu đến một ô, hoặc như là các giá trị riêng.

Ví dụ

Công thức =CHOOSE(A1;B1;B2;B3;"Hôm nay";"Hôm qua";"Ngày mai"), chẳng hạn, trả về nội dung của ô B2 cho « A1=2 »; cho « A1=4 », hàm trả về chuỗi « Hôm nay ».

COLUMN

Trả về số thứ tự cột của một tham chiếu ô. Nếu tham chiếu là một ô, thì trả về số thứ tự cột của ô đó ; nếu tham số là một vùng ô, thì số cột tương ứng sẽ được trả về theo một mảng nếu công thức được nhập vào như một công thức mảng. Nếu hàm COLUMN với một tham số tham chiếu vùng không phải được dùng cho một công thức mảng, thì quyết định chỉ số thứ tự cột của ô thứ nhất bên trong vùng đó.

Cú pháp

COLUMN(Tham_chiếu)

Tham_chiếu là tham chiếu đến một ô hay vùng ô có số thứ tự cột đầu tiên cần tìm.

Không nhập tham chiếu thì tìm số thứ tự cột của ô chứa công thức. LibreOffice Calc tự động đặt tham chiếu thành ô hiện tại.

Ví dụ

=COLUMN(A1) bằng với 1. Cột A là cột đầu tiên của bảng.

=COLUMN(C3:E3) bằng với 3. Cột C là cột thứ ba của bảng.

=COLUMN(D3:G10) trả về 4 vì cột D là cột thứ tư của bảng, và hàm COLUMN không được dùng làm công thức mảng. (Trong trường hợp này, giá trị thứ nhất của mảng lúc nào cũng được dùng làm kết quả.)

Hai công thức {=COLUMN(B2:B7)} và =COLUMN(B2:B7) đều trả về 2 vì tham chiếu chỉ chứa cột B làm cột thứ hai của bảng. Vì vùng cột đơn chỉ có một số thứ tự cột, không phân biệt giữa công thức bình thường và công thức dạng công thức mảng.

=COLUMN() trả về 3 nếu công thức được nhập vào cột C.

{=COLUMN(Chó)} trả về mảng hàng đơn (3, 4) nếu con « Chó » là vùng đặt tên (C1:D3).

COLUMNS

Trả về số các cột có trong tham chiếu đã cho.

Cú pháp

COLUMNS(Mảng)

Mảng là tham chiếu đến một phạm vi các ô có tổng số cột cần tìm. Đối số cũng có thể là một ô riêng lẻ.

Ví dụ

=COLUMNS(B5) trả về 1 vì một ô chỉ chứa một cột.

=COLUMNS(A1:C5) bằng với 3. Tham chiếu chứa ba cột.

=COLUMNS(Chó) trả về 2 nếu con Chó là phạm vi đặt tên (C1:D3).

DDE

Trả về kết quả của một liên kết dựa vào DDE. Nếu nội dung của phạm vi hay phần đã liên kết còn thay đổi, thì giá trị đã trả về sẽ cũng thay đổi. Bạn cần phải nạp lại bảng tính hoặc chọn lệnh trình đơn Sửa - Liên kết để thấy các liên kết đã cập nhật. Không cho phép liên kết đa nền tảng, v.d. liên kết từ một bản cài đặt LibreOffice chạy từ một máy Windows đến một tài liệu được tạo trên một máy Linux.

Cú pháp

DDE("Phục_vụ"; "Tập_tin"; "Phạm_vi"; Chế_độ)

Server is the name of a server application. LibreOffice applications have the server name "soffice".

Tập_tin là tên tập tin hoàn toàn, gồm có đặc tả đường dẫn.

Phạm_vi là vùng chứa dữ liệu cần ước tính.

Chế_độ là một tham số còn tùy chọn mà điều khiển phương pháp theo đó máy chủ DDE chuyển đổi dữ liệu sang số.

Mode	Hiệu ứng
0 hay thiếu	Định dạng số từ kiểu dáng ô « Mặc định »
1	Dữ liệu lúc nào cũng được đọc theo định dạng tiêu chuẩn cho tiếng Anh Mỹ
2	Dữ liệu được lấy dạng văn bản; không chuyển đổi sang số

Ví dụ

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

ERRORTYPE

Trả về số tương ứng với một giá trị lỗi xảy ra trong một ô khác. Với sự giúp của số này, bạn có thể tạo một thông điệp lỗi.

Cú pháp

ERRORTYPE(Tham_chiếu)

Tham_chiếu chứa địa chỉ cua ô trong đó lỗi xảy ra.

Ví dụ

Nếu ô A1 hiển thị « Err:518 », hàm =ERRORTYPE(A1) trả về số 518.

GETPIVOTDATA

Hàm GETPIVOTDATA trả về một giá trị kết quả từ một bảng DataPilot. Giá trị có địa chỉ được đặt dùng các tên trường và tên mục, để nó còn lại hợp lệ nếu bố trí của bảng DataPilot cứ thay đổi.

Cú pháp

Có thể sử dụng hai lời xác định cú pháp khác nhau :

GETPIVOTDATA(Trường_đích; DataPilot; [ Trường 1; Mục 1; ... ])

GETPIVOTDATA(DataPilot; Ràng_buộc)

Cú pháp thứ hai được giả sử nếu đưa ra chính xác hai tham số, tham số đầu tiên là một ô hay tham chiếu phạm vi các ô. Cú pháp thứ nhất được giả sử trong các trường hợp khác. Trợ lý Hàm hiển thị cú pháp thứ nhất.

Cú pháp thứ nhất

Trường_đích là một chuỗi mà chọn một của những trường dữ liệu của bảng DataPilot. Chuỗi này có thể là tên của cột nguồn, hay tên trường dữ liệu như được hiển thị trên bảng (v.d. « Tổng - Buôn bán »).

DataPilot là một tham chiếu đến một ô hay phạm vi các ô mà được định vị bên trong một bảng DataPilot hay chứa một bảng DataPilot. Nếu phạm vi ô chứa vài bảng DataPilot, có dùng bảng được tạo cuối cùng.

Không đưa ra cặp Trường n / Mục n thì trả về tổng số tổng quát. Có thì mỗi cặp thêm một ràng buộc mà kết quả phải thoả. Trường n là tên của một trường từ bảng DataPilot. Mục n là tên của một mục từ trường đó.

Nếu bảng DataPilot chứa chỉ một giá trị kết quả riêng lẻ mà thoả tất cả các ràng buộc, hoặc một tổng phụ mà tóm tắt tất cả các giá trị tương ứng, thì trả về kết quả đó. Không có kết quả tương ứng, hoặc có vài kết quả không có tổng phụ, thì trả về lỗi. Các điều kiện này áp dụng cho những kết quả nằm trong bảng DataPilot.

Nếu dữ liệu nguồn chứa các mục bị ẩn bởi thiết lập của bảng DataPilot, dữ liệu đó bị bỏ qua. Thứ tự của các cặp Trường/Mục không có tác động. Tên của trường hay mục không phân biệt chữ hoa/thường.

Không đưa ra ràng buộc cho một trường trang thì dùng ngầm giá trị được chọn cho trường đó. Nếu đưa ra một ràng buộc cho một trường trang, nó phải tương ứng với giá trị được chọn của trường đó, không thì trả về lỗi. Trường trang là trường ở góc trên bên trái một bảng DataPilot, được điềndùng vùng Trường trang của hộp thoại Bố trí DataPilot. Từ mỗi trường trang, một mục (giá trị) có thể được chọn, thì chỉ mục đó được xử lý trong phép tính.

Giá trị tổng phụ từ bảng DataPilot chỉ được dùng nếu nó dùng hàm « auto » (tự động), trừ khi được ghi rõ trong ràng buộc, xem Cú pháp thứ hai bên dưới).

Cú pháp thứ hai

DataPilot có cùng một nghĩa trong cú pháp thứ nhất.

Ràng buộc là một danh sách định giới bằng dấu cách. Cũng có thể đặt mục giữa dấu nháy đơn. Toàn bộ chuỗi phải nằm giữa dấu nháy kép, nếu bạn không tham chiếu đến chuỗi đó từ một ô khác.

Một của những mục có thể là tên trường dữ liệu. Tên trường dữ liệu có thể bị bõ sót nếu bảng DataPilot chỉ chứa một trường dữ liệu, không thì phải có nó.

Mỗi mục khác ghi rõ một ràng buộc có dạng Trường[Mục] (gồm có cặp ngoặc vuông), hoặc chỉ có Mục nếu tên mục duy nhất trong mọi trường được dùng trong bảng DataPilot.

Một tên hàm có thể được thêm dưới dạng Trường[Mục;Hàm], mà sẽ gây ra ràng buộc chỉ tương ứng với giá trị tổng phụ mà dùng hàm đó. Những tên hàm có thể là Sum (Tổng), Count (Đếm), Average (Trung bình), Max (Đại), Min (Tiểu), Product (Tích), Count (Đếm: chỉ các số), StDev (Độ lệch chuẩn: mẫu), StDevP (Độ lệch chuẩn: dân số), Var (Phương sai: mẫu), and VarP (Phương sai: dân số), không phân biệt chữ hoa/thường.

HLOOKUP

Tìm một giá trị và tham chiếu đến những ô bên dưới vùng đã chọn. Hàm này thẩm tra hàng đầu của một mảng chứa một giá trị nào đó không. Hàm thì trả về giá trị trong một hàng của mảng, đặt tên trong Chỉ_số cùng cột.

Cú pháp

HLOOKUP(SearchCriterion; Array; Index; Sorted)

See also: VLOOKUP (columns and rows are exchanged)

HYPERLINK

Khi bạn nhấn vào một ô mà chứa hàm HYPERLINK, siêu liên kết sẽ mở.

Nếu bạn sử dụng tham số cell text còn tùy chọn, thì hàm tìm địa chỉ URL, sau đó hiển thị chuỗi văn bản.

Cú pháp

HYPERLINK("URL") hay HYPERLINK("URL"; "CellText")

URL ghi rõ địa chỉ là đích đến của liên kết. Tham số CellText còn tùy chọn là chuỗi văn bản được hiển thị trong ô, và kết quả của hàm. Không đưa ra tham số CellText thì hiển thị URL trong chuỗi văn bản của ô, và trong kết quả của hàm.

Số 0 được trả về cho các ô và phần tử ma trận trống.

Ví dụ

Công thức =HYPERLINK("http://www.example.org") hiển thị chuỗi "http://www.example.org" trong ô, và thực hiện siêu liên kết đó khi được nhấn vào.

Công thức =HYPERLINK("http://www.example.org";"Nhấn vào đây") hiển thị chuỗi « Nhấn vào đây » trong ô, và thực hiện siêu liên kết "http://www.example.org" khi được kích hoạt.

=HYPERLINK("http://www.example.org";12345) hiện số 12345 và thi hành siêu liên kết http://www.example.org khi nhấn.

=HYPERLINK($B4) mà ô B4 chứa địa chỉ http://www.example.org. Hàm thêm địa chỉ này vào địa chỉ URL của ô siêu liên kết, sau đó trả về cùng một chuỗi làm kết quả công thức.

=HYPERLINK("http://www.";"Nhấn vào ") & "example.org" hiển thị chuỗi « Nhấn vào example.org » trong ô, và thực hiện siêu liên kết "http://www.example.org" khi được kích hoạt.

=HYPERLINK("#Trang1.A1";"Lên đầu") hiển thị chuỗi « Lên đầu » và nhảy về vị trí Trang1:A1 trong tài liệu này.

=HYPERLINK("file:///C:/writer.odt#Đặc_tả";"Đi tới siêu liên kết trong Writer") hiển thị chuỗi « Đi tới siêu liên kết trong Writer », và nhảy tới liên kết đã lưu « Đặc_tả ».

INDEX

Hàm INDEX trả về một phạm vi phụ, được xác định theo số thứ tự hàng/cột, hay một chỉ số phạm vi còn tùy chọn. Phụ thuộc vào ngữ cảnh, hàm INDEX trả về một tham chiếu hay nội dung.

Cú pháp

INDEX(Tham_chiếu; Hàng; Cột; Phạm_vi)

Tham_chiếu là một tham chiếu, được nhập hoặc một cách trực tiếp hoặc bằng cách ghi rõ một tên phạm vi. Nếu tham chiếu chứa nhiều phạm vi, bạn cần phải đặt tên của tham chiếu hay phạm vi giữa dấu ngoặc đơn.

Hàng (tùy chọn) đại diện chỉ số hàng của phạm vi tham chiếu, cho đó cần trả về một giá trị. Trong trường hợp 0 (không có hàng cụ thể), trả về tất cả các hàng đã tham chiếu.

Cột (tùy chọn) đại diện chỉ số cột của phạm vi tham chiếu, cho đó cần trả về một giá trị. Trong trường hợp 0 (không có cột cụ thể), trả về tất cả các cột đã tham chiếu.

Phạm_vi (tùy chọn) đại diện chỉ số của phạm vi phụ, nế tham chiếu đện một phạm vi đa mục.

Ví dụ

=INDEX(Prices;4;1) trả về giá trị từ hàng 4, cột 1 của phạm vi cơ sở dữ liệu được xác định dưới Dữ liệu > Xác định như là Giá (Prices).

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

=INDEX(A1:B6;1) trả về một tham chiếu đến hàng đầu tiên của khối A1:B6.

=INDEX(A1:B6;0;1) trả về một tham chiếu đến cột đầu tiên của khối A1:B6.

=INDEX((multi);4;1) indicates the value contained in row 4 and column 1 of the (multiple) range, which you named under Sheet - Named Ranges and Expressions - Define as multi. The multiple range may consist of several rectangular ranges, each with a row 4 and column 1. If you now want to call the second block of this multiple range enter the number 2 as the range parameter.

=INDEX(A1:B6;1;1) ngụ ý giá trị ở góc trên, bên trái của phạm vi A1:B6.

=INDEX((multi);0;0;2) trả về một tham chiếu đến phạm vi thứ hai của phạm vi đa mục.

INDIRECT

Trả về tham chiếu được một chuỗi văn bản ghi rõ. Hàm này cũng có thể được dùng để trả về vùng của một chuỗi tương ứng.

Cú pháp

INDIRECT(Tham_chiếu; A1)

Tham_chiếu đại diện một tham chiếu đến một ô hay vùng (theo dạng văn bản) cho đó cần trả về nội dung.

A1 (optional) - nếu có giá trị là 0 thì kiểu kí hiệu R1C1 sẽ được sử dụng, trái lại nếu như tham số này không có mặt hoặc có giá trị khác 0 thì kiểu kí hiệu A1 sẽ được sử dụng.

Ví dụ

=INDIRECT(A1) bằng với 100 nếu ô A1 chứa C108 làm tham chiếu và C108 chứa giá trị 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) cộng lại tất cả các ô trong vùng từ A1 đến ô có địa chỉ được xác định bởi hàng 1, cột 3. Vì thế cộng lại vùng A1:C3.

LOOKUP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

Cú pháp

LOOKUP(Tiêu_chuẩn_tìm; Véc-tơ_tìm; Véc-tơ_kết_quả)

Tiêu_chuẩn_tìm là giá trị cần tìm; được nhập hoặc một cách trực tiếp hoặc làm một tham chiếu.

Véc-tơ_tìm là vùng hàng đơn hay cột đơn trong đó cần tìm kiếm.

Véc-tơ_kết_quả là một phạm vi hàng đơn hay cột đơn khác từ đó lấy kết quả của hàm. Kết quả là ô của véc-tơ kết quả có cùng một chỉ số với mục tương ứng được tìm bởi véc-tơ tìm.

Ví dụ

=LOOKUP(A1;D1:D100;F1:F100) tìm kiếm trong ô tương ứng trong phạm vi D1:D100 tìm số bạn đã nhập vào ô A1. Đối với mục tương ứng đã tìm, chỉ số được quyết định, v.d. ô thứ 12 trong phạm vi này. Sau đó thì nội dung của ô thứ 12 được trả về làm giá trị của hàm (trong véc-tơ kết quả).

MATCH

Trả về vị trí tương đối của một mục trong một mảng tương ứng với một giá trị đã ghi rõ. Hàm này trả về vị trí của biến được tìm trong lookup_array (mảng tra cứu) dạng số.

Cú pháp

MATCH(Tiêu_chuẩn_tìm; Mảng_tra_cứu; Kiểu)

Tiêu_chuẩn_tìm là giá trị cần tìm trong mảng cột/hàng đơn.

Mảng_tra_cứu là tham chiếu trong đó cần tìm kiếm. Một mảng tra cứu có thể là một hàng/cột đơn, hay phần của một hàng/cột đơn.

Kiểu có thể đại diện một của những giá trị (1, 0, -1). Nếu kiểu là 1 hay không đưa ra tham số tùy chọn này, giả sử rằng cột đầu của mảng tìm được sắp xếp theo thứ tự tăng dần. Nếu kiểu là -1, giả sử rằng cột được sắp xếp theo thứ tự giảm dần. Đây tương ứng với cùng một hàm trong MS Excel.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

Nếu kiểu là 1, hay không đưa ra tham số thứ ba, thì trả về chỉ số của giá trị cuối cùng nhỏ hơn hay bằng với tiêu chuẩn tìm kiếm. Trường hợp này có tác động ngay cả khi mảng tìm không phải được sắp xếp. Đối với kiểu -1, trả về giá trị đầu lớn hơn hay bằng.

Ví dụ

=MATCH(200;D1:D100) tìm kiếm qua vùng D1:D100, mà được sắp xếp theo cột D, so với giá trị 200. Một khi tới giá trị này, trả về số thứ tự cua hàng chứa nó. Nếu tìm một giá trị lớn hơn trong khi tìm kiếm, thì trả về số thứ tự của hàng trước đó.

OFFSET

Trả về giá trị của một ô bị bù lại theo một số hàng/cột nào đó từ một điểm tham chiếu đã cho.

Cú pháp

OFFSET(Tham_chiếu; Hàng; Cột; Cao; Rộng)

Tham_chiếu là tham chiếu từ đó hàm tìm tham chiếu mới.

Hàng là số hàng theo đó tham chiếu bị sửa chữa lên (giá trị âm) hay xuống.

Hàng là số hàng theo đó tham chiếu bị sửa chữa lên (giá trị âm) hay xuống.

Cao (tùy chọn) là bề cao theo chiều dọc của một vùng bắt đầu ở vị trí tham chiếu mới.

Rộng (optional) là bề rộng theo chiều ngang của một vùng bắt đầu ở vị trí tham chiếu mới.

Không cho phép đối số Hàng hay Cột đưa tới số không hay hàng/cột đầu âm.

Không cho phép đối số Cao hay Rộng đưa tới số không hay số đếm hàng/cột âm.

Trong các hàm của Calc LibreOffice , các thông số được đánh dấu như là « tùy chọn » có thể bỏ qua chỉ khi nào đằng sau nó không còn tham số nào nữa. Ví dụ, một hàm có 4 tham số, trong đó 2 tham số cuối được đánh dấu « tùy chọn », bạn có thể bỏ qua tham số thứ 4 hoặc cả hai tham số 3 và 4, nhưng bạn không thể bỏ chỉ mỗi tham số thứ 3.

Ví dụ

=OFFSET(A1;2;2) trả về giá trị trong ô C3 (A1 được dời xuống theo hai hàng và hai cột). Nếu ô C3 chứa giá trị 100, hàm này trả về giá trị 100.

=OFFSET(B2:C3;1;1) trả về một tham chiếu đến B2:C3 được dời xuống theo một hàng và sang phải theo một cột (C3:D4).

=OFFSET(B2:C3;-1;-1) trả về một tham chiếu đến B2:C3 được dời lên theo một hàng và sang trái theo một cột (A1:B2).

=OFFSET(B2:C3;0;0;3;4) trả về một tham chiếu đến B2:C3 có kích cỡ được thay đổi thành 3 hàng và 4 cột (B2:E4).

=OFFSET(B2:C3;1;0;3;4) trả về một tham chiếu đến B2:C3 được dời xuống theo một hàng, có kích cỡ được thay đổi thành 3 hàng và 4 cột (B2:E4).

=SUM(OFFSET(A1;2;2;5;6)) quyết định tổng số diện tích bắt đầu từ ô C3 và có chiều cao 5 hàng và chiều rộng 6 cột (diện tích = C3:H7).

ROW

Trả về số thứ tự hàng của một tham chiếu ô. Nếu tham chiếu này là một ô, hàm này trò chuyện số thứ tự hàng của ô đó. Nếu tham chiếu là một phạm vi các ô, nó trả về các số thứ tự hàng tương ứng trong một mảng cột đơn nếu công thức được nhập vào dưới dạng một công thức mảng. Nếu hàm ROW với một tham chiếu phạm vi không được dùng trong một công thức mảng, chỉ trả về số thứ tự hàng của ô đầu tiên trong phạm vi đó.

Cú pháp

ROW(Tham_chiếu)

Tham_chiếu là một ô, vùng hay tên của vùng.

Nếu bạn không chỉ ra một tham chiếu, hàm sẽ tìm số thứ tự hàng của ô chứa công thức. LibreOffice Calc tự động đặt tham chiếu thành ô hiện tại.

Ví dụ

Công thức =ROW(B3) trả về 3 vì tham chiếu chỉ tới hàng thứ ba trên bảng.

Công thức {=ROW(D5:D8)} trả về mảng cột đơn (5, 6, 7, 8) vì tham chiếu đã ghi rõ chứa các hàng 5 đến 8.

Công thức =ROW(D5:D8) trả về 5 vì hàm ROW không được dùng làm công thức mảng, và chỉ trả về hàng đầu của tham chiếu.

Hai công thức {=ROW(A1:E1)} và =ROW(A1:E1) đều trả về 1 vì tham chiếu chỉ chứa hàng 1 làm cột đầu của bảng. (Vì vùng hàng đơn chỉ có một số thứ tự hàng, không khác gì trường hợp công thức được dùng làm công thức mảng.)

Công thức =ROW() trả về 3 nếu công thức được nhập vào hàng 3.

Công thức {=ROW(Chó)} trả về mảng cột đơn (1, 2, 3) nếu con « Chó » là vùng đặt tên (C1:D3).

ROWS

Trả về số hàng trong một tham chiếu hay mảng.

Cú pháp

ROWS(Mảng)

Mảng là tham chiếu hay vùng đặt tên cho đó cần tính tổng số hàng.

Ví dụ

Công thức =Rows(B5) trả về 1 vì một ô chỉ chứa một hàng.

=ROWS(A10:B12) trả về 3.

Công thức =ROWS(Chó) trả về 3 nếu con « Chó » là vùng đặt tên (C1:D3).

SHEET

Trả về số thứ tự trang tính của một tham chiếu hay chuỗi đại diện một tên trang tính. Nếu bạn không nhập vào tham số thì kết quả là số thứ tự trang tính của bảng tính chứa công thức đó.

Cú pháp

SHEET(Tham_chiếu)

Tham_chiếu còn tùy chọn: nó là tham chiếu đến một ô, vùng hay chuỗi tên trang tính.

Ví dụ

=SHEET(Trang2.A1) thì trả về 2 nếu Trang2 là trang tính thứ hai của tài liệu bảng tính.

SHEETS

Xác định số trang tính trong một tham chiếu. Nếu bạn không nhập vào tham số thì nó trả về số trang tính trong tài liệu hiện tại.

Cú pháp

SHEETS(Tham_chiếu)

Tham_chiếu là tham chiếu đến một trang tính hay vùng. Tham số này còn tùy chọn.

Ví dụ

=SHEETS(Trang1.A1:Trang3.G12) trả về 3 nếu Trang tính số 1-3 nằm theo thứ tự được ngụ ý.

STYLE

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats have to be defined beforehand.

Cú pháp

STYLE("Kiểu_dáng"; Thời_gian; "Kiểu_dáng2")

Kiểu_dáng là tên của một kiểu dáng ô được gán cho ô đó. Tên kiểu dáng phải được nhập vào giữa dấu nhấy kép.

Thời_gian là một khoảng thời gian tùy chọn, tính theo giây. Không đưa ra tham số này thì kiểu dáng sẽ không thay đổi sai khi một khoảng thời gian nào đó.

Kiểu_dáng2 là tên tùy chọn của một kiểu dáng ô được gán cho ô đó sau một khoảng thời gian nào đó. Không đưa ra tham số này thì giả sử « Mặc định ».

Trong các hàm của Calc LibreOffice , các thông số được đánh dấu như là « tùy chọn » có thể bỏ qua chỉ khi nào đằng sau nó không còn tham số nào nữa. Ví dụ, một hàm có 4 tham số, trong đó 2 tham số cuối được đánh dấu « tùy chọn », bạn có thể bỏ qua tham số thứ 4 hoặc cả hai tham số 3 và 4, nhưng bạn không thể bỏ chỉ mỗi tham số thứ 3.

Ví dụ

Công thức =STYLE("Invisible";60;"Default") định dạng ô theo định dạng trong suốt trong 60 giây sau khi tài liệu được tính lại hay nạp, sau đó thì gán định dạng « Mặc định ». Cả hai định dạng ô này phải được xác định sẵn.

Vì STYLE() có một giá trị trả về thuộc số là 0, giá trị trả về này được phụ thêm vào một chuỗi. Có thể tránh trường hợp này dùng T(), như trong mẫu ví dụ theo đây

="Text"&T(STYLE("myStyle"))

Xem thêm CURRENT() tìm ví dụ mẫu khác.

VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact SearchCriterion is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

Cú pháp

=VLOOKUP(SearchCriterion; Array; Index; Sorted)

Tiêu_chuẩn_tìm là giá trị được tìm trong cột đầu của mảng.

Mảng là tham chiếu, mà phải trải ra ít nhất hai cột.

Chỉ_số là số thứ tự của cột trong mảng mà chứa giá trị cần trả về. Cột đầu có số thứ tự 1.

Sorted is an optional parameter that indicates whether the first column in the array is sorted in ascending order. Enter the Boolean value FALSE or zero if the first column is not sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is between the lowest and highest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return this message: Error: Value Not Available.

Ví dụ

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Hãy nhập vào ô B1 công thức này:

=VLOOKUP(A1;D1:E100;2)

Một khi bạn nhập một số vào ô A1, ô B1 sẽ hiển thị chuỗi văn bản tương ứng được chứa trong cột thứ hai của tham chiếu D1:E100. Nhập một số không tồn tại thì hiển thị chuỗi văn bản có số kế tiếp, về hướng xuống. Để ngăn cản trường hợp này, nhập FALSE (Sai) làm tham số cuối cùng trong công thức, để tạo một thông điệp lỗi khi một số không tồn tại được nhập vào.