Behandlung von leeren Zellen

From LibreOffice Help
Jump to: navigation, search

In älteren Versionen der Software wurden leere Zellwerte je nach Kontext als Zahl 0 oder leere Zeichenkette aufgefasst. Nur der direkte Vergleich =A1=0 bzw. =A1="" ergab immer WAHR, falls A1 leer war. Ein leerer Inhalt wird jetzt weitergereicht, bis er benutzt wird. Deshalb ergibt =SVERWEIS(...)=0 und =SVERWEIS(...)="" jeweils WAHR, falls sich der Verweis auf eine leere Zelle bezieht.

Ein einfacher Bezug zu einer leeren Zelle wird immer noch als die Zahl 0 angezeigt, obwohl sie nicht notwendigerweise vom Typ numerisch ist. Daher funktionieren Vergleiche mit der Bezugszelle wie erwartet.

Für das folgende Beispiel enthält A1 eine Zahl, B1 ist leer und C1 enthält einen Bezug zu B1:

A1: 1 B1: <leer> C1: =B1 (zeigt 0 an)

=B1=0 => WAHR

=B1="" => WAHR

=C1=0 => WAHR

=C1="" => WAHR (früher FALSCH)

=ISTZAHL(B1) => FALSCH

=ISTZAHL(C1) => FALSCH (früher WAHR)

=ISTZAHL(SVERWEIS(1;A1:C1;2)) => FALSCH (B1)

=ISTZAHL(SVERWEIS(1;A1:C1;3)) => FALSCH (C1, früher WAHR)

=ISTTEXT(B1) => FALSCH

=ISTTEXT(C1) => FALSCH

=ISTTEXT(SVERWEIS(1;A1:C1;2) => FALSCH (B1, früher WAHR)

=ISTTEXT(SVERWEIS(1;A1:C1;3)) => FALSCH (C1)

=ISTLEER(B1) => WAHR

=ISTLEER(C1) => FALSCH

=ISTLEER(SVERWEIS(1;A1:C1;2) => WAHR (B1, früher FALSCH)

=ISTLEER(SVERWEIS(1;A1:C1;3)) => FALSCH (C1)

Note.png Beachten Sie, dass sich MS Excel anders verhält, und immer eine Zahl als Bezug zu einer leeren Zelle (oder einer Formel, die eine leere Zelle zurückgibt) ergibt. z.B.:

A1: <leer>

B1: =A1 => zeigt 0 an, aber ist nur ein Bezug zu einer leeren Zelle

=ISTZAHL(A1) => FALSCH

=ISTTEXT(A1) => FALSCH

=A1=0 => WAHR

=A1="" => WAHR

=ISTZAHL(B1) => FALSCH (MS-Excel: WAHR)

=ISTTEXT(B1) => FALSCH

=B1=0 => WAHR

=B1="" => WAHR (MS-Excel: FALSCH)

C1: =SVERWEIS(...) mit einem leeren Zellbezug => zeigt leer an (MS-Excel zeigt 0 an)

=ISTZAHL(SVERWEIS(...) => FALSCH

=ISTTEXT(SVERWEIS(...)) => FALSCH

=ISTZAHL(C1) => FALSCH (MS-Excel: WAHR)

=ISTTEXT(C1) => FALSCH