Wiskundige functies

Deze categorie bevat de wiskundige functies voor Calc. Wilt u de Functie-Assistent openen, dan kiest u Invoegen - Functie.

AGGREGEREN

Deze functie geeft een aggregatie-resultaat van de berekeningen in het assortiment. U kunt verschillende statistische functies die hieronder staan gebruiken. Met de Aggregatie-functie kunt u verborgen rijen, fouten, SUBTOTAAL en andere statistische functie resultaten weglaten uit de berekening.

SOM.ALS

Geeft de som van de waarden van de cellen in een bereik die aan meerdere criteria in meerdere bereiken voldoen.

ABS

Berekent de absolute waarde van een getal.

Syntaxis

ABS(Getal)

Getal is het getal waarvan de absolute waarde moet worden berekend. De absolute waarde van een getal is zijn waarde zonder het +/- teken.

Voorbeeld

=ABS(-56) geeft 56 terug.

=ABS(12) geeft 12 terug.

=ABS(0) geeft 0 terug.

AFRONDEN

Rondt een getal af op een bepaald aantal decimalen.

Syntaxis

AFRONDEN(Getal; Aantal)

Geeft Getal afgerond tot Aantal plaatsen achter de komma terug. De functie rondt af naar het dichtstbijzijnde geheel getal als Aantal wordt weggelaten of nul is. De functie rondt af op de dichtstbijzijnde 10, 100, 1000, enzovoort als Aantal negatief is.

Deze functie rond af naar het dichtstbijzijnde getal. Zie ook AFRONDEN.NAARBENEDEN en AFRONDEN.NAAR.BOVEN voor alternatieven.

Voorbeeld

=AFRONDEN(2,348;2) geeft 2,35 terug.

=AFRONDEN(-32,4834;3) geeft -32,483 terug. Wijzig de opmaak van de cel om alle getallen achter de komma te zien.

=AFRONDEN(2,348;0) geeft 2 terug.

=AFRONDEN(2,5) geeft 3 terug.

=AFRONDEN(987,65;-2) geeft 1000 terug.

AFRONDEN.BENEDEN

Rondt een getal naar beneden af op het dichtstbijzijnde veelvoud van de stapgrootte.

Syntaxis

AFRONDEN.BENEDEN(Getal; Stapgrootte; Modus)

Getal is het getal dat naar beneden moet worden afgerond.

Stapgrootte is de waarde waar met welk veelvoud ervan het getal naar beneden wordt afgerond.

Modus is een optionele waarde. Als de waarde voor Modus ingevuld is en niet nul is en als Getal en Significantie negatief zijn, dan wordt de afronding gebaseerd op de absolute waarde van Getal, dat wil zeggen dat negatieve getallen van nul af afgerond worden. Als de waarde voor Modus nul of niet ingevuld is, worden negatieve getallen naar nul toe afgerond.

Voorbeeld

=AFRONDEN.BENEDEN( -11;-2) geeft -12 terug

=AFRONDEN.BENEDEN( -11;-2;0) geeft -12 terug

=AFRONDEN.BENEDEN( -11;-2;1) geeft -10 terug

AFRONDEN.BOVEN

Rondt een getal af op het dichtstbijzijnde veelvoud van de stapgrootte.

Syntaxis

AFRONDEN.BOVEN(Getal; Stapgrootte; Modus)

Getal is het getal dat naar boven moet worden afgerond.

Stapgrootte is het getal, op een veelvoud waarvan naar boven moet worden afgerond.

Modus is een optionele waarde. Als de waarde voor Modus ingevuld is en niet nul is en als Getal en Significantie negatief zijn, dan wordt de afronding gebaseerd op de absolute waarde van Getal, dat wil zeggen dat negatieve getallen van nul af afgerond worden. Als de waarde voor Modus nul of niet ingevuld is, worden negatieve getallen naar nul toe afgerond.

Voorbeeld

=AFRONDEN.BOVEN(-11;-2) geeft -10 terug

=AFRONDEN.BOVEN(-11;-2;0) geeft -10 terug

=AFRONDEN.BOVEN(-11;-2;1) geeft -10 terug

AFRONDEN.N.VEELVOUD

Geeft een getal terug dat is afgerond naar het dichtstbijzijnde veelvoud van een ander getal.

Syntaxis

AFRONDEN.N.VEELVOUD(Getal; veelvoud)

Geeft Getal, afgerond tot het dichtstbijzijnde veelvoud van Veelvoud, weer.

Een alternatieve implementatie zou zijn Meerdere * AFRONDEN(Getal/Meerdere).

Voorbeeld

=AFRONDEN.N.VEELVOUD(15,5;3) geeft 15 terug, omdat 15,5 dichter bij 15 (= 3*5) ligt, dan bij 18 (= 3*6).

=AFRONDEN.N.VEELVOUD(1,4;0,5) geeft 1,5 (= 0,5*3) terug.

AFRONDEN.NAAR.BENEDEN

Rondt een getal af naar beneden, in de richting van nul, tot een bepaalde precisie.

Syntaxis

AFRONDEN.NAAR.BENEDEN(Getal; Aantal)

Geeft Getal afgerond naar beneden (in de richting van nul) naar Aantal getallen achter de komma. De functie rondt naar beneden af op een geheel getal als Aantal wordt weggelaten of nul is. De functie rondt naar beneden af op de volgende 10, 100, 1000, enzovoort als Aantal negatief is.

Deze functie rondt af in de richting van nul. Zie AFRONDEN.NAAR.BOVEN en AFRONDEN voor alternatieven.

Voorbeeld

=AFRONDEN.NAAR.BENEDEN(1.234;2) geeft 1,23 terug.

=AFRONDEN.NAAR.BENEDEN(45,67;0) geeft 45 terug.

=AFRONDEN.NAAR.BENEDEN(-45,67;0) geeft -45 terug.

=AFRONDEN.NAAR.BENEDEN(987,65;-2) geeft 900 terug.

AFRONDEN.NAAR.BOVEN

Rondt een getal af, weg van nul, tot een bepaalde precisie.

Syntaxis

AFRONDEN.NAAR.BOVEN(Getal; Aantal)

Geeft Getal naar boven afgerond (weg van nul) tot op Aantal plaatsen achter de komma. De functie rondt naar boven af op een geheel getal als Aantal wordt weggelaten of nul is. De functie rondt naar boven af op de volgende 10, 100, 1000, enzovoort als Aantal negatief is.

Deze functie rondt af, weg van nul. Zie AFRONDEN.NAAR.BENEDEN en AFRONDEN voor alternatieven.

Voorbeeld

=AFRONDEN.NAAR.BOVEN(1,1111;2) geeft 1,12 terug.

=AFRONDEN.NAAR.BOVEN(1,2345;1) geeft 1,3 terug.

=AFRONDEN.NAAR.BOVEN(45.67;0) geeft 46 terug.

=AFRONDEN.NAAR.BOVEN(-45,67) geeft -46 terug.

=AFRONDEN.NAAR.BOVEN(987,65;-2) geeft 1000 terug.

ASELECT

Geeft als resultaat een willekeurig getal tussen 0 en 1.

Syntaxis

ASELECT()

Deze functie levert een nieuw willekeurig getal steeds als Calc opnieuw berekent. Druk op F9 om handmatig te berekenen.

Kopieer cellen die elk =ASELECT() bevatten en gebruik Bewerken - Plakken speciaal (met Alles plakken en Formules niet gemarkeerd en Getallen gemarkeerd) om willekeurige getallen te genereren die nooit opnieuw berekend worden.

Voorbeeld

=ASELECT() geeft een willekeurig getal tussen 0 en 1 terug.

ASELECTTUSSEN

Geeft een willekeurig geheel getal terug uit een gespecificeerd bereik.

Syntaxis

ASELECTTUSSEN(kleinste getal; grootste getal)

Geeft een willekeurig geheel getal terug tussen de gehele getallen Beneden en Boven (inclusief beide).

Deze functie produceert, elke keer als Calc opnieuw berekent, een nieuw willekeurig getal. Druk op Shift++F9 om, handmatig, Calc opnieuw te laten berekenen.

Kopieer cellen die deze functie bevatten en gebruik Bewerken - Plakken speciaal (met Alles plakken en Formules niet gemarkeerd en Getallen gemarkeerd) om willekeurige getallen te genereren die nooit opnieuw berekend worden.

Voorbeeld

=ASELECTTUSSEN(20;30) geeft een geheel terug tussen 20 en 30.

BOOGCOS

Berekent de inverse trigonometrische cosinus van een getal.

Syntaxis

BOOGCOS(Getal)

Deze functie geeft de inverse trigonometrische cosinus van Getal terug, dat is de hoek (in radialen) waarvan de cosinus Getal is. De teruggegeven hoek ligt tussen 0 en PI.

Gebruik de functie GRADEN om de hoek in graden terug te geven.

Voorbeeld

=BOOGCOS(-1) geeft 3,14159265358979 terug (PI radialen)

=GRADEN(BOOGCOS(0,5)) geeft 60 terug. De cosinus van 60 graden is 0,5.

BOOGCOSH

Berekent de inverse cosinus hyperbolicus van een getal.

Syntaxis

BOOGCOSH(Getal)

Deze functie geeft de inverse cosinus hyperbolicus van Getal terug, dat is het getal waarvan de cosinus hyperbolicus Getal is.

Getal moet groter of gelijk zijn aan 1.

Voorbeeld

=BOOGCOSH(1) geeft 0 terug.

=BOOGCOSH(COSH(4)) geeft 4 terug.

BOOGCOT

Geeft de inverse cotangens weer (de boogcotangens) van het opgegeven getal.

Syntaxis

BOOGCOT(Getal)

Deze functie geeft de inverse trigonometrische cotangens van Getal terug, dat is de hoek (in radialen) waarvan de cotangens Getal is. De teruggegeven hoek ligt tussen 0 en PI.

Gebruik de functie GRADEN om de hoek in graden terug te geven.

Voorbeeld

=BOOGCOT(1) geeft 0,785398163397448 terug (PI/4 radialen).

=GRADEN(BOOGCOT(1)) geeft 45 terug. De tangens van 45 graden is 1.

BOOGCOTH

Berekent de inverse cotangens hyperbolicus van een bepaald getal.

Syntaxis

BOOGCOTH(Getal)

Deze functie geeft de inverse cotangens hyperbolicus van Getal terug, dat is het getal waarvan de cotangens hyperbolicus Getal is.

Een fout treedt op als Getal tussen, inclusief, -1 en 1 ligt.

Voorbeeld

=BOOGCOTH(1,1) geeft de inverse cotangens hyperbolicus van 1,1 terug, ongeveer 1,52226.

BOOGSIN

Berekent de inverse trigonometrische sinus van een getal.

Syntaxis

BOOGSIN(Getal)

Deze functie geeft de inverse trigonometrische sinus van Getal terug, dat is de hoek (in radialen) waarvan de sinus Getal is. De teruggegeven hoek ligt tussen -PI/2 en +PI/2.

Gebruik de functie GRADEN om de hoek in graden terug te geven.

Voorbeeld

=BOOGSIN(0) geeft 0 terug.

=BOOGSIN(1) geeft 1,5707963267949 terug (PI/2 radialen).

=GRADEN(BOOGSIN(0,5)) geeft 30 terug. De sinus van 30 graden is 0,5.

BOOGSINH

Berekent de inverse sinus hyperbolicus van een getal.

Syntaxis

BOOGSINH(Getal)

Deze functie geeft de inverse sinus hyperbolicus van Getal terug, dat is het getal waarvan de sinus hyperbolicus Getal is.

Voorbeeld

=BOOGSINH(-90) geeft ongeveer -5,1929877 terug.

=BOOGSINH(SINH(4)) geeft 4 terug.

BOOGTAN

Berekent de inverse trigonometrische tangens van een getal.

Syntaxis

BOOGTAN(Getal)

Deze functie geeft de inverse tangens hyperbolicus van Getal terug, dat is het getal waarvan de tangens hyperbolicus Getal is. De teruggegeven hoek ligt tussen -PI/2 en PI/2.

Gebruik de functie GRADEN om de hoek in graden terug te geven.

Voorbeeld

=BOOGTAN(1) geeft 0,785398163397448 terug (PI/4 radialen).

=GRADEN(BOOGTAN(1)) geeft 45 terug. De tangens van 45 graden is 1.

BOOGTAN2

Geeft de inverse trigonometrische tangens van de gespecificeerde x- en y-coördinaten.

Syntaxis

BOOGTAN2(GetalX; GetalY)

Getal is de waarde van de x-coördinaat.

Getal is de waarde van de y-coördinaat.

BOOGTAN2 geeft de inverse trigonometrische tangens terug, dat is de hoek (in radialen) tussen de x-as en een lijn tussen punt GetalX en GetalY naar de oorsprong. De teruggegeven hoek ligt tussen -PI en PI.

Gebruik de functie GRADEN om de hoek in graden terug te geven.

Voorbeeld

=BOOGTAN2(20;20) geeft 0,785398163397448 terug (PI/4 radialen).

=GRADEN(BOOGTAN2(12,3;12,3)) geeft 45 toe. De tangens van 45 graden is 1.

BOOGTANH

Berekent de inverse tangens hyperbolicus van een getal.

Syntaxis

BOOGTANH(Getal)

Deze functie geeft de inverse tangens hyperbolicus van Getal terug, dat is het getal waarvan de tangens hyperbolicus Getal is.

Getal moet voldoen aan de voorwaarde -1 < Getal < 1.

Voorbeeld

=BOOGTANH(0) geeft 0 terug.

BOVENGRENS.PRECIES

Rondt een getal af op het dichtstbijzijnde veelvoud van de stapgrootte, ongeacht het teken van de verhoging.

Syntaxis

BOVENGRENS.PRECIES(Getal; Stapgrootte)

Getal (vereist) is het getal dat naar boven moet worden afgerond.

Stapgrootte (optioneel) is het getal, op een veelvoud waarvan naar boven moet worden afgerond.

Voorbeeld

=BOVENGRENS.PRECIES(-11;-2) geeft -10 terug

COMBINATIES

Geeft het aantal combinaties van elementen zonder herhaling.

Syntaxis

COMBINATIES(Aantal1; Aantal2)

Aantal1 is het aantal items in de verzameling.

Aantal2 is het aantal items waaruit in de verzameling gekozen kan worden.

COMBINATIES geeft het aantal manieren terug om deze items te kiezen. Bijvoorbeeld: als er 3 items A, B en C in een verzameling zitten, kunt u 2 items op 3 verschillende manieren kiezen, namelijk AB, AC en BC.

COMBINATIES implementeert de formule: Aantal1!/(Aantal2!*(Aantal1-Aantal2)!)

Voorbeeld

=COMBINATIES(3;2) geeft 3 terug.

COMBINATIES2

Geeft het aantal combinaties van een deelverzameling van items terug, inclusief herhalingen.

Syntaxis

COMBINATIES2(Aantal1; Aantal2)

Aantal1 is het aantal items in de verzameling.

Aantal2 is het aantal items waaruit in de verzameling gekozen kan worden.

COMBINATIES2 geeft het aantal unieke manieren weer om deze items te kiezen, waarbij de volgorde van kiezen niet belangrijk is en herhaling van items is toegestaan. Als er bijvoorbeeld 3 items A, B en C in een verzameling zijn opgenomen, kunt u 2 items kiezen op 6 verschillende manieren, namelijk AA, AB, AC, BB, BC en CC.

COMBINATIES2 implementeert de formule: (Aantal1+Aantal2-1)! / (Aantal2!(Aantal1-1)!)

Voorbeeld

=COMBINATIES2(3;2) geeft 6 terug.

CONVERTEREN_OOO

Converteert een getal uit een bepaald maatstelsel naar een ander maatstelsel. De conversiefactoren worden opgegeven in een lijst in de configuratie.

De lijst van conversiefactoren bevatte eens de oude Europese valuta en de Euro (zie de voorbeelden hieronder). We stellen voor de nieuwe functie EURO.CONVERTEREN te gebruiken voor het converteren van die valuta.

Syntaxis

CONVERTEREN_OOO(waarde;"tekst";"tekst")

Voorbeeld

=CONVERTEREN_OOO(100;"ATS";"EUR") geeft de Euro-waarde van 100 Oostenrijkse schilling.

=CONVERTEREN_OOO(100;"EUR";"DEM") converteert 100 Euro naar Duitse marken.

COS

Geeft de cosinus van de opgegeven hoek terug (in radialen).

Syntaxis

COS(Getal)

Geeft de (trigonometrische) cosinus van Getal terug, de hoek in radialen.

Gebruik de functie RADIALEN om de cosinus van een hoek in graden weer te geven.

Voorbeelden

=COS(PI()*2) geeft 1 terug, de cosinus van 2*PI radialen.

=COS(RADIALEN(60)) geeft 0,5 terug, de cosinus van 60 graden.

COSEC

Geeft de cosecans van de opgegeven hoek (in radialen). De cosecant van een hoek is gelijk aan 1 gedeeld door de sinus van die hoek

Syntaxis

COSEC(Getal)

Geeft de (trigonometrische) cosecans vanNummer, de hoek in radialen.

Gebruik de functie RADIALEN om de cosinus van een hoek in graden weer te geven.

Voorbeelden

=COSEC(PI()/4)geeft ongeveer 1,4142135624, de inverse van de sinus van PI/4 radialen.

=COSEC(RADIANS(30)) geeft 2, de cosecans van 30 graden.

COSECH

Geeft de hyperbolische cosecans van een getal.

Syntaxis

COSECH(Getal)

Geeft de cosecans hyperbolicus van Getal terug.

Voorbeeld

=COSECH(1)geeft ongeveer 0,8509181282, de hyperbolische cosecans van 1.

COSH

Berekent de cosinus hyperbolicus van een getal.

Syntaxis

COSH(Getal)

Geeft de cosinus hyperbolicus van Getal terug.

Voorbeeld

=COSH(0) geeft 1 terug, de cosinus hyperbolicus van 0.

COT

Geeft de cotangens van de opgegeven hoek terug (in radialen).

Syntaxis

COT(Getal)

Geeft de (trigonometrische) cotangens van Getal terug, de hoek in radialen.

Gebruik de functie RADIALEN om de cotangens van een hoek in graden weer te geven.

De cotangens van een hoek is hetzelfde als 1 gedeeld door de tangens van die hoek.

Voorbeelden:

=COT(PI()/4) geeft 1 terug, de cotangens van PI/4 radialen.

=COT(RADIALEN(45)) geeft 1 terug, de cotangens van 45 graden.

COTH

Berekent de cotangens hyperbolicus van een gegeven getal (hoek).

Syntaxis

COTH(Getal)

Geeft de cotangens hyperbolicus van Getal terug.

Voorbeeld

=COTH(1) geeft de cotangens hyperbolicus van 1, ongeveer 1,3130.

EURO.CONVERTEREN

Converteert oude Europese nationale valuta naar en van Euro's.

Syntaxis

EURO.CONVERTEREN(Waarde; "Valuta1"; "Valuta2", volledige_precisie, triangulatie_precisie)

Waarde is het bedrag van de valuta dat moet worden geconverteerd.

Valuta1 en Valuta2 zijn de respectievelijke valutaeenheden waarvan en waarnaar geconverteerd moet worden. Deze moeten tekst zijn, de officiële afkorting voor de valuta (bijvoorbeeld "EUR"). De koersen (weergegeven per Euro) werden vastgesteld door de Europese Commissie.

Volledige_precisie is optioneel. Indien weggelaten of ONWAAR wordt het resultaat afgerond tot achter de komma zoals voor Valuta2. Als Volledige_precisie WAAR is, wordt het resultaat niet afgerond.

Triangulatie_precisie is optioneel. Indien Triangulatie_precisie is opgegeven en >=3 wordt het tussenresultaat van een driehoeksconversie (valuta1,EUR,valuta2) afgerond naar die precisie. Indien Triangulatie_precisie is weggelaten wordt het resultaat niet afgerond. Ook als Valuta2 "EUR" is wordt Triangulatie_precisie gebruikt alsof triangulatie nodig was en wordt de conversie van EUR naar EUR toegepast.

Voorbeelden

=EURO.CONVERTEREN(100;"ATS";"EUR") converteert 100 Oostenrijkse schilling naar Euro's.

=EURO.CONVERTEREN(100;"EUR";"DEM") converteert 100 Euro's naar Duitse marken.

EVEN

Rondt een positief getal naar boven af naar het volgende even gehele getal en rondt een negatief getal naar beneden af naar het volgende even gehele getal.

Syntaxis

EVEN(Getal)

Geeft Getal afgerond naar boven op het volgende gehele getal, weg van nul.

Voorbeelden

=EVEN(2,3) geeft 4 terug.

=EVEN(2) geeft 2 terug.

=EVEN(0) geeft 0 terug.

=EVEN(-0,5) geeft -2 terug.

EXP

Geeft e verheven tot de macht van een getal. De constante e heeft een waarde van ongeveer 2,71828182845904.

Syntaxis

EXP(Getal)

Getal is de macht waartoe e verheven moet worden.

Voorbeeld

=EXP(1) geeft 2,71828182845904 terug, de mathematische constante e naar Calc's nauwkeurigheid.

FACULTEIT

Geeft de faculteit van een getal terug.

Syntaxis

FACULTEIT(Getal)

Geeft Getal!, de faculteit van Getal, berekend als 1*2*3*4* ... * Getal.

=FACULTEIT(0) geeft per definitie 1 terug.

De faculteit van een negatief getal geeft de foutcode 502 "ongeldig argument" terug.

Voorbeeld

=FACULTEIT(3) geeft 6 terug.

=FACULTEIT(0) geeft 1 terug.

GCD_EXCEL2003

Het resultaat is de grootste gemene deler van een lijst met getallen.

Syntaxis

GCD_EXCEL2003(Getal(len))

Getal(len) is een lijst van maximaal 30 getallen.

Voorbeeld

=GCD_EXCEL2003(5;15;25) geeft 5 terug.

GEH.GET.

Rondt een getal naar beneden af op het dichtstbijzijnde gehele getal.

Syntaxis

GEH.GET(Getal)

Geeft Getal afgerond naar beneden naar het dichtstbijzijnde gehele getal terug.

Negatieve getallen worden afgerond naar het gehele getal daar onder.

Voorbeeld

=INT(5,7) geeft 5 terug.

=INT(-1,3) geeft -2 terug.

GEHEEL

Breekt een getal af door decimalen te verwijderen.

Syntaxis

GEHEEL(Getal; Aantal)

Geeft Getal terug met ten hoogste Aantal plaatsen achter de komma. Meer getallen achter de komma worden eenvoudigweg verwijderd, ongeacht hun teken.

GEHEEL(Getal; 0) gedraagt zich als INT(Getal) voor positieve getallen, maar rondt effectief af in de richting van nul voor negatieve getallen.

Voorbeeld

=GEHEEL(1,239;2) geeft 1,23 terug. De 9 gaat verloren.

=GEHEEL(-1,234999;3) geeft -1,234 terug. Alle 9's gaan verloren.

GGD

Geeft de grootste gemene deler van twee of meer gehele getallen.

De grootste gemene deler is het positieve grootste gehele getal waardoor elk van de opgegeven gehele getallen zonder restwaarde kan worden gedeeld.

Syntaxis

GGD(Geheel getal1; Geheel getal2; ...; Geheel getal30)

Geheel getal1 tot en met 30 zijn maximaal 30 gehele getallen waarvan de grootste gemene deler moet worden berekend.

Voorbeeld

=GGD(16;32;24) geeft het resultaat 8, omdat 8 het grootste getal is dat 16, 24 en 32 kan delen zonder een restant.

=GGD(B1:B3) waarbij de cellen B1, B2 en B3 bevatten: 9, 12, 9 geeft 3.

GRADEN

Converteert radialen naar graden.

Syntaxis

GRADEN(Getal)

Getal is de hoek in radialen die moet worden geconverteerd naar graden.

Voorbeeld

=GRADEN(PI()) geeft 180 graden terug.

ISO.BOVENGRENS

Rond een getal naar boven af op het dichtstbijzijnde veelvoud van de stapgrootte, ongeacht het teken van de stapgrootte

Syntaxis

ISO.BOVENGRENS(Getal; Stapgrootte)

Getal (vereist) is het getal dat naar boven moet worden afgerond.

Stapgrootte (optioneel) is het getal, op een veelvoud waarvan naar boven moet worden afgerond.

Voorbeeld

=AFRONDEN.BOVEN(-11;-2) geeft -10 terug

KGV

Geeft het kleinste gemene veelvoud van een of meer gehele getallen.

Syntaxis

KGV(Geheel getal1; Geheel getal2; ...; Geheel getal30)

Geheel getal1 tot en met 30 zijn maximaal 30 gehele getallen waarvan het laagste gemene veelvoud moet worden berekend.

Voorbeeld

Indien u de getallen 512;1024 en 2000 in de tekstvakken Getal 1, 2 en 3 invoert, zal 128000 worden teruggegeven als het resultaat.

KWADRATENSOM

Als u de som van de kwadraten van getallen wilt berekenen (optellen van de kwadraten van de argumenten), voert u deze in de tekstvelden in.

Syntaxis

KWADRATENSOM(Getal1; Getal2; ...; Getal30)

Getal1 tot en met 30 zijn maximaal 30 argumenten waarvan de som van de kwadraten moet worden berekend.

Voorbeeld

Indien u de getallen 2; 3 en 4 in de tekstvakken Getal 1, 2 en 3 invoert, zal 29 worden teruggegeven als het resultaat.

LCM_EXCEL2003

Het resultaat is het kleinste gemene veelvoud van een lijst met getallen.

Syntaxis

LCM_EXCEL2003(Getal(len))

Getal(len) is een lijst van maximaal 30 getallen.

Voorbeeld

=LCM_EXCEL2003(5;15;25) geeft 75 terug.

LN

Geeft de natuurlijke logaritme op basis van de constante e van een getal. De constante e heeft een waarde van ongeveer 2,71828182845904.

Syntaxis

LN(Getal)

Getal is de waarde waarvan de natuurlijke logaritme berekend moet worden.

Voorbeeld

=LN(3) geeft het natuurlijk logaritme van 3 terug (ongeveer 1,0986).

=LN(EXP(321)) geeft 321 terug.

LOG

Geeft het logaritme van een getal tot de gespecificeerde basis.

Syntaxis

LOG(Getal; Basis)

Getal is de waarde waarvan het logaritme berekend moet worden.

Basis (optioneel) is de base voor berekening van de logaritme. Indien weggelaten wordt 10 als basis beschouwd.

Voorbeeld

=LOG(10;3) geeft de logaritme naar de basis 3 van 10 (ongeveer 2,0959).

=LOG(7^4;7) geeft 4 terug.

LOG10

Geeft de logaritme tot de basis 10 van een getal.

Syntaxis

LOG10(Getal)

Geeft de logaritme naar basis 10 van Getal terug.

Voorbeeld

=LOG10(5) geeft de basis-10 logaritme van 5 (ongeveer 0,69897).

MACHT

Geeft een getal, verheven tot een bepaalde macht, terug.

Syntaxis

MACHT(Basis; Macht)

Geeft Basis verhoogd met de macht Macht terug.

Hetzelfde resultaat kan worden bereikt door de exponentiële operator ^ te gebruiken:

Basis^Macht

Voorbeeld

=MACHT(4;3) geeft 64 terug, dat 4 tot de macht 3 is.

=4^3 geeft ook 4 tot de macht 3 terug.

MULTINOMIAAL

Geeft de faculteit van de som van de argumenten gedeeld door het product van de faculteiten van de argumenten.

Syntaxis

MULTINOMIAAL(Getal(len))

Getal(len) is een lijst van maximaal 30 getallen.

Voorbeeld

=MULTINOMIAAL(F11:H11) geeft 1260 terug, als F11 tot en met H11 de waarden 2, 3 en 4 bevatten. Dit komt overeen met de formule =(2+3+4)! / (2!*3!*4!)

ONDERGRENS.PRECIES

Rondt een getal naar beneden af op het dichtstbijzijnde veelvoud van de stapgrootte, ongeacht het teken van de stapgrootte

Syntaxis

ONDERGRENS.PRECIES(Getal; Stapgrootte)

Getal is het getal dat naar beneden moet worden afgerond.

Stapgrootte is de waarde waar met welk veelvoud ervan het getal naar beneden wordt afgerond.

Voorbeeld

=ONDERGRENS.PRECIES( -11;-2) geeft -12 terug

ONEVEN

Rondt een positief getal naar boven af op het dichtstbijzijnde oneven gehele getal en een negatief getal naar beneden naar het dichtstbijzijnde oneven gehele getal.

Syntaxis

ONEVEN(Getal)

Geeft Getal afgerond naar boven tot het volgende oneven geheel getal terug, weg van nul.

Voorbeeld

=ONEVEN(1,2) geeft 3 weer.

=ONEVEN(1) geeft 1 weer.

=ONEVEN(0) geeft 1 terug.

=ONEVEN(-3,1) geeft -5 weer.

PI

Geeft 3,14159265358979 terug, de waarde van de wiskundige constante PI met 14 decimale plaatsen.

Syntaxis

PI()

Voorbeeld

=PI() geeft 3,14159265358979 terug.

POS.NEG

Geeft het teken terug van een getal. Geeft 1 terug als het getal positief is, -1 indien negatief en 0 indien nul.

Syntaxis

POS.NEG(Getal)

Getal is het getal waarvoor het plus- of minteken vastgesteld moet worden.

Voorbeeld

=POS.NEG(3,4) geeft 1 terug.

=POS.NEG(-4,5) geeft -1 terug.

PRODUCT

Vermenigvuldigt alle getallen die als argumenten zijn gegeven en geeft het product.

Syntaxis

PRODUCT(Getal1; Getal; ...; Getal30)

Getal1 tot en met 30 zijn maximaal 30 argumenten waarvan het product moet worden berekend.

PRODUCT geeft getal1 * getal2 * getal3 * ... weer.

Voorbeeld

=PRODUCT(2;3;4) geeft 24 terug.

QUOTIËNT

Geeft het deel van het gehele getal terug van een deling.

Syntaxis

QUOTIENT(Teller; Noemer)

Geeft het geheel getal-gedeelte van Teller gedeeld door Noemer weer.

QUOTIENT is hetzelfde als INT(noemer/teller), met uitzondering van het feit dat het foutmeldingen met verschillende foutcodes kan geven.

Voorbeeld

=QUOTIENT(11;3) geeft 3 terug. De resterende 2 gaan verloren.

RADIALEN

Converteert graden naar radialen.

Syntaxis

RADIALEN(Getal)

Getal is de hoek in graden die moet worden geconverteerd naar radialen.

Voorbeeld

=RADIALEN(90) geeft 1,5707963267949 terug, wat PI/2 is naar Calc's nauwkeurigheid.

REST

Geeft het restgetal als het ene gehele getal wordt gedeeld door een ander.

Syntaxis

REST(Deeltal; Deler)

Voor argumenten voor gehele getallen geeft deze functie Restgetal modulo Deler, dat is het restgetal als Restgetal wordt gedeeld door Deler.

Deze functie is geïmplementeerd als Restgetal - Deler * INT(Restgetal/Deler) en deze formule geeft het resultaat als de argumenten geen gehele getallen zijn.

Voorbeeld

=REST(22;3) geeft 1 terug, het restgetal als 22 is gedeeld door 3.

=REST(11.25;2.5) geeft 1,25 terug.

SEC

Geeft de snijlijn van de opgegeven hoek (in radialen). De snijlijn van een hoek gelijk aan 1 gedeeld door de cosinus van die hoek

Syntaxis

SEC(Getal)

Geeft de (trigonometrische) secans van Aantal, de hoek in radialen.

Gebruik de functie RADIALEN om de secans van een hoek in graden weer te geven.

Voorbeelden

=SEC(PI()/4) geeft ongeveer 1.4142135624 terug, het omgekeerde van de cosinus van PI/4 radialen.

=SEC(RADIANS(60)) geeft 2 terug, de secans van 60 graden.

SECH

Geeft de secans hyperbolicus van een getal terug.

Syntaxis

SECH(Getal)

Geeft de secans hyperbolicus van Getal terug.

Voorbeeld

=SECH(0) geeft 1 terug, de secans hyperbolicus van 0.

SIN

Geeft de sinus van de opgegeven hoek terug (in radialen).

Syntaxis

SIN(Getal)

Geeft de (trigonometrische) sinus van Getal terug, de hoek in radialen.

Gebruik de functie RADIALEN om de sinus van een hoek in graden weer te geven.

Voorbeeld

=SIN(PI()/2) geeft 1 terug, de sinus van PI/2 radialen.

=SIN(RADIALEN(30)) geeft 0,5 terug, de sinus van 30 graden.

SINH

Berekent de sinus hyperbolicus van een getal.

Syntaxis

SINH(Getal)

Geeft de sinus hyperbolicus van Getal terug.

Voorbeeld

=SINH(0) geeft 0 terug, de sinus hyperbolicus van 0.

SOM

Telt alle getallen in een cellenbereik op.

Syntaxis

SOM(Getal1; Getal2; ...; Getal30)

Getal1 tot en met 30 zijn maximaal 30 argumenten waarvan de som moet worden berekend.

Voorbeeld

Indien u de getallen 2; 3 en 4 in de tekstvakken Getal 1, 2 en 3 invoert, zal 9 worden teruggegeven als het resultaat.

=SOM(A1;A3;B5) berekent de som van de drie cellen. =SOM (A1:E10) berekent de som van alle cellen in het celbereik A1 tot en met E10.

Voorwaarden die met EN gekoppeld zijn, kunnen als volgt met de functie SOM() gebruikt worden:

Voorbeeld uitgaande van: U heeft rekeningen in een tabel ingevoerd. Kolom A bevat de datumwaarde van de rekening, kolom B de bedragen. U wilt een formule vinden die u kunt gebruiken om het totaal van alle bedragen te berekenen, maar alleen voor een bepaalde maand, bijvoorbeeld alleen het bedrag voor de periode >=01-01-2008 tot <01-02-2008. Het bereik met de datumwaarden betreft A1:A40, het bereik dat de bedragen bevat die moeten worden getotaliseerd is B1:B40. C1 bevat de startdatum, 01-01-2008, van de rekeningen die moeten worden gebruikt en C2 de datum, 01-02-2008, die niet langer moet worden gebruikt.

Voer de volgende formule als een matrixformule in:

=SOM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Wilt u dit als een matrixformule invoeren, dan moet u Shift + Enter indrukken in plaats van alleen de Enter-toets om de formule te sluiten. De formule wordt dan tussen accolades in de Formulebalk weergegeven.

{=SOM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

De formule is gebaseerd op het feit dat het resultaat van een vergelijking 1 is als aan de criteria wordt voldaan en 0 als daaraan niet wordt voldaan. De individuele vergelijkingsresulten zullen worden behandeld als een matrix en gebruikt in matrixvermenigvuldiging en aan het einde zullen de individuele waarden worden getotaliseerd om de resultaatmatrix terug te geven.

SOM.ALS

Telt de cellen op die door een bepaald criterium gespecificeerd zijn. Deze functie wordt gebruikt om door een bereik te bladeren wanneer u een bepaalde waarde zoekt.

Syntaxis

SOM.ALS(Bereik; Criteria; Sombereik)

Bereik is het bereik waarop de criteria toegepast moeten worden.

Criteria is de cel waarin het zoekcriterium weergegeven wordt of het zoekcriterium zelf. Als het criterium in de formule wordt opgenomen, moet het tussen dubbele aanhalingsteken geplaatst worden.

Sombereik is het bereik waarvan de waarden worden opgesomd. De waarden die worden gevonden in het Bereik worden opgesomd als deze parameter niet wordt opgegeven.

Voorbeeld

Alleen negatieve getallen opsommen: =SOM.ALS(A1:A10;"<0")

=SOM.ALS(A1:A10;">0";B1:10) - telt de waarden in het bereik B1:B10 alleen op als de corresponderende waarden in het bereik A1:A10 >0 zijn.

Zie AANTAL.ALS() voor nog een aantal syntaxisvoorbeelden die kunnen worden gebruikt met SOM.ALS().

SOM.MACHTREEKS

Telt de eerste argumenten van een machtreeks op.

SOM.MACHTREEKS(x;n;m;coëfficiënten) = coëfficiënt_1*x^n + coëfficiënt_2*x^(n+m) + coëfficiënt_3*x^(n+2m) +...+ coëfficiënt_i*x^(n+(i-1)m)

Syntaxis

SOM.MACHTREEKS(X; N; M; Coëfficiënten)

X is de invoerwaarde voor de machtreeks.

N is de initiële macht

M is de verhoging waarmee N moet worden verhoogd

Coëfficiënten is een reeks coëfficienten. Voor elke coëfficiënt wordt de som van de uitgebreid met één sectie.

SUBTOTAAL

Berekent subtotalen. Als een bereik al subtotalen bevat, worden deze niet gebruikt voor verdere berekeningen. Gebruik deze functie met de AutoFilters om alleen de gefilterde records in aanmerking te nemen.

Syntaxis

SUBTOTAAL(Functie; Bereik)

Functie is een getal dat voor een van de volgende functies staat:

Functie-index (inclusief verborgen waarden)	Functie-index (negeert verborgen waardes)	Functie
1	101	GEMIDDELDE
2	102	AANTAL
3	103	AANTALARG
4	104	MAX
5	105	MIN
6	106	PRODUCT
7	107	STDEV
8	108	STDEVP
9	109	SOM
10	110	VAR
11	111	VARP

Gebruik nummers 1-11 om handmatig verborgen rijen bij te sluiten of 101-111 om ze uit te sluiten; gefilterde cellen zijn altijd uitgesloten.

Bereik is het bereik waarvan de cellen opgenomen zijn.

Voorbeeld

U heeft een tabel in het celbereik A1:B6 met een rekening voor materiaal voor 10 studenten. Rij 2 (Pen) is handmatig verborgen. U wilt de som van de getoonde cijfers zien; dat wil zeggen, alleen het subtotaal voor de gefilterde rijen. In dit geval zou de juiste formule zijn:

	A	B
1	ITEM	AANTAL
2	Pen	10
3	Potlood	10
4	Kladblok	10
5	Vlakgom	10
6	Potloodslijper	10

=SUBTOTAAL(9;B2:B6) geeft 50.

=SUBTOTAAL(109;B2:B6) geeft 40.

TAN

Geeft de tangens van de opgegeven hoek (in radialen) terug.

Syntaxis

TAN(Getal)

Geeft de (trigonometrische) tangens van Getal terug, de hoek in radialen.

Gebruik de functie RADIALEN om de tangens van een hoek in graden terug te geven.

Voorbeeld

=TAN(PI()/4) geeft 1 terug, de tangens van PI/4 radialen.

=TAN(RADIALEN(45)) geeft 1 terug, de tangens van 45 graden.

TANH

Berekent de tangens hyperbolicus van een getal.

Syntaxis

TANH(Getal)

Geeft de tangens hyperbolicus van Getal terug.

Voorbeeld

=TANH(0) geeft 0 terug, de tangens hyperbolicus van 0.

WORTEL

Geeft de positieve vierkantswortel van een getal terug.

Syntaxis

WORTEL(Getal)

Geeft de positieve vierkantswortel van Getal.

Getal moet positief zijn.

Voorbeeld

=WORTEL(16) geeft 4 terug.

=WORTEL(-16) geeft een ongeldig argument-fout.

WORTEL.PI

Geeft de vierkantswortel van (PI maal een getal) terug.

Syntaxis

WORTEL.PI(getal)

Geeft de positieve vierkantswortel van (PI vermenigvuldigd met Getal) terug.

Dit komt overeen met WORTEL(PI()*Getal).

Voorbeeld

=WORTEL.PI(2) geeft de vierkantswortel van (2PI) terug, ongeveer 2,506628.