Funktion AGGREGAT
Diese Funktion ergibt die Gesamtheit einer Berechnung in einem Bereich. Sie können verschiedene unten aufgelistete Gesamtheiten verwenden. Die Funktion erlaubt es, ausgeblendete Zeilen, Fehlerwerte, und die Ergebnisse der Funktionen TEILERGEBNIS und AGGREGAT bei der Berechnung nicht zu berücksichtigen.
 |
Die Funktion AGGREGAT wird auf einen vertikalen Bereich mit aktivem AutoFilter angewandt. Wenn der AutoFilter nicht aktiviert ist, funktioniert die automatische Neuberechnung des Funktionsergebnisses nicht für nachträglich verborgene Zeilen. Die Funktion ist nicht für horizontale Bereiche konzipiert, funktioniert mit Einschränkungen aber trotzdem. Inbesondere funktioniert AGGREGAT nicht für ausgeblendete Spalten, funktioniert hingegen aber korrekt, wenn Fehlerwerte und die Ergebnisse der Funktionen TEILERGEBNIS und AGGREGAT bei der Berechnung nicht berücksichtigt werden sollen. |
Syntax
AGGREGAT(Funktion; Optionen; Ref1 [; Ref2 [; …]])
oder
AGGREGAT(Funktion; Optionen; Matrix [; k])
Funktion – erforderliches Argument. Ein Funktionsindex oder ein Zellbezug mit Werten zwischen 1 und 19, übereinstimmend mit folgender Tabelle.
|
Funktionsindex |
Zugehörige Funktion |
|
1 |
MITTELWERT |
|
2 |
ANZAHL |
|
3 |
ANZAHL2 |
|
4 |
MAX |
|
5 |
MIN |
|
6 |
PRODUKT |
|
7 |
STABW.S |
|
8 |
STABW.N |
|
9 |
SUMME |
|
10 |
VAR.S |
|
11 |
VAR.P |
|
12 |
MEDIAN |
|
13 |
MODUS.EINF |
|
14 |
KGRÖSSTE |
|
15 |
KKLEINSTE |
|
16 |
QUANTIL.INKL |
|
17 |
QUARTILE.INKL |
|
18 |
QUANTIL.EXKL |
|
19 |
QUARTILE.EXKL |
Option (erforderlich). Ein Optionsindex oder ein Zellbezug mit Werten zwischen 0 und 7, der festlegt, welcher Bereich bei der Anwendung der Funktion ignoriert werden soll.
|
Optionsindex |
Zugehörige Funktion |
|
0 |
Nur verschachtelte Funktionen TEILERGEBNIS und AGGREGAT ignorieren |
|
1 |
Nur ausgeblendete Zeilen sowie verschachtelte Funktionen TEILERGEBNIS und AGGREGAT ignorieren |
|
2 |
Nur Fehlerwerte sowie verschachtelte Funktionen TEILERGEBNIS und AGGREGAT ignorieren |
|
3 |
Ausgeblendete Zeilen, Fehlerwerte sowie verschachtelte Funktionen TEILERGEBNIS und AGGREGAT ignorieren |
|
4 |
Nichts ignorieren |
|
5 |
Nur ausgeblendete Zeilen ignorieren |
|
6 |
Nur Fehlerwerte ignorieren |
|
7 |
Nur ausgeblendete Zeilen und Fehlerwerte ignorieren |
Bezug 1 (erforderlich). Das erste numerische Argument (wenn der Bereich aus einer Werteliste innerhalb der Funktion stammt) oder ein Bezug zu einer Zelle, die dieses enthält.
Bezug 2, 3, ... - optional. Ein numerischer Wert oder ein Verweis auf einer Zelle (bis zu 253 Argumente), die für die Berechnung berücksichtigt werden sollen.
Matrix (erforderlich). Eine Matrix, angegeben durch die Bereichsgrenzen, den Namen eines benannten Bereichs oder die Spaltenbeschriftung.
|
Um Spaltenbeschriftungen verwenden zu können, muss in den Optionen „Spalten-/Zeilenbeschriftungen automatisch erkennen“ aktiviert sein. |
k (erforderlich - in folgenden Funktionen: KGRÖSSTE, KKLEINSTE, QUANTIL.INKL, QUARTILE.INKL, QUANTIL.EXKL und QUARTILE.EXKL). Ist ein numerisches Argument, welches dem zweiten Argument dieser Funktionen entsprechen muss.
Beispiele
|
A |
B |
C |
|
|
1 |
Spalte eins |
Spalte zwei |
Spalte drei |
|
2 |
34 |
11 |
12 |
|
3 |
10 |
56 |
35 |
|
4 |
#DIV/0! |
5 |
3 |
|
5 |
20 |
8 |
1 |
|
6 |
0 |
8 |
9 |
|
7 |
#WERT! |
20 |
21 |
|
8 |
5 |
7 |
8 |
|
9 |
14 |
0 |
5 |
=AGGREGAT(4;2;A2:A9)
Ergibt den Maximalwert des Bereichs A2:A9 = 34, wohingegen =MAX(A2;A9) den Fehler Err:511 ergibt.
=AGGREGAT(9;5;A5:C5)
Ergibt die Summe des Bereichs A5:C5 = 29, auch, wenn einige der Spalten versteckt sind.
=AGGREGAT(9;5;B2:B9)
Ergibt die Summe der Spalte B = 115. Falls irgendeine Zeile ausgeblendet ist, wird deren Wert nicht berücksichtigt, falls beispielsweise die 7. Zeile ausgeblendet ist, ergibt die Funktion 95.
Wenn Sie die Funktion auf einen dreidimensionalen Bereich anwenden müssen, zeigt Ihnen dieses Beispiel, wie Sie dies tun.
=AGGREGAT(13;3;Tabelle1.B2:B9:Tabelle3.B2:B9)
Ergibt den Modalwert aller Werte der zweiten Spalte der Tabellen 1 bis 3 (wenn diese dieselben Daten enthalten) = 8.
Sie können für jedes Argument der Formel Bezüge zu Zellen oder Bereichen verwenden. Das folgende Beispiel zeigt, wie dies funktioniert. Außerdem zeigt es, dass Sie Spaltennamen verwenden können, um eine Matrix zu festzulegen.
=AGGREGAT(E3;E5;'SpalteEins')
Wenn E3 = 13 und E5 = 5, ergibt die Funktion den Modalwert der ersten Spalte = 10.