Funkcje arkusza kalkulacyjnego

Poniżej przedstawiono opisy funkcji grupy Arkusz kalkulacyjny poparte przykładem.

Aby wykonać tę operację... Wstaw - Funkcja - Kategoria Arkusz kalkulacyjny

NR.BŁĘDU

Zwraca liczbę reprezentującą określony numer błędu lub wartość błędu #NIE DOTYCZY, jeśli błąd nie występuje.

ADR.POŚR

Zwraca odwołanie określone przez ciąg tekstowy. Funkcja może także zwracać obszar odpowiadającego jej ciągu.

Składnia

ADR.POŚR(Odwołanie; A1)

Odwołanie oznacza odwołanie do komórki lub obszaru (w postaci tekstowej), dla której należy zwrócić zawartość.

A1 (parametr opcjonalny) – jeżeli ma wartość 0, używana jest notacja W1K1. Jeżeli argument ten jest nieobecny lub została mu przypisana wartość inna niż 0, używana jest notacja A1.

Przykład

=ADR.POŚR(A1) zwraca wartość 100, jeśli komórka A1 zawiera odwołanie do komórki C108, a komórka C108 zawiera wartość 100.

=SUMA(ADR.POŚR("a1:" & ADRES(1;3))) sumuje komórki w obszarze od komórki A1 do komórki, której adres został zdefiniowany w wierszu 1 i kolumnie 3. Zostaną zatem zsumowane wartości komórek w zakresie A1:C1.

ADRES

Zwraca adres komórki (odwołanie) jako tekst zgodnie z określonymi numerami wiersza i kolumny. Funkcja pozwala na stosowanie adresacji bezwzględnej (np. $A$1), względnej (np. A1) lub mieszanej (np. A$1 lub $A1). Można także określić nazwę arkusza.

Aby zapewnić interoperacyjność, funkcje ADRES oraz ADR.POŚR obsługują dodatkowy argument, który umożliwia zdefiniowanie, czy zamiast domyślnej notacji A1 będzie używana notacja W1K1.

W funkcji ADRES argument ten jest czwartym wpisywanym argumentem, co spowodowało, że opcjonalny argument pozwalający zdefiniować nazwę arkusza został przeniesiony na pozycję piątą.

W przypadku funkcji ADR.POŚR argument ten znajduje się na drugiej pozycji.

W obu funkcjach, gdy argument przyjmie wartość 0, używana będzie notacja W1K1. Jeżeli argument nie zostanie zdefiniowany lub będzie miał wartość inną niż 0, używana będzie notacja A1.

W przypadku notacji W1K1 funkcja ADRES, zwracając łańcuchy adresowe, używa znaku wykrzyknika ('!') w charakterze separatora nazwy arkusza, a funkcja ADR.POŚR oczekuje, że wykrzyknik będzie separatorem nazwy arkusza. Przy notacji A1 w obu przypadkach funkcję separatora nazwy arkusza pełni kropka ('.').

Otwierając dokument w formacie ODF 1.0/1.1, funkcja ADRES, w której nazwa arkusza jest czwartym argumentem, przesunie ten argument w taki sposób, aby stał się on piątym argumentem funkcji. Na czwartej pozycji zostanie wstawiony nowy argument, który przyjmie wartość 1.

Przy zapisywaniu dokumentu w formacie ODF 1.0/1.1, w przypadku gdy funkcje ADRES używają czwartego argumentu, będzie on usunięty.

Składnia

ADRES(nr_wiersza; nr_kolumny; ABS; A1; "arkusz")

Wiersz oznacza numer wiersza odwołania do komórki

Kolumna oznacza numer kolumny odwołania do komórki (numer, nie litera)

Adres_bezwzględny określa typ odwołania:

1: bezwzględne ($A$1)

2: odwołanie do wiersza jest bezwzględne, odwołanie do komórki jest względne (A$1)

3: wiersz (względne); kolumna (bezwzględne) ($A1)

4: względne (A1)

A1 (parametr opcjonalny) – jeżeli ma wartość 0, używana jest notacja W1K1. Jeżeli argument ten jest nieobecny lub została mu przypisana wartość inna niż 0, używana jest notacja A1.

Arkusz oznacza nazwę arkusza. Należy ją umieścić w cudzysłowie.

Przykład:

=ADRES(1;1;2;"Arkusz2") zwraca następującą wartość: Arkusz2.A$1

Jeśli komórka A1 na arkuszu 2 zawiera wartość -6, można odwołać się pośrednio do komórki za pomocą formuły =MODUŁ.LICZBY(ADR.POŚR(B2)) w komórce B2. Wynikiem jest wartość bezwzględna w określonym w B2 odwołaniu do komórki (w tym przypadku 6).

DDE

Zwraca wynik łącza DDE. Jeśli zawartość zakresu lub sekcji łącza ulegnie zmianie, zwracana wartość także się zmieni. Aby aktualizacja łącz była widoczna, należy ponownie załadować arkusz lub wybrać Edycja - Łącza. Łącza utworzone pomiędzy różnymi platformami, na przykład z instalacji LibreOffice pracującej w systemie Windows do dokumentu na komputerze z systemem Linux nie są dopuszczalne.

Składnia

DDE("serwer";"plik";"zakres";tryb)

Server is the name of a server application. LibreOffice applications have the server name "soffice".

Plik oznacza pełną nazwę pliku wraz z określeniem ścieżki dostępu.

Zakres oznacza zakres zawierający dane do obliczeń.

Tryb (parametr opcjonalny) określa sposób, w jaki serwer DDE konwertuje dane na liczby.

Tryb	Efekt
0 lub brak	Format liczb ze stylu komórki "Domyślnie"
1	Dane są zawsze interpretowane w standardowym formacie dla języka angielskiego (USA)
2	Dane są pobierane w postaci tekstu bez konwersji na liczby

Przykład

=DDE("soffice";"c:\office\document\data1.ods";"arkusz1.A1") odczytuje zawartość komórki A1 na arkuszu Arkusz1 programu LibreOffice Calc zapisanego w pliku data1.ods.

=DDE("soffice";"c:\office\document\motto.ods";"Motto na dziś") zwraca motto w komórce zawierającej tę formułę. W pierwszej kolejności w dokumencie motto.ods zawierającym motto należy wprowadzić wiersz tekstu, a następnie zdefiniować go jako pierwszy wiersz sekcji o nazwie Motto na dziś (w programie LibreOffice Writer w menu Wstaw - Sekcja). Po zmodyfikowaniu (i zapisaniu) motta w dokumencie programu LibreOffice Writer, zostanie ono zaktualizowane w komórkach programu LibreOffice Calc zawierających zdefiniowane łącze DDE.

HIPERŁĄCZE

Po kliknięciu komórki zawierającej funkcję HIPERŁĄCZE zostaje otwarty adres docelowy.

Jeśli jest używany parametr opcjonalny Tekst_komórki, formuła lokalizuje adres URL i wyświetla tekst albo liczbę.

Składnia

HIPERŁĄCZE("URL") lub HIPERŁĄCZE("URL";"tekst komórki")

URL określa cel łącza. Parametr opcjonalny Tekst_komórki to wartość tekstowa lub liczbowa wyświetlana w komórce i zwracana jako wynik. Jeśli parametr Tekst_komórki nie został określony, tekstem wyświetlanym w komórce i zwracanym wynikiem jest URL.

Dla pustych komórek i elementów macierzy zwracana jest wartość 0.

Przykład

=HIPERŁĄCZE("http://www.przyklad.org") wyświetla tekst "http://www.przyklad.org" i po kliknięciu otwiera adres http://www.przyklad.org.

=HIPERŁĄCZE("http://www.przyklad.org";"Kliknij tutaj") wyświetla w komórce tekst "Kliknij tutaj" i po kliknięciu otwiera adres http://www.przyklad.org.

=HIPERŁĄCZE("http://www.przyklad.org";12345) wyświetla liczbę 12345 i po kliknięciu otwiera stronę internetową pod adresem http://www.przyklad.org.

=HIPERŁĄCZE($B4), gdzie komórka B4 zawiera adres http://www.przyklad.org. Ta funkcja dodaje http://www.przyklad.org do adresu URL komórki z hiperłączem i zwraca ten sam tekst.

=HIPERŁĄCZE("http://www.";"Kliknij") & "przyklad.org" wyświetla w komórce tekst "Kliknij przyklad.org" i po kliknięciu otwiera stronę internetową pod adresem http://www.przyklad.org.

=HIPERŁĄCZE("#Arkusz1.A1";"Przejdź do góry") wyświetla tekst Przejdź do góry i przeskakuje do komórki Arkusz1.A1 w tym dokumencie.

=HYPERLINK("file:///C:/writer.odt#Specification";"Przejdź do zakładki programu Writer") wyświetla tekst Przejdź do zakładki programu Writer, ładuje podany dokument tekstowy i przeskakuje do zakładki "Specification".

INDEKS

Funkcja INDEKS zwraca zawartość komórki określonej przez numer wiersza i kolumny lub opcjonalnie przez nazwę zakresu.

Składnia

INDEKS(odwołanie;wiersz;kolumna;zakres)

Odwołanie jest odwołaniem wprowadzonym bezpośrednio lub przez podanie nazwy zakresu. Jeśli odwołanie składa się z wielu zakresów, odwołanie lub nazwę zakresu należy ująć w nawiasy.

Wiersz (parametr opcjonalny) oznacza numer wiersza odwołania do zakresu, dla którego należy zwrócić wartość. W przypadku wartości zero (brak określonego wiersza) zwrócone zostaną wszystkie wiersze, do których zostało podane odwołanie.

Kolumna (parametr opcjonalny) oznacza numer kolumny odwołania do zakresu, dla którego należy zwrócić wartość. W przypadku zera (braku określonej kolumny), zostaną zwrócone wszystkie kolumny, do których istnieje odwołanie.

Zakres (parametr opcjonalny) oznacza indeks podzakresu (w przypadku odwołania do zakresu złożonego).

Przykład

=INDEKS(Ceny;4;1) zwraca wartość z wiersza 4 i kolumny 1 bazy danych zdefiniowanej jako Ceny za pomocą polecenia menu Dane - Definiuj.

=INDEKS(Suma_X;4;1) zwraca wartość w wierszu 4 i kolumnie 1 zakresu Suma_X zdefiniowanego za pomocą polecenia menu Arkusz - Nazwane zakresy i wyrażenia - Definiuj.

=INDEKS(A1:B6;1) zwraca odwołanie do pierwszego wiersza zakresu A1:B6.

=INDEKS(A1:B6;0;1) zwraca odwołanie do pierwszej kolumny zakresu A1:B6.

=INDEKS((wiele);4;1) oznacza wartość znajdującą się w 4 wierszu 1 kolumny z jednego lub kilku zakresów, które zostały nazwane w Arkusz - Nazwane zakresy i wyrażenia - Definiuj jako kilka. Kilka zakresów może zawierać kilka kwadratowych zakresów, każdy w 4 wierszu i 1 kolumnie. Jeśli teraz chcesz wezwać następny odcinek tych kilku zakresów wprowadź cyfrę 2 jako parametr zakresu.

=INDEKS(A1:B6;1;1) oznacza wartość w lewym górnym rogu zakresu A1:B6.

=INDEKS((zakres_złożony;0;0;2) zwraca odwołanie do drugiego zakresu z zakresu złożonego.

KOLUMNA

Zwraca numer kolumny odwołania do komórki. Jeśli odwołanie dotyczy komórki, zwracany jest numer kolumny tej komórki; jeśli parametrem jest obszar komórek, zwracane są numery odpowiednich komórek w postaci macierzy jednowierszowej (pod warunkiem wprowadzenia formuły w postaci macierzowej). Jeśli funkcja KOLUMNA z parametrem w postaci odwołania do obszaru nie została wprowadzona w postaci macierzowej, zostanie określony wyłącznie numer kolumny pierwszej komórki tego obszaru.

Składnia

KOLUMNA(odwołanie)

Odwołanie oznacza odwołanie do komórki lub obszaru komórek, dla którego należy odnaleźć numer pierwszej kolumny.

Jeśli odwołanie nie zostało podane, zostanie zwrócony numer kolumny komórki, w której wprowadzono formułę. Program LibreOffice Calc automatycznie definiuje odwołanie do bieżącej komórki.

Przykład

=KOLUMNA(A1) zwraca wartość 1. Kolumna A jest pierwszą kolumną w tabeli.

=KOLUMNA(C3:E3) zwraca wartość 3. Kolumna C jest trzecią kolumną w tabeli.

=KOLUMNA(D3:G10) zwraca wartość 4, ponieważ kolumna D jest czwartą kolumną w tabeli, a funkcja KOLUMNA nie została użyta jako formuła macierzowa (w takim przypadku wynikiem jest zawsze pierwsza wartość macierzy).

{=KOLUMNA(B2:B7)} i =KOLUMNA(B2:B7) zwracają wartość 2, ponieważ odwołanie zawiera wyłącznie kolumnę B będącą drugą kolumną w tabeli. Ponieważ obszary składające się z jednej kolumny mają tylko jeden numer kolumny, nie ma znaczenia, czy formuła została zapisana w postaci macierzowej.

=KOLUMNA() zwraca wartość 3, jeśli formuła została wprowadzona w kolumnie C.

{=KOLUMNA(Królik)} zwraca jednokolumnową macierz (3, 4) jeśli we wskazanym obszarze (C1:D3) znajduje się słowo "Królik".

LICZBA.ARKUSZY

Określa liczbę arkuszy odwołania. Jeśli nie zostały podane żadne parametry, funkcja zwraca liczbę arkuszy bieżącego dokumentu.

Składnia

LICZBA.ARKUSZY(odwołanie)

Odwołanie jest odwołaniem do arkusza lub obszaru. Ten parametr jest opcjonalny.

Przykład

=LICZBA.ARKUSZY(Arkusz1.A1:Arkusz3.G12) zwraca wartość 3, jeśli Arkusz1, Arkusz2 i Arkusz3 występują w określonej kolejności.

LICZBA.KOLUMN

Zwraca liczbę kolumn podanego odwołania.

Składnia

LICZBA.KOLUMN(macierz)

Macierz oznacza odwołanie do zakresu komórek, dla którego należy obliczyć liczbę kolumn. Argument może być też pojedynczą komórką.

Przykład

=LICZBA.KOLUMN(B5) zwraca wartość 1, ponieważ komórka zawiera tylko jedną kolumnę.

=LICZBA.KOLUMN(A1:C5) zwraca wartość 3. Odwołanie składa się z trzech kolumn.

=LICZBA.KOLUMN(Królik) zwraca wartość 2, jeśli Królik jest nazwanym zakresem (C1:D3).

LICZBA.WIERSZY

Zwraca liczbę wierszy w odwołaniu lub w macierzy.

Składnia

LICZBA.WIERSZY(macierz)

Macierz oznacza odwołanie lub nazwany obszar, dla którego należy obliczyć liczbę wierszy.

Przykład

=LICZBA.WIERSZY(B5) zwraca wartość 1, ponieważ komórka zawiera tylko jeden wiersz.

=LICZBA.WIERSZY(A10:B12) zwraca wartość 3.

=WIERSZE(Królik) zwraca wartość 3, jeśli "Królik" jest nazwanym obszarem (C1:D3).

NR.BŁĘDU

Zwraca liczbę określającą wartość błędu, który wystąpił w komórce. Za pomocą tego numeru można wygenerować tekst komunikatu.

Składnia

NR.BŁĘDU(odwołanie)

Odwołanie zawiera adres komórki, w której wystąpił błąd.

Przykład

Jeśli w komórce A1 został wyświetlony komunikat Błąd:518, funkcja =NR.BŁĘDU(A1) zwraca liczbę 518.

OBSZARY

Zwraca liczbę pojedynczych zakresów należących do zakresu złożonego. Zakres może składać się z ciągłego obszaru komórek lub z pojedynczej komórki.

Funkcja oczekuje jednego argumentu. Jeśli chcesz podać wiele zakresów, musisz je umieścić w dodatkowych nawiasach. Wprowadzane zakresy można rozdzielać znakiem średnika (;), jednak jest on automatycznie konwertowany na operator tyldy (~). Tylda służy do łączenia zakresów.

Składnia

OBSZARY(odwołanie)

Odwołanie oznacza odwołanie do komórki lub zakresu komórek.

Przykład

=OBSZARY((A1:B3;F2;G1)) zwraca wartość 3, ponieważ jest to odwołanie do trzech komórek i/lub obszarów. Po wpisaniu formuła jest konwertowana na =OBSZARY((A1:B3~F2~G1)).

=OBSZARY(Wszystko) zwraca wartość 1, jeśli w menu Dane - Definiuj Zakres został zdefiniowany zakres Wszystko.

PODAJ.POZYCJĘ

Zwraca względną pozycję elementu macierzy pasującego do określonej wartości. Funkcja zwraca pozycję wartości odnalezionej w przeszukiwanej_macierzy w postaci liczbowej.

Składnia

PODAJ.POZYCJĘ(kryterium_wyszukiwania;przeszukiwana_macierz;typ)

Kryterium_wyszukiwania określa wyszukiwaną wartość w macierzy składającej się z jednego wiersza lub jednej kolumny.

Przeszukiwana_macierz jest przeszukiwanym odwołaniem. Przeszukiwana macierz może być jednym wierszem lub kolumną, a także częścią jednego wiersza lub kolumny.

Typ może przyjmować wartości 1, 0 lub -1. Jeśli typ = 1 lub nie został podany, zakłada się, że pierwsza kolumna przeszukiwanej macierzy została posortowana w kolejności rosnącej. Jeśli Typ = -1, zakłada się, że pierwsza kolumna została posortowana w kolejności malejącej. Odpowiada to analogicznej funkcji programu Microsoft Excel.

Jeśli typ = 0, zwracane są tylko wartości dokładnie pasujące do kryterium. Jeśli to samo kryterium zostało odnalezione kilka razy, zwracane jest wyłącznie pierwsze wystąpienie. Wyrażenia regularne lub symbole wieloznaczne można wyszukiwać wyłącznie, jeśli typ = 0 (jeśli włączono w opcjach obliczeń).

Jeśli typ = 1 lub trzeci parametr nie został podany, zwracana jest ostatnia wartość mniejsza lub równa kryterium wyszukiwania. Ma to zastosowanie nawet w sytuacji, kiedy przeszukiwana macierz nie została posortowana. Jeśli typ = -1, zwracana jest pierwsza wartość większa lub równa.

Przykład

=PODAJ.POZYCJĘ(200;D1:D100) poszukuje wartości 200 w zakresie D1:D100, który został posortowany według kolumny D. Po odnalezieniu tej wartości zwracany jest numer zawierającego jej wiersza. Jeśli podczas przeszukiwania kolumny zostanie odnaleziona większa wartość, zwracany jest numer poprzedniego wiersza.

PRZESUNIĘCIE

Zwraca wartość przesunięcia komórki o pewną liczbę wierszy i kolumn względem danego punktu odniesienia.

Składnia

PRZESUNIĘCIE(odwołanie;wiersze;kolumny;wysokość;szerokość)

Odwołanie jest komórką, od której funkcja wyszukuje nowego odwołania.

Wiersze to liczba komórek, o którą nastąpi przesunięcie odwołania w górę (wartość ujemna) lub w dół. Użyj 0, aby pozostać w tym samym wierszu.

Kolumny to liczba kolumn, o którą nastąpi przesunięcie odwołania w lewo (wartość ujemna) lub w prawo. Użyj 0, aby pozostać w tej samej kolumnie.

Wysokość (parametr opcjonalny) to wysokość obszaru zaczynającego się w pozycji nowego odwołania.

Szerokość (parametr opcjonalny) jest szerokością obszaru zaczynającego się w pozycji nowego odwołania.

Z argumentów Wiersze i Kolumny nie mogą wynikać zerowe lub ujemne początkowe wiersze lub kolumny.

Z argumentów Wysokość i Szerokość nie może wynikać zerowa lub ujemna liczba wierszy bądź kolumn.

W funkcjach programu LibreOffice można nie podawać parametrów oznaczonych jako "opcjonalnych", tylko jeśli za nimi nie występują inne parametry. Na przykład w funkcji o czterech parametrach, w której dwa ostatnie parametry są oznaczone jako "opcjonalne", można nie podawać parametru 4 lub parametrów 3 i 4, ale nie można nie podawać tylko parametru 3.

Przykład

=PRZESUNIĘCIE(A1;2;2) zwraca wartość w komórce C3 (A1 przesunięta w dół o dwa wiersze i dwie kolumny). Jeśli komórka C3 zawiera wartość 100, funkcja zwraca wartość 100.

=PRZESUNIĘCIE(B2:C3;1;1) zwraca odwołanie do B2:C3 po przesunięciu o 1 wiersz w dół i jedną kolumnę w prawo (C3:D4).

=PRZESUNIĘCIE(B2:C3;-1;-1) zwraca odwołanie do B2:C3 po przesunięciu o 1 wiersz w górę i jedną kolumnę w lewo (A1:B2).

=PRZESUNIĘCIE(B2:C3;0;0;3;4) zwraca odwołanie do B2:C3 po zmianie rozmiaru na 3 wiersze i 4 kolumny (B2:E4).

=PRZESUNIĘCIE(B2:C3;1;0;3;4) zwraca odwołanie do B2:C3 po przesunięciu w dół o jeden wiersz i zmianie rozmiaru na 3 wiersze i 4 kolumny (B3:E5).

=SUMA(PRZESUNIĘCIE(A1; 2; 2; 5; 6)) zwraca sumę wartości obszaru rozpoczynającego się w komórce C3 o wysokości 5 wierszy i szerokości 6 kolumn (obszar=C3:H7).

SHEET

Zwraca numer arkusza odwołania lub ciąg określający nazwę arkusza. Jeśli nie zostaną podane żadne parametry, wynikiem jest numer arkusza zawierającego formułę.

Składnia

ARKUSZ(odwołanie)

Odwołanie (parametr opcjonalny) jest ciągiem określającym odwołanie do komórki lub obszaru.

Przykład

=ARKUSZ(Arkusz2.A1) zwraca wartość 2, jeśli Arkusz2 jest drugim arkuszem dokumentu.

STYL

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats have to be defined beforehand.

Składnia

STYL("styl";czas;"styl_2")

Styl oznacza nazwę stylu, który jest zastosowany do komórki. Nazwy stylów muszą być wprowadzane w cudzysłowach.

Czas jest parametrem opcjonalnym oznaczającym czas w sekundach. W przypadku braku tego parametru styl nie zostanie zmieniony po upływie określonego czasu.

Styl_2 oznacza nazwę stylu, który zostanie zastosowany do komórki po upływie określonego czasu. W przypadku braku tego parametru przyjmowany jest styl o nazwie "Domyślny".

W funkcjach programu LibreOffice można nie podawać parametrów oznaczonych jako "opcjonalnych", tylko jeśli za nimi nie występują inne parametry. Na przykład w funkcji o czterech parametrach, w której dwa ostatnie parametry są oznaczone jako "opcjonalne", można nie podawać parametru 4 lub parametrów 3 i 4, ale nie można nie podawać tylko parametru 3.

Przykład

=STYL("Niewidoczny";60;"Domyślny") stosuje do komórki format niewidoczny przez 60 sekund po przeliczeniu lub załadowaniu dokumentu. Po tym czasie zastosowany zostaje format domyślny. Formaty komórek należy zdefiniować wcześniej.

Ponieważ wynik funkcji STYL() jest wartością liczbową równą zero, zostaje ona dołączona do ciągu. Można tego uniknąć, korzystając z funkcji T(), jak to zaprezentowano w następującym przykładzie

="Tekst"&T(STYL("mójStyl"))

Inny przykład można znaleźć w opisie funkcji BIEŻĄCY().

WEŹDANETABELI

Funkcja WEŹDANETABELI zwraca wartość wynikową z tabeli przestawnej. Wartość jest adresowana za pomocą nazw pola i elementu, dlatego też pozostaje prawidłowa po zmianie układu tabeli przestawnej.

Składnia

Można zastosować dwie różne definicji składni:

WEŹDANETABELI(Pole docelowe; tabela przestawna; [ Pole 1; Element 1; ... ])

WEŹDANETABELI (tabela przestawna; Ograniczenia)

Druga składnia jest używana, jeśli są dane dokładnie dwa parametry, z czego pierwszy parametr jest komórką lub odwołaniem do zakresu komórek. Pierwsza składnia jest używana we wszystkich pozostałych przypadkach. Kreator funkcji przedstawia pierwszą składnię.

Pierwsza składnia

Pole docelowe jest ciągiem, który wybiera jedno z pól danych tabeli przestawnej. Nazwa ciągu może być nazwą kolumny źródłowej lub nazwą pola danych, jak to zostało przedstawione w tabeli (np. "Suma – Sprzedaż").

tabela przestawna jest odwołaniem do komórki lub zakresu komórek umieszczonych wewnątrz tabeli przestawnej lub zawierających ją. Jeśli zakres komórek zawiera kilka tabel przestawnych, będzie wykorzystana tabela, która została utworzona jako ostatnia.

Jeśli nie zostały podane żadne pary danych Pole n / Element n, zwracana jest suma końcowa. W przeciwnym razie każda para dodaje ograniczenie, które musi być spełnione przez wyniki. Pole n jest nazwą pola z tabeli przestawnej. Element n jest nazwą elementu z tego pola.

Jeśli tabela przestawna zawiera tylko jedną wartość wynikową, która spełnia wszystkie ograniczenia, lub wartość sumy pośredniej wszystkich zgodnych wartości, ten wynik jest zwracany. Jeśli nie ma zgodnego wyniku lub kilka z nich nie ma sumy pośredniej, zwracany jest błąd. Te warunki mają zastosowanie do wyników zawartych w tabeli przestawnej.

Jeśli dane źródłowe zawierają pozycje ukryte przez ustawienia tabeli przestawnej, są one ignorowane. Kolejność par Pole/Element nie ma znaczenia. W nazwach pól i elementów nie jest rozróżniana wielkość liter.

Jeśli nie zostało podane żadne ograniczenie dla pola strony, wybrana wartość pola zostanie zastosowana bezwarunkowo. Jeśli zostało podane ograniczenie dla pola strony, musi ono odpowiadać wybranej wartości pola lub zostanie zwrócony błąd. Pola strony są to pola w lewej górnej części tabeli przestawnej, wypełniane przy użyciu obszaru "Pola strony" w oknie dialogowym tabeli przestawnej. Z każdego pola strony, element (wartość) można wybrać i tylko taki element jest uwzględniany w obliczeniach.

Wartości sum częściowych z tabeli przestawnej są używane pod warunkiem, że wykorzystują funkcję "auto" (z wyjątkiem sytuacji, kiedy jest to określone w ograniczeniu, zobacz Druga składnia poniżej).

Druga składnia

tabela przestawna ma to samo znaczenie, co w pierwszej składni.

Ograniczenia to lista oddzielona spacjami. Pozycje mogą być zapisane w apostrofach. Cały ciąg musi być umieszczony w cudzysłowach, chyba że stosowane jest odwołanie do ciągu z innej komórki.

Jedna z pozycji może być nazwą pola danych. Nazwa pola danych może zostać pominięta, jeśli tabela przestawna zawiera tylko jedno pole danych, w przeciwnym razie musi być określona.

Każda z tych pozycji określa ograniczenie w formie Pole[Element]. Element musi być umieszczony w nawiasach kwadratowych, o ile nazwa elementu nie jest jednoznaczna we wszystkich polach używanych w tabeli przestawnej.

Nazwa funkcji może być dodana w postaci Pole[Element;Funkcja], co wymusza ograniczenia dopasowania tylko do wartości sum częściowych, które wykorzystują tę funkcję. Dopuszczalne nazwy funkcji to: Suma, Policz, Średnia, Maks, Min, Iloczyn, Ile.liczb, Odch. standardowe, Odch.standard. popul., Wariancja i Wariancja popul. Wielkość liter nie ma znaczenia.

WIERSZ

Zwraca numer wiersza odwołania do komórki. Jeśli odwołanie jest komórką, funkcja zwraca numer wiersza tej komórki. Jeśli odwołanie jest zakresem komórek, funkcja zwraca odpowiednie numery wierszy w postaci macierzy składającej się jednej kolumny (pod warunkiem wprowadzenia formuły w postaci macierzowej). Jeśli funkcja WIERSZ z parametrem w postaci odwołania do zakresu nie została wprowadzona w postaci macierzowej, zwracany jest wyłącznie numer wiersza pierwszej komórki tego obszaru.

Składnia

WIERSZ(odwołanie)

Odwołanie jest komórką, obszarem lub nazwą obszaru.

Jeśli odwołanie nie zostało podane, zwracany jest numer wiersza komórki, w której wprowadzono formułę. Program LibreOffice Calc automatycznie definiuje odwołanie do bieżącej komórki.

Przykład

=WIERSZ(B3) zwraca wartość 3, ponieważ odwołanie określa trzeci wiersz tabeli.

{=WIERSZ(D5:D8)} zwraca jednokolumnową macierz (5, 6, 7, 8), ponieważ odwołanie określa wiersze od 5 do 8.

=WIERSZ(D5:D8) zwraca wartość 5, ponieważ funkcja WIERSZ nie została zapisana w postaci macierzowej, w związku z czym zwracany jest wyłącznie numer pierwszego wiersza odwołania.

{=WIERSZ(A1:E1)} i =WIERSZ(A1:E1) zwracają wartość 1, ponieważ odwołanie zawiera wyłącznie wiersz 1 będący pierwszym wierszem w tabeli. Ponieważ obszary składające się z jednego wiersza mają tylko jeden numer wiersza, nie ma znaczenia, czy formuła została zapisana w postaci macierzowej.

=WIERSZ() zwraca wartość 3, jeśli formuła została wprowadzona w wierszu 3.

{=WIERSZ(Królik)} zwraca macierz jednokolumnową (1, 2, 3), jeśli "Królik" jest nazwanym obszarem (C1:D3).

WYBIERZ

Na podstawie indeksu zwraca wartość z listy zawierającej do 30 argumentów.

Składnia

WYBIERZ(indeks;wartość_1;...wartość_30)

Indeks oznacza odwołanie lub liczbę od 1 do 30 określającą, którą wartość z listy należy wybrać.

Wartość_1...wartość_30 stanowi listę elementów wprowadzonych w postaci odwołań do komórek lub wartości.

Przykład

=WYBIERZ(A1;B1;B2;B3;"Dzisiaj";"Wczoraj";"Jutro") zwraca zawartość komórki B2 dla A1 = 2; dla A1 = 4 funkcja zwraca tekst "Dzisiaj".

WYSZUKAJ

Zwraca zawartość komórki zawartej w jednym wierszu, jednej kolumnie lub w macierzy. Opcjonalnie przypisana wartość (o tym samym indeksie) może być zwracana w innym wierszu lub kolumnie. W przeciwieństwie do funkcji WYSZUKAJ.PIONOWO i WYSZUKAJ.POZIOMO wektor przeszukiwany i wynikowy mogą być w różnych miejscach i nie muszą być przylegające. Przeszukiwany wektor funkcji WYSZUKAJ musi być ponadto posortowany, w przeciwnym razie funkcja nie będzie zwracać użytecznych wyników.

Składnia

WYSZUKAJ(kryterium_wyszukiwana;przeszukiwany_wektor;wektor_wynikowy)

Kryterium_wyszukiwania określa wyszukiwaną wartość wprowadzoną bezpośrednio lub jako odwołanie.

Przeszukiwany_wektor określa przeszukiwany obszar składający się z jednego wiersza lub jednej kolumny.

Wektor_wynikowy jest innym zakresem składającym się z jednego wiersza lub jednej kolumny, z którego pobierany jest wynik funkcji. Wynik jest komórką wektora wynikowego o tym samym indeksie stanowiącą odnaleziony element w wektorze wyszukiwania.

Przykład

=WYSZUKAJ(A1;D1:D100;F1:F100) poszukuje w zakresie D1:D100 komórki zawierającej wartość wprowadzoną w komórce A1. Dla odnalezionego wystąpienia obliczany jest indeks, na przykład komórka numer 12 w danym zakresie. Następnie zawartość 12 komórki jest zwracana jako wartość funkcji (w postaci wektora wyników).

WYSZUKAJ.PIONOWO

Pionowe wyszukiwanie za pomocą odwołania do sąsiednich komórek po prawej stronie. Funkcja ta sprawdza czy konkretna wartość znajduje się w pierwszej kolumnie macierzy. Funkcja następnie zwraca wartość w tym samym wierszu w kolumnie wskazanej przez indeks. Jeśli parametr posortowane jest pominięty lub ustawiony na TRUE lub jeden, zakłada się, że dane są sortowane w porządku rosnącym. W tym przypadku, jeśli dokładne Kryterium_wyszukiwania nie zostanie znalezione, ostatnia wartość mniejsza niż kryterium zostanie zwrócona. Jeśli posortowane jest ustawiona na FALSE lub zero, dokładne dopasowanie musi się znaleźć, w przeciwnym wypadku wynikiem będzie błąd Błąd: Wartość niedostępna. Dla parametru zero, dane nie muszą być posortowane w porządku rosnącym.

Składnia

=WYSZUKAJ.PIONOWO(kryterium_wyszukiwana;macierz;indeks;posortowane)

Kryterium_wyszukiwania określa wyszukiwaną wartość w pierwszej kolumnie macierzy.

Macierz oznacza odwołanie składające się z co najmniej dwóch kolumn.

Indeks oznacza numer kolumny w macierzy zawierającej wartość, która ma być zwrócona. Pierwsza kolumna ma numer 1.

Posortowane jest parametrem opcjonalnym oznaczającym, że pierwsza kolumna została posortowana w kolejności alfabetycznej. Jeśli pierwsza kolumna nie została posortowana w kolejności alfabetycznej, parametr ten powinien mieć wartość logiczną FAŁSZ. Posortowane kolumny mogą być przeszukiwane znacznie szybciej, a funkcja zawsze zwraca wartość, nawet jeśli poszukiwana wartość nie została dokładnie dopasowana (pod warunkiem, że znajduje się pomiędzy najniższą i najwyższą wartością posortowanej listy). W listach nieposortowanych wartość poszukiwana musi dokładnie odpowiadać kryterium. W przeciwnym razie funkcja zwraca komunikat: Błąd: Wartość niedostępna.

Przykład

Po wprowadzeniu numeru dania menu do komórki A1 nazwa dania ma pojawić się natychmiast w sąsiedniej komórce (B1). Przypisanie numeru do nazwy znajduje się w macierzy D1:E100. D1 zawiera numer 100, E1 zawiera nazwę zupa jarzynowa, następne komórki zawierają kolejne 100 elementów. Numery w kolumnie D są sortowane w kolejności rosnącej, zatem opcjonalny parametr posortowane nie jest wymagany.

W komórce B1 wprowadź następującą formułę:

=WYSZUKAJ.PIONOWO(A1;D1:E100;2)

Po wprowadzeniu numeru do komórki A1 w komórce B1 zostanie wyświetlony odpowiedni tekst zawarty w drugiej kolumnie odwołania D1:E100. Wprowadzenie nie istniejącego numeru powoduje wyświetlenie wartości z następnej komórki. Aby temu zapobiec, jako ostatni parametr formuły należy wprowadzić wyrażenie logiczne FAŁSZ, dzięki czemu wprowadzenie nieistniejącego numeru powoduje wyświetlenie komunikatu o błędzie.

WYSZUKAJ.POZIOMO

Szuka wartości i odwołania do komórek poniżej zaznaczonego obszaru. Funkcja sprawdza, czy pierwszy wiersz macierzy zawiera określoną wartość, a następnie w tej samej kolumnie zwraca wartość wiersza macierzy nazwanego Indeks.

Składnia

=WYSZUKAJ.POZIOMO(kryterium_wyszukiwania;macierz;indeks;posortowane)

Zobacz także: WYSZUKAJ.PIONOWO (zamienione kolumny i wiersze)