Funcions de base de dades
En aquesta secció es presenten les funcions que s'utilitzen amb les dades organitzades en una sola fila de dades per a cada registre.
La categoria Base de dades es podria confondre amb una base de dades integrada al LibreOffice. Tanmateix, no hi ha cap relació entre les bases de dades del LibreOffice i la categoria Base de dades del LibreOffice Calc. |
Dades d'exemple:
Les dades següents s'utilitzaran en alguns dels exemples de descripció de funcions:
L'interval A1:E10 llista els nens que han anat a la festa d'aniversari d'en Joan. La informació següent apareix per a cada entrada: la columna A mostra el nom; la B, el curs; tot seguit es mostren l'edat (en anys), la distància fins a l'escola (en metres) i el pes (en quilograms).
A |
B |
C |
D |
E |
|
1 |
Nom |
Curs |
Edat |
Distància fins a l'escola |
Pes |
2 |
Andreu |
3 |
9 |
150 |
40 |
3 |
Elisabet |
4 |
10 |
1000 |
42 |
4 |
Carles |
3 |
10 |
300 |
51 |
5 |
Daniel |
5 |
11 |
1200 |
48 |
6 |
Eva |
2 |
8 |
650 |
33 |
7 |
Curs |
2 |
7 |
300 |
42 |
8 |
Ariadna |
1 |
7 |
200 |
36 |
9 |
Enric |
3 |
9 |
1200 |
44 |
10 |
Irene |
2 |
8 |
1000 |
42 |
11 |
|||||
12 |
|||||
13 |
Nom |
Curs |
Edat |
Distància fins a l'escola |
Pes |
14 |
>600 |
||||
15 |
|||||
16 |
BDCOMPTA |
5 |
La fórmula de la cel·la B16 és =BDCOMPTA(A1:E10;0;A13:E14)
Paràmetres de les funcions de base de dades:
Els elements següents són les definicions dels paràmetres de totes les funcions de base de dades:
BaseDeDades és l'interval de cel·les que defineix la base de dades.
CampDeBaseDeDades indica la columna on actuarà la funció després que s'hagin aplicat els criteris de cerca del primer paràmetre i que s'hagin seleccionat les files de dades; no té relació amb els criteris de cerca. Pel paràmetre CampDeBaseDeDades podeu introduir una referència a una cel·la de capçalera o a un nombre per especificar la columna dins de l'àrea de la Base de dades, a partir de l'1. Per fer referència a una columna mitjançant el nom de la capçalera d'aquesta columna, poseu el nom de la capçalera entre cometes.
CriterisDeCerca és l'interval de cel·les que conté els criteris de cerca. Si escriviu diversos criteris en una fila, es connecten mitjançant la conjunció I; si escriviu els criteris en diverses files, es connecten mitjançant la conjunció O. S'ignoraran les cel·les buides en els criteris de cerca.
Trieu LibreOffice ▸ PreferènciesEines ▸ Opcions - LibreOffice Calc ▸ Càlcul per definir com ha d'actuar el LibreOffice Calc en cercar entrades idèntiques.
Vegeu també la pàgina wiki sobre Comptatge i suma condicionals.
BDCOMPTA
BDCOMPTA compta el nombre de files (registres) d'una base de dades que coincideixen amb els criteris de cerca que heu indicat i que contenen valors numèrics.
Sintaxi
BDCOMPTA(BaseDeDades; [CampDeBaseDeDades]; CriterisDeCerca)
Si s'omet l'argument del CampDeBaseDeDades, BDCOMPTA retorna el recompte de tots els registres que compleixin els criteris. Pel paràmetre CampDeBaseDeDades podeu introduir una referència a una cel·la de capçalera o a un nombre per especificar la columna dins de l'àrea de la Base de dades, a partir de l'1. Per fer referència a una columna mitjançant el nom de la capçalera d'aquesta columna, poseu el nom de la capçalera entre cometes.
Exemple
En l'exemple anterior (desplaceu-vos cap amunt), volem saber quants nens han de recórrer més de 600 metres per arribar a l'escola. El resultat es mostrarà a la cel·la B16. Situeu el cursor a la cel·la B16 i introduïu-hi la fórmula =BDCOMPTA(A1:E10;0;A13:E14). L'Auxiliar de funcions us ajuda a triar els intervals.
Base de dades és l'interval de dades que s'ha d'avaluar, incloses les capçaleres: en aquest cas, A1:E10. CampDeBaseDeDades indica la columna dels criteris de cerca; en aquest cas, tota la base de dades. CriterisDeCerca és l'interval on podeu introduir els paràmetres de cerca; en aquest cas, A13:E14.
Per saber quants nens de segon curs tenen més de 7 anys, suprimiu l'entrada >600 de la cel·la D14 i introduïu 2 a la cel·la B14 (a sota de Curs); tot seguit, introduïu >7 a la cel·la C14 que hi ha a la dreta de la cel·la anterior. El resultat és 2: dos nens de segon curs tenen més de 7 anys. Com que ambdós criteris són a la mateixa fila, es connecten mitjançant I.
BDCOMPTAA
BDCOMPTAA compta el nombre de files (registres) d'una base de dades que coincideixen amb les condicions de cerca que heu indicat i que contenen valors numèrics o alfanumèrics.
Sintaxi
BDCOMPTAA(BaseDeDades; [CampDeBaseDeDades]; CriterisDeCerca)
If the DatabaseField argument is omitted, DCOUNTA returns the count of all records that satisfy Criteria. Pel paràmetre CampDeBaseDeDades podeu introduir una referència a una cel·la de capçalera o a un nombre per especificar la columna dins de l'àrea de la Base de dades, a partir de l'1. Per fer referència a una columna mitjançant el nom de la capçalera d'aquesta columna, poseu el nom de la capçalera entre cometes.
Exemple
En l'exemple anterior (desplaceu-vos cap amunt) podeu cercar el nombre de nens el nom dels quals comença amb la lletra E o amb una lletra posterior. Editeu la fórmula de la cel·la B16 perquè hi aparegui =BDCOMPTAA(A1:E10;"Nom";A13:E14). Suprimiu el criteri de cerca anterior i introduïu >=E en el camp A14 de la columna Nom. El resultat és 5. Si ara suprimiu tots els valors numèrics que corresponen a l'Ariadna a la fila 8, el resultat canvia a 4. La fila 8 ja no s'inclou en el comptatge perquè no conté cap valor. El nom Ariadna és text, no pas un valor. Tingueu en compte que el paràmetre "CampDeBaseDeDades" ha de fer referència a una columna que pugui contenir valors.
BDDESVEST
BDDESVEST calcula la desviació estàndard d'una població en funció d'una mostra; per fer-ho, utilitza els nombres d'una columna d'una base de dades que coincideixin amb els criteris de cerca. Els registres es tracten com una mostra de dades. Això vol dir que els nens de l'exemple representen una secció transversal de tots els nens. Tingueu en compte que, perquè un resultat sigui representatiu, cal que la mostra sigui superior a 1000.
Sintaxi
BDDESVEST(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per trobar la desviació estàndard del pes de tots els nens que tenen la mateixa edat a l'exemple (desplaceu-vos cap amunt), introduïu la fórmula següent a la cel·la B16:
=BDDESVEST(A1:E10;"Pes";A13:E14)
A la fila 14 de la columna Edat, introduïu 7, 8, 9 i així successivament. El resultat que apareix és la desviació estàndard del pes de tots els nens que tenen aquesta edat.
BDDESVESTP
La funció BDDESVESTP calcula la desviació estàndard d'una població, basada en totes les cel·les d'un interval de dades que coincideixen amb els criteris de cerca. A l'exemple, els registres es tracten com una població completa.
Sintaxi
BDDESVESTP(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per trobar la desviació estàndard del pes de tots els nens que tenen la mateixa edat i que han anat a la festa d'aniversari d'en Joan (desplaceu-vos cap amunt), introduïu la fórmula següent a la cel·la B16:
=BDDESVESTP(A1:E10;"Pes";A13:E14)
A la fila 14, a Edat, introduïu 7, 8, 9 i així successivament. El resultat és la desviació estàndard del pes de tots els nens de la mateixa edat per als quals s'ha comprovat el pes.
BDEXTREU
BDEXTREU retorna el contingut de la cel·la referenciada en una base de dades que coincideixi amb els criteris de cerca que s'hagin indicat. En cas d'error, la funció retorna #VALOR! si no ha trobat cap fila o bé Err502 si ha trobat més d'una cel·la.
Sintaxi
BDEXTREU(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
En l'exemple anterior (desplaceu-vos cap amunt), volem saber a quin curs va un nen determinat, el nom del qual s'introdueix a la cel·la A14. La fórmula s'introdueix a la cel·la B16 i és lleugerament diferent dels exemples anteriors perquè només es pot introduir una columna (un camp de base de dades) a Camp de la base de dades. Introduïu la fórmula següent:
=BDEXTREU(A1:E10;"Curs";A13:E14)
Introduïu el nom Francesc a la cel·la A14 i veureu el resultat 2. En Francesc va a segon. Introduïu "Edat" en comptes de "Curs" i obtindreu l'edat d'en Francesc.
O bé introduïu el valor 11 només a la cel·la C14, i suprimiu la resta d'entrades d'aquesta fila. Editeu la fórmula de la cel·la B16 tal com s'indica tot seguit:
=BDEXTREU(A1:E10;"Nom";A13:E14)
En comptes del curs, es consulta el nom. La resposta apareix immediatament: en Daniel és l'únic alumne que té 11 anys.
BDMAX
BDMAX retorna el contingut màxim d'una cel·la (camp) determinada d'una base de dades (tots els registres) que coincideixi amb les condicions de cerca que s'hagin indicat.
Sintaxi
BDMAX(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per esbrinar quant pesa l'alumne amb més pes en cada curs de l'exemple anterior (desplaceu-vos cap amunt), introduïu la fórmula següent a B16:
=BDMAX(A1:E10;"Pes";A13:E14)
A Curs, introduïu 1, 2, 3, i així successivament. Després d'introduir un número de curs, apareix el pes del nen que pesa més del curs en qüestió.
BDMIN
BDMIN retorna el contingut mínim d'una cel·la (camp) en una base de dades que coincideixi amb els criteris de cerca que s'hagin indicat.
Sintaxi
BDMIN(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per trobar la distància més curta cap a l'escola per als nens de cada curs de l'exemple anterior (desplaceu-vos cap amunt), introduïu la fórmula següent a la cel·la B16:
=BDMIN(A1:E10;"Distància fins a l'escola";A13:E14)
A la fila 14, a Curs, introduïu 1, 2, 3 i així successivament. Apareixerà la distància més curta fins a l'escola per a cada curs.
BDMITJANA
BDMITJANA retorna la mitjana dels valors de totes les cel·les (camps) de totes les files (registres de la base de dades) que coincideixen amb els criteris de cerca que s'hagin indicat.
Sintaxi
BDMITJANA(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per trobar el pes mitjà de tots els nens de la mateixa edat de l'exemple anterior (desplaceu-vos cap amunt), introduïu la fórmula següent en la cel·la B16:
=BDMITJANA(A1:E10;"Pes";A13:E14)
A la fila 14, a Edat, introduïu 7, 8, 9 i així successivament. Apareix el pes mitjà de tots els nens que tenen aquesta edat.
BDPRODUCTE
BDPRODUCTE multiplica totes les cel·les d'un interval de dades determinat on els continguts de les cel·les coincideixin amb els criteris de cerca.
Sintaxi
BDPRODUCTE(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Amb l'exemple de la festa d'aniversari anterior (desplaceu-vos amunt), no hi ha cap aplicació d'aquesta funció que tingui sentit.
BDSUM
BDSUM retorna el total de totes les cel·les en un camp de base de dades, en totes les files (registres) que coincideixin amb els criteris de cerca que hàgiu indicat.
Sintaxi
BDSUM(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per saber la longitud acumulada de les distàncies fins a l'escola de cadascun dels nens que han anat a la festa d'en Joan (desplaceu-vos cap amunt), introduïu la fórmula següent a la cel·la B16:
=BDSUM(A1:E10;"Distància fins a l'escola";A13:E14)
Introduïu 2 a la fila 14, a Curs. Apareixerà la suma (1950) de les distàncies fins a l'escola de tots els nens que van a segon.
BDVAR
BDVAR retorna la variància de totes les cel·les d'un camp de base de dades en tots els registres que coincideixin amb els criteris de cerca que s'hagin indicat. Els registres de l'exemple es tracten com una mostra de dades. Perquè un resultat sigui representatiu, la mostra ha de ser superior a 1000.
Sintaxi
BDVAR(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per saber la variància del pes de tots els nens de l'exemple anterior (desplaceu-vos cap amunt) que tenen la mateixa edat, introduïu la fórmula següent a la cel·la B16:
=BDVAR(A1:E10;"Pes";A13:E14)
A la fila 14 de la columna Edat, introduïu 7, 8, 9 i així successivament. Apareixerà el resultat de la variància dels valors del pes de tots els nens que tenen aquesta edat.
BDVARP
BDVARP calcula la variància per a tots els valors de les cel·les d'un camp de base de dades determinat en tots els registres que coincideixin amb els criteris de cerca indicats. Els registres de l'exemple es tracten com una població completa.
Sintaxi
BDVARP(BaseDeDades; CampDeBaseDeDades; CriterisDeCerca)
Exemple
Per trobar la variància del pes de tots els nens que tenen la mateixa edat i que són a la festa d'aniversari d'en Joan (desplaceu-vos cap amunt), introduïu la fórmula següent a la cel·la B16:
=BDVARP(A1:E10;"Pes";A13:E14)
A la fila 14, a Edat, introduïu 7, 8, 9 i així successivament. Apareix la variància dels valors del pes de tots els nens que tenen aquesta edat i que aniran a la festa d'aniversari d'en Joan.