Funções de folha de cálculo

From LibreOffice Help
Jump to: navigation, search

Esta secção contém descrições das funções da folha de cálculo junto com um exemplo.

Inserir - Função - Categoria Folha de cálculo

OBTERDADOSDIN

A função OBTERDADOSDIN devolve um resultado da tabela dinâmica. O valor é referenciado atrás dos nomes de item e campo, permanecendo válido se o esquema da tabela dinâmica mudar.

Sintaxe

Pode utilizar duas definições de sintaxe diferentes:

OBTERDADOSDIN(campo_dados; tabela_dinâmica; [ campo1; item 1; ... ])

OBTERDADOSDIN(tabela_dinâmica; restrições)

A segunda sintaxe é assumida se forem fornecidos exatamente dois parâmetros, dos quais o primeiro parâmetro é uma referência a uma célula ou a um intervalo de células. A primeira sintaxe é assumida em todos os outros casos. O Assistente de funções mostra a primeira sintaxe.

Primeira sintaxe

campo_dados é o nome do campo a partir do qual os valores serão extraídos. Pode ser o nome da coluna de origem ou o nome do campo de dados tal como está na tabela (como "Soma - Vendas").

tabela_dinâmica é a referência a uma célula ou intervalo de células que está posicionada numa tabela dinâmica, ou inclui uma tabela dinâmica. Se o intervalo de células inclui várias tabelas dinâmicas, é utilizada a tabela que foi criada em último lugar.

Se não forem indicados pares campo/item, é devolvida a soma total. Caso contrário, cada par adiciona uma restrição que o resultado terá de satisfazer. Campo é o nome de um campo da tabela dinâmica. Item é o nome de um item desse campo.

Se a tabela dinâmica só incluir um valor de resultado que satisfaça todas as restrições ou um valor de subtotal que resuma todos os valores correspondentes, esse resultado é devolvido. Se não existir qualquer resultado correspondente ou existirem vários sem um subtotal para os mesmos, é devolvido um erro. Estas condições aplicam-se ao resultados incluídos na tabela dinâmica.

Se a origem dos dados incluir entradas que estejam ocultas por definições da tabela dinâmica, estão são ignoradas. A ordem dos pares campo/item não é significativa. Os nomes de campo e item não diferenciam maiúsculas e minúsculas.

Se não indicar qualquer restrição para um campo de página, é usado implicitamente o valor selecionado no campo. Se for fornecida uma restrição para um campo de página, esta terá de corresponder ao valor selecionado no campo, ou será devolvido um erro. Os campos de página são os campos que se encontram na parte superior esquerda de uma tabela dinâmica, e são preenchidos utilizando a área "Campos de página" da caixa de diálogo esquema da tabela dinâmica. Pode selecionar um item (valor) a partir de cada campo de página, o que significa que apenas esse item será incluído no cálculo.

Os valores de subtotal da tabela dinâmica apenas serão utilizados se utilizarem a função "auto" (exceto quando especificado na restrição, consultar Segunda sintaxe).

Segunda sintaxe

tabela_dinâmica tem o mesmo significado da primeira sintaxe.

restrições é uma lista separada por espaços. As entradas podem ser introduzidas entre plicas. A cadeia completa tem de ser colocada entre aspas, a não ser que referencie uma cadeia de outra célula.

Uma das entradas pode ser o nome do campo de dados. O nome do campo de dados pode não ser preenchido se a tabela dinâmica incluir apenas um campo de dados. Caso contrário, terá de ser preenchido.

Cada uma das outras entradas especifica uma restrição no formulário campo[item] (com caracteres literais [ e ]) ou apenas item se o nome do item for único dentro de todos os campos utilizados na tabela dinâmica.

Pode adicionar um nome de função segundo a forma Campo[Item;Função], o que fará com que a restrição corresponda apenas a valores de subtotal que utilizem essa função. Os nomes de função possíveis são Soma, Contar, Média, Máximo, Mínimo, Produto, Contar (só números), DesvPad (amostra), DesvPadN (população), Variância (amostra) e Variâncias (população), não sensíveis a maiúsculas/minúsculas.

PROCV

Procura vertical com referência às células adjacentes à direita. Esta função verifica se um determinado valor está contido na primeira coluna de uma matriz. Em seguida, a função devolve o valor na mesma linha da coluna com o nome Índice. Se o parâmetro ordenação for omitido ou definido como VERDADEIRO ou um, pressupõe-se que os dados estão ordenados de forma ascendente. Neste caso, se o valor_procurar exato não for encontrado, será devolvido o último valor inferior ao critério. Se ordenação for definido como FALSO ou zero, é necessário encontrar uma correspondência exata, caso contrário o erro Erro: valor não disponível será o resultado. Por este motivo, com um valor zero, os dados não necessitam de ser ordenados de forma ascendente.

A procura suporta expressões regulares. Pode introduzir "all.*", por exemplo, para localizar a primeira localização de "all" seguida de quaisquer caracteres. Se pretende procurar texto que também é uma expressão regular, necessita de anteceder cada carácter com \. Pode ativar e desativar a avaliação automática da expressão regular em Ferramentas - Opções - LibreOffice Calc - Calcular.

Sintaxe

=PROCV(valor_procurar; matriz; índice; ordenação)

valor_procurar corresponde ao valor a procurar na primeira coluna da tabela.

matriz corresponde À matriz ou intervalo de dados da referência com, pelo menos, duas colunas.

índice corresponde ao número da coluna na matriz de onde o valor deve ser retirado. A primeira coluna tem o número 1.

ordenação corresponde a um parâmetro opcional que indica se a primeira coluna da matriz é ordenada de forma ascendente. Introduza o valor booleano FALSO ou zero se a primeira coluna não estiver ordenada de forma ascendente. As procuras em colunas ordenadas são muito mais rápidas e a função devolve sempre um valor, mesmo se o valor a procurar não tiver sido encontrado na sua forma exata, se esse valor estiver entre os valores mais baixo e mais alto da lista ordenada. Em listas não ordenadas, o valor a procurar tem de ter uma correspondência exata. Caso contrário, a função irá devolver a seguinte mensagem: Erro: valor não disponível.

Processamento de células vazias

Exemplo

O utilizador pretende que, ao introduzir o número de um prato do menu na célula A1, o nome do prato seja mostrado imediatamente como texto na célula (B1). A atribuição de números aos nomes está contida na matriz D1:E100. D1 contém 100, E1 contém o nome Sopa de vegetais e assim sucessivamente para os 100 pratos. Os números na coluna D são ordenados de forma ascendente. Assim, o parâmetro opcional ordenação não é necessário.

Introduza a seguinte fórmula em B1:

=PROCV(A1;D1:E100;2)

Assim que introduz um número em A1, a célula B1 irá mostrar o texto existente na segunda coluna da referência D1:E100. Se introduzir um número não existente, a célula mostra o texto correspondente ao número imediatamente a seguir. Para evitar que tal aconteça, introduza FALSO como último parâmetro da fórmula; dessa forma, a célula mostra uma mensagem de erro quando se introduz um número não existente.

COLS

Devolve o número de colunas de uma matriz ou referência.

Sintaxe

COLS(matriz)

matriz corresponde à matriz ou referência a um intervalo de células, cujo número total de colunas deve ser determinado. O argumento também pode corresponder a uma única célula.

Exemplo

=COLS(B5) devolve 1 uma vez que uma célula só contém uma coluna.

=COLS(A1:C5) equivale a 3. A referência abrange três colunas.

=COLS(Coelho) devolve 2 se Coelho for o nome do intervalo (C1:D3).

COL

Devolve o número de coluna da referência da célula. Se a referência corresponder a uma célula, devolve o número de coluna da célula; se o parâmetro corresponder a uma área de células, os números de coluna correspondentes são devolvidos numa matriz de linha singular, se a fórmula for introduzida como fórmula de matriz. Se a função COL com um parâmetro referente a uma área não for utilizada como fórmula de matriz, é determinado apenas o número de coluna da primeira célula da área.

Sintaxe

COL(referência)

referência corresponde à referência a uma célula ou intervalopara a qual se pretende encontrar o número da primeira coluna.

Se não introduzir qualquer referência, é devolvido o número de coluna da célula onde a fórmula foi introduzida. O LibreOffice Calc define automaticamente a referência para a célula atual.

Exemplo

=COL(A1) equivale a 1. A coluna A é a primeira coluna na tabela.

=COL(C3:E3) equivale a 3. A coluna C corresponde à terceira coluna da tabela.

=COL(D3:G10) devolve 4, uma vez que a coluna D corresponde à quarta coluna da tabela e a função COL não é utilizada como uma fórmula de matriz. (Neste caso, o primeiro valor da matriz é sempre utilizado como o resultado.)

{=COL(B2:B7)} e =COL(B2:B7) devolvem ambas 2, uma vez que a referência apenas contém a coluna B como segunda coluna da tabela. Uma vez que as áreas de coluna única apenas têm um número de coluna, é indiferente se a fórmula é utilizada como fórmula de matriz ou não.

=COL() devolve 3 se a fórmula tiver sido introduzida na coluna C.

{=COL(Coelho)} devolve a matriz de linha única (3, 4), se "Coelho" for o nome da área (C1:D3).

INDIRETO

Devolve a referência especificada por um valor de texto. Esta função também pode ser utilizada para devolver a área da cadeia correspondente.

Para interoperabilidade, as funções ENDEREÇO e INDIRETO suportam um parâmetro opcional para especificar se deve ser utilizada a notação de endereço L1C1 em vez da notação A1.

Na função ENDEREÇO, o parâmetro é inserido como o quarto parâmetro, movendo o parâmetro de nome da folha opcional para a quinta posição.

Na função INDIRETO, o parâmetro é acrescentado como o segundo parâmetro.

Em ambas as funções, se o argumento for inserido com o valor 0, é utilizada a notação L1C1. Se o argumento não for fornecido ou tiver um valor diferente de 0, é utilizada a notação A1.

No caso da notação L1C1, a função ENDEREÇO devolve cadeias de endereço utilizando o ponto de exclamação '!' como o separador do nome da folha e a função INDIRETO espera o ponto de exclamação como separador do nome da folha. Ambas as funções ainda utilizam o ponto '.' como o separador do nome da folha na notação A1.

Ao abrir documentos no formato ODF 1.0/1.1, as funções ENDEREÇO que apresentem um nome de folha como quarto parâmetro, irão mover o nome de folha para o quinto parâmetro. Será introduzido um novo quarto parâmetro com o valor 1.

Ao guardar um documento no formato ODF 1.0/1.1, se as funções ENDEREÇO tiverem um quarto parâmetro, esse parâmetro será removido.

Note.png Não guarde uma folha de cálculo no formato ODF 1.0/1.1, se o quarto parâmetro da função ENDEREÇO tenha sido utilizado com um valor de 0.
Note.png A função INDIRETO é guardada sem a conversão para o formato ODF 1.0/1.1. Se estivesse presente o segundo parâmetro, uma versão anterior do Calc iria devolver um erro para essa função.

Sintaxe

INDIRETO(ref_texto; A1)

ref_texto representa uma referência a uma célula ou área (na forma de texto) para a qual devolver o conteúdo.

A1 (opcional) - se definido como 0 ou Falso, é utilizada a notação L1C1. Se este parâmetro for omisso ou estiver definido um valor diferente de 0, é utilizada a notação A1.

Note.png Se abrir uma folha de cálculo do Excel que utiliza endereços indiretos calculados a partir das funções em cadeia, os endereços da folha não serão convertidos automaticamente. Por exemplo, o endereço do Excel em INDIRETO("nomedoficheiro!nomedafolha"&B1) não é convertido num endereço de Calc em INDIRETO("nomedoficheiro.nomedafolha"&B1).

Exemplo

=INDIRETO(A1) equivale a 100 se A1 incluir C108 como uma referência e a célula C108 incluir um valor de 100.

=SOMA(INDIRETO("a1:" & ENDEREÇO(1;3))) soma as células na área de A1 até à célula com o endereço definido pela linha 1 e coluna 3. Ou seja, soma a área A1:C1.

ÍNDICE

ÍNDICE devolve o valor ou a referência de uma célula na interseção de uma linha e uma coluna, num determinado intervalo.

Sintaxe

ÍNDICE(referência; linha; coluna; intervalo)

referência é uma referência, introduzida diretamente ou especificando um nome de intervalo. Se a referência for constituída por vários intervalos, deve colocar a referência ou o nome do intervalo entre parênteses.

linha (opcional) representa o índice da linha do intervalo de referência para o qual se pretende devolver um valor. Se especificar zero (nenhuma linha específica), são devolvidas todas as linhas referenciadas.

coluna (opcional) representa o índice da coluna do intervalo de referência para o qual se pretende devolver um valor. Se especificar zero (nenhuma coluna específica) são devolvidas todas as colunas referenciadas.

intervalo (opcional) representa o índice do subintervalo, caso este se refira a um intervalo múltiplo.

Exemplo

=ÍNDICE(preços;4;1) devolve o valor da linha 4 e coluna 1 do intervalo de base de dados definido em Dados - Definir como preços.

=ÍNDICE(soma_x;4;1) devolve o valor do intervalo soma_x na linha 4 e coluna 1, como definido em Inserir - Nomes - Definir.

=ÍNDICE(A1:B6;1) devolve uma referência à primeira linha de A1:B6.

=ÍNDICE(A1:B6;0;1) devolve uma referência à primeira coluna de A1:B6.

=ÍNDICE((multi);4;1) indica o valor da linha 4 e coluna 1 do intervalo (múltiplo), ao qual foi atribuído o nome multi em Inserir - Nomes - Definir. O intervalo múltiplo pode ser constituído por vários intervalos retangulares, cada um deles com uma linha 4 e coluna 1. Se pretender invocar o segundo bloco deste intervalo múltiplo, introduza o número 2 como parâmetro intervalo.

=ÍNDICE(A1:B6;1;1) indica o valor no canto superior esquerdo do intervalo A1:B6.

=ÍNDICE((multi);0;0;2) devolve uma referência ao segundo intervalo do intervalo múltiplo.

TIPOERRO

Devolve o número correspondente ao valor de erro. Com a ajuda deste número, pode criar um texto de mensagem de erro.

Se ocorrer um erro, a função devolve um valor lógico ou numérico.

Note.png Se clicar na célula que contém o erro, a barra de estado mostra o código de erro pré-definido do LibreOffice.

Sintaxe

TIPOERRO(valor_erro)

valor_erro contém o endereço da célula na qual ocorre o erro.

Exemplo

Se a célula A1 mostrar Err:518, a função =TIPOERRO(A1) devolve o número 518.

DDE

Devolve os dados de uma ligação DDE. Se o conteúdo do intervalo ou secção for alterado, o valor devolvido também será alterado. Deve recarregar a folha de cálculo ou escolher Editar - Ligações para ver as ligações atualizadas. Não são permitidas ligações entre plataformas diferentes (por exemplo, entre um documento do LibreOffice instalado numa máquina Windows e um documento criado numa máquina Linux.

Sintaxe

DDE("servidor"; "ficheiro"; "intervalo"; modo)

servidor é o nome da aplicação que serve de servidor. As aplicações do LibreOffice têm "soffice" como nome de servidor.

ficheiro é o nome de ficheiro completo, incluindo a especificação do caminho.

intervalo é a área que contém os dados que pretende avaliar.

modo é um parâmetro opcional que controla o método através do qual o servidor DDE converte os respetivos dados em números.

modo efeito
0 ou em falta Formato numérico do estilo de célula "Padrão"
1 Os dados são sempre interpretados segundo o formato padrão para inglês americano
2 Os dados são obtidos em forma de texto; não são convertidos em números

Exemplo

=DDE("soffice";"c:\office\documento\dados1.sxc";"folha1.A1") lê o conteúdo da célula A1 na folha1 da folha de cálculo dados1.sxc do LibreOffice Calc.

=DDE("soffice";"c:\office\documento\mote.sxw";"Mote de hoje") devolve um mote na célula que contém esta fórmula. Primeiro tem de introduzir uma linha no documento mote.sxw que contém o texto e definir a mesma como a primeira linha de uma secção denominada Mote de hoje (no LibreOffice Writer em Inserir - Secção). Se o mote for modificado (e guardado) no documento do LibreOffice Writer, o mote é atualizado em todas as células do LibreOffice Calc nas quais esta ligação DDE estiver definida.

HIPERLIGAÇÃO

Ao clicar numa célula que contenha a função HIPERLIGAÇÃO, abre-se a hiperligação.

Se utilizar o parâmetro opcional texto_célula, a fórmula localiza o URL e mostra o texto ou o número.

Tip.png Para abrir uma célula com hiperligação através do teclado, selecione a célula, prima F2 para introduzir o modo Editar, desloque o cursor em frente da hiperligação, prima Shift+F10 e escolha Abrir hiperligação.

Sintaxe

HIPERLIGAÇÃO("endereço") ou HIPERLIGAÇÃO("endereço"; "texto_célula")

endereço especifica o destino da ligação. O parâmetro opcional texto_célula corresponde ao texto ou número da célula e será devolvido como resultado. Se o parâmetro texto_célula não for especificado, o endereço é apresentado no texto da célula e será devolvido como resultado.

O número 0 é devolvido para células vazias e elementos de matriz.

Exemplo

=HIPERLIGAÇÃO("http://www.exemplo.org") mostra o texto "http://www.exemplo.org" na célula e executa a hiperligação http://www.exemplo.org ao clicar na mesma.

=HIPERLIGAÇÃO("http://www.exemplo.org";"Clique aqui") mostra o texto "Clique aqui" na célula e executa a hiperligação http://www.exemplo.org ao clicar na mesma.

=HIPERLIGAÇÃO("http://www.exemplo.org";12345) mostra o número 12345 e executa a hiperligação http://www.exemplo.org ao clicar na mesma.

=HIPERLIGAÇÃO($B4) em que a célula B4 contém http://www.exemplo.org. A função adiciona http://www.exemplo.org ao URL da célula da hiperligação e devolve o mesmo texto que é utilizado como resultado da fórmula.

=HIPERLIGAÇÃO("http://www.";"Clique em ") & "exemplo.org" mostra o texto "Clique em exemplo.org" na célula, e executa a hiperligação http://www.exemplo.org ao clicar na mesma.

=HIPERLIGAÇÃO("#Folha1.A1";"Ir para o início") mostra o texto Ir para o início e vai para a célula Folha1.A1 deste documento.

=HIPERLIGAÇÃO("file:///C:/writer.odt#Especificação";"Ir para marcador do Writer") mostra o texto Ir para marcador do Writer, carrega o documento especificado e vai para o marcador "Especificação".

ÁREAS

Devolve o número de áreas numa referência. Uma área é um intervalo de células contíguas ou uma única célula.

A função espera um único argumento. Se especificar vários intervalos, terá de colocá-los entre parênteses adicionais. Pode introduzir vários intervalos utilizando um ponto e vírgula (;) como separador, embora este seja automaticamente convertido para o operador til (~). O til é utilizado para unir intervalos.

Sintaxe

ÁREAS(referência)

A referência representa a referência a uma célula ou intervalo de dados.

Exemplo

=ÁREAS((A1:B3;F2;G1)) devolve 3, uma vez que se trata de uma referência a três células e/ou áreas. Após a entrada, é convertido para =ÁREAS((A1:B3~F2~G1)).

=ÁREAS(Tudo) devolve 1 se tiver definido uma área com o nome "Tudo" em Dados - Definir intervalo.

LINS

Devolve o número de linhas de uma referência ou matriz.

Sintaxe

LINS(matriz)

matriz é a referência ou área com nome definido cujo número total de linhas deve ser determinado.

Exemplo

=LINS(B5) devolve 1, visto que uma célula contém apenas uma linha.

=LINS(A10:B12) devolve 3.

=LINS(Coelho) devolve 3 se "Coelho" for o nome da área (C1:D3).

LIN

Devolve o número de linha de uma referência de célula. Se a referência for uma célula, devolve o número de linha da célula. Se a referência corresponder a um intervalo de células, devolve os números de linha correspondentes numa Matriz de coluna singular se a fórmula for introduzida como fórmula de matriz. Se a função LIN com uma referência a um intervalo não for utilizada como fórmula de matriz, é devolvido apenas o número de linha da primeira célula do intervalo.

Sintaxe

LIN(referência)

referência é uma célula, uma área ou o nome de uma área.

Se não indicar uma referência, é devolvido o número de linha da célula onde a fórmula é introduzida. O LibreOffice Calc define automaticamente a referência para a célula atual.

Exemplo

=LIN(B3) devolve 3 uma vez que a referência corresponde à terceira linha da tabela.

{=LIN(D5:D8)} devolve a matriz de coluna única (5, 6, 7, 8), uma vez que a referência especificada contém as linhas 5 a 8.

=LIN(D5:D8) devolve 5 uma vez que a função LIN não é utilizada como fórmula de matriz, devolvendo apenas o número da primeira linha da referência.

{=LIN(A1:E1)} e =LIN(A1:E1) devolvem ambos 1, uma vez que a referência apenas contém a linha 1 como a primeira linha da tabela. (Visto as áreas de linha única terem apenas um número de linha, é indiferente se a fórmula é utilizada como fórmula de matriz ou não.)

=LIN() devolve 3 se a fórmula tiver sido introduzida na linha 3.

{=LIN(Coelho)} devolve a matriz de coluna única (1, 2, 3) se "Coelho" for o nome da área (C1:D3).

PROCH

Procura um valor e referência às células situadas por baixo da área selecionada. Esta função verifica se a primeira linha de uma matriz contém um determinado valor. A função devolve o valor numa linha da matriz, indicada no Índice, na mesma coluna.

A procura suporta expressões regulares. Pode introduzir "all.*", por exemplo, para localizar a primeira localização de "all" seguida de quaisquer caracteres. Se pretende procurar texto que também é uma expressão regular, necessita de anteceder cada carácter com \. Pode ativar e desativar a avaliação automática da expressão regular em Ferramentas - Opções - LibreOffice Calc - Calcular.

Sintaxe

PROCH(valor_procurar; matriz; índice; ordenação)

Consulte também: PROCV (as colunas e linhas são trocadas)

Processamento de células vazias

SELECIONAR

Utiliza um índice para devolver um valor de uma lista constituída por 30 valores ou menos.

Sintaxe

SELECIONAR(núm_índice; valor1; ...; valor30)

núm_índice corresponde à referência ou número entre 1 e 30 que indica qual é o valor a ser obtido da lista.

valor1...valor30 são a lista de valores introduzidos como referência a uma célula ou como valores individuais.

Exemplo

=SELECIONAR(A1;B1;B2;B3;"Hoje";"Ontem";"Amanhã"), por exemplo, devolve o conteúdo da célula B2 para A1 = 2; para A1 = 4, a função devolve o texto "Hoje".

ESTILO

Aplica um estilo à célula que contém a fórmula. Após um determinado tempo, pode ser aplicado outro estilo. Esta função devolve sempre o valor 0, permitindo adicioná-la a outra função sem alterar o seu valor. Em conjunto com a função ATUAL, permite aplicar uma cor a uma célula, independentemente do valor. Por exemplo: =...+ESTILO(SE(ATUAL()>3;"vermelho";"verde")) aplica o estilo "vermelho" à célula se o valor for maior que 3; caso contrário, é aplicado o estilo "verde". Tem que definir os dois formatos de células antes de aplicar a função.

Sintaxe

ESTILO("estilo"; duração; "estilo2")

estilo é o nome de um estilo atribuído à célula. Os nomes de estilo devem ser introduzidos entre aspas.

duração é um intervalo de tempo opcional, em segundos. Se este parâmetro estiver em falta, o estilo não será alterado após um determinado período de tempo.

estilo2 é o nome opcional de um estilo atribuído à célula após um determinado período de tempo. Se este parâmetro estiver em falta, é assumido o "Padrão".

Nas funções do LibreOffice Calc, pode excluir parâmetros marcados como "opcionais" apenas quando não são seguidos por mais parâmetros. Por exemplo, numa função com 4 parâmetros, em que os dois últimos parâmetros são marcados como "opcionais", pode excluir o parâmetro 4 ou os parâmetros 3 e 4, mas não apenas o parâmetro 3.

Exemplo

=ESTILO("Invisível";60;"Padrão") atribui uma transparência à célula durante 60 segundos, após o documento ter sido recalculado ou carregado e, em seguida, retorna ao formato padrão. Tem que definir antecipadamente ambos os formatos de células.

Uma vez que ESTILO() tem um valor de retorno numérico de zero, este valor de retorno é acrescentado a uma cadeia. Esta situação pode ser evitada utilizando T(), tal como no seguinte exemplo

="Texto"&T(ESTILO("meuEstilo"))

Consulte também ATUAL() para obter outro exemplo.

PROC

Devolve o conteúdo de uma célula de um intervalo de coluna ou linha única. Opcionalmente, o valor atribuído (do mesmo índice) é devolvido numa coluna ou linha diferente. Em contraste com as funções PROCV e PROCH, os vectores de procura e de resultados podem estar em posições diferentes. Não é necessário que sejam adjacentes. Adicionalmente, o vetor de procura da função PROC tem de estar ordenado de forma ascendente. Caso contrário, a procura não devolverá qualquer valor útil.

Note.png Se PROC não conseguir encontrar o critério de procura, faz corresponder o maior valor ao vetor de procura menor ou igual ao critério de procura.

A procura suporta expressões regulares. Pode introduzir "all.*", por exemplo, para localizar a primeira localização de "all" seguida de quaisquer caracteres. Se pretende procurar texto que também é uma expressão regular, necessita de anteceder cada carácter com \. Pode ativar e desativar a avaliação automática da expressão regular em Ferramentas - Opções - LibreOffice Calc - Calcular.

Sintaxe

PROC(valor_procurar; vetor_procura; vetor_resultado)

valor_procurar é o valor a ser procurado, introduzido diretamente ou como uma referência.

vetor_procura é a área de uma coluna ou uma linha onde a procura deve ser realizada.

vetor_resultado é o outro intervalo de uma linha ou uma coluna a partir do qual é obtido o resultado da função. O resultado é a célula do vetor de resultados com o mesmo índice da ocorrência encontrada no vetor de procura.

Processamento de células vazias

Exemplo

=PROC(A1;D1:D100;F1:F100) procura a célula correspondente no intervalo D1:D100 do número introduzido em A1. É determinado o índice da ocorrência encontrada, por exemplo, a 12.ª célula deste intervalo. Assim, o conteúdo da 12.ª célula é devolvido como valor da função (no vetor de resultados).

DESLOCAMENTO

Devolve o valor de uma célula deslocada num determinado número de linhas e colunas de um determinado ponto de referência.

Sintaxe

DESLOCAMENTO(referência; linhas; colunas; altura; largura)

referência é a referência a partir da qual a função procura a nova referência.

linhas é o número de linhas com base no qual a referência foi corrigida para cima (valor negativo) ou para baixo.

colunas (opcional) é o número de colunas com base no qual a referência foi corrigida para a esquerda (valor negativo) ou para a direita.

altura (opcional) é a altura vertical de uma área que começa na posição da nova referência.

largura (opcional) é a largura horizontal de uma área que começa na posição da nova referência.

Os argumentos linhas e colunas não devem indicar uma linha ou coluna inicial nula ou negativa.

Os argumentos altura e largura não podem indicar uma contagem de linhas ou colunas negativa ou igual a zero.

Nas funções do LibreOffice Calc, pode excluir parâmetros marcados como "opcionais" apenas quando não são seguidos por mais parâmetros. Por exemplo, numa função com 4 parâmetros, em que os dois últimos parâmetros são marcados como "opcionais", pode excluir o parâmetro 4 ou os parâmetros 3 e 4, mas não apenas o parâmetro 3.

Exemplo

=DESLOCAMENTO(A1;2;2) devolve o valor na célula C3 (A1 deslocada duas linhas e duas colunas para baixo). Se C3 incluir o valor 100, esta função devolve o valor 100.

=DESLOCAMENTO(B2:C3;1;1) devolve uma referência a B2:C3 movido 1 linha para baixo e uma coluna para a direita (C3:D4).

=DESLOCAMENTO(B2:C3;-1;-1) devolve uma referência a B2:C3 movida 1 linha para cima e uma coluna para a esquerda (A1:B2).

=DESLOCAMENTO(B2:C3;0;0;3;4) devolve uma referência a B2:C3 redimensionada a 3 linhas e 4 colunas (B2:E4).

=DESLOCAMENTO(B2:C3;1;0;3;4) devolve uma referência a B2:C3 movido uma linha para baixo e redimensionada a 3 linhas e 4 colunas (B2:E4).

=SOMA(DESLOCAMENTO(A1;2;2;5;6)) determina o total da área que começa na célula C3 e tem uma altura de 5 linhas e uma largura de 6 colunas (área=C3:H7).

CORRESP

Devolve a posição relativa de um objeto numa matriz e que corresponda ao valor especificado. A função devolve a posição do valor encontrado na matriz_procura na forma numérica.

Sintaxe

CORRESP(valor_procurar; matriz_procura; tipo)

valor_procurar corresponde ao valor a procurar para encontrar o objeto na matriz ou célula.

matriz_procura corresponde ao intervalo de células que contém os valores de procura. A matriz de procura pode ser uma linha ou coluna única ou parte de uma linha ou coluna única.

tipo pode receber os valores 1, 0 ou -1. Se = 1 ou omisso, assume-se que a matriz_procura está por ordem ascendente. Se = -1, assume-se que a matriz_procura está por ordem descendente. Se = 0, devolve a posição da primeira ocorrência exata, independentemente da ordenação. Isto corresponde à mesma função no Microsoft Excel.

Se tipo = 0, só são procuradas as correspondências exatas. Se o valor a procurar for encontrado mais do que uma vez, a função devolve o índice do primeiro valor correspondente. Só é possível procurar expressões regulares se tipo = 0.

Se tipo = 1 ou se o terceiro parâmetro estiver em falta, é devolvido o índice do último valor inferior ou igual ao valor a procurar. Isto é válido mesmo se a matriz de procura não estiver ordenada. Se tipo = -1, é devolvido o primeiro valor maior ou igual.

A procura suporta expressões regulares. Pode introduzir "all.*", por exemplo, para localizar a primeira localização de "all" seguida de quaisquer caracteres. Se pretende procurar texto que também é uma expressão regular, necessita de anteceder cada carácter com \. Pode ativar e desativar a avaliação automática da expressão regular em Ferramentas - Opções - LibreOffice Calc - Calcular.

Exemplo

=CORRESP(200;D1:D100) procura o valor 200 na área D1:D100, ordenada pela coluna D. Logo que este valor for encontrado, a função devolve o número da linha onde este se encontra. Se for encontrado um valor maior durante a procura na coluna, é devolvido o número da linha anterior.

FOLS

Devolve o número de folhas da referência especificada. Se não introduzir quaisquer parâmetros, devolve o número de folhas do documento ativo.

Sintaxe

FOLS(referência)

referência corresponde à referência a uma célula ou intervalo de dados. Este parâmetro é opcional.

Exemplo

=FOLS(Folha1.A1:Folha3.G12) devolve 3 se Folha1, Folha2 e Folha3 existirem na sequência indicada.

FOLHA

Devolve o número da folha de uma referência ou de uma linha. Se não introduzir quaisquer parâmetros, o resultado corresponderá ao número de folha da folha de cálculo que contém a fórmula.

Sintaxe

FOL(referência)

referência é opcional e corresponde a uma referência a uma célula, intervalo ou cadeia de texto com um nome de folha.

Exemplo

=FOL(Folha2.A1) devolve 2, se Folha2 corresponder à segunda folha no documento de folha de cálculo.

ENDEREÇO

Devolve o endereço (referência) de uma célula na forma de texto, de acordo com os números de linha e coluna especificados. É possível determinar se o endereço deve ser interpretado como um endereço absoluto (por exemplo, $A$1), como um endereço relativo (por exemplo, A1) ou um endereço de forma mista (A$1 ou $A1). Também é possível especificar o nome da folha.

Para interoperabilidade, as funções ENDEREÇO e INDIRETO suportam um parâmetro opcional para especificar se deve ser utilizada a notação de endereço L1C1 em vez da notação A1.

Na função ENDEREÇO, o parâmetro é inserido como o quarto parâmetro, movendo o parâmetro de nome da folha opcional para a quinta posição.

Na função INDIRETO, o parâmetro é acrescentado como o segundo parâmetro.

Em ambas as funções, se o argumento for inserido com o valor 0, é utilizada a notação L1C1. Se o argumento não for fornecido ou tiver um valor diferente de 0, é utilizada a notação A1.

No caso da notação L1C1, a função ENDEREÇO devolve cadeias de endereço utilizando o ponto de exclamação '!' como o separador do nome da folha e a função INDIRETO espera o ponto de exclamação como separador do nome da folha. Ambas as funções ainda utilizam o ponto '.' como o separador do nome da folha na notação A1.

Ao abrir documentos no formato ODF 1.0/1.1, as funções ENDEREÇO que apresentem um nome de folha como quarto parâmetro, irão mover o nome de folha para o quinto parâmetro. Será introduzido um novo quarto parâmetro com o valor 1.

Ao guardar um documento no formato ODF 1.0/1.1, se as funções ENDEREÇO tiverem um quarto parâmetro, esse parâmetro será removido.

Note.png Não guarde uma folha de cálculo no formato ODF 1.0/1.1, se o quarto parâmetro da função ENDEREÇO tenha sido utilizado com um valor de 0.
Note.png A função INDIRETO é guardada sem a conversão para o formato ODF 1.0/1.1. Se estivesse presente o segundo parâmetro, uma versão anterior do Calc iria devolver um erro para essa função.

Sintaxe

ENDEREÇO(linha; coluna; abs; A1; texto_folha)

linha representa o número de linha a utilizar na referência

coluna representa o número da coluna a utilizar na referência (o número, não a letra)

abs determina o tipo de referência:

1: absoluta ($A$1)

2: o tipo de referência da linha é absoluta; a referência da coluna é relativa (A$1)

3: linha (relativa); coluna (absoluta) ($A1)

4: relativa (A1)

A1 (opcional) - se definido como 0 ou Falso, é utilizada a notação L1C1. Se este parâmetro for omisso ou estiver definido um valor diferente de 0, é utilizada a notação A1.

folha representa o nome da folha. Tem de ser colocado entre aspas.

Exemplo:

=ENDEREÇO(1;1;2;folha) devolve o seguinte: Folha2.A$1

Se a célula A1 na folha 2 incluir o valor -6, pode fazer uma referência indireta à célula referenciada utilizando uma função em B2, introduzindo =ABS(INDIRETO(B2)). O resultado é o valor absoluto da referência de célula especificada em B2 que, neste caso, corresponde a 6.


Related Topics

Funções do Calc por categoria no wiki do LibreOffice