Funcions del full de càlcul

From LibreOffice Help
Jump to: navigation, search

Aquesta secció conté descripcions de les funcions del full de càlcul i en mostra exemples.

Insereix - Funció - Categoria Full de càlcul

EXTREUDADESPIVOT

La funció EXTREUDADESPIVOT retorna un valor de resultat d'una taula dinàmica. Aquest valor s'adreça mitjançant noms de camp i d'element, de manera que continuarà essent vàlid encara que canviï el disseny de la taula dinàmica.

Sintaxi

Es poden utilitzar dues definicions de sintaxi diferents:

EXTREUDADESPIVOT(CampDeDestinació; TaulaDinàmica; [ Camp 1; Element 1; ... ])

EXTREUDADESPIVOT(TaulaDinàmica; Restriccions)

S'assumeix la segona sintaxi si s'indiquen exactament dos paràmetres, el primer dels quals és una referència de cel·la o d'interval de cel·les. En la resta de casos, s'assumeix la primera sintaxi. L'Auxiliar de funcions mostra la primera sintaxi.

Primera sintaxi

CampDeDestinació és una cadena que selecciona un dels camps de dades de la taula dinàmica. La cadena pot ser el nom de la columna d'origen o del camp de dades tal com es mostra a la taula (com ara "Suma - Vendes").

TaulaDinàmica és una referència a una cel·la o a un interval de cel·les que es troba dins una taula dinàmica o que conté una taula dinàmica. Si l'interval de cel·les conté diverses taules dinàmiques, s'utilitza l'última taula creada.

Si no s'indica cap parell Camp n / Element n, es retorna la suma total. En cas contrari, cada parell afegeix una restricció que el resultat ha de complir. Camp n és el nom d'un camp de la taula dinàmica. Element n és el nom d'un element d'aquest camp.

Si la taula dinàmica només conté un valor de resultat que compleixi totes les restriccions, o un resultat de subtotal que agrupi tots els valors coincidents, es retorna aquest resultat. Si no hi ha cap resultat que coincideixi, o n'hi ha diversos sense cap subtotal, es retorna un error. Aquestes condicions s'apliquen als resultats que inclou la taula dinàmica.

Si les dades font contenen entrades que estan amagades a causa de la configuració de la taula dinàmica, s'ignoren. L'ordre de les parelles Camp/Element no és important. En els noms de camp i d'element no es distingeix entre majúscules i minúscules.

Si no s'indica cap restricció per a un camp de pàgina, s'utilitza implícitament el valor seleccionat del camp. Si s'indica una restricció per a un camp de pàgina, ha de coincidir amb el valor seleccionat del camp; si no hi coincideix, es retorna un error. Els camps de pàgina són els camps de la part superior esquerra de la taula dinàmica, que s'emplenen en l'àrea "Camps de pàgina" del diàleg de disseny de la taula dinàmica. De cada camp de pàgina es pot seleccionar un element (valor), la qual cosa vol dir que només s'inclou aquest element en el càlcul.

Els valors de subtotal de la taula dinàmica només s'utilitzen si fan servir la funció "auto" (llevat de si s'indica en la restricció; en aquest cas, vegeu Segona sintaxi tot seguit).

Segona sintaxi

TaulaDinàmica té el mateix significat que en la primera sintaxi.

Restriccions és una llista separada per espais. Les entrades poden contenir cometes (cometes simples). Tota la cadena ha d'estar entre cometes (cometes dobles), si no és que referencieu la cadena des d'una altra cel·la.

Una de les entrades pot ser el nom del camp de dades. El nom del camp de dades es pot ometre si la taula dinàmica només conté un camp de dades; altrament, ha d'estar present.

Cadascuna de les altres entrades indica una restricció en la forma Camp[Element] (amb els caràcters literals [ i ]), o només Element si el nom de l'element és únic en tots els camps que s'utilitzen en la taula dinàmica.

Si s'afegeix un nom de funció en la forma Camp[Element;Funció], la restricció només coincidirà amb els valors de subtotal que utilitzin la funció. Els noms de funció possibles són Suma, Comptatge, Mitjana, Max, Min, Producte, Comptatge (només nombres), DesVest (mostra), DesvEstP (població), Var (mostra) i VarP (població), sense distingir entre majúscules i minúscules.

CONSULTAV

Cerca vertical amb referència a les cel·les adjacents de la dreta. Aquesta funció comprova si la primera columna d'una matriu conté un valor determinat. Tot seguit, la funció retorna el valor de la mateixa fila de la columna anomenada per l'Índex. Si s'omet el paràmetre CriterisDOrdenació o s'estableix a CERT o a un, s'assumeix que les dades estan ordenades de manera ascendent. En aquest cas, si no es troba el CriteriDeCerca exacte, es retornarà l'últim valor més petit que el criteri de cerca. Si s'estableix CriterisDOrdenació a FALS o a zero, s'ha de trobar una coincidència exacta; en cas contrari, el resultat serà l'error Error: valor no disponible. Per tant, amb un valor de zero no cal ordenar les dades de manera ascendent.

La cerca permet l'ús d'expressions regulars. Per exemple, podeu introduir "tot.*" per trobar la primera aparició de la cadena "tot" seguida per qualssevol caràcters. Si voleu cercar un text que també és una expressió regular, cal que precediu cada caràcter amb el caràcter \. Podeu habilitar o inhabilitar l'avaluació automàtica de les expressions regulars des del menú Eines - Opcions - LibreOffice Calc - Càlcul.

Sintaxi

=CONSULTAV(CriteriDeCerca; Matriu; Índex; Ordre)

CriteriDeCerca és el valor que se cerca en la primera columna de la matriu.

Matriu és la referència, que ha d'incloure com a mínim dues columnes.

Índex és el número de la columna de la matriu que conté el valor que s'ha de retornar. La primera columna té el número 1.

CriterisDOrdenació és un paràmetre opcional que indica si la primera columna de la matriu s'ordena de manera ascendent. Introduïu el valor booleà FALS o zero si la primera columna no s'ordena de manera ascendent. Les columnes ordenades es poden cercar molt més ràpidament; a més, la funció sempre retorna un valor si es troba entre el valor més gran i el més petit de la llista ordenada, fins i tot quan no coincideix exactament amb el valor de cerca. En les llistes que no estan ordenades, el valor ha de coincidir exactament amb el valor de cerca. En cas contrari, la funció retornarà el missatge següent: Error: el valor no es troba disponible.

Gestió de cel·les buides

Exemple

Suposeu que voleu introduir el número d'un plat del menú a la cel·la A1, i el nom del plat ha d'aparèixer en forma de text a la cel·la del costat (B1) immediatament. L'assignació Nombre a Nom es troba en la matriu D1:E100. D1 conté 100, E1 conté el nom Crema de verdures i així successivament per a 100 elements del menú. Els nombres de la columna D s'ordenen de manera ascendent; per tant, el paràmetre opcional CriterisDOrdenació no és necessari.

Introduïu la fórmula següent a B1:

=CONSULTAV(A1;D1:E100;2)

Tan bon punt introduïu un nombre a A1, B1 mostrarà el text corresponent que apareix a la segona columna de la referència D1:E100. Si introduïu un nombre que no existeix, apareixerà el text del nombre inferior següent. Per evitar que això passi, introduïu FALS com a últim paràmetre de la fórmula perquè es generi un missatge d'error quan s'introdueixi un nombre no existent.

COLUMNES

Retorna el nombre de columnes de la referència determinada.

Sintaxi

COLUMNES(Matriu)

Matriu és la referència d'un interval de cel·les el nombre total de columnes del qual cal trobar. L'argument pot ser una única cel·la.

Exemple

=COLUMNES(B5) retorna 1 perquè una cel·la només conté una columna.

=COLUMNES(A1:C5) és igual a 3. La referència comprèn tres columnes.

=COLUMNES(Conill) retorna 2 si Conill és l'interval anomenat (C1:D3).

COLUMNA

Retorna el número de columna d'una referència de cel·la. Si la referència és una cel·la, es retorna el número de columna de la cel·la; si el paràmetre és una àrea de cel·la, es retornen els números de columna corresponents en una matriu d'una sola fila si la fórmula s'introdueix com a fórmula matricial. Si no s'utilitza la funció COLUMNA amb una referència d'àrea per a una fórmula matricial, només es determina el número de columna de la primera cel·la de l'àrea.

Sintaxi

COLUMNA(Referència)

Referència és la referència a una cel·la o a una àrea de cel·les de la qual s'ha de cercar el número de la primera columna.

Si no indiqueu cap referència, se cercarà el número de columna de la cel·la on s'introdueixi la fórmula. El LibreOffice Calc defineix automàticament la referència de la cel·la actual.

Exemple

=COLUMNA(A1) és igual a 1. La columna A és la primera columna de la taula.

=COLUMNA(C3:E3) és igual a 3. La columna C és la tercera columna de la taula.

=COLUMNA(D3:G10) retorna 4 perquè la columna D és la quarta columna de la taula i la funció COLUMNA no s'utilitza com a fórmula matricial. (En aquest cas, el primer valor de la matriu sempre s'utilitza com a resultat.)

{=COLUMNA(B2:B7)} i =COLUMNA(B2:B7) retornen 2 perquè la referència només conté la columna B com la segona columna de la taula. Atès que les àrees d'una sola columna només tenen un número de columna, és indiferent si la fórmula s'utilitza com a fórmula matricial o no.

=COLUMNA() retorna 3 si s'ha introduït la fórmula a la columna C.

{=COLUMNA(Conill)} retorna la matriu d'una sola fila (3, 4) si "Conill" és l'àrea anomenada (C1:D3).

INDIRECTE

Retorna la referència especificada per una cadena de text. Aquesta funció també pot utilitzar-se per retornar l'àrea d'una cadena corresponent.

Per motius d'interoperabilitat, les funcions ADREÇA i INDIRECTE admeten un paràmetre opcional per indicar si s'ha d'utilitzar la notació d'adreça R1C1 en lloc de la notació A1 habitual.

A ADREÇA, el paràmetre s'insereix com a quart paràmetre, de manera que el paràmetre de nom de full opcional es desplaça a la cinquena posició.

A INDIRECTE, el paràmetre s'afegeix com a segon paràmetre.

En totes dues funcions, si l'argument s'insereix amb el valor 0 s'utilitza la notació R1C1. Si no es dóna l'argument o si aquest té un valor que no sigui 0, s'utilitza la notació A1.

En el cas de la notació R1C1, ADREÇA retorna cadenes d'adreça amb el signe d'exclamació '!' com a separador per als noms del full, i INDIRECTE espera el signe d'exclamació com a separador per als noms del full. Totes dues funcions utilitzen el punt '.' com a separador per als noms del full amb la notació A1.

Si obriu documents amb format ODF 1.0/1.1, les funcions ADREÇA que mostren un nom de full com a quart paràmetre desplaçaran aquest nom de full per tal que esdevingui el cinquè paràmetre, i inseriran un nou quart paràmetre amb el valor 1.

Si deseu un document en format ODF 1.0/1.1, en cas que les funcions ADREÇA tinguin un quart paràmetre, el suprimiran.

Note.png No deseu el full de càlcul en l'antic format ODF 1.0/1.1 si el nou quart paràmetre de la funció ADREÇA s'ha utilitzat amb valor 0.
Note.png La funció INDIRECTE es desa sense fer la conversió al format ODF 1.0/1.1. Si hi ha un segon paràmetre, les versions antigues del Calc retornaran un error per a aquesta funció.

Sintaxi

INDIRECTE(Ref; A1)

Ref representa una referència a una cel·la o a una àrea (en un formulari de text) per a la qual es retornen els continguts.

A1 (opcional): si s'estableix a 0, s'utilitzarà la notació R1C1. Si el paràmetre no existeix o si s'ha establert a un valor que no sigui 0, s'utilitzarà la notació A1.

Note.png Si obriu un full de càlcul de l'Excel que utilitza adreces indirectes que s'han calculat a partir de funcions de cadena, les adreces del full no es traduiran automàticament. Per exemple, l'adreça de l'Excel a INDIRECTE("nomdelfitxer!nomdelfull"&B1) no es converteix en l'adreça del Calc a INDIRECTE("nomdelfitxer.nomdelfull"&B1).

Exemple

=INDIRECTE(A1) és igual a 100 si A1 conté C108 com a referència i la cel·la C108 conté un valor de 100.

=SUMA(INDIRECTE("a1:" & ADREÇA(1;3))) totalitza les cel·les de l'àrea A1 fins a la cel·la de la qual s'ha definit l'adreça amb la fila 1 i la columna 3. Això vol dir que es calcula el total de l'àrea A1:C1.

INDEX

INDEX retorna un subinterval, especificat pel nombre de fila i de columna, o un índex d'intervals opcional. Segons el context, INDEX retorna una referència o contingut.

Sintaxi

INDEX(Referència; Fila; Columna; Interval)

Referència és una referència, introduïda directament o mitjançant l'especificació d'un nom d'interval. Si la referència consta de diversos intervals, heu d'introduir la referència o el nom de l'interval entre parèntesis.

Fila (opcional) representa l'índex de la fila de l'interval de referència del qual s'ha de retornar un valor. Si és zero (no s'ha indicat cap fila), es retornen totes les files referenciades.

Columna (opcional) representa l'índex de columna de l'interval de referència per al qual s'ha de retornar un valor. En el cas de zero (cap columna específica), es retornen totes les columnes a les quals es fa referència.

Interval (opcional) representa l'índex del subinterval quan fa referència a un interval múltiple.

Exemple

=INDEX(Preus;4;1) retorna el valor de la fila 4 i de la columna 1 de l'interval de base de dades que heu definit a Dades - Defineix com a Preus.

=INDEX(SumaX;4;1) retorna el valor de l'interval SumaX de la fila 4 i la columna 1 tal com s'ha definit a Insereix - Noms - Defineix.

=INDEX(A1:B6;1) retorna una referència a la primera fila de l'interval A1:B6.

=INDEX(A1:B6;0;1) retorna una referència a la primera columna de l'interval A1:B6.

=ÍNDEX((multi);4;1) indica el valor contingut a la fila 4 i a la columna 1 de l'interval (múltiple), que heu anomenat amb Insereix - Noms - Defineix com múltiple. L'interval múltiple pot consistir en diversos intervals rectangulars, cada un amb una fila 4 i columna 1. Si voleu cridar el segon bloc d'aquest interval múltiple introduïu el número 2 com el paràmetre interval.

=INDEX(A1:B6;1;1) indica el valor de la part superior esquerra de l'interval A1:B6.

=INDEX((multi);0;0;2) retorna una referència al segon interval de l'interval múltiple.

TIPUSERROR

Retorna el nombre corresponent a un valor d'error que aparegui en una cel·la diferent. Amb l'ajuda d'aquest nombre, podeu generar un missatge d'error en forma de text.

Si es produeix un error, la funció retorna un valor lògic o numèric.

Note.png La barra d'estat mostra el codi d'error predefinit del LibreOffice si feu clic a la cel·la que conté l'error.

Sintaxi

TIPUSERROR(Referència)

Referència conté l'adreça de la cel·la on es produeix l'error.

Exemple

Si la cel·la A1 mostra Err:518, la funció =TIPUSERROR(A1) retorna el nombre 518.

DDE

Retorna el resultat d'un enllaç basat en DDE. Si els continguts de la secció o de l'interval enllaçat canvien, el valor retornat també canviarà. Per veure els enllaços actualitzats, actualitzeu el full de càlcul o trieu Edita - Enllaços. No es permeten els enllaços multiplataforma (per exemple, des d'una instal·lació del LibreOffice que s'executi en un ordinador amb el Windows a un document creat en un ordinador amb el Linux).

Sintaxi

DDE("Servidor"; "Fitxer"; "Interval"; Mode)

Servidor és el nom d'una aplicació de servidor. En el cas de les aplicacions del LibreOffice, el nom de servidor és «soffice».

Fitxer és el nom de fitxer complet, inclosa l'especificació del camí.

Interval és l'àrea que conté les dades que s'han d'avaluar.

Mode és un paràmetre opcional que controla el mètode pel qual el servidor DDE converteix les dades en nombres.

Mode Efecte
0 o hi manca Format numèric de l'estil de cel·la "Per defecte"
1 Les dades sempre s'interpreten en el format estàndard de l'anglès americà.
2 Les dades es recuperen com a text; no hi ha conversió a nombres

Exemple

=DDE("soffice";"c:\office\document\dades1.sxc";"full1.A1") llegeix el contingut de la cel·la A1 en el Full1 del full de càlcul dades1.sxc del LibreOffice Calc.

=DDE("soffice";"c:\office\document\lema.sxw";"Lema del dia") retorna un lema en la cel·la que conté aquesta fórmula. En primer lloc, heu d'introduir una línia en el document lema.sxw que conté el text del lema i definir-lo com la primera línia d'una secció anomenada Lema del dia (al LibreOffice Writer, a Insereix - Secció). Si es modifica (i es desa) el lema en el document del LibreOffice Writer, s'actualitza el lema en totes les cel·les del LibreOffice Calc en què s'hagi definit aquest enllaç DDE.

ENLLAÇ

Quan feu clic en una cel·la que conté la funció ENLLAÇ, s'obre l'enllaç.

Si utilitzeu el paràmetre opcional TextDeCel·la, la fórmula cerca l'URL i tot seguit mostra el text o el número.

Tip.png Per obrir una cel·la enllaçada amb el teclat, seleccioneu la cel·la i premeu F2 per entrar al mode d'edició; tot seguit, moveu el cursor al davant de l'enllaç, premeu Maj+F10 i trieu Obre l'enllaç.

Sintaxi

ENLLAÇ("URL") o ENLLAÇ("URL"; "TextDeCel·la")

URL indica l'enllaç de destinació. El paràmetre TextDeCel·la opcional és el text o un número que es mostra a la cel·la i es retornarà com a resultat. Si no s'indica el TextDeCel·la, es mostra l'URL en el text de cel·la i es retornarà com a resultat.

En les cel·les i elements de matriu buits, es retornarà el número 0.

Exemple

=ENLLAÇ("http://www.exemple.org") mostra el text "http://www.exemple.org" a la cel·la i, quan s'hi fa clic, executa l'enllaç http://www.exemple.org.

=ENLLAÇ("http://www.exemple.org";"Feu clic aquí") mostra el text "Feu clic aquí" a la cel·la i, quan s'hi fa clic, executa l'enllaç http://www.exemple.org.

=ENLLAÇ("http://www.exemple.org";12345) mostra el número 12345 i, quan s'hi fa clic, executa l'enllaç http://www.exemple.org.

=ENLLAÇ($B4), on la cel·la B4 conté http://www.exemple.org. La funció afegeix http://www.exemple.org a l'URL de la cel·la que conté l'enllaç i retorna el mateix text que s'utilitza com a resultat de la fórmula.

=ENLLAÇ("http://www.";"Feu clic a") & "exemple.org" mostra el text Feu clic a exemple.org a la cel·la i executa l'enllaç http://www.exemple.org en fer-hi clic.

=ENLLAÇ("#Full1.A1";"Vés amunt") mostra el text Vés amunt i va a la cel·la Full1.A1 d'aquest document.

=ENLLAÇ("file:///C:/writer.odt#Especificació";"Vés al marcador del Writer") mostra el text Vés al marcador del Writer, carrega el document de text indicat i va al marcador "Especificació".

AREES

Retorna el nombre d'intervals individuals que pertanyen a un interval múltiple. Un interval pot estar format per cel·les contigües o per una sola cel·la.

La funció espera un sol argument. Si definiu diversos intervals, els heu de posar entre parèntesis addicionals. Es poden introduir diversos intervals utilitzant el punt i coma (;) com a divisor, però es converteix automàticament en l'operador de titlla (~). La titlla s'utilitza per unir intervals.

Sintaxi

AREES(Referència)

Referència representa la referència a la cel·la o a un interval de cel·les.

Exemple

=AREES((A1:B3;F2;G1)) retorna 3, ja que és una referència a tres cel·les i/o àrees. Després de l'entrada, es converteix en =AREES((A1:B3~F2~G1)).

=AREES(Totes) retorna 1 si heu definit una àrea anomenada Totes a Dades - Defineix l'interval.

FILES

Retorna el nombre de files d'una referència o matriu.

Sintaxi

FILES(Matriu)

Matriu és la referència o l'àrea anomenada de la qual s'ha de determinar el nombre total de files.

Exemple

=FILES(B5) retorna 1 perquè una cel·la només conté una fila.

=FILES(A10:B12) retorna 3.

=FILES(Conill) retorna 3 si "Conill" és l'àrea anomenada (C1:D3).

FILA

Retorna el número de fila d'una referència de cel·la. Si la referència és una cel·la, retorna el número de fila de la cel·la. Si és un interval de cel·les, retorna els números de fila corresponents en una matriu d'una columna si s'introdueix la fórmula com a fórmula matricial. Si la funció FILA amb una referència d'interval no s'utilitza en una fórmula matricial, només es retornarà el número de fila de la primera cel·la de l'interval.

Sintaxi

FILA(Referència)

Referència és una cel·la, una àrea o el nom d'una àrea.

Si no indiqueu una referència, es trobarà el número de fila de cel·la on s'introdueix la fórmula. El LibreOffice Calc defineix automàticament la referència de la cel·la actual.

Exemple

=FILA(B3) retorna 3 perquè la referència es refereix a la tercera fila de la taula.

{=FILA(D5:D8)} retorna la matriu d'una sola columna (5, 6, 7, 8) perquè la referència indicada conté de la fila 5 a la 8.

=FILA(D5:D8) retorna 5 perquè la funció FILA no s'utilitza com una fórmula matricial i només es retorna el nombre de la primera fila de la referència.

{=FILA(A1:E1)} i =FILA(A1:E1) retornen 1 perquè la referència només conté la fila 1 com la primera columna de la taula. (Com que les àrees d'una sola fila només tenen un número de fila, no hi ha cap diferència si la fórmula s'utilitza en una fórmula matricial o no.)

=FILA() retorna 3 si s'ha introduït la fórmula a la fila 3.

{=FILA(Conill)} retorna la matriu d'una sola columna (1, 2, 3) si "Conill" és l'àrea anomenada (C1:D3).

CONSULTAH

Cerca un valor i una referència en les cel·les situades sota l'àrea seleccionada. Aquesta funció verifica si la primera fila d'una matriu conté un valor determinat. Tot seguit, la funció retorna el valor en una fila de la matriu, anomenada en l'Índex, en la mateixa columna.

La cerca permet l'ús d'expressions regulars. Per exemple, podeu introduir "tot.*" per trobar la primera aparició de la cadena "tot" seguida per qualssevol caràcters. Si voleu cercar un text que també és una expressió regular, cal que precediu cada caràcter amb el caràcter \. Podeu habilitar o inhabilitar l'avaluació automàtica de les expressions regulars des del menú Eines - Opcions - LibreOffice Calc - Càlcul.

Sintaxi

CONSULTAH(CriterisDeCerca; Matriu; Índex; Ordenats)

Vegeu també:CONSULTAV (s'intercanvien les columnes i les files).

Gestió de cel·les buides

TRIA

Utilitza un índex per retornar un valor d'una llista de fins a 30 valors.

Sintaxi

TRIA(Índex; Valor1; ...; Valor30)

Índex és una referència o un nombre entre 1 i 30 que indica quin valor s'ha d'extreure de la llista.

Valor1...Valor30 és la llista de valors introduïts com a referència a una cel·la o com a valors individuals.

Exemple

=TRIA(A1;B1;B2;B3;"Avui";"Ahir";"Demà"), per exemple, retorna el contingut de la cel·la B2 per a A1 = 2; per a A1 = 4, la funció retorna el text "Avui".

ESTIL

Aplica un estil a la cel·la que conté la fórmula. Després d'un període de temps establert, es pot aplicar un altre estil. Aquesta funció sempre retorna el valor 0 i, així, permet afegir-la a una altra funció sense canviar-ne el valor. Juntament amb la funció ACTUAL, podeu aplicar un color a una cel·la independentment del valor que contingui. Per exemple: =...+ESTIL(SI(ACTUAL()>3;"vermell";"verd")) aplica l'estil "vermell" a la cel·la si el valor és més gran que 3; en cas contrari, s'hi aplica l'estil "verd". Ambdós formats s'han d'haver definit abans d'aplicar la funció.

Sintaxi

ESTIL("Estil"; Temps; "Estil2")

Estil és el nom d'un estil de cel·la assignat a la cel·la. Els noms d'estil s'han d'escriure entre cometes.

Temps és un interval de temps opcional, indicat en segons. Si s'omet aquest paràmetre, no es modificarà l'estil fins que no hagi passat una quantitat de temps determinada.

Estil2 és el nom opcional d'un estil de cel·la que s'assigna a la cel·la després d'un període de temps determinat. Si no s'introdueix aquest paràmetre, s'utilitza el valor "Per defecte".

En les funcions del LibreOffice Calc, els paràmetres marcats com a "opcionals" es poden ometre quan no hi ha cap altre paràmetre que els segueixi. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a "opcionals", es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

Exemple

=ESTIL("Invisible";60;"PerDefecte") aplica un format transparent a la cel·la durant 60 segons després que s'hagi tornat a calcular el document o s'hagi carregat; tot seguit, s'hi assigna la formatació Per defecte. Ambdós formats s'han d'haver definit abans d'aplicar la funció.

Com que ESTIL() té un valor numèric de retorn zero, aquest valor de retorn s'afegeix a una cadena. Per evitar-ho, utilitzeu T() com en l'exemple següent:

="Text"&T(ESTIL("ElMeuEstil"))

Consulteu també ACTUAL() per veure'n un altre exemple.

CONSULTA

Retorna els continguts d'una cel·la, ja sigui d'un interval d'una fila o d'una columna. Opcionalment, es retorna el valor assignat (del mateix índex) en una columna i una fila diferent. Contràriament a CONSULTAV i a CONSULTAH, el vector de cerca i el resultant es poden trobar en posicions diferents; no cal que siguin adjacents. A més, el vector de cerca de la funció CONSULTA ha d'estar ordenat de manera ascendent; si no ho està, la cerca no retornarà cap resultat utilitzable.

Note.png Si CONSULTA no pot trobar el criteri de cerca, coincideix amb el valor més gran del vector de cerca que sigui més petit o igual que el criteri de cerca.

La cerca permet l'ús d'expressions regulars. Per exemple, podeu introduir "tot.*" per trobar la primera aparició de la cadena "tot" seguida per qualssevol caràcters. Si voleu cercar un text que també és una expressió regular, cal que precediu cada caràcter amb el caràcter \. Podeu habilitar o inhabilitar l'avaluació automàtica de les expressions regulars des del menú Eines - Opcions - LibreOffice Calc - Càlcul.

Sintaxi

CONSULTA(CriteriDeCerca; VectorDeCerca; VectorResultant)

CriteriDeCerca és el valor que s'ha de cercar; es pot introduir directament o com una referència.

VectorDeCerca és l'àrea d'una fila o d'una columna que s'ha de cercar.

VectorResultant és un altre interval d'una sola fila o d'una sola columna d'on s'extreu el resultat de la funció. El resultat és la cel·la del vector resultant amb el mateix índex que la instància trobada en el vector de cerca.

Gestió de cel·les buides

Exemple

=CONSULTA(A1;D1:D100;F1:F100) cerca la cel·la corresponent de l'interval D1:D100 per al nombre que heu introduït a A1. Es determina l'índex de la instància que s'ha trobat; per exemple, la 12a cel·la de l'interval. Tot seguit, es retornen els continguts de la 12a cel·la com el valor de la funció (en el vector resultant).

DESPLAÇAMENT

Retorna el valor d'un desplaçament de cel·la d'un nombre determinat de files i columnes a partir d'un punt de referència indicat.

Sintaxi

DESPLAÇAMENT(Referència; Files; Columnes; Alçada; Amplada)

Referència és la referència a partir de la qual la funció cerca la referència nova.

Files és el nombre de files amb què s'ha corregit la referència cap amunt (valor negatiu) o cap avall.

Columnes (opcional) és el nombre de columnes per a les quals s'ha corregit la referència cap a l'esquerra (valor negatiu) o cap a la dreta.

Alçada (opcional) és l'alçada vertical d'una àrea que comença en la posició de referència nova.

Amplada (opcional) és l'amplada horitzontal d'una àrea que comença en la nova posició de referència.

Els arguments Files i Columnes no han de conduir a zero o a un inici negatiu de fila o de columna.

Els arguments Alçada i Amplada no han de conduir a zero o a un comptatge negatiu de files o de columnes.

En les funcions del LibreOffice Calc, els paràmetres marcats com a "opcionals" es poden ometre quan no hi ha cap altre paràmetre que els segueixi. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a "opcionals", es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

Exemple

=DESPLAÇAMENT(A1;2;2) retorna el valor de la cel·la C3 (A1 desplaçada dues files i dues columnes cap avall). Si C3 conté el valor 100, la funció retorna el valor 100.

=DESPLAÇAMENT(B2:C3;1;1) retorna una referència a B2:C3 desplaçada 1 fila i 1 columna cap a la dreta (C3:D4).

=DESPLAÇAMENT(B2:C3;-1;-1) retorna una referència a B2:C3 desplaçada una fila cap amunt i una columna cap a l'esquerra (A1:B2).

=DESPLAÇAMENT(B2:C3;0;0;3;4) retorna una referència cap a l'interval B2:C3 redimensionada a 3 files i 4 columnes (B2:E4).

=DESPLAÇAMENT(B2:C3;1;0;3;4) retorna una referència a B2:C3 desplaçada una fila redimensionada en 3 files i 4 columnes (B2:E4).

=SUMA(DESPLAÇAMENT(A1;2;2;5;6)) determina el total de l'àrea que comença a la cel·la C3, i que té una alçada de 5 files i una amplada de 6 columnes (àrea=C3:H7).

COINCIDEIX

Retorna la posició relativa d'un element contingut en una matriu que coincideixi amb un valor determinat. La funció retorna la posició del valor que s'ha trobat en la matriu_de_cerca en forma de nombre.

Sintaxi

COINCIDEIX(CriteriDeCerca; MatriuDeCerca; Tipus)

CriteriDeCerca és el valor que s'ha de cercar en la matriu d'una sola fila o d'una sola columna.

MatriuDeCerca és la referència que se cerca. Una matriu de cerca pot constar d'una sola fila o columna, o bé pot formar part d'una sola fila o columna.

Tipus pot tenir els valors 1, 0 o -1. Si Tipus = 1 o si manca aquest paràmetre opcional, s'assumeix que la primera columna de la matriu de cerca està ordenada de manera ascendent. Si Tipus = -1 s'assumeix que la columna està ordenada de manera descendent. Això correspon a la mateixa funció del Microsoft Excel.

Si Tipus = 0, només es troben les coincidències exactes. Si es troba el criteri de cerca més d'una vegada, la funció retorna l'índex del primer valor coincident. Només podeu cercar expressions regulars si Tipus = 0.

Si Tipus = 1 o manca el tercer paràmetre, es retorna l'índex de l'últim valor que sigui més petit o igual que el criteri de cerca. Aquesta regla s'aplica quan la matriu de cerca no està ordenada. Per a Tipus = -1, es retorna el primer valor que sigui més gran o igual que el criteri.

La cerca permet l'ús d'expressions regulars. Per exemple, podeu introduir "tot.*" per trobar la primera aparició de la cadena "tot" seguida per qualssevol caràcters. Si voleu cercar un text que també és una expressió regular, cal que precediu cada caràcter amb el caràcter \. Podeu habilitar o inhabilitar l'avaluació automàtica de les expressions regulars des del menú Eines - Opcions - LibreOffice Calc - Càlcul.

Exemple

=COINCIDEIX(200;D1:D100) cerca el valor 200 en l'àrea D1:D100, que s'ha ordenat per la columna D. Tan bon punt es troba aquest valor, es retorna el nombre de la fila on s'ha trobat. Si es troba un valor més gran durant la cerca a la columna, es retorna el nombre de la fila anterior.

FULLS

Determina el nombre de fulls d'una referència. Si no introduïu cap paràmetre, retorna el nombre de fulls del document actual.

Sintaxi

FULLS(Referència)

Referència és la referència a un full o a una àrea. Aquest paràmetre és opcional.

Exemple

=FULLS(Full1.A1:Full3.G12) retorna 3 si el Full1, el Full2 i el Full3 existeixen en la seqüència indicada.

FULL

Retorna el número de full d'una referència o d'una cadena que representa un nom de full. Si no introduïu cap paràmetre, el resultat és el número de full del full de càlcul que conté la fórmula.

Sintaxi

FULL(Referència)

Referència és opcional i és la referència a una cel·la, a una àrea o a una cadena de nom de full.

Exemple

=FULL(Full2.A1) retorna 2 si Full2 és el segon full del document de full de càlcul.

ADREÇA

Retorna una adreça de cel·la (referència) en forma de text en funció dels nombres de fila i de columna especificats. Podeu determinar si l'adreça s'ha d'interpretar com a adreça absoluta (per exemple, $A$1), com a adreça relativa (per exemple, A1) o en forma mixta (A$1 o $A1). També podeu indicar el nom del full.

Per motius d'interoperabilitat, les funcions ADREÇA i INDIRECTE admeten un paràmetre opcional per indicar si s'ha d'utilitzar la notació d'adreça R1C1 en lloc de la notació A1 habitual.

A ADREÇA, el paràmetre s'insereix com a quart paràmetre, de manera que el paràmetre de nom de full opcional es desplaça a la cinquena posició.

A INDIRECTE, el paràmetre s'afegeix com a segon paràmetre.

En totes dues funcions, si l'argument s'insereix amb el valor 0 s'utilitza la notació R1C1. Si no es dóna l'argument o si aquest té un valor que no sigui 0, s'utilitza la notació A1.

En el cas de la notació R1C1, ADREÇA retorna cadenes d'adreça amb el signe d'exclamació '!' com a separador per als noms del full, i INDIRECTE espera el signe d'exclamació com a separador per als noms del full. Totes dues funcions utilitzen el punt '.' com a separador per als noms del full amb la notació A1.

Si obriu documents amb format ODF 1.0/1.1, les funcions ADREÇA que mostren un nom de full com a quart paràmetre desplaçaran aquest nom de full per tal que esdevingui el cinquè paràmetre, i inseriran un nou quart paràmetre amb el valor 1.

Si deseu un document en format ODF 1.0/1.1, en cas que les funcions ADREÇA tinguin un quart paràmetre, el suprimiran.

Note.png No deseu el full de càlcul en l'antic format ODF 1.0/1.1 si el nou quart paràmetre de la funció ADREÇA s'ha utilitzat amb valor 0.
Note.png La funció INDIRECTE es desa sense fer la conversió al format ODF 1.0/1.1. Si hi ha un segon paràmetre, les versions antigues del Calc retornaran un error per a aquesta funció.

Sintaxi

ADREÇA(Fila; Columna; ABS; A1; "Full")

Fila representa el número de fila de la referència de cel·la.

Columna representa el número de columna de la referència de cel·la (el número, no la lletra).

Abs determina el tipus de referència:

1: absoluta ($A$1)

2: el tipus de referència de la fila és absolut; la referència de la columna és relativa (A$1)

3: fila (relativa); columna (absoluta) ($A1)

4: relativa (A1)

A1 (opcional): si s'estableix a 0, s'utilitzarà la notació R1C1. Si el paràmetre no existeix o si s'ha establert a un valor que no sigui 0, s'utilitzarà la notació A1.

Full representa el nom del full. Cal col·locar-lo entre cometes dobles.

Exemple:

=ADREÇA(1;1;2;"Full2") retorna: Full2.A$1

Si la cel·la A1 del full 2 conté el valor -6, podeu fer referència indirectament a la cel·la referenciada si introduïu la funció =ABS(INDIRECTE(B2)) a B2. El resultat és el valor absolut de la referència de cel·la indicada a B2, que en aquest cas és 6.


Related Topics

Funcions del Calc per categoria a la wiki d'ajuda del LibreOffice