Regnearksfunktioner

Dette afsnit indeholder beskrivelser af Regnearksfunktioner samt et eksempel.

For at tilgå denne kommando... Indsæt - Funktion - Kategori Regneark

FEJL.TYPE

Returnerer et tal, som repræsenterer en specifik fejltype, eller fejlværdien #N/A, hvis der ikke er nogen fejl.

ADDRESS

Returnerer en celleadresse (reference) som tekst, i henhold til de angivne række- og kolonnenumre. Efter eget valg kan du fastslå om adressen fortolkes som en absolut adresse (for eksempel, $A$1), som en relativ adresse (som A1) eller i en blandet form (A$1 eller $A1). Du kan også angive navnet på arket.

Af hensyn til interoperabilitet understøtter funktionerne ADRESSE og INDIREKTE (INDIRECT på engelsk) en valgfri parameter til at angive om R1C1 adresse metode skal anvendes i stedet for den sædvanlige A1 metode.

I ADRESSE, bliver parameteren indsat som den fjerde parameter, hvilket flytter det valgfri arknavn parameter til den femte placering.

I INDIREKTE (INDIRECT på engelsk), er parameteren tilføjet som den anden parameter.

I begge funktioner gælder det, at hvis argumentet bliver indsat med værdien 0, så bliver R1C1-notationen brugt. Hvis argumentet er ikke givet eller har en anden værdi end 0, så bliver A1-notationen brugt.

I tilfælde af R1C1 metode, returnerer ADRESSE strenge ved hjælp af udråbstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT på engelsk) forventer udråbstegnet som arknavn skilletegn. Begge funktioner bruger stadig punktum '.' som skilletegn for arknavn med A1 metode.

Når du åbner dokumenter med ODF 1.0/1.1 formater, hvor ADRESSE-funktionen viser et arknavn som den fjerde parameter, vil ændre arknavnet til at blive den femte parameter. En ny fjerde parameter med værdien 1 vil blive indsat.

Når du gemmer et dokument i ODF 1.0/1.1 format, vil den fjerde parameter i ADDRESS funktionen blive fjernet.

Syntaks

ADRESSE(Række; Kolonne; ABS; A1; "Ark")

Række repræsenterer rækkenummeret for cellereferencen

Kolonne repræsenterer kolonnenummeret for cellereferencen (tallet, ikke bogstavet)

ABS bestemmer typen af reference:

1: absolut ($A$1)

2: rækkereferencetype er absolut; kolonnereference er relativ (A$1)

3: række (relativ); kolonne (absolut) ($A1)

4: relativ (A1)

A1 (valgfri) - hvis sat til 0,bliver notationen R1C1 brugt. Hvis parameteren mangler eller er sat til en anden værdi end 0, bliver notationen A1 brugt.

Ark repræsenterer navnet på arket. Det skal være placeret i dobbelt citationstegn.

Eksempel:

=ADRESSE(1; 1; 2; "Ark2") returnerer følgende: Ark2.A$1

Hvis cellen A1 i ark 2 indeholder værdien -6, og referencen i dette eksempel står i B2, kan du referere indirekte til den refererede celle ved i en ny celle at indtaste =ABS(INDIREKTE(B2)). Resultatet er den absolutte værdi af den cellereference, der er specificeret i B2, som i dette tilfælde er 6.

ANTAL.ARK (SHEETS på engelsk)

Afgør antallet af ark i en henvisning. Hvis du ikke indtaster en parameter, returneres antal ark i det aktuelle dokument.

Syntaks

ANTAL.ARK(Reference)

Reference er referencen til et ark eller et område. Denne parameter er valgfri.

Eksempel

=ANTAL.ARK(Ark1.A1:Ark3.G12) returnerer 3, hvis Ark1, Ark2 og Ark3 findes i den angivne rækkefølge.

DDE

Returnerer resultatet af en DDE-baseret kæde. Hvis indholdet af det forbundne område eller den forbundne sektion ændres, vil den returnerede værdi også ændre sig. Du skal indlæse regnearket på ny eller vælge Rediger - Kæder for at se de opdaterede referencer. Referencer på tværs af platforme, for eksempel fra en LibreOffice installation som kører på en Windows-maskine til et dokument oprettet på en Linux-maskine, er ikke tilladt.

Syntaks

DDE("Server"; "Fil"; "Område"; Tilstand)

Server er navnet på et serverprogram. LibreOfficeprogrammer har servernavnet "soffice".

Fil er det fuldstændige filnavn, inklusive sti specifikation.

Område er området, som indeholder data, der skal valideres.

Tilstand er en valgfri parameter, der bestemmer den metode, som DDE-serveren bruger til at konvertere sine data til tal.

Tilstand	Effekt
0 eller udeladt	Talformat fra celletypografien "Standard"
1	Data bliver altid fortolket som standard US engelsk format.
2	Data bliver hentet som tekst; ingen konvertering til tal.

Eksempel

=DDE("soffice"; "c:\Kontor\dokument\data1.ods"; "ark1.A1") læser celleindholdet af celle A1 i ark1 fra LibreOffice Calc-regnearket data1.ods.

=DDE("soffice";"c:\Kontor\dokument\motto.odt";"Dagens Motto") returnerer et motto i den celle, som indeholder denne formel. Først skal du indtaste en linje i motto.odt dokumentet som indeholder mottoets tekst og angive den som den første linje af en sektion med navnet Dagens Motto (i LibreOffice Writer under Indsæt - Sektion). Hvis mottoet bliver ændret (og gemt) i LibreOffice Writer dokumentet, bliver mottoet opdateret i alle LibreOffice Calc celler hvor denne DDE-kæde er defineret.

FEJLTYPE (ERRORTYPE på engelsk)

Returnerer tallet svarende til enfejlværdi der optræder i en anden celle. Ved hjælp af dette tal, kan du generere en tekst til fejlmeddelelsen.

Syntaks

FEJLTYPE(Reference)

Reference indeholder adressen på den celle, som fejlen opstår i.

Eksempel

Hvis celle A1 viser Err:518, returnerer funktionen =FEJLTYPE(A1) tallet 518.

FORSKYDNING (OFFSET på engelsk)

Returnerer værdien af en celleforskydning for et bestemt antal af rækker og kolonner fra et givet referencepunkt.

Syntaks

FORSKYDNING(Reference; Rækker; Kolonner; Højde; Bredde)

Reference er cellen, hvorfra funktionen leder efter den nye reference.

Rækker er antallet af celler som referencen blev korrigeret opad (negativ værdi) eller nedad.

Rækker er antallet af celler som referencen blev korrigeret opad (negativ værdi) eller nedad.

Højde er den valgfrie lodrette højde for et område, der begynder ved den nye referenceposition.

Bredde (valgfri) er den vandrette bredde for et område, der begynder ved den nye referenceposition.

argumenter Rækker og Kolonner må ikke føre til nul eller en negativ startrække eller -kolonne

argumenter Højde og Bredde må ikke føre til nul eller et negativt antal af rækker eller kolonner.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. For eksempel i en funktion med fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

Eksempel

=FORSKYDNING(A1; 2; 2) returnerer værdien i celle C3 (A1 flyttet med to rækker og to kolonner nedad). Hvis C3 indeholder værdien 100 returnerer denne funktion værdien 100.

=OFFSET(B2:C3;1;1) returnerer en reference til B2:C3 flyttet 1 række ned og en kolonne til højre (C3:D4).

=OFFSET(B2:C3;-1;-1) returnerer en reference til B2:C3 flyttet 1 række op og en kolonne til venstre (A1:B2).

=OFFSET(B2:C3;0;0;3;4) returnerer en reference til B2:C3 med størrelsen ændret til 3 rækker og 4 kolonner (B2:E4).

=FORSKYDNING(B2:C3;1;0;3;4) returnerer en reference til B2:C3 flyttet en række ned og med størrelsen ændret til 3 rækker og 4 kolonner (B3:E5).

=SUM(FORSKYDNING(A1;2;2;5;6)) bestemmer summen af det område der starter i celle C3 og har en højde på 5 rækker og en bredde af 6 kolonner (område=C3:H7).

GETPIVOTDATA

Funktionen GETPIVOTDATA returnerer en resultatværdi fra en pivottabel. Værdien adresseres ved hjælp at felt- og elementnavnene, således at de forbliver valide såfremt pivottabellens opbygning senere ændres.

Syntaks

To forskellige syntaksdefinitioner kan bruges:

GETPIVOTDATA(Målfelt; pivottabel; [ Felt 1; Element 1; ... ])

GETPIVOTDATA(pivottabel; Begrænsninger)

Syntaks nr. 2 antages at være brugt hvis netop to parametre er givet, hvor den første parameter er en reference til en celle eller et celleområde. Den første syntaks antages at være brugt i alle andre tilfælde. Funktionsguiden viser den første syntaks.

Første syntaks

Målfelt er en tekststreng som vælger et af pivottabellens datafelter. Tekststrengen kan være navnet på kildekolonnen eller navn på datafeltet som vises i tabellen ("Sum - Salg").

pivottabel er en reference til en celle eller et celleområde som er placeret inden i en pivottabel eller som indeholder en pivottabel. Hvis celleområdet består af flere pivottabeller, vil den senest brugte pivottabel blive anvendt.

Hvis intet Felt n / Element n par er opgivet, returneres totalen. Ellers tilføjer hvert par en begrænsning som resultatet skal leve op til. Felt n er navnet på et felt fra pivottabellen. Element n er navnet på et element fra selvsamme felt.

Hvis pivottabellen kun består af et en enkelt resultatværdi som lever op til afgrænsningerne, eller en subtotal som summerer alle matchende værdier, vil denne værdi bleve returneret. Hvis der ikke er matchende resultater, eller der er flere resultater uden opsummering, returneres en fejl. Disse betingelser knytter sig til resultater fra pivottabellen.

Hvis kildedata indeholder bestanddele som er skjult som følge af indstillinger for pivottabellen, ignoreres de. Rækkefølgen af felter og elementer er ikke vigtig. Felter og elementnavne er ikke afhængige af at være præcise med hensyn til STORE og små bogstaver.

Hvis der ikke gives begrænsning på sidefelter, bruges feltets aktuelt valgte værdi implicit. Hvis der er begrænsning på sidefelter, må det matche feltets aktuelt valgte værdi, ellers returneres en fejl. Sidefelter er feltet allerøverst til venstre i en pivottabel, som er bestemt af området "Sidefelter" i dialogen "Pivottabel layout", Fra hvert sidefelt kan der vælges et element (værdi), hvilket betyder at kun den værdi medtages i beregningen.

Værdier for subtotal fra pivottabellen bruges kun, hvis de benytter funktionen "auto" (bortset fra specificerede begrænsninger, se Anden syntaks herunder).

Anden syntaks

pivottabel har samme betydning som ved første syntaks.

Begrænsninger er en mellemrumssepareret liste. Elementer kan være i citationstegn (enkelte citationstegn). Hele tekststrengen skal være omkranset af citationstegn (dobbelte citationstegn), med mindre du refererer til tekststrengen fra en anden celle.

En af indtastningerne kan være datafeltnavnet. Datafeltnavnet kan undlades, hvis pivottabellen alene består af et datafelt, ellers skal det være tilstede.

Hver af de øvrige indtastninger angiver en begrænsning på formen Felt[Element] (med de konkrete tegn [ og ]), eller blot Element hvis elementnavnet er unikt i alle felter som er brugt i pivottabellen.

Et funktionsnavn kan tilføjes på formen felt[element;funktion], hvilket betyder at kriterierne kun passer på subtotal værdier som bruger denne funktion. De mulige funktionsnavne er Sum, Tæl, Middel, Maks, Min, Produkt, Tæl (kun tal), Stdafv, Stdafvp, Varians, og Variansp. Der skelnes ikke mellem store og små bogstaver.

HYPERLINK

Når du klikker på en celle, som indeholder HYPERLINK-funktioner, åbner hyperlinket.

Hvis du bruger den valgfri parameter celletekst, finder formlen URL'en, og viser så teksten.

Syntaks

HYPERLINK("URL") eller HYPERLINK("URL"; "Celletekst")

URL specificerer kædemålet. Den valgfri parameter Celletekst er den tekst eller det tal, som vises i cellen og som returneres som resultatet. Hvis parameteren Celletekst ikke er angivet, vises parameteren URL i cellens tekst og returneres som resultatet.

Tallet 0 returneres for tomme celler og matrixelementer.

Eksempel

=HYPERLINK("http://www.example.org") viser teksten "http://www.example.org" i cellen og udfører hyperlinket http://www.example.org når der klikkes på den.

=HYPERLINK("http://www.eksempel.org"; "Klik her") viser teksten "Klik her" i cellen og udfører hyperlinket http://www.eksempel.org når der klikkes på cellen.

=HYPERLINK("http://www.eksempel.org";12345) viser tallet 12345 og udfører hyperlinket http://www.eksempel.org når der bliver klikket.

=HYPERLINK($B4) hvor celle B4 indeholder HTTP://www.eksempel.org". Funktionen tilføjer "HTTP://www.eksempel.org" til URL'en i hyperlinkcellen og returnerer den samme tekst, som bruges som formelresultat.

=HYPERLINK("HTTP://www."; "Klik ") & "eksempel.org" viser teksten "Klik eksempel.org" i cellen og udfører hyperlinket HTTP://www.eksempel.org når der klikkes på cellen.

=HYPERLINK("#Sheet1.A1";"Go to top") viser teksten Gå til toppen og hopper til cellen Ark1.A1 i dette dokument.

=HYPERLINK("file:///C:/writer.odt#Specifikation";"Gå til Writer-bogmærke") viser teksten Gå til Writer-bogmærke, indlæser det angivne tekstdokument og hopper til bogmærket "Specifikation".

INDEKS (INDEX på engelsk)

INDEKS returnerer indholdet af en celle, angivet enten ved række og kolonne eller ved et navngivet område. Afhængig af konteksten returnerer INDEKS enten indhold eller en reference.

Syntaks

INDEKS(Reference; Række; Kolonne; Område)

Reference er en cellereference, enten indtastet direkte eller ved at benytte navnet på et område. Hvis referencen består af flere områder, skal du sætte referencen eller områdenavnet i parentes.

Række (valgfri) repræsenterer rækkenummeret af referenceområdet, hvor der skal returneres en værdi fra. Hvis nul (ingen specifik række) returneres alle refererede rækker

Kolonne (valgfri) repræsenterer kolonnenummeret af referenceområdet, hvor der skal returneres en værdi fra. Hvis nul (ingen specifik kolonne) returneres alle refererede kolonner.

Område (valgfri) repræsenterer indekset for underområdet hvis der refereres til flere områder.

Eksempel

=INDEKS(Priser;4;1) returnerer værdien fra række 4 og kolonne 1 af databaseområdet defineret i Data - Definer som Priser.

=INDEKS(SumX; 4; 1) returnerer værdien fra området SumX i række 4 og kolonne 1 som defineret i Ark - Navngivne områder og udtryk - Definer.

=INDEKS(A1:B6;1) returnerer en reference til den første række i A1:B6.

=INDEKS(A1:B6;0;1) returnerer en reference til den første kolonne i A1:B6.

=INDEKS((multi);4;1) indikerer værdien i række 4 kolonne 1 i det definerede (multi-) område, som du navngav under Ark - Navngivne områder og udtryk - Definer som multi. Multiområdet kan bestå af flere enkelte rektangulære områder, hver med en række 4 og kolonne 1. Hvis du senere ønsker at kalde den anden blok fra multiområdet kan du indtaste tallet 2 som områdeparameter.

=INDEKS(A1:B6;1;1) angiver værdien i det øverste venstre hjørne af området A1:B6.

=INDEKS((multi);0;0;2) returnerer en reference til det andet område af multiområdet.

INDIREKTE (INDIRECT på engelsk)

Returnerer Henvisning angivet ved en tekststreng. Denne funktion kan også bruges til at returnere området af en tilsvarende streng.

Syntaks

INDIREKTE(Reference; A1)

Reference repræsenterer en reference til en celle eller et område (i tekst form) hvorfra der skal returneres en værdi.

A1 (valgfri) - hvis sat til 0,bliver notationen R1C1 brugt. Hvis parameteren mangler eller er sat til en anden værdi end 0, bliver notationen A1 brugt.

Eksempel

=INDIREKTE(A1) er lig med 100, hvis A1 indeholder C108 som en reference, og celle C108 indeholder en værdi på 100.

=SUM(INDIREKTE("A1:" & ADRESSE(1;3))) summerer cellerne i området fra A1 op til cellen, hvis adresse er defineret ved række 1 og kolonne 3. Det vil sige: A1:C1 er opsummeret.

KOLONNE (COLUMN på engelsk)

Returnerer kolonnenummeret for en cellereference. Hvis referencen er en celle bliver kolonnenummeret for cellen returneret. Hvis parameteren er et celleområde, bliver det tilsvarende kolonnenummer returneret i en enkeltrækket Matrix hvis formlen bliver indtastet som en matrixformel. Hvis funktionen KOLONNE, med en områdereference parameter ikke bliver brugt til en matrixformel, bliver kun kolonnenummeret for den første celle indenfor området bestemt.

Syntaks

KOLONNE(Reference)

Reference en reference til en celle eller celleområde hvis første kolonnenummer skal findes.

Hvis ingen reference indtastes, bliver kolonnenummeret for cellen hvori formlen er indtastet fundet.LibreOffice Calc sætter automatisk henvisningen til den aktuelle celle.

Eksempel

=KOLONNE(A1) er lig med 1. Kolonne A er den første kolonne i tabellen.

=KOLONNE(C3:E3) er lig med 3. Kolonne C er den tredje kolonne i tabellen.

=KOLONNE(D3:G10) returnerer 4, fordi kolonne D er den fjerde kolonne i tabellen, og KOLONNE-funktionen ikke er brugt som en matrixformel. (I dette tilfælde bruges den første værdi i et område altid som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) returnerer hver især 2 fordi referencen kun indeholder kolonne B som den anden kolonne i tabellen. Fordi enkelt-kolonne områder kun har et kolonnenummer, gør det ingen forskel om formlen bliver brugt som en matrixformel.

==KOLONNE() returnerer 3 hvis formlen blev indtastet i kolonne C.

{=KOLONNE(Kanin)} returnerer enkeltrækkematricen (3; 4) hvis "Kanin" er det navngivne område (C1:D3).

KOLONNER (COLUMNS på engelsk)

Returnerer antallet af kolonner i den givne reference.

Syntaks

KOLONNER(Matrix)

Matrix er referencen til et celleområde hvis totale antal kolonner skal findes. Argumentet kan også være en enkelt celle.

Eksempel

=Kolonner(B5) returnerer 1, fordi en celle kun indeholder en kolonne.

=KOLONNER(A1:C5) er lig med 3. Henvisningen indbefatter tre Kolonner.

=KOLONNER(Kanin) returnerer 2 hvisKanin er det navngivne område (C1:D3).

LOPSLAG (VLOOKUP på engelsk)

Lodret søgning med henvisning til tilstødende celler til højre. Denne funktion kontrollerer, om en bestemt værdi er indeholdt i den første kolonne i et område. Funktionen returnerer i så fald værdien til samme linje af en bestemt tabelkolonne, navngivet Indeks. Hvis parametren Sorteringsrækkefølge er undladt eller sat til TRUE, bliver det antaget, at dataene er sorteret i stigende rækkefølge. I dette tilfælde vil, hvis det eksakte søgekriterie ikke blev fundet, den sidste værdi, der er mindre end kriteriet, blive returneret. Hvis Sorteringsrækkefølge er sat til FALSE eller nul, skal der findes et eksakt match, ellers vil fejlen Fejl: Værdi ikke tilgængelig blive returneret. Med en værdi på nul behøver dataene dog ikke at være sorteret stigende.

Syntaks

=LOPSLAG(Søgekriterie; Matrix; Indeks; Sorteret)

Opslagsværdi er værdien der søges efter i den første kolonne i tabellen.

Matrix er referencen, som skal omfatte mindst to kolonner.

Indeks er kolonnenummeret i området som indeholder værdien som skal returneres. Den første kolonne har tallet 1.

Sorteret er en valgfri parameter, som indikerer, om den første kolonne i området er sorteret i stigende orden. Indtast den logiske værdi FALSK, hvis den første kolonne ikke er sorteret i stigende orden. I sorterede kolonner kan der søges meget hurtigere, og funktionen vil altid returnere en værdi, selv hvis søgningen ikke gav et præcist resultat, hvis det er mellem den laveste og højeste værdi i den sorterede liste. I usorterede lister skal søgningen give et præcist resultat. Ellers returnerer funktionen denne besked:Fejl: Værdi er ikke tilgængelig.

Eksempel

Du vil indtaste varenummeret i menuen i celle A1, og navnet på retten skal med det samme fremkomme i den tilstødende celle (B1). Værdien til konvertering fra nummer til navn findes i området D1:E100. D1 indeholder 100, E1 indeholder navnet Grøntsagssuppe og så videre op til 100 menupunkter. Tallene i kolonne D er sorteret i stigende orden; derfor er den valgfri parameter Sorteret ikke nødvendig.

Indtast følgende formel i B1:

=LOPSLAG(A1;D1:E100;2)

Så snart du indtaster et tal i A1 vil B1 vise den tilsvarende tekst indeholdt i den anden kolonne af referencen D1:E100. Indtastning af et ikke eksisterende tal viser teksten med næste tal i rækken. For at forhindre dette, indtastes FALSK som sidste parameter i formlen så en fejlmeddelelse genereres når et ikke eksisterende tal er indtastet.

OMRÅDER (AREAS på engelsk)

Returnerer antallet af individuelle områder som tilhører et multiområde. Et område kan bestå af sammenhængende celler eller en enkelt celle.

Funktionen forventer et enkelt argument. Hvis du angiver flere områder, skal du omgive dem i yderligere parenteser. Flere områder kan indtastes ved at bruge semikolon (;) som deler, men disse ændres automatisk til en tilde (~). Tilde bruges til at samle områder.

Syntaks

OMRÅDER(Reference)

Reference repræsenterer referencen til en celle eller et celleområde.

Eksempel

=OMRÅDER(A1:B3;F2;G1) returnerer 3, fordi det er en reference til tre celler og/eller celleområder. Efter indtastning konverteres det til = OMRÅDER((A1:B3~F2~G1)).

=OMRÅDER(Alt) returnerer 1, hvis du har defineret et område ved navn Alt under Data - Definer område.

ROW

Returnerer rækkenummeret for en cellereference. Hvis referencen er en celle, returnerer den rækkenummeret for cellen. Hvis referencen er et celleområde, returnerer den det tilsvarende rækkenummer i en enkeltkolonne Matrix hvis formlen er indtastet som en matrixformel. Hvis RÆKKE-funktionen med en områdereference ikke bliver brugt i en matrixformel, returneres kun rækkenummeret for den første områdecelle.

Syntaks

RÆKKE(Reference)

Reference er en celle, et område eller navnet på et område.

Hvis du ikke angiver en reference, vil rækkenummeret for cellen, hvor formlen er indtastet, blive fundet.LibreOffice Calc sætter automatisk referencen til den aktuelle celle.

Eksempel

RÆKKE(B3) returnerer 3, fordi referencen henviser til den tredje række i tabellen.

{=RÆKKE(D5:D8)} returnerer den enkeltkolonnede matrix (5, 6, 7, 8), fordi den specificerede reference indeholder rækkerne 5 til 8.

=RÆKKE(D5:D8) returnerer 5, fordi RÆKKE-funktionen ikke bliver brugt som matrixformel og kun nummeret på første række i referencen returneres.

{=RÆKKE(A1:E1)} og =RÆKKE(A1:E1) returnerer begge 1, fordi referencen kun indeholder række 1 som den første række i tabellen. (Fordi enkeltrækkede områder kun har en enkelt række tal, gør det ingen forskel, om formlen er brugt som en matrixformel.)

=RÆKKE() returnerer 3 hvis formlen blev indtastet i række 3.

{=RÆKKE(Kanin)} returnerer den enkeltkolonnede matrix (1, 2, 3), hvis "Kanin" er det navngivne område (C1:D3).

RÆKKER (ROWS på engelsk)

Returnerer antal rækker i en reference eller en matrix.

Syntaks

RÆKKER(Matrix)

Matrix er referencen eller det navngivne område, hvis totale antal rækker skal findes.

Eksempel

=Rækker(B5) returnerer 1, fordi en celle indeholder kun en enkelt række.

=RÆKKER(A10:B12) returnerer 3.

=RÆKKER(Kanin) returnerer 3, hvis "Kanin" er det navngivne område (C1:D3).

SAMMENLIGN (MATCH på engelsk)

Returnerer den relative position for et element i en matrix, som svarer til en angivet værdi. Funktionen returnerer positionen af værdien fundet i opslagsmatricen som et tal.

Syntaks

SAMMENLIGN(Opslagsværdi; Opslagsmatrix; Type)

Opslagsværdi er værdien, som der skal søges efter i enkeltrække- eller enkeltkolonnematricen.

Opslagsmatrix er referencen, der skal søges i. Et opslagsområde kan være en enkelt række eller kolonne eller en del af en enkelt række eller kolonne.

Type kan have værdierne 1, 0 eller -1. Hvis Type = 1 eller hvis denne valgfri parameter mangler, antages det, at den første kolonne i opslagsområdet er sorteret i stigende orden. Hvis Type = -1 antages det, at kolonnen er sorteret i faldende orden. Dette svarer til samme funktion i Microsoft Excel.

Hvis Type = 0, findes kun eksakte sammenfald. If søgekriteriet er fundet mere end en gang, returnerer funktionen indekset til den overenstemmelse. Kun hvis Type = 0 kan du søge efter regulære udtryk (hvis det er aktiveret i beregningsindstillingerne) eller jokere (hvis det er aktiveret i beregningsindstillingerne).

Hvis Type = 1 eller den tredje parameter mangler, returneres den sidste værdi der er mindre eller lig med søgekriteriet. Dette gælder selv når opslagsområdet ikke er sorteret. For Type = -1 returneres den første værdi der er større eller lig med.

Eksempel

=SAMMENLIGN(200;D1:D100) søger i området D1:D100, som er sorteret efter kolonne D, efter værdien 200. Så snart denne værdi er nået, returneres rækkenummeret hvor den blev fundet. Hvis en højere værdi er fundet undervejs i søgningen i kolonnen, returneres rækkenummeret for den foregående række.

SHEET

Returnerer arknummeret for en henvisning eller en streng som repræsenter et arknavn. Hvis du ikke indtaster en parameter, er resultatet arknummeret for regnearket som indeholder formlen.

Syntaks

ARK(Reference)

Reference er valgfri og er referencen til en celle, et område eller et arknavn.

Eksempel

=ARK(Ark2.A1) returnerer 2, hvis Ark2 er det andet ark i regnearksdokumentet.

SLÅ.OP (LOOKUP på engelsk)

Returnerer indholdet af en celle enten fra et enkeltrækket eller enkeltkolonnet område. Eventuelt returneres den tildelte værdi (af det samme indeks) i en anden kolonne og række. I modsætning til LOPSLAG og VOPSLAG kan søge- og resultatvektor være på forskellige placeringer; de behøver ikke at støde op til hinanden. Desuden skal søgevektoren for SLÅ.OP være sorteret i stigende rækkefølge, ellers vil søgningen ikke returnere et brugbart resultat.

Syntaks

SLÅ.OP(Opslagsværdi; Opslagsvektor; Resultatvektor)

Opslagsværdi er værdien, der skal søges efter; direkte indtastet eller som en reference.

Opslagsvektor er det enkeltrækkede eller enkeltkolonnede område, som skal afsøges.

Resultatvektor er et andet enkeltrækket eller enkeltkolonnet område, fra hvilket resultatet for funktionen bliver taget. Resultatet er cellen fra resultatvektoren med samme indeks som eksemplaret i søgevektoren.

Eksempel

=SLÅ.OP(A1; D1:D100; F1:F100) søger den tilsvarende celle i område D1:D100 for tallet du indtastede i A1. For forekomsten der findes bestemmes indekset, for eksempel, den 12. celle i dette område. Dernæst returneres indholdet af den 12. celle som værdien af funktionen (i resultatvektoren).

TYPOGRAFI (STYLE på engelsk)

Tildeler en typografi til den celle, der indeholder formlen. Efter et angivet tidsrum kan en anden typografi tildeles. Denne funktion returnerer altid værdien 0, hvilket giver dig mulighed for at lægge den til en anden funktion uden at ændre værdien. Sammen med funktionen AKTUEL kan du tildele en farve til en celle afhængig af værdien. For eksempel: =...+TYPOGRAFI(HVIS(AKTUEL()>3; "rød";"grøn")) tildeler typografien "rød" til cellen, hvis værdien er større end 3, ellers tildeles typografien "grøn". Begge celleformater skal være defineret på forhånd.

Syntaks

TYPOGRAFI(Typografi; Tid; Typografi2)

Typografi er navnet på en celletypografi tildelt til cellen. Typografinavne skal indtastes i anførselstegn.

Tid er en valgfri tidsperiode i sekunder. Hvis denne parameter mangler, vil typografien ikke blive ændret efter et bestemt tidsrum.

Typografi2 er den valgfrie celletypografi tildelt til cellen efter et bestemt tidsrum. Hvis denne parameter mangler vil "Standard" blive benyttet.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. For eksempel i en funktion med fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

Eksempel

=TYPOGRAFI("Usynlig";60;"Standard") formaterer cellen i gennemsigtigt format i 60 sekunder efter dokumentet blev genberegnet eller indlæst, herefter anvendes formatet Standard. Begge celleformater skal være defineret på forhånd.

Da TYPOGRAFI() har en numerisk returværdi på nul, bliver denne returværdi føjet til en streng. Dette kan undgås ved at bruge T() som i det følgende eksempel

="Tekst"&T(TYPOGRAFI("minTypografi"))

Se også AKTUEL() for et andet eksempel.

VOPSLAG (HLOOKUP på engelsk)

Søger efter en værdi og reference til cellerne nedenfor det valgte område. Denne funktion verificerer at den første række af et område indeholder en bestemt værdi. Funktionen returnerer så værdien i en række af området, navngivet i Indeks, i samme kolonne.

Syntaks

VOPSLAG(Søgekriterie; Matrix; Indeks; Sorteret)

Se også:LOPSLAG(kolonner og rækker er byttet)

VÆLG (CHOOSE på engelsk)

Bruger et indeks til at returnere en værdi fra en liste af op til 30 værdier.

Syntaks

VÆLG(Indeks; Værdi1; ...Værdi30)

Indeks er en reference eller et tal mellem 1 og 30, som indikerer, hvilke værdier der skal tages fra listen.

Værdi_1...Værdi_30 er listen af værdier indtastet som en reference til en celle eller som individuelle værdier.

Eksempel

=VÆLG(A1; B1; B2; B3; "I dag"; "I går"; "I morgen"), returnerer for eksempel indholdet af celle B2 til A1 = 2; til A1 = 4. Funktionen returnerer teksten "I dag".