Munkafüzetfüggvények

Ez a szakasz tartalmazza a munkafüzet-kezelő függvények példával szemléltetett leírását.

Ennek a parancsnak az eléréséhez... Válassza a Beszúrás - Függvény - Kategória: Munkafüzet lehetőséget.

HIBA.TÍPUS

Visszaad egy konkrét hibatípust képviselő számot, vagy a #HIÁNYZIK hibaértéket, ha nincs hiba.

ADDRESS

Egy cella címét (hivatkozását) adja eredményül szövegként, a meghatározott sor és oszlop száma szerint. Meghatározhatja, hogy a címzés abszolút címzésként (például: $A$1), relatív címzésként (például: A1) vagy esetleg a kettő ötvözeteként (A$1 vagy $A1) kerül értelmezésre. Ezen kívül megadhatja a munkalap nevét is.

Kompatibilitási okból a CÍM és INDIREKT függvények támogatnak egy opcionális paramétert, amellyel megadható hogy az R1C1 (S1O1) jelölés használandó-e a megszokott A1 stílus helyett.

A CÍM esetén a paraméter a negyedik paraméterként kerül megadásra, eltolva az opcionális munkalapnév paramétert az ötödik pozícióra.

Az INDIREKT esetén a paraméter második paraméterként kerül felhasználásra.

Mindkét függvény esetén az argumentum 0 értéke az R1C1 jelölés használatát jelenti. Ha az argumentum nincs megadva, vagy értéke nem nulla, akkor az A1 jelölés kerül felhasználásra.

Az R1C1 jelölés esetén a CÍM a cím karakterláncokat a munkalapnév-elválasztóként felkiáltójelet (!) használva adja vissza, az INDIREKT pedig felkiáltójeleket vár munkalapnév-elválasztóként. Mindkét függvény továbbra is a pont (.) munkalapnév-elválasztót használja az A1 jelölés esetén.

Az ODF 1.0/1.1 formátumú dokumentumok megnyitásakor a munkalap nevét negyedik paraméterként megjelenítő CÍM függvények el lesznek tolva, hogy a munkalapnév az ötödik paraméter legyen. Egy új, 1 értékű negyedik paraméter kerül beszúrásra.

A dokumentum ODF 1.0/1.1 formátumba mentésekor a CÍM függvények negyedik paramétere, ha van, eltávolításra kerül.

Szintaxis

CÍM(sor; oszlop; absz.; A1; "munkalap")

A sor a cellahivatkozás sorszámát jelöli.

Az oszlop a cellahivatkozás oszlopszámát (nem betűjelét) jelöli.

Az absz. meghatározza a hivatkozás típusát:

1: abszolút ($A$1)

2: a sorhivatkozás abszolút, az oszlophivatkozás relatív (A$1)

3: sor (relatív); oszlop (abszolút) ($A1)

4: relatív (A1)

A1 (opcionális) – ha 0, akkor az R1C1 jelölés érvényes. Ha a paraméter hiányzik, vagy nem 0, akkor az A1 jelölés érvényes.

A munkalap megadja a munkalap nevét. A nevet idézőjelek közé kell tenni.

Példa:

A =CÍM(1;1;2;;"Munkalap2") a következőt adja eredményül: Munkalap2.A$1.

Ha a Munkalap2 A1 cellája -6 értéket tartalmaz, akkor közvetett módon is hivatkozhat a hivatkozott cellára a B2 cellában elhelyezett függvény segítségével. Ehhez írja be az =ABS(INDIREKT(B2)) függvényt. Az eredmény a B2 cellában megadott cellahivatkozás abszolút értéke, vagyis ebben az esetben 6.

DDE

Egy DDE-alapú hivatkozás eredményét adja vissza. Ha a csatolt tartomány, illetve szakasz tartalma módosul, akkor az eredményül kapott érték maga is módosul. Ilyenkor újra kell töltenie a munkafüzetet, vagy a Szerkesztés - Hivatkozások menüparancsot kell választania a frissített hivatkozások megjelenítéséhez. A keresztplatformos hivatkozások (például Windows-gépen futó LibreOffice telepítésből Linux-gépen létrehozott dokumentumra) nem megengedettek.

Szintaxis

DDE("kiszolgáló"; "fájl"; "tartomány"; mód)

Server is the name of a server application. LibreOffice applications have the server name "soffice".

A fájl elérési utat is tartalmazó teljes fájlnév.

A tartomány a kiértékelni kívánt adatokat tartalmazó terület.

A mód opcionális paraméter, amely szabályozza, hogy a DDE-kiszolgáló milyen módon konvertálja az adatokat számokká.

Mód	Hatás
0 vagy hiányzik	Számformátum az „Alapértelmezett” cellastílusból
1	Az adatokat mindig a sztenderd amerikai angol szerint értelmezi
2	Az adatot szövegként kapja meg; nem alakítja át számokká

Példa

A =DDE("soffice";"c:\office\document\adatok1.ods";"Munkalap1.A1") beolvassa az adatok1.ods LibreOffice-munkafüzet Munkalap1 nevű munkalapjának A1 celláját.

A =DDE("soffice";"c:\office\document\motto.odt";"Nap idézete") eredményül egy – a képletet tartalmazó cellában található – idézetet ad. Először írjon be egy idézetet tartalmazó sort a motto.odt dokumentumba, majd határozza meg a sort a Nap idézete szakasz első soraként (az LibreOffice Writer Létrehozás - Szakasz parancsának segítségével). Ha az idézetet módosítja a LibreOffice Writer-dokumentumban (és a dokumentumot menti), akkor az idézet az összes olyan LibreOffice Calc-cellában frissítésre kerül, amelyben a DDE-hivatkozás szerepel.

ELTOLÁS

Egy adott hivatkozási ponttól megadott számú sorral és oszloppal eltolt cella értékét adja eredményül.

Szintaxis

ELTOLÁS(hivatkozás; sorok; oszlopok; magasság; szélesség)

A hivatkozás azon hivatkozás, amelytől kezdve a függvény az új hivatkozást keresi.

A sorok azon sorok száma, amellyel a hivatkozás felfelé (negatív érték) vagy lefelé korrigálásra kerül. A 0 használatával ugyanabban a sorban maradhat.

Az oszlopok (opcionális) azon oszlopok száma, amellyel a hivatkozás balra (negatív érték) vagy jobbra korrigálásra kerül. A 0 használatával ugyanabban az oszlopban maradhat.

A magasság (opcionális) az új hivatkozáspozíción kezdődő terület függőleges magassága.

A szélesség (opcionális) az új hivatkozáspozíción kezdődő terület vízszintes szélessége.

A sorok és az oszlopok argumentumok nem mutathatnak nulla vagy negatív kezdetű sorra vagy oszlopra.

A magasság és a szélesség argumentumok nem mutathatnak nulla vagy negatív számú sorra vagy oszlopra.

A LibreOffice Calc függvényeinél az „opcionális” paramétereket nem kötelező megadni, ha nem követi azokat további paraméter. Ha például egy négy paramétert elfogadó függvénynél az utolsó kettő „opcionális”, akkor a 4. vagy a 3. és 4. paramétert nem kötelező megadni, de csak a 3. elhagyása nem lehetséges.

Példa

Az =ELTOLÁS(A1;2;2) eredményül a C3 cellában található értéket adja (A1-től két oszloppal jobbra és két sorral lefelé). Ha a C3 cella a 100 értéket tartalmazza, akkor a függvény eredményül a 100 értéket adja vissza.

Az =ELTOLÁS(B2:C3;1;1) a B2:C3 hivatkozástól az 1 sorral lejjebb és 1 oszloppal jobbra levő hivatkozást (C3:D4) adja vissza.

Az =ELTOLÁS(B2:C3;-1;-1) a B2:C3 hivatkozástól az 1 sorral feljebb és 1 oszloppal balra levő hivatkozást (A1:B2) adja vissza.

Az =ELTOLÁS(B2:C3;0;0;3;4) a B2:C3 hivatkozásból a 3 sorra és 4 oszlopra átméretezett hivatkozást (B2:E4) adja vissza.

Az =ELTOLÁS(B2:C3;1;0;3;4) a B2:C3 hivatkozásból az 1 sorral lejjebb tolt és 3 sorra és 4 oszlopra átméretezett hivatkozást (B3:E5) adja vissza.

A =SZUM(ELTOLÁS(A1;2;2;5;6)) a C3 cellánál kezdődő, 5 sor magas, és 6 oszlop széles terület (terület=C3:H7) összegét határozza meg.

FKERES

Függőleges keresés hivatkozással a jobb oldali szomszédos cellákra. Ez a függvény azt vizsgálja, hogy egy adott érték szerepel-e egy tömb első oszlopában. A függvény ezt az értéket adja vissza az index nevű oszlop azonos sorában. Ha a rendezett paraméter nincs megadva, IGAZ értékre, illetve 1-re van állítva, akkor a függvény úgy veszi, hogy az adatok növekvő sorrendben vannak. Ebben az esetben, ha nem található pontosan a keresési_feltétel, akkor a keresési feltételnél kisebb utolsó érték lesz visszaadva. Ha a rendezett paraméter HAMIS vagy nulla, akkor pontos találatra van szükség, ellenkező esetben a Hiba: Érték nem érhető el hiba lesz az eredmény. A nulla érték mellett nem szükséges növekvő sorrendbe rendezni az adatokat.

Szintaxis

=FKERES(keresési_feltétel; tömb; index; rendezett)

A keresési_feltétel a tömb első oszlopában keresett érték.

A tömb legalább két oszlopból álló hivatkozás.

Az index a visszakapni kívánt értéket tartalmazó oszlop száma a tömbben. Az első oszlop száma 1.

A rendezett opcionális paraméter, amely azt jelöli, hogy a tömb első oszlopa növekvő sorrendben van-e rendezve. Ha az első oszlop nincs növekvő sorrendben rendezve, akkor írja be a logikai HAMIS vagy a nulla értéket. A rendezett oszlopokban a keresés sokkal gyorsabb, illetve a függvény minden esetben visszaad egy értéket. Ez igaz még akkor is, ha a függvény a keresési értékkel nem talált pontos egyezést, feltéve, hogy az érték a rendezett lista legmagasabb és a legalacsonyabb rendezett értéke között található. Nem rendezett listák esetén a keresési értéknek pontosan egyeznie kell. Ha nem így van, a függvény a következő üzenetet adja vissza: Hiba: Érték nem érhető el.

Példa

A menün található egyik étel számát meg kívánja adni az A1 cellában úgy, hogy az étel neve – szövegként – azonnal megjelenjen a szomszédos (B1) cellában. A Szám-Név hozzárendelést a D1:E100 tömb tartalmazza. A D1 100-at tartalmaz, E1 a Zöldségleves nevet tartalmazza, és így tovább, mind a száz menütételre. A D oszlop számai növekvő sorrendben rendezettek, tehát az opcionális rendezett paramétert nem szükséges megadni.

Adja meg a B1-es cellába a következő képletet:

=FKERES(A1;D1:E100;2)

Amint az A1 cellában megadja a számot, a B1 megjeleníti a D1:E100 hivatkozás második oszlopából a vonatkozó szöveget. Ha nem létező számot ad meg, akkor a következő számhoz tartozó szöveg jelenik meg. Ennek megakadályozására a képlet utolsó paramétereként adja meg a HAMIS értéket. Ennek eredményeként egy nem létező szám beírásakor hibaüzenet jelenik meg.

HIBA.TÍPUS

Egy másik cellában fellépő hibaértéknek megfelelő számot ad eredményül. Ezeknek a számoknak a segítségével hibaüzeneteket hozhat létre.

Szintaxis

HIBA.TÍPUS(hivatkozás)

A hivatkozás a hibát tartalmazó cella címzése.

Példa

Ha az A1 cella a Hiba:518 hibakódot jeleníti meg, a =HIBA.TÍPUS(A1) függvény az 518 értéket adja vissza.

HIPERHIVATKOZÁS

Ha olyan cellára kattint, amely a HIPERHIVATKOZÁS függvényt tartalmazza, a hiperhivatkozás megnyílik.

Ha a kiegészítő cella szövege paramétert is megadja, akkor a képlet megkeresi az URL-t, majd megjeleníti a szöveget.

Szintaxis

HIPERHIVATKOZÁS("URL") vagy HIPERHIVATKOZÁS("URL"; "cella szövege")

Az URL a hivatkozás célja. A kiegészítő cella szövege paraméter jelenik meg a cellában, és ezt adja vissza a függvény. Ha nincs megadva a cella szövege paraméter, akkor az URL jelenik meg a cellában, és ezt adja vissza a függvény.

Üres cellákra és mátrixelemekre a 0 számot adja vissza.

Példa

A =HIPERHIVATKOZÁS("http://www.példa.hu") a „http://www.példa.hu” szöveget jeleníti meg, és a http://www.példa.hu címre ugrik, ha rákattint.

A =HIPERHIVATKOZÁS("http://www.példa.hu";"Kattintson ide") a „Kattintson ide” szöveget jeleníti meg, és a http://www.példa.hu címre ugrik, ha rákattint.

A =HIPERHIVATKOZÁS("http://www.példa.hu";12345) az 12345 számot jeleníti meg, és a http://www.példa.hu címre ugrik, ha rákattint.

A =HIPERHIVATKOZÁS($B4), ahol a B4 cella tartalma a http://www.példa.hu. A függvény a http://www.példa.hu címet adja hozzá a hiperhivatkozás-cella URL-jéhez, és ugyanazt a szöveget adja vissza, amely a képlet eredménye.

A =HIPERHIVATKOZÁS("http://www.";"Kattintson ide:") & "példa.hu" a „Kattintson ide: példa.hu” szöveget jeleníti meg, és a http://www.példa.hu címre ugrik, ha rákattint.

A =HIPERHIVATKOZÁS("#Munkalap1.A1";"Ugrás a lap tetejére") megjeleníti az „Ugrás a lap tetejére” szöveget, és a dokumentum Munkalap1.A1 cellájára ugrik.

A =HIPERHIVATKOZÁS("file:///C:/writer.odt#Specifikáció";"Ugrás a Writer-könyvjelzőre") megjeleníti az Ugrás a Writer-könyvjelzőre szöveget, és a „Specifikáció” könyvjelzőre ugrik.

HOL.VAN

Kiszámítja a megadott értékkel egyező tömb egy elemének relatív helyzetét. A függvény számként adja vissza a Keresési tömb segítségével megtalált érték helyzetét.

Szintaxis

HOL.VAN(keresési_feltétel; keresési_tömb; típus)

A keresési_feltétel az egyetlen sorból, illetve oszlopból álló tömbben keresendő érték.

A keresési_tömb a keresés helyét megadó hivatkozás. A keresési tömb állhat egyetlen sorból vagy oszlopból, illetve lehet egy sor vagy oszlop egy része.

A típus az 1, 0, illetve -1 értékek valamelyikét veheti fel. Ha a típus = 1, illetve a választható paraméter nincs megadva, akkor a függvény feltételezi, hogy a keresési tömb első oszlopa növekvő sorrendben rendezett. Ha a típus = -1, akkor a függvény feltételezi, hogy az oszlop csökkenő sorrendben rendezett. Ez megegyezik a Microsoft Excel hasonló funkciójával.

Ha a típus = 0, akkor a függvény kizárólag a pontos egyezéseket találja meg. Ha a keresési feltétel több találatot eredményez, akkor a függvény az első találatot adja eredményül. Csak a típus = 0 esetén kereshet reguláris kifejezésekre (ha engedélyezett a számítás beállításaiban) vagy helyettesítő karakterekre (ha engedélyezett a számítás beállításaiban).

Ha a típus = 1 vagy a harmadik paraméter nincs megadva, akkor eredményül a függvény az utolsóként előforduló, a keresési feltételnél kisebb vagy azzal egyenlő érték indexét adja vissza. Ez abban az esetben is igaz, ha a keresési tömb nincs rendezve. Ha a típus = -1, a függvény eredményül az első nagyobb vagy egyenlő értéket adja vissza.

Példa

A =HOL.VAN(200;D1:D100) a D oszlop szerint rendezett D1:D100 területen belül keresi a 200 értéket. Amint a függvény eléri ezt az értéket, az értéket tartalmazó sor száma visszaadásra kerül. Ha az oszlop keresése során a függvény ennél nagyobb értéket talál, akkor az előző sor száma kerül visszaadásra.

INDEX

Az INDEX egy altartományt ad vissza, amelyet sor- vagy oszlopszám, illetve egy opcionális tartományindex határoz meg. A kontextustól függően az INDEX hivatkozást vagy tartalmat ad vissza.

Szintaxis

INDEX(hivatkozás; sor; oszlop; tartomány)

A hivatkozás közvetlenül vagy tartománynév megadásával meghatározott cellahivatkozás. Ha a hivatkozás több tartományból áll, akkor a hivatkozást, illetve tartománynevet zárójelek között szükséges megadni.

A sor (opcionális) a hivatkozástartomány sorindexe, amelyre vonatkozóan egy értéket meg kíván kapni. Nulla érték esetén (nincs megadva sor) visszaad minden hivatkozott sort.

Az oszlop (opcionális) a hivatkozástartomány oszlopindexe, amelyre vonatkozóan egy értéket meg kíván kapni. Nulla érték esetén (nincs megadva oszlop) visszaad minden hivatkozott oszlopot.

A tartomány (opcionális) az altartomány indexelése, több tartományt tartalmazó hivatkozás esetén.

Példa

Az =INDEX(Árak;4;1) eredményül az Adatok - Tartomány definiálása párbeszédablakban Árak néven megadott adatbázis-tartomány 4. sorának 1. oszlopában található értéket adja vissza.

Az =INDEX(SumX;4;1) eredményül a Munkalap - Nevesített tartományok és kifejezések - Megadás párbeszédablakban a SumX néven megadott adatbázis-tartomány 4. sorának 1. oszlopában található értéket adja vissza.

Az =INDEX(A1:B6;1) az A1:B6 első sorára mutató hivatkozást adja vissza.

Az =INDEX(A1:B6;0;1) az A1:B6 első oszlopára mutató hivatkozást adja vissza.

Az =INDEX((multi);4;1) eredményül a Munkalap - Nevesített tartományok és kifejezések - Megadás párbeszédablakban a multi néven megadott adatbázis-tartomány 4. sorának 1. oszlopában található értéket adja vissza. A többszörös tartomány több téglalap alakú tartományból állhat, és mindegyik rendelkezhet 4. sorral és 1. oszloppal. Ha a többszörös tartomány második blokkját kívánja meghívni, akkor tartomány paraméterként adjon meg 2-t.

Az =INDEX(A1:B6;1;1) az A1:B6 tartomány bal felső értékét jelöli.

Az =INDEX((multi);0;0;2) a többszörös tartomány második tartományára mutató hivatkozást adja vissza.

INDIREKT

Egy karaktersorozat által meghatározott hivatkozást adja vissza. Ezzel a függvénnyel a megfelelő karakterlánc területét is vissza lehet adni.

Szintaxis

INDIREKT(hivatkozás; A1)

A hivatkozás cella- vagy területhivatkozás (szöveges formátumban), amelyre vonatkozóan a tartalmat meg kívánja kapni.

A1 (opcionális) – ha 0, akkor az R1C1 jelölés érvényes. Ha a paraméter hiányzik, vagy nem 0, akkor az A1 jelölés érvényes.

Példa

Az =INDIREKT(A1) 100-zal egyenlő, ha az A1 cella a C108-as cellára való hivatkozást tartalmazza, és a C108 cella a 100 értéket tartalmazza.

A =SZUM(INDIREKT("A1:" & CÍM(1;3))) összegzi azon cellákat, amelyek az A1 cellától azon celláig terjedő területen találhatók, amely címét az 1. sor 3. oszlopában meghatározta. Tehát, az A1:C1 terület lesz összegezve.

KERES

Egy egysoros vagy egyoszlopos cellatartományból származó cella tartalmát adja eredményül. Esetleg a hozzárendelt érték (azonos indexszel) egy másik sorban, illetve oszlopban kerül visszaadásra. Az FKERES és a VKERES függvénnyel ellentétben a keresési, illetve az eredményvektorok lehetnek eltérő helyeken, nem kell szomszédosnak lenniük. Ezen kívül a KUTAT keresési vektorját növekvő sorrendbe kell rendezni, ellenkező esetben a keresés nem jár használható eredménnyel.

Szintaxis

KERES(keresési_feltétel; keresési_vektor; eredményvektor)

A keresési_feltétel a keresendő érték; lehet közvetlenül vagy hivatkozásként beírva.

A keresési_vektor az egyetlen sorból vagy egyetlen oszlopból álló terület, ahol keresni kell.

Az eredményvektor egy másik egyetlen sorból vagy egyetlen oszlopból álló tartomány, amelyből a függvény eredménye kiválasztásra kerül. Az eredmény az eredményvektor azon cellája, amely a keresési vektorban megtalált példánnyal azonos indexszel rendelkezik.

Példa

A =KERES(A1;D1:D100;F1:F100) a D1:D100 tartomány vonatkozó cellájában keresi az A1 cellában megadott értéket. A megadott példányra a függvény megállapítja az indexet, például a tartomány 12. cellája. Ezt követően a 12. cella tartalma kerül visszaadásra a függvény eredményeként (az eredmény vektorban).

KIMUTATÁSADATOT.VESZ

A KIMUTATÁSADATOT.VESZ függvény egy kimutatástáblából adja vissza az eredményt. Az érték címzése mező- és elemnevek használatával történik, így az érvényes marad akkor is, ha a kimutatástábla elrendezése megváltozik.

Szintaxis

Két különböző szintaxis használható:

KIMUTATÁSADATOT.VESZ(célmező; kimutatástábla; [ 1. mező; 1. elem; ... ])

KIMUTATÁSADATOT.VESZ(kimutatástábla; kényszerfeltételek)

A második szintaxis feltételezi, hogy pontosan két paraméter van megadva, és ezek közül az első egy cella- vagy cellatartomány-hivatkozás. Az első szintaxis van feltételezve minden más esetben. A Függvénytündér az első szintaxist jeleníti meg.

Első szintaxis

A célmező egy karakterlánc, amely kijelöli a kimutatástábla adatmezőinek egyikét. A karakterlánc lehet egy forrásoszlop neve, vagy az adatcímke neve, ahogy az a táblázatban látható (például „Összeg - Eladások”).

A kimutatástábla egy hivatkozás egy cellára vagy cellatartományra, amely a kimutatástáblán belül van, vagy egy kimutatástáblát tartalmaz. Ha a cellatartomány több kimutatástáblát tartalmaz, akkor az utoljára létrehozott táblázat lesz használva.

Ha nincsenek megadva n. mező / n. elem párok, akkor az összeg lesz az eredmény. Egyébként mindegyik pár egy kényszerfeltételt ad hozzá, amelyet az eredménynek ki kell elégítenie. Az n. mező a kimutatástábla egyik mezőjének a neve. Az n. elem az abban a mezőben levő elem neve.

Ha a kimutatástábla csak egyetlen olyan eredményértéket tartalmaz, amely kielégíti a kényszerfeltételeket, vagy az összes illeszkedő értéket összegző részösszegeredményt, akkor az az eredmény lesz visszaadva. Ha nincs illeszkedő eredmény, vagy több van részösszeg nélkül, akkor hibajelzés lesz visszaadva. Ezek a feltételek a kimutatástáblában megtalálható eredményekre lesznek alkalmazva.

Ha a forrásadatok olyan bejegyzéseket tartalmaznak, amelyek a kimutatástábla beállításai miatt el vannak rejtve, akkor ezek nem lesznek figyelembe véve. A mező/elem párok sorrendje nem lényeges. A mező- és elemneveknél a kis- és nagybetűk nincsenek megkülönböztetve.

Ha nincs megadva kényszerfeltétel egy oldalmezőre, akkor a mező kijelölt értéke lesz közvetve használva. Ha meg van adva kényszerfeltétel egy oldalmezőre, akkor annak illeszkednie kell a mező kijelölt értékéhez, különben hiba lesz visszaadva. Az oldalmezők egy kimutatástábla bal felső mezői, amelyek a kimutatástábla Elrendezés párbeszédablakának „Oldalmezők” területének használatával vannak kitöltve. Minden oldalmezőből egy elem (érték) jelölhető ki, ami csak azt jelenti, hogy az elem része lesz a számításnak.

A kimutatástáblából származó részösszegértékek csak akkor lesznek használva, ha azok az „auto” függvényt használják (kivéve ha a kényszerfeltételben van megadva, lásd alább a Második szintaxis részt).

Második szintaxis

A kimutatástábla jelentése ugyanaz, mint az első szintaxisban.

A kényszerfeltételek egy szóközökkel elválasztott lista. Az elemeit aposztrófok közé lehet tenni. A teljes karakterláncot idézőjelek közé kell tenni, hacsak nem hivatkozik a karakterláncra egy másik cellából.

A bejegyzések egyike lehet az adatmező neve. Az adatmező neve kihagyható, ha a kimutatástábla csak egy adatmezőt tartalmaz, különben kötelező.

Minden más bejegyzés egy kényszerfeltételt határoz meg a Mező[Elem] (a [ és ] karakterrel) vagy csak az Elem formában, ha az elem neve egyedi a kimutatástáblában használt összes mező között.

A függvény neve a Mező[Elem;Függvény] formában adható meg, amely azt eredményezi, hogy a kényszerfeltétel csak azokra a részösszegekre illeszkedik, amelyek ezt a függvényt használják. A lehetséges függvénynevek: Összeg, Darab, Átlag, Maximum, Minimum, Szorzat, Darab (csak számok), Szórás (minta), SzórásP (sokaság), Variancia (minta) és VarianciaP (sokaság), a kis- és nagybetűk között nincs különbség.

LAP

A hivatkozás munkalapszámát vagy egy munkalapnevet képviselő karaktersorozatot ad eredményül. Ha nem ad meg paramétereket, az eredmény a képletet tartalmazó munkalap száma a táblázatban.

Szintaxis

LAP(hivatkozás)

A hivatkozás opcionális cella- vagy területhivatkozás, illetve munkalapnév-karakterlánc.

Példa

Az =LAP(Munkalap2.A1) függvény a 2 értéket adja vissza, ha a Munkalap2 a munkafüzet-dokumentum második munkalapja.

LAPOK

Megállapítja a hivatkozás munkalapjainak számát. Ha nem ad meg paramétereket, az aktuális dokumentum munkalapjainak számát adja vissza.

Szintaxis

LAPOK(hivatkozás)

A hivatkozás munkalap- vagy területhivatkozás. A paraméter megadása nem kötelező.

Példa

Az =LAPOK(Munkalap1.A1:Munkalap3.G12) függvény a 3 értéket adja vissza, ha a Munkalap1, Munkalap2 és Munkalap3 munkalapok a megadott sorrendben vannak.

OSZLOP

Egy cellahivatkozás oszlopszámát adja eredményül. Ha a hivatkozás cella, akkor a cella oszlopszámát adja eredményül. Ha a paraméter cellaterület, akkor a függvény a vonatkozó oszlopszámokat adja eredményül egy egyetlen sorból álló tömb formájában, feltéve, hogy a képlet tömbképletként kerül megadásra. Ha a területhivatkozás-paraméterrel rendelkező OSZLOP függvényt nem tömbképletre használja, akkor csak a területen belül található első cella oszlopszáma kerül meghatározásra.

Szintaxis

OSZLOP(hivatkozás)

A hivatkozás a cella-, illetve cellaterület-hivatkozás, amelyre vonatkozóan az első oszlop számát meg kívánja határozni.

Ha a hivatkozás értékének nem ad meg semmit, a képletet tartalmazó cella oszlopának számát adja vissza. A LibreOffice Calc a hivatkozást automatikusan az aktuális cellára állítja.

Példa

Az =OSZLOP(A1) képlet az 1 értéket adja vissza. Az A oszlop a táblázat első oszlopa.

Az =OSZLOP(C3:E3) képlet 3-mal egyenlő. A C oszlop a táblázat harmadik oszlopa.

Az =OSZLOP(D3:G10) eredményül 4-et ad, mivel a D oszlop a táblázat negyedik oszlopa, és az OSZLOP függvényt nem tömbképletként használta. (Ebben az esetben eredményül a függvény mindig a tömb első értékét adja vissza.)

Az {=OSZLOP(B2:B7)} és a =OSZLOP(B2:B7) eredményül egyaránt 2-t ad, mivel a hivatkozás csak a B oszlopot tartalmazza a táblázat második oszlopaként. Mivel az egyetlen oszlopból álló területek csak egy oszlopszámmal rendelkeznek, nem számít, hogy a képletet tömbképletként használja-e.

Az =OSZLOP() képlet a 3 értéket adja vissza, ha a képlet a C oszlopban lett megadva.

Az {=OSZLOP(Nyúl)} egy egyetlen sorból álló tömböt (3, 4) ad eredményül, ha a (C1:D3) terület neve „Nyúl”.

OSZLOPOK

Az adott hivatkozásban szereplő oszlopok számát adja eredményül.

Szintaxis

OSZLOPOK(tömb)

A tömb az a cellatartomány-hivatkozás, amelyre vonatkozóan az oszlopok számát meg kívánja határozni. Az argumentum lehet egyetlen cella is.

Példa

Az =OSZLOPOK(B5) függvény az 1 értéket adja vissza, mert a cella csak egy oszlopot tartalmaz.

Az =OSZLOPOK(A1:C5) függvény értéke 3. A hivatkozás három oszlopot tartalmaz.

Az =OSZLOPOK(Nyúl) eredményül 2-t ad, ha a (C1:D3) tartomány neve Nyúl.

ROW

A cellahivatkozás sorának számát adja eredményül. Ha a hivatkozás cella, akkor eredményül a cella sorszámát adja vissza. Ha a hivatkozás cellatartomány, akkor a függvény eredményül a vonatkozó sorszámokat adja egy egyoszlopos tömb formájában, ha a képlet tömbképletként került megadásra. Ha a tartományhivatkozással rendelkező SOR függvényt nem tömbképlet részeként használja, akkor a függvény csak a tartomány első cellájának sorszámát adja eredményül.

Szintaxis

SOR(hivatkozás)

A hivatkozás egy cella, egy terület vagy egy területnév.

Ha nem jelöl ki hivatkozást, a képletet tartalmazó cella sorának számát adja vissza. A LibreOffice Calc a hivatkozást automatikusan az aktuális cellára állítja.

Példa

A =SOR(B3) képlet a 3 értéket adja vissza, mert a hivatkozás a táblázat harmadik sorára hivatkozik.

A {=SOR(D5:D8)} képlet a (5, 6, 7, 8) egyoszlopos tömböt adja vissza, mert a megadott hivatkozás az 5 és 8 közötti sorokat tartalmazza.

A =SOR(D5:D8) képlet az 5 értéket adja vissza, mert a ROW függvényt nem tömbhivatkozásként használta, és csak a hivatkozás első sorának számát adja vissza.

A {=SOR(A1:E1)} és a =ROW(A1:E1) egyaránt 1-et ad vissza, mivel a hivatkozás csak az 1. sort tartalmazza a táblázat első soraként. (Mivel az egyetlen sorból álló területek csak egy sorszámmal rendelkeznek, nem számít, hogy a képletet tömbképletként használja-e.)

A =SOR() képlet a 3 értéket adja vissza, ha a képletet a 3. sorba írja be.

A {=SOR(Nyúl)} egy egyetlen sorból álló tömböt (1, 2, 3) ad eredményül, ha a (C1:D3) terület neve „Nyúl”.

SOROK

Egy hivatkozás vagy tömb sorainak számát adja eredményül.

Szintaxis

SOROK(tömb)

A tömb az a hivatkozás vagy névvel ellátott terület, amelyre vonatkozóan a sorok számát meg kívánja határozni.

Példa

A =SOROK(B5) képlet az 1 értéket adja vissza, mert a cella csak egy oszlopot tartalmaz.

A =SOROK(A10:B12) képlet a 3 értéket adja vissza.

A =SOROK(Nyúl) eredményül 3-at ad, ha a (C1:D3) terület neve „Nyúl”.

STYLE

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats have to be defined beforehand.

Szintaxis

STYLE("stílus"; idő; "stílus_2")

A stílus a cellához rendelt stílus neve. A stílusneveket idézőjelek között kell megadni.

Az idő (opcionális) másodpercekben megadott időtartomány. Ha a paraméter nincs megadva, akkor a stílus nem kerül módosításra egy adott idő elteltével.

A stílus_2 (opcionális) a cellához egy bizonyos idő elteltével hozzárendelésre kerülő stílus neve. Ha a paraméter nincs megadva, akkor a függvény az „Alapértelmezett” stílust használja.

A LibreOffice Calc függvényeinél az „opcionális” paramétereket nem kötelező megadni, ha nem követi azokat további paraméter. Ha például egy négy paramétert elfogadó függvénynél az utolsó kettő „opcionális”, akkor a 4. vagy a 3. és 4. paramétert nem kötelező megadni, de csak a 3. elhagyása nem lehetséges.

Példa

A =STYLE("Láthatatlan";60;"Alapértelmezett") a cellát átlátszó formátummal formázza a dokumentum újraszámítását, illetve betöltését követően 60 másodpercig, majd az Alapértelmezett formátum kerül a cellához hozzárendelésre. Mindkét cellaformátumot használat előtt meg kell határoznia.

Mivel a STYLE() függvény visszatérési értéke a nulla szám, ez az érték hozzáíródik a karakterlánchoz. Ez elkerülhető a T() használatával, mint azt az alábbi példa bemutatja.

="Szöveg"&T(STYLE("Saját stílus"))

Egy másik példáért lásd még a CURRENT() leírását.

TERÜLET

Azon tartományok számát adja eredményül, amelyek egy többszörös tartományba tartoznak. Egy tartomány összefüggő cellákból vagy egy magában álló cellából állhat.

A függvény egyetlen argumentumot vár. Ha több tartományt ad meg, akkor ezeket további zárójelek közé kell tenni. Több tartomány pontosvesszővel (;) elválasztva írható be, de ez automatikusan a tilde (~) operátorrá lesz alakítva. A tilde használatos tartományok összekapcsolására.

Szintaxis

TERÜLET(hivatkozás)

A Hivatkozás a cellához vagy cellatartományhoz tartozó hivatkozást jelöli.

Példa

Az =TERÜLET(A1:B3;F2;G1) függvény a 3 értéket adja vissza, mert ez három cellára és/vagy területre való hivatkozást tartalmaz. A bevitel után ez a =TERÜLET((A1:B3~F2~G1)) képletté konvertálódik.

Az =TERÜLET(Minden) eredményül 1-et ad akkor, ha megadott egy Minden nevű területet az Adatok - Tartomány definiálása párbeszédablakban.

VKERES

A kijelölt terület alatti cellákhoz értéket és hivatkozást keres. A függvény ellenőrzi, hogy egy tömb első sora tartalmaz-e egy bizonyos értéket. A függvény ezután visszaadja a tömb egy sorának az index oszlopban megnevezett értékét ugyanabban az oszlopban.

Szintaxis

VKERES(keresési_feltétel; tömb; index; rendezett)

Lásd még: FKERES (oszlopok és sorok felcserélésre kerülnek).

VÁLASZT

Egy 1-től 30-ig terjedő listából index használatával visszaad egy értéket.

Szintaxis

VÁLASZT(index; érték_1; ...érték_30)

Az index 1–30 közötti érték vagy hivatkozás, amely meghatározza, hogy a lista melyik eleme kerül visszaadásra.

Az érték_1...érték_30 az értékek felsorolása, cellahivatkozásokként vagy egyedi értékekként megadva.

Példa

A =VÁLASZT(A1;B1;B2;B3;"Ma";"Tegnap";"Holnap") például a B2 cella tartalmát adja eredményül A1 = 2 esetén. A1 = 4 esetén a függvény a „Ma” szöveget adja eredményül.