Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

数学函数

From LibreOffice Help
Jump to: navigation, search

此类别包含 Calc 的数学函数。要打开函数向导,请选择插入 - 函数

Contents

CONVERT

将某个值由一个测量单位换算为另一个测量单位。换算因数已在配置列表中给出。

以前的换算因数列表包含旧欧洲货币和欧元(如下例所示)。我们建议使用新函数 EUROCONVERT 进行这些货币的换算。

语法

CONVERT(value;"text";"text")

示例

=CONVERT(100;"ATS";"EUR") 返回 100 奥地利先令的欧元值。

=CONVERT(100;"EUR";"DEM") 将 100 欧元换算成德国马克。

FLOOR.PRECISE

将数字向下舍入到Significance最近的倍数,不论Significance的正负号是什么样的。

语法

FLOOR.PRECISE(数字, Significance)

数字 表示将要被向下舍入的数字。

Significance“数字”将被向下舍入到该Significance的倍数。

示例

=FLOOR.PRECISE( -11,-2) 返回 -12

FLOOR

将数字向下舍入到Significance最接近的倍数。

语法

FLOOR(数字, Significance, 模式)

数字 是指要被向下舍入的数字。

Significance 是指向下舍入成其倍数的数字。

模式 是可选值。如果设定了“模式”值且不为零,并且“数字”和 "Significance" 都为负数,则将会根据“数字”的绝对值进行舍入。导出为 MS Excel 格式时,改参数将会被忽略,因为 Excel 不识别第三个参数。

Warning.png 如果参数“数字”和 "Significance" 都是负数,且“模式”等于零或未指定,那么 LibreOffice Calc 和 Excel 中的导出结果将会不同。如果将电子表格导出为 Excel,请使用“模式=1”以在 Excel 和 Calc 中得到相同的结果。

示例

=FLOOR( -11,-2) 返回 -12

=FLOOR( -11,-2,0) 返回 -12

=FLOOR( -11,-2,1) 返回 -10

SIGN

返回数字的正负号。如果是正数则返回 1;如果是负值,则返回 -1。如果数字是零,则返回 0。

语法

SIGN(数字)

数字 确定其正负号的数字。

示例

=SIGN(3.4) 返回 1。

=SIGN(-4.5) 返回 -1。

MROUND

将一个数字舍入为另一个数字最接近的倍数。

语法

MROUND(数字, 倍数)

返回 数字 舍入到最接近 倍数 倍数的值。

一个备选的实现方式为:Multiple * ROUND(Number/Multiple)

示例

=MROUND(15.5,3) 返回 15,因为与 18 (= 3*6) 相比,15.5 更接近 15 (= 3*5)。

=MROUND(1.4,0.5) 返回 1.5 (= 0.5*3)。

CSCH

返回数字的双曲余割。

语法

CSCH(Number)

返回 Number 的双曲余割。

示例

=CSCH(1) 的返回值约为 0.8509181282,即 1 的双曲余割。

SECH

返回一个数的双曲正割。

语法

SECH(Number)

返回 Number 的双曲正割值。

示例

=SECH(0) 返回 1,即 0 的双曲正割。

CSC

返回给定角度的余割(单位:弧度)。角度的余割值等于 1 除以该角的正弦

语法

CSC(数字)

返回弧度角 数字 的(三角)余割。

要以度为单位返回角的余割值,请使用 RADIANS 函数。

示例

=CSC(PI()/4) 的返回值约等于 1.4142135624,即 PI/4 弧度的正弦的倒数。

=CSC(RADIANS(30)) 返回 2,即 30 度的余割。

SEC

返回给定角度的正割(单位:弧度)。角度的正割等于 1 除以该角的余弦

语法

SEC(Number)

返回弧度角 Number 的(三角)正割。

要以度为单位返回角度的正割值,请使用 RADIANS 函数。

示例

=SEC(PI()/4) 的返回值约为 1.4142135624,即 π/4 弧度余弦的导数。

=SEC(RADIANS(60)) 返回 2,即 60 度角的正割。

COUNTBLANK

返回空白单元格的数目。

语法

COUNTBLANK(Range)

返回单元格区域 Range 中的空白单元格的个数。

示例

如果单元格 A1、A2、B1 和 B2 全部为空,=COUNTBLANK(A1:B2) 返回 4。

ACOS

返回一个数字的反三角余弦值。

语法

ARCCOS(number)

此函数返回 Number 的反三角余弦值,即该角度(用弧度表示)的余弦是 Number。返回的角度在 0 和 PI 之间。

要返回角度,请使用 DEGREES 函数。

示例

=ACOS(-1) 返回 3.14159265358979(PI 弧度)

=DEGREES(ACOS(0.5)) 返回 60。60 度的余弦值是 0.5。

ACOSH

返回一个数字的反双曲余弦值。

语法

ACOSH(Number)

此函数返回 Number 的反双曲线余弦值,即该值的双曲余弦值是 Number。

Number 必须大于或等于 1。

示例

=ACOSH(1) 返回 0。

=ACOSH(COSH(4)) 返回 4。

SQRT

返回一个数的正平方根。

语法

SQRT(数字)

返回 数字 的正平方根。

“数字”必须为正数。

示例

=SQRT(16) 返回 4。

=SQRT(-16) 返回无效参数错误。

ACOT

返回给定数值的反余切值。

语法

ACOT(number)

此函数返回 Number 的反三角余切值,即该角度(用弧度表示)的余切是 Number。返回的角度在 0 和 PI 之间。

要返回角度,请使用 DEGREES 函数。

示例

=ACOT(1) 返回 0.785398163397448(PI/4 弧度)。

=DEGREES(ACOT(1)) 返回 45。45 度的正切值是 1。

ACOTH

返回给定数字的反双曲余切值。

语法

ACOTH(number)

此函数返回 Number 的反双曲余切值,即该值的双曲余切值是 Number。

如果 Number 的值在 -1 和 1(包含 -1 和 1)之间,那么会有一个错误产生。

示例

=ACOTH(1.1) 返回 1.1 的双曲余切值,近似值 1.52226。

ASIN

返回一个数字的反三角正弦值。

语法

ASIN(Number)

此函数返回 Number 的反三角正弦值,即该角度(用弧度表示)的正弦是 Number。返回的角度在 -PI/2 和 +PI/2 之间。

要返回角度,请使用 DEGREES 函数。

示例

=ASIN(0) 返回 0。

=ASIN(1) 返回 1.5707963267949(PI/2 弧度)。

=DEGREES(ASIN(0.5)) 返回 30。30 度的正弦值是 0.5。

ASINH

返回一个数字的反双曲正弦值。

语法

ASINH(number)

此函数返回 Number 的反双曲正弦值,即双曲正弦是 Number 的数值。

示例

=ASINH(-90) 返回近似值 -5.1929877。

=ASINH(SINH(4)) 返回 4。

ATAN

返回一个数字的反三角正切值。

语法

ATAN(number)

此函数返回 Number 的反三角正切值,即该角度(用弧度表示)的正切是 Number。返回的角度在 -PI/2 和 PI/2 之间。

要返回角度,请使用 DEGREES 函数。

示例

=ATAN(1) 返回 0.785398163397448(PI/4 弧度)。

=DEGREES(ATAN(1)) 返回 45。45 度的正切值是 1。

ATAN2

返回指定的 x 和 y 坐标的反三角正切值。

语法

ATAN2(NumberX; NumberY)

NumberX 是点的 x 坐标值。

NumberY 是点的 y 坐标值。

ATAN2 返回 X 轴和从点 NumberX, NumberY 到原点的直线的夹角(用弧度表示)的反三角正切值。返回的角度在 -PI 和 PI 之间。

要返回角度,请使用 DEGREES 函数。

示例

=ATAN2(20;20) 返回 0.785398163397448(PI/4 弧度)。

=DEGREES(ATAN2(12.3;12.3)) 返回 45。45 度的正切值是 1。

ATANH

计算一个数字的反双曲正切值。

语法

ATANH(number)

此函数返回 Number 的反双曲正切值,即该值的双曲正切值是 Number。

Number 必须满足条件:-1 < number < 1。

示例

=ATANH(0) 返回 0。

COS

返回给定角度(用弧度表示)的余弦值。

语法

COS(Number)

返回 Number 的(三角)余弦值,用弧度表示的角度。

要返回角度的余弦值,请使用 RADIANS 函数。

示例

=COS(PI()/2) 返回 0,PI/2 弧度的余弦值。

=COS(RADIANS(60)) 返回 0.5,60 度角的余弦值。

COSH

返回一个数字的双曲余弦值。

语法

COSH(Number)

返回 Number 的双曲余弦值。

示例

=COSH(0) 返回 1,0 的双曲余弦值。

COT

返回给定角度(用弧度表示)的余切值。

语法

COT(Number)

返回用弧度表示的角度 Number 的(三角)余切值。

可以使用 RADIANS 函数来返回一个角度(用度数表示)的余切值。

一个角的余切值等于 1 除以该角的正切值。

示例:

=COT(PI()/4) 返回 1,PI/4 弧度的余切值。

=COT(RADIANS(45)) 返回 1,45 度角的余切值。

SQRTPI

返回一个数字与 PI 的乘积的平方根。

语法

SQRTPI(数字)

返回 (PI 乘以 数字r)的正平方根。

相当于 SQRT(PI()*数字)

示例

=SQRTPI(2) 返回 (2PI) 的平方根,约等于 2.506628。

COTH

返回给定数字(角度)的双曲余切值。

语法

COTH(Number)

返回 Number 的双曲余切值。

示例

=COTH(1) 返回 1 的双曲余切值,近似值 1.3130。

DEGREES

将弧度转换为度。

语法

DEGREES(Number)

Number 是指将被转换为度数的用弧度表示的角度值。

示例

=DEGREES(PI()) 返回 180 度。

EXP

返回以 e 为底的指数函数值。常数 e 的值约为 2.71828182845904。

语法

EXP(Number)

Number 是以 e 为底数的指数。

示例

=EXP(1) 返回 2.71828182845904,数学常量 e 的值根据 Calc 的精度而定。

FACT

返回一个数字的阶乘。

语法

FACT(Number)

返回 Number!,Number 的阶乘,计算 1*2*3*4* ... * Number。

根据定义,=FACT(0) 返回 1。

负数的阶乘将返回“无效参数”错误信息。

示例

=FACT(3) 返回 6。

=FACT(0) 返回 1。

INT

将数字舍入为最接近的整数。

语法

INT(Number)

返回 Number 向下舍入到最接近整数的数值。

负数向下舍入到下面的整数。

示例

=INT(5.7) 返回 5。

=INT(-1.3) 返回 -2。

EVEN

将正数向上舍入为下一个偶数,将负数向下舍入为下一个偶数。

语法

EVEN(Number)

返回 Number 远离零值,向上舍入到下一个偶数的数值。

示例

=EVEN(2.3) 返回 4。

=EVEN(2) 返回 2。

=EVEN(0) 返回 0。

=EVEN(-0.5) 返回 -2。

GCD

返回两个或多个整数的最大公约数。

最大公约数是可以整除所有给定整数的最大正整数。

语法

GCD(Integer1; Integer2; ...; Integer30)

Integer1 To 30 指最多 30 个要计算最大公约数的整数。

示例

=GCD(16;32;24) 返回 8,因为 8 是整除 16、24 和 32 的最大数字。

=GCD(B1:B3) 的结果为 3,其中单元格 B1、B2 和 B3 包含 9129

GCD_ADD

计算一列数的最大公约数。

Note.png 这些名称以 _ADD 结尾的函数会返回与对应的 Microsoft Excel 函数相同的结果。使用不带 _ADD 的函数可得到基于国际标准的结果。例如,WEEKNUM 函数基于国际标准 ISO 6801 对指定日期计算星期编号,而 WEEKNUM_ADD 会返回与 Microsoft Excel 中相同的星期编号。

语法

GCD_ADD(number)

Number(s) 是最多有 30 个数字的列表。

示例

=GCD_ADD(5;15;25) 返回 5。

ISEVEN

如果数值是偶数,则返回 TRUE;如果是奇数,则返回 FALSE。

语法

ISEVEN(Value)

Value 是要检查的数值。

如果 Value 不是一个整数,那么小数点后的所有数字都将被忽略。Value 的正负符号也将被忽略。

示例

=ISEVEN(48) 返回 TRUE

=ISEVEN(33) 返回 FALSE

=ISEVEN(0) 返回 TRUE

=ISEVEN(-2.1) 返回 TRUE

=ISEVEN(3.999) 返回 FALSE

ISODD

如果数值是奇数,则返回 TRUE;如果是偶数,则返回 FALSE。

语法

ISODD(value)

Value 是要检查的数值。

如果 Value 不是一个整数,那么小数点后的所有数字都将被忽略。Value 的正负符号也将被忽略。

示例

=ISODD(33) 返回 TRUE

=ISODD(48) 返回 FALSE

=ISODD(3.999) 返回 TRUE

=ISODD(-3.1) 返回 TRUE

RANDBETWEEN

返回一个在确定区域内的整型随机数。

语法

RANDBETWEEN(Bottom; Top)

返回一个介于 BottomTop(全部包含)之间的随机整数。

每次 Calc 重新计算时,该函数都会生成一个新的随机数。要手动使 Calc 重新计算,请按 Shift+Ctrl+F9 组合键。

要生成非重新计算的随机数,复制包含此函数的单元格,并且使用编辑 - 选择性粘贴(选中数值,而不选全部粘贴公式)。

示例

=RANDBETWEEN(20;30) 返回介于 20 到 30 之间的整数。

LCM

计算一个或多个整数的最小公倍数。

语法

LCM(Integer1; Integer2; ...; Integer30)

Integer1 to 30 是指最多 30 个要计算最小公倍数的整数。

示例

如果您分别在 Integer1、2 和 3 中输入数字 51210242000,将返回结果 128000。

LCM_ADD

计算一列数的最小公倍数。

Note.png 这些名称以 _ADD 结尾的函数会返回与对应的 Microsoft Excel 函数相同的结果。使用不带 _ADD 的函数可得到基于国际标准的结果。例如,WEEKNUM 函数基于国际标准 ISO 6801 对指定日期计算星期编号,而 WEEKNUM_ADD 会返回与 Microsoft Excel 中相同的星期编号。

语法

LCM_ADD(Number(s))

Number(s) 是最多有 30 个数字的列表。

示例

=LCM_ADD(5;15;25) 返回 75。

COMBIN

返回元素所有组合的数目(不计重复)。

语法

COMBIN(Count1; Count2)

Count1 是指集合中条目的总数。

Count2 是指在集合中所选择的条目的数量。

COMBIN 返回按照顺序组合方式选择条目的种类。例如,如果一个集合有 3 个条目 A、B 和 C,则您可以用 3 种不同的方式来选择 2 项,分别是 AB、AC 和 BC。

COMBIN 执行公式: Count1!/(Count2!*(Count1-Count2)!)

示例

=COMBIN(3;2) 返回 3。

COMBINA

返回条目的一个子集的所有组合的数目(计算重复)。

语法

COMBINA(Count1; Count2)

Count1 是指集合中条目的总数。

Count2 是指在集合中所选择的条目的数量。

COMBINA 返回选择元素的组合方式数目,与选择顺序无关,并且允许重复选择元素。例如,如果一个集合有 3 个条目 A、B 和 C,则您可以用 6 种不同的方式来选择 2 项,分别是 AB、BA、AC、CA、BC 和 CB。

COMBINA 执行公式:(Count1+Count2-1)!/ (Count2!(Count1-1)!)

示例

=COMBINA(3;2) 返回 6。

TRUNC

通过删除数字的小数位来截取一个数字。

语法

TRUNC(Number; Count)

返回最多带有 Count 位小数的 Number。全部删除多余的小数位,不考虑正负符号。

对于正数,TRUNC(Number; 0) 等同于 INT(Number),但对于负数,则是趋近零值舍入。

Warning.png 可显示的小数点位数在 工具 - 选项 - LibreOffice Calc - 计算中指定。

示例

=TRUNC(1.239;2) 返回 1.23。舍去 9。

=TRUNC(-1.234999;3) 返回 -1.234。所有的 9 都舍去。

LN

返回以常数 e 为底的某个数值的自然对数。常数 e 的值约为 2.71828182845904。

语法

LN(Number)

Number 要计算其自然对数的值。

示例

=LN(3) 返回的是 3 的自然对数值(近似于 1.0986)。

=LN(EXP(321)) 返回 321。

LOG

计算数字以指定基数为底数的对数。

语法

LOG(Number; Base)

Number 是指要计算其对数的数值。

Base(可选)是对数计算的底数。如果忽略,则默认 10 为底数。

示例

=LOG(10;3) 返回以 3 为底的 10 的对数值(近似于 2.0959)。

=LOG(7^4;7) 返回 4。

LOG10

返回以 10 为底数的对数。

语法

LOG10(Number)

返回 Number 以 10 为底的对数值。

示例

=LOG10(5) 返回底数为 -10 的 5 的对数值(近似值 0.69897)。

ISO.CEILING

将数字向上舍入到最接近Significance的倍数,无论Significance的正负号如何。

语法

ISO.CEILING(数字, Significance)

数字(必填)表示需要舍入的数字。

Significance(可选)“数字”将会被舍入到该Significance的倍数。

示例

=ISO.CEILING(-11,-2) 返回 -10

CEILING.PRECISE

将数字向上舍入到最接近Significance的倍数,无论Significance的正负号如何。

语法

CEILING.PRECISE(数字, Significance)

数字(必填)表示需要舍入的数字。

Significance(可选)“数字”将会被舍入到该Significance的倍数。

示例

=CEILING.PRECISE(-11,-2) 返回 -10

CEILING

将一个数字向上舍入为最接近基数的倍数。

语法

CEILING(Number; Significance; Mode)

Number 是指要向上舍入的数字。

Significance 是将数值向上舍入为其倍数的数字。

Mode 是可选值。如果给定了 Mode 值且不为零,并且如果 Number 和 Significance 都为负值,则系统根据 Number 的绝对值进行舍入。导出至 MS Excel 时,会忽略此参数,因为 Excel 不识别第三个参数。

Warning.png 如果参数 Number 和 Significance 都是负数并且 Mode 值等于零或未指定,则导入完成后,LibreOffice 和 Excel 中的结果不同。如果将电子表格导出至 Excel,请使用 Mode=1 以在 Excel 和 Calc 中获得相同的结果。

示例

=CEILING(-11;-2) 返回 -10

=CEILING(-11;-2;0) 返回 -10

=CEILING(-11;-2;1) 返回 -12

PI

返回 3.14159265358979,即数学常量 PI 的值,保留 14 位小数位数。

语法

PI()

示例

=PI() 返回 3.14159265358979。

RAND

返回 0 至 1 之间的随机数。

语法

RAND()

该函数在Calc每次重新计算时生成一个随机数。若想要强制Calc重算,请按F9键。

要生成非重新计算的随机数,请复制包含 =RAND() 内容的单元格,并使用 编辑 - 选择性粘贴(选中数值,而不是全部粘贴公式)。

示例

=RAND() 返回介于 0 和 1 之间的随机数字。

MULTINOMIAL

返回各变量之和的阶乘除以各变量阶乘的乘积之商。

语法

MULTINOMIAL(Number(s))

Number(s) 是最多有 30 个数字的列表。

示例

如果 F11 到 H11 包含值 234=MULTINOMIAL(F11:H11) 返回 1260。这相当于公式 =(2+3+4)! / (2!*3!*4!)

POWER

返回给定数字的幂运算结果。

语法

POWER(Base; Exponent)

返回以 Base 为底数,以 Exponent 为幂的乘幂。

相同的结果可以通过使用取幂运算符 ^ 来获得:

Base^Exponent

示例

=POWER(4;3) 返回 64,是 4 的 3 次幂。

=4^3 也返回 4 的 3 次方。

SERIESSUM

计算一个幂级数的第一项之和。

SERIESSUM(x;n;m;coefficients) = coefficient_1*x^n + coefficient_2*x^(n+m) + coefficient_3*x^(n+2m) +...+ coefficient_i*x^(n+(i-1)m)

语法

SERIESSUM(X; N; M; Coefficients)

X 是幂级数的输入值。

N 是首项乘幂

M 增加 N 的递增量

Coefficients 是一系列的系数。每多一个系数,该幂级数便增加一项。

PRODUCT

将作为参数给出的所有数字相乘并返回乘积。

语法

PRODUCT(Number1; Number2; ...; Number30)

Number1 to 30 是要计算最多为 30 个参数的乘积。

PRODUCT 返回 number1 * number2 * number3 * ...

示例

=PRODUCT(2;3;4) 返回 24。

SUMSQ

如果要计算数字的平方和(参数平方的总和),请将这些数字输入文本字段。

语法

SUMSQ(Number1; Number2; ...; Number30)

Number1 to 30 是要计算最多可达 30 个参数的平方和。

示例

如果在 Number 1、2 和 3 文本框中分别输入数字 234,则结果是 29。

MOD

返回某个数字除以除数之后的余数。

语法

MOD(Divident; Divisor)

对于整型参数,该函数返回以 Divisor 为模的 Dividend,就是 DividendDivisor 所除后的余数。

这个函数的作用是给出 Dividend - Divisor * INT(Dividend/Divisor) 的计算结果,并且这个公式给出了参数不是整型的情况。

示例

=MOD(22;3) 返回 1,是 22 除以 3 时得到的余数。

=MOD(11.25;2.5) 返回 1.25。

QUOTIENT

返回除法运算的整数部分。

语法

QUOTIENT(Numerator; Denominator)

返回 Denominator 除以 Numerator 的整数部分。

除了用不同的错误编码显示不同的错误结果外,QUOTIENT 相当于 INT(numerator/denominator) 函数。

示例

=QUOTIENT(11;3) 返回 3。余数 2 被省略。

RADIANS

将角度转换为弧度

语法

RADIANS(Number)

Number 是指要被转换为弧度的用度数表示的角度值。

示例

=RADIANS(90) 返回 1.5707963267949,即 PI/2,该值根据 Calc 的精度而定。

ROUND

将一个数字舍入到某一特定个数的小数位。

语法

ROUND(Number; Count)

返回舍入到 Count 位小数的 Number。如果 Count 被省略或者为零,该函数就舍入到最接近的整数。如果 Ccunt 是负数,则此函数舍入为最接近的 10,100,1000,依次类推。

此函数舍入到最近的数。另请参见 ROUNDDOWN 和 ROUNDUP。

示例

=ROUND(2.348;2) 返回 2.35

=ROUND(-32.4834;3) 返回 -32.483。修改单元格格式以查看所有小数。

=ROUND(2.348;0) 返回 2。

=ROUND(2.5) 返回 3。

=ROUND(987.65;-2) 返回 1000。

ROUNDDOWN

将数字向下舍入,趋近零值,达到指定的精度。

语法

ROUNDDOWN(Number; Count)

返回向下舍入(趋近零值)到 Count 位小数的 Number。如果 Count 被省略或为零,则此函数向下舍入为一个整数;如果 Count 是负数,则此函数向下舍入为 10,100,1000,依次类推。

此函数趋近零值舍入,另请参见 ROUNDUP 和 ROUND。

示例

=ROUNDDOWN(1.234;2) 返回 1.23。

=ROUNDDOWN(45.67;0) 返回 45。

=ROUNDDOWN(-45.67) 返回 -45。

=ROUNDDOWN(987.65;-2) 返回 900。

COUNTIF

返回某一单元格区域中符合特定条件的单元格数目。

查找支持正则表达式。例如,您可以输入 "all.*" 来查找起始部分为 "all" 且后跟任意字符的内容首次出现的位置。如果您想要查找一个同时也是正则表达式的文本,则您必须在每个字符前面加上一个 \ 字符。您能够在 工具 - 选项 - LibreOffice Calc - 计算中切换正则表达式自动求值功能的打开和关闭状态。

语法

COUNTIF(Range; Criteria)

range 是指定要执行某一条件的区域。

Criteria 表示数字、表达式或字符串形式的条件。这些条件决定计算哪些单元格。您也可以输入正则表达式形式的搜索文本,例如,b.* 表示所有以 b 开头的文字。还可以指示包含搜索条件的单元格范围。如果要搜索精确的文字正文,请用双引号括住文本。

示例

A1:A10 是单元格范围,包含数字 20002009。单元格 B1 包含数字 2006。在单元格 B2,输入公式:

=COUNTIF(A1:A10;2006) - 返回 1

=COUNTIF(A1:A10;B1) - 返回 1

=COUNTIF(A1:A10;">=2006") - 返回 4

=COUNTIF(A1:A10;"<"&B1) - 当 B1 包含 2006 时,返回 6

=COUNTIF(A1:A10;C2) 计算区域 A1:A10 中大于 2006 的单元格的数量,其中单元格 C2 包含文本 >2006

仅计算负数:=COUNTIF(A1:A10;"<0")

ROUNDUP

远离零值向上舍入某个数到指定精度。

语法

ROUNDUP(Number; Count)

返回向上舍入(远离零值)到 Count 位小数的 Number。如果 Count 被省略或者为零,此函数向上舍入为一个整数。如果 Count 是负数,则此函数向上舍入为 10,100,1000,依次类推。

此函数远离零值向上舍入。另请参见 ROUNDDOWN 和 ROUND。

示例

=ROUNDUP(1.1111;2) 返回 1.12。

=ROUNDUP(1.2345;1) 返回 1.3。

=ROUNDUP(45.67;0) 返回 46。

=ROUNDUP(-45.67) 返回 -46。

=ROUNDUP(987.65;-2) 返回 1000。

SIN

返回给定角度(用弧度表示)的正弦值。

语法

SIN(Number)

返回用弧度表示的角度 Number 的(三角)正弦值。

要返回角度的正弦值,请使用 RADIANS 函数。

示例

=SIN(PI()/2) 返回 1,PI/2 弧度的正弦值。

=SIN(RADIANS(30)) 返回 0.5,是 30 度的正弦值。

SINH

返回一个数字的双曲正弦值。

语法

SINH(Number)

返回 Number 的双曲正弦值。

示例

=SINH(0) 返回 0,0 的双曲正弦值。

SUM

将某一单元格范围内的所有数字相加。

语法

SUM(Number1; Number2; ...; Number30)

Number 1 to Number 30 是要计算最多可达 30 个参数的总和。

示例

如果分别在 Number 1;2 和 3 文本框中输入数字 234,将返回结果 9。

=SUM(A1;A3;B5) 计算三个单元格的数值总和。=SUM (A1:E10) 计算单元格区域 A1 至 E10 的数值总和。

由 AND 链接的条件可以按照以下方式与函数 SUM() 一起使用:

示例:您已在表格中输入了发货单。列 A 记录发货单的日期值,列 B 记录数量。您希望使用一个公式来计算指定月份的总量,比如,只计算 2008-01-01 到 2008-02-01 之间的金额总数。此日期值的单元格区域是 A1:A40,计算数量所在的区域是 B1:B40。单元格 C1 中存储的是发货单起始日期,2008-01-01,C2 存储的是日期 2008-02-01,计算日期包括前者,但不包括后者。

输入以下公式作为数组公式:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

要将它作为数组公式输入时,您必须按住 Shift+ Ctrl+ Enter 组合键关闭公式,而不是简单的按 Enter 键。这样一来,公式栏中将显示该公式,并用一对花括号括起来。

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

此公式建立在比较结果的基础上,如果符合条件,则比较结果为 1,反之为 0。单个的比较结果将被视为数组,并用于计算矩阵乘积,最后将计算各个值的总和以得到结果矩阵。

SUMIF

添加由给定条件指定的单元格。当您查找一个特定值时,此函数用于浏览区域。

查找支持正则表达式。例如,您可以输入 "all.*" 来查找起始部分为 "all" 且后跟任意字符的内容首次出现的位置。如果您想要查找一个同时也是正则表达式的文本,则您必须在每个字符前面加上一个 \ 字符。您能够在 工具 - 选项 - LibreOffice Calc - 计算中切换正则表达式自动求值功能的打开和关闭状态。

语法

SUMIF(Range; Criteria; SumRange)

range 是指定要执行某一条件的区域。

Criteria 是显示搜索条件的单元格,或是搜索条件本身。如果将条件写入公式,两侧必须括有双引号。

SumRange 是指总和各个数值的区域。在没有输入参数的情况下,只会计算区域内的数值总和。

Note.png SUMIF 仅在 Criteria 参数中,并且没有给定可选的 SumRange 参数时,支持引用连接运算符 (~)。

示例

仅对负数求和:=SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:10) - 只有 A1:A10 范围中的相应值大于零时,才对 B1:B10 范围中的值进行求和。

请参见 COUNTIF(),以获取可用于 SUMIF() 的更多语法示例。

TAN

返回给定角度(用弧度表示)的正切值。

语法

TAN(Number)

返回用弧度表示的角度 Number 的(三角)正切值。

可以使用 RADIANS 函数来返回一个角度(用度数表示)的正切值。

示例

=TAN(PI()/4) 返回 1,PI/4 弧度的正切值。

=TAN(RADIANS(45)) 返回 1,即 45 度的正切值。

TANH

返回一个数字的双曲正切值。

语法

TANH(Number)

返回 Number 的双曲正切值。

示例

=TANH(0) 返回 0,0 的双曲正切值。

SUBTOTAL

计算分类汇总。如果一个区域已包含分类汇总,则它们不能用于进一步的计算。将此函数和自动筛选同时使用,可以仅计算已筛选的记录。

语法

SUBTOTAL(Function; Range)

Function 是一个表示下列某个函数的数字:

函数索引 函数
1 AVERAGE
2 COUNT
3 COUNTA
4 MAX
5 MIN
6 PRODUCT
7 STDEV
8 STDEVP
9 SUM
10 VAR
11 VARP

Range 是指公式必须顾及的单元格区域。

示例

在工作表的单元格区域 A1:B5 中的列 A 中记录了城市,列 B 中记录对应的数值。经过自动筛选后,只显示含有城市 Hamburg 的行。您需要查看所显示的数值的和,也就是说,要查看筛选出的行的分类汇总。在这种情况下,正确的公式是:

=SUBTOTAL(9;B2:B5)

EUROCONVERT

此函数用于实现以前的欧洲货币值与现在的欧元之间的换算。

语法

EUROCONVERT(Value; "From_currency"; "To_currency", full_precision, triangulation_precision)

Value 是指要换算的货币数目。

From_currencyTo_currency 分别是换算前和换算后的货币单位,这些必须是货币的官方缩写文本(例如,"EUR")。所采用的汇率(以每欧元表示)是由欧洲委员会制定的。

Full_precision 是可选的。如果忽略或为 False,则结果参照 To 货币的小数部分被舍入。如果 Full_precision 为 True,结果不被舍入。

Triangulation_precision 是可选的。如果 Triangulation_precision 已给定且 >=3,三角转换 (currency1,EUR,currency2) 的中间结果舍入到该精度。如果忽略 Triangulation_precision,中间结果不被舍入。此外,如果 To 货币为 "EUR",则也会使用 Triangulation_precision,正如需要三角转换并且应用从 EUR 到 EUR 的转换一样。

示例

=EUROCONVERT(100;"ATS";"EUR") 将 100 奥地利先令换算成欧元。

=EUROCONVERT(100;"EUR";"DEM") 将 100 欧元换算成德国马克。

ODD

将正数向上舍入为最接近的奇数整数,并将负数向下舍入为最接近的奇数整数。

语法

ODD(Number)

返回 Number 远离零值,向上舍入到下一个奇数的数值。

示例

=ODD(1.2) 返回 3。

=ODD(1) 返回 1。

=ODD(0) 返回 1。

=ODD(-3.1) 返回 -5。

ABS

返回数字的绝对值。

语法

ABS(Number)

Number 是指要计算其绝对值的数值。一个数值的绝对值是不带 +/- 号的数值。

示例

=ABS(-56) 返回 56。

=ABS(12) 返回 12。

=ABS(0) 返回 0。


Related Topics

Calc函数分类 在LibreOffice 帮助维基