Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Matematične funkcije

From LibreOffice Help
Jump to: navigation, search

Ta kategorija vsebuje matematične funkcije za Calc. Če želite odpreti Čarovnika za funkcije, izberiteVstavi – Funkcija.

Contents

CONVERT

Pretvori vrednost iz enih merskih enot v druge. Faktorji pretvorbe so podani v seznamu nastavitev.

Nekoč je ta seznam faktorjev pretvorbe vključevala nekdanje evropske valute in evro (glejte spodnje primere). Če želite pretvoriti te valute, predlagamo uporabo nove funkcije EUROCONVERT.

Skladnja

CONVERT(vrednost;"besedilo";"besedilo")

Primer

=CONVERT(100;"SIT";"EUR") pretvori 100 slovenskih tolarjev v evre.

=CONVERT(100;"EUR";"DEM") pretvori 100 evrov v nemške marke.

FLOOR.PRECISE

Zaokroži število navzdol na najbližji večkratnik značilnega števila ne glede na predznak značilnega števila.

Skladnja

FLOOR.PRECISE(število; značilno_število)

Število je število, ki ga želimo zaokrožiti navzdol.

Značilno_število je število, na katerega večkratnik želimo število zaokrožiti navzdol.

Primer

=FLOOR.PRECISE( -11;-2) vrne -12.

FLOOR

Zaokroži število navzdol na najbljižji večkratnik značilnega števila.

Skladnja

FLOOR(število; značilno_število; način)

Število je število, ki ga želimo zaokrožiti navzdol.

Značilno_število je število, na katerega večkratnik želimo število zaokrožiti navzdol.

Način je neobvezen argument. Če je vrednost načina podana in ni enaka nič ter sta število in značilno_število negativna, se zaokrožanje izvrši na osnovi absolutne vrednosti števila. Ta parameter se ne upošteva pri izvozu v datoteke programa MS Excel, saj Excel ne pozna tretjega parametra.

Warning.png Če sta oba parametra število in značilno_število negativna in če je najpogostejša_vrednost enaka nič ali pa ni določena, se bodo rezultati v LibreOffice Calc in Excelu po izvozu razlikovali. Če delovni list izvozite v Excel, uporabite najpogostejša_vrednost=1, če želite dobiti enake rezultate v Excelu in modulu Calc.

Primer

=FLOOR( -11;-2) vrne -12.

=FLOOR( -11;-2;0) vrne -12.

=FLOOR( -11;-2;1) vrne -10.

SIGN

Vrne predznak števila. Vrne 1, če je število pozitivno, -1, če je število negativno, in 0, če je število nič.

Skladnja

SIGN(število)

Število je število, katerega predznak želimo ugotoviti.

Primer

=SIGN(3,4) vrne 1.

=SIGN(-4,5) vrne -1.

MROUND

Vrne število, zaokroženo na najbližji večkratnik drugega števila.

Skladnja

MROUND(Število; Večkratnik)

Vrne število, zaokroženo na najbližji večkratnik Večkratnika.

Drugače bi to lahko zapisali kot Večkratnik * ROUND(Število/Večkratnik).

Primer

=MROUND(15,5;3) vrne 15, saj je 15,5 bližje 15 (= 3*5) kot 18 (= 3*6).

=MROUND(1,4;0,5) vrne 1,5 (= 0,5*3).

CSCH

Vrne hiperbolični kosekans števila.

Skladnja

CSCH(število)

Vrne hiperbolični kosekans števila.

Primer

=CSCH(1) vrne približno 0,8509181282, kar je hiperbolični kosekans 1.

SECH

Vrne hiperbolični sekans števila.

Skladnja

SECH(število)

Vrne hiperbolični sekans števila.

Primer

=SECH(0) vrne 1, kar je hiperbolični sekans 0.

CSC

Vrne kosekans danega kota (v radianih). Kosekans kota je enak 1, deljeni z sinusom tega kota.

Skladnja

CSC(število)

Vrne (trigonometrični) kosekans števila, kot v radianih.

Če želite kosekans kota v stopinjah, uporabite funkcijo RADIANS.

Primeri

=CSC(PI()/4) vrne približno 1,4142135624, to je obratna vrednost sinusa PI/4 radianov.

=CSC(RADIANS(30)) vrne 2, kosekans 30 stopinj.

SEC

Vrne sekans danega kota (v radianih). Sekans kota je enak 1, delejeni s kosinusom tega kota.

Skladnja

SEC(število)

Vrne (trigonometrični) sekans števila, kot v radianih.

Če želite vrnjeno vrednost sekansa kota v stopinjah, uporabite funkcijo RADIANS.

Primeri

=SEC(PI()/4) vrne približno 1,4142135624, to je obratna vrednost kosinusa PI/4 radianov.

=SEC(RADIANS(60)) vrne 2, sekans 60 stopinj.

COUNTBLANK

Vrne število praznih celic.

Skladnja

COUNTBLANK(obseg)

Vrne število praznih celic v okviru obsega celic obseg.

Primer

=COUNTBLANK(A1:B2) vrne 4, če so celice A1, A2, B1 in B2 prazne.

ACOS

Vrne obraten trigonometrični kosinus števila.

Skladnja

ACOS(število)

Ta funkcija vrne inverzni arkus kosinus števila, kar je kot (v radianih), katerega kosinus je število. Vrnjeni kot ima vrednost med 0 in PI.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ACOS(-1) vrne 3,14159265358979 (PI radianov)

=DEGREES(ACOS(0,5)) vrne 60. Kosinus 60 stopinj je 0,5.

ACOSH

Vrne obratni hiperbolični kosinus števila.

Skladnja

ACOSH(število)

Ta funkcija vrne inverzni hiperbolični kosinus števila, kar je število, katerega hiperbolični kosinus je število.

Število mora biti večje ali enako 1.

Primer

=ACOSH(1) vrne 0.

=ACOSH(COSH(4)) vrne 4.

SQRT

Vrne pozitivno vrednost korena števila.

Skladnja

SQRT(število)

Vrne pozitivni koren števila.

Število mora biti pozitivno.

Primer

=SQRT(16) vrne 4.

=SQRT(-16) vrne napako neveljaven argument.

ACOT

Vrne inverzni kotangens (arkus tangens) danega števila.

Skladnja

ACOT(število)

Ta funkcija vrne inverzni trigonometrični kotangens števila, kar je kot (v radianih), katerega kotangens je število. Vrnjeni kot ima vrednost med 0 in PI.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ACOT(1) vrne 0,785398163397448 (PI/4 radianov).

=DEGREES(ACOT(1)) vrne 45. Tangens 45 stopinj je 1.

ACOTH

Vrne obratni hiperbolični kotangens danega števila.

Skladnja

ACOTH(število)

Ta funkcija vrne inverzni hiperbolični kotangens števila, kar je število, katerega hiperbolični kotangens je število.

Napaka se pojavi, če ima število vrednost med vključno -1 in 1.

Primer

=ACOTH(1,1) vrne inverzni hiperbolični kotangens 1,1, kar je približno 1,52226.

ASIN

Vrne obratni trigonometrični sinus števila.

Skladnja

ASIN(število)

Ta funkcija vrne inverzni trigonometrični sinus števila, kar je kot (v radianih), katerega sinus je število. Vrnjeni kot ima vrednost med -PI/2 in +PI/2.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ASIN(0) vrne 0.

=ASIN(1) vrne 1.5707963267949 (PI/2 radianov).

=DEGREES(ASIN(0,5)) vrne 30. Sinus 30 stopinj je 0,5.

ASINH

Vrne obratni hiperbolični sinus števila.

Skladnja

ASINH(število)

Ta funkcija vrne inverzni hiperbolični sinus števila, ki je število, katerega hiperbolični sinus je število.

Primer

=ASINH(-90) vrne približno -5,1929877.

=ASINH(SINH(4)) vrne 4.

ATAN

Vrne obratni trigonometrični tangens števila.

Skladnja

ATAN(število)

Ta funkcija vrne inverzni trigonometrični tangens števila, kar je kot (v radianih), katerega tangens je število. Vrnjeni kot ima vrednost med -PI/2 in PI/2.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ATAN(1) vrne 0,785398163397448 (PI/4 radianov).

=DEGREES(ATAN(1)) vrne 45. Tangens 45 stopinj je 1.

ATAN2

Vrne obratni trigonometrični tangens določenih koordinat x in y.

Skladnja

ATAN2(številoX; številoY)

ŠteviloX je vrednost koordinate X.

ŠteviloY je vrednost koordinate Y.

ATAN2 vrne inverzni trigonometrični tangens, to je kot (v radianih) med osjo X in črto od točke številoX, številoY do izhodišča. Vrnjeni kot ima vrednost med -PI in PI.

Če želite vrnjeno vrednost kota v stopinjah, uporabite funkcijo DEGREES.

Primer

=ATAN2(20;20) vrne 0,785398163397448 (PI/4 radianov).

=DEGREES(ATAN2(12,3;12,3)) vrne 45. Tangens 45 stopinj je 1.

ATANH

Vrne obratni hiperbolični tangens števila.

Skladnja

ATANH(število)

Ta funkcija vrne inverzni hiperbolični tangens števila, kar je število, katerega hiperbolični tangens je število.

Število mora ustrezati pogoju: -1 < število < 1.

Primer

=ATANH(0) vrne 0.

COS

Vrne kosinus podanega kota (v radianih).

Skladnja

COS(število)

Vrne (trigonometrični) kosinus števila, kot v radianih.

Če želite kosinus kota v stopinjah, uporabite funkcijo RADIANS.

Primeri

=COS(PI()/2) vrne 0, to je kosinus PI/2 radianov.

=COS(RADIANS(60)) vrne 0,5, kosinus 60 stopinj.

COSH

Vrne hiperbolični kosinus števila.

Skladnja

COSH(število)

Vrne hiperbolični kosinus števila.

Primer

=COSH(0) vrne 1, kar je hiperbolični kosinus 0.

COT

Vrne kotangens danega kota (v radianih).

Skladnja

COT(število)

Vrne (trigonometrični) kotangens števila, kot v radianih.

Če želite vrnjeno vrednost kotangensa kota v stopinjah, uporabite funkcijo RADIANS.

Kotangens kota je enak 1, deljeno s tangensom tega kota.

Primeri:

=COT(PI()/4) vrne 1, kotangens PI/4 radianov.

=COT(RADIANS(45)) vrne 1, kotangens 45 stopinj.

SQRTPI

Vrne kvadratni koren izraza (PI krat število).

Skladnja

SQRTPI(število)

Vrne pozitivno vrednost kvadratnega korena od (PI pomnoženo s številom).

To je enako SQRT(PI()*število).

Primer

=SQRTPI(2) vrne kvadratni koren števila (2PI), približno 2,506628.

COTH

Vrne hiperbolični kotangens danega števila (kota).

Skladnja

COTH(število)

Vrne hiperbolični kotangens števila.

Primer

=COTH(1) vrne hiperbolični kotangens 1, približno 1,3130.

DEGREES

Radiane spremeni v stopinje.

Skladnja

DEGREES(število)

Število je kot v radianih, ki bo pretvorjen v stopinje.

Primer

=DEGREES(PI()) vrne 180 stopinj.

EXP

Vrne e, stopnjevan na potenco števila. Vrednost konstante e je približno 2.71828182845904.

Skladnja

EXP(število)

Število je potenca, na katero želimo eksponirati konstanto e.

Primer

=EXP(1) vrne 2,71828182845904, matematično konstanto e s Calcovo natančnostjo.

FACT

Vrne fakulteto števila.

Skladnja

FACT(število)

Vrne število!, fakulteto števila, ki se izračuna kot 1*2*3*4* ... * število.

=FACT(0) po definiciji vrne 1.

Fakulteta negativnega števila vrne napako »neveljaven argument«.

Primer

=FACT(3) vrne 6.

=FACT(0) vrne 1.

INT

Število zaokroži navzdol na najbližje celo število.

Skladnja

INT(število)

Vrne število, zaokroženo navzdol na najbližje celo število.

Negativna števila se zaokrožijo navzdol na spodnje celo število.

Primer

=INT(5,7) vrne 5.

=INT(-1,3) vrne -2.

EVEN

Zaokroži pozitivno število na naslednje sodo celo število in negativno število navzdol na naslednje sodo celo število.

Skladnja

EVEN(število)

Vrne število zaokroženo navzgor na naslednje sodo celo število, stran od nič.

Primeri

=EVEN(2,3) vrne 4.

=EVEN(2) vrne 2.

=EVEN(0) vrne 0.

=EVEN(-0,5) vrne -2.

GCD

Vrne največji skupni delitelj dveh ali več celih števil.

Največji skupni delitelj je največje pozitivno celo število, ki brez ostanka deli vsa podana cela števila.

Skladnja

GCD(celo_število1; celo_število2; ...; celo_število30)

Celo_število1 do 30 je največ 30 celih števil, za katera želimo izračunati največji skupni delitelj.

Primer

=GCD(16;32;24) vrne rezultat 8, ker je 8 največje število, ki deli 16, 24 in 32 brez ostanka.

=GCD(B1:B3), kjer celice B1, B2, B3 vsebujejo vrednosti 9, 12, 9, vrne 3.

GCD_ADD

Rezultat je največji skupni delitelj seznama števil.

Note.png Funkcije, katerih imena se končajo z _ADD, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez _ADD. Primer: funkcija WEEKNUM izračuna številko tedna za določen datum na podlagi mednarodnega standarda ISO 6801, WEEKNUM_ADD pa vrne enako številko tedna kot Microsoft Excel.

Skladnja

GCD_ADD(Število/a)

Število/a je seznam največ 30 števil.

Primer

=GCD_ADD(5;15;25) vrne 5.

ISEVEN

Vrne TRUE, če je vrednost sodo celo število ali FALSE, če je vrednost liha.

Skladnja

ISEVEN(vrednost)

Vrednost je vrednost, ki jo želimo preveriti.

Če Vrednost ni celo število, so vse decimalke prezrte. Prezrt je tudi predznak Vrednosti.

Primer

=ISEVEN(48) vrne TRUE

=ISEVEN(33) vrne FALSE.

=ISEVEN(0) vrne TRUE

=ISEVEN(-2,1) vrne TRUE

=ISEVEN(3,999) vrne FALSE

ISODD

Vrne TRUE, če je vrednost liha, ali FALSE, če je število sodo.

Skladnja

ISODD(vrednost)

Vrednost je vrednost, ki jo želimo preveriti.

Če Vrednost ni celo število, so vse decimalke prezrte. Prezrt je tudi predznak Vrednosti.

Primer

=ISODD(33) vrne TRUE

=ISODD(48) vrne FALSE.

=ISODD(3,999) vrne TRUE

=ISODD(-3,1) vrne TRUE

RANDBETWEEN

Vrne naključno celo število iz navedenega obsega.

Skladnja

RANDBETWEEN(Dno; Vrh)

Vrne naključno celo število med Dnomin Vrhom (vključno z obema).

Ta funkcija izdela novo naključno število vsakokrat, ko Calc opravi preračun. Če želite izvesti ponovni izračun ročno, pritisnite kombinacijo tipk dvigalka+krmilka+F9.

Če želite generirati naključna števila, ki se nikoli ponovno ne izračunajo, kopirajte celice, ki vsebujejo to funkcijo, in uporabite Uredi – Posebno lepljenje (tako da Prilepi vse in Formule nista označena in da je označeno polje Števila).

Primer

=RANDBETWEEN(20;30) vrne celo število med 20 in 30.

LCM

Vrne najmanjši skupni večkratnik enega ali več celih števil.

Skladnja

LCM(celo_število1; celo_število2; ...; celo_število30)

Celo_število1 do 30 je največ 30 števil, za katera želimo izračunati najmanjši skupni večkratnik.

Primer

Če v besedilne okvire 1;2 in 3 vnesete števila 512;1024 in 2000, bo rezultat število 128000.

LCM_ADD

Rezultat je najmanjši skupni večkratnik seznama števil.

Note.png Funkcije, katerih imena se končajo z _ADD, dajo enake rezultate kot ustrezne funkcije programa Microsoft Excel. Za rezultate, ki temeljijo na mednarodnih standardih, uporabljajte funkcije brez _ADD. Primer: funkcija WEEKNUM izračuna številko tedna za določen datum na podlagi mednarodnega standarda ISO 6801, WEEKNUM_ADD pa vrne enako številko tedna kot Microsoft Excel.

Skladnja

LCM_ADD(število/a)

Število/a je seznam največ 30 števil.

Primer

=LCM_ADD(5;15;25) vrne 75.

COMBIN

Vrne število kombinacij podmnožic elementov brez ponovitev.

Skladnja

COMBIN(števec1; števec2)

Števec1 je število elementov v množici.

Števec2 je število elementov v množici, med katerimi je mogoče izbirati.

COMBIN vrne število načinov izbora teh elementov. Primer: če imamo v množici tri elemente A, B in C, lahko 2 elementa izberemo na 3 različne načine: AB, AC in BC.

COMBIN izračuna izraz: števec1!/(števec2!*(števec1-števec2)!)

Primer

=COMBIN(3;2) vrne 3.

COMBINA

Vrne število kombinacij podmnožic elementov, vključno s ponovitvami.

Skladnja

COMBINA(števec1; števec2)

Števec1 je število elementov v množici.

Števec2 je število elementov v množici, med katerimi je mogoče izbirati.

COMBINA vrne število različnih načinov izbora teh elementov, pri čemer vrstni red izbiranja ni pomemben, dovoljeno je tudi ponavljanje elementov. Primer: če imamo v množici tri elemente, A, B in C, lahko 2 elementa izberemo na 6 različnih načinov: AA, AB, AC, BB, BC in CC.

COMBINA izračuna izraz: (števec1+števec2-1)! / (števec2!(števec1-1)!)

Primer

=COMBINA(3;2) vrne 6.

TRUNC

Odreže število tako, da odstrani decimalna mesta.

Skladnja

TRUNC(število; števec)

Vrne število z največ števec decimalnimi mesti. Presežek decimalnih mest je enostavno odstranjen, ne glede na predznak.

TRUNC(število; 0) se vede kot INT(število) za pozitivna števila, negativna števila pa zaokroži proti ničli.

Warning.png Vidna decimalna mesta rezultata so določena v Orodja – Možnosti – LibreOffice Calc – Izračuni.

Primer

=TRUNC(1,239;2) vrne 1,23. Pri tem je 9 odrezana.

=TRUNC(-1,234999;3) vrne -1,234. Vse 9-ke so odrezane.

LN

Vrne naravni logaritem, katerega osnova je konstanta e. Vrednost konstante e je približno 2.71828182845904.

Skladnja

LN(število)

Število je vrednost, katere naravni logaritem želimo izračunati.

Primer

=LN(3) vrne naravni logaritem števila 3 (približno 1,0986).

=LN(EXP(321)) vrne 321.

LOG

Vrne logaritem števila na določeno osnovo.

Skladnja

LOG(število, osnova)

Število je vrednost, katere logaritem želimo izračunati.

Osnova (neobvezno) je osnova za izračun logaritma. Če je izpuščena, je privzeta osnova 10.

Primer

=LOG(10;3) vrne logaritem števila 10 z osnovo 3 (približno 2,0959).

=LOG(7^4;7) vrne 4.

LOG10

Vrne logaritem števila z osnovo 10.

Skladnja

LOG10(število)

Vrne logaritem z osnovo 10 števila.

Primer

=LOG10(5) vrne logaritem števila 5 z osnovo 10 (približno 0,69897).

ISO.CEILING

Zaokroži število navzgor na najbližji večkratnik značilnega števila ne glede na predznak značilnega števila.

Skladnja

ISO.CEILING(število, značilno_število)

Število (obvezno) je število, ki ga želimo zaokrožiti.

Značilno_število (neobvezno) je število, na katerega večkratnik želimo vrednost zaokrožiti navzgor.

Primer

=ISO.CEILING(-11;-2) vrne -10

CEILING.PRECISE

Zaokroži število navzgor na najbližji večkratnik značilnega števila ne glede na predznak značilnega števila.

Skladnja

CEILING.PRECISE(število, značilno_število)

Število (obvezno) je število, ki ga želimo zaokrožiti.

Značilno_število (neobvezno) je število, na katerega večkratnik želimo vrednost zaokrožiti navzgor.

Primer

=CEILING.PRECISE(-11;-2) vrne -10

CEILING

Število zaokroži navzgor na najbližji večkratnik značilnega števila.

Skladnja

CEILING(število, značilno_število; najpogostejša_vrednost)

Število je število, ki ga želimo zaokrožiti.

Značilno_število je število, na katerega večkratnik želimo navzgor zaokrožiti vrednost.

Način je neobvezen argument. Če je vrednost načina podana in ni enaka nič ter sta število in značilno_število negativna, se zaokrožanje izvrši na osnovi absolutne vrednosti števila. Ta parameter se ne upošteva pri izvozu v datoteke programa MS Excel, saj Excel ne pozna tretjega parametra.

Warning.png Če sta oba parametra število in značilno_število negativna in če je vrednost najpogostejša_vrednost enaka nič ali ni podana, so bosta rezultata v LibreOffice in Excelu po končanem uvozu razlikovala. Če delovni list izvozite v Excel, uporabite najpogostejša_vrednost=1, da bodo rezultati v Excelu enaki kot v modulu Calc.

Primer

=CEILING(-11;-2) vrne -10

=CEILING(-11;-2;0) vrne -10

=CEILING(-11;-2;1) vrne -12

PI

Vrne 3,14159265358979, vrednost matematične konstante PI, na 14 decimalnih mest natančno.

Skladnja

PI()

Primer

=PI() vrne 3,14159265358979.

RAND

Vrne naključno število med 0 in 1.

Skladnja

RAND()

Ta funkcija izdela novo naključno število vsakokrat, ko Calc opravi preračun. Če želite izvesti ponovni izračun ročno, pritisnite tipko F9.

Če želite generirati naključna števila, ki se nikoli ne preračunajo, kopirajte celice, ki vsebujejo funkcijo =RAND(), in uporabite Uredi – Posebno lepljenje (tako da Prilepi vse in Formule nista označena in da je označeno polje Števila).

Primer

=RAND() vrne naključno število med 0 in 1.

MULTINOMIAL

Vrne zmnožek vrste faktorjev vsote argumentov deljenih z produktom zmnožka vrste faktorjev in argumentov.

Skladnja

MULTINOMIAL(število/a)

Število/a je seznam največ 30 števil.

Primer

=MULTINOMIAL(F11:H11) vrne 1260, če celice od F11 do H11 vsebujejo vrednosti 2, 3 in 4. To ustreza formuli =(2+3+4)! / (2!*3!*4!)

POWER

Vrne število na potenco drugega števila.

Skladnja

POWER(osnova; stopnja_potence)

Vrne osnovo na stopnjo potence stopnja_potence.

Enak rezultat lahko dosežemo z uporabo operatorja ^:

osnova^stopnja_potence

Primer

=POWER(4;3) vrne 64, kar je 4 na 3. potenco.

=4^3 vrne tudi 4 na potenco 3.

SERIESSUM

Sešteje prve člene potenčnega zaporedja.

SERIESSUM(x;n;m;koeficient) = koeficient_1*x^n + koeficient_2*x^(n+m) + koeficient_3*x^(n+2m) +...+ koeficient_i*x^(n+(i-1)m)

Skladnja

SERIESSUM(X; N; M; koeficienti)

X je vhodna vrednost potenčnega zaporedja.

N je začetna stopnja potence.

M je prirastek za povečanje N-ja.

Koeficienti je niz koeficientov. Za vsak koeficient je niz vsote povečan za en razdelek.

PRODUCT

Zmnoži vsa dana števila, ki so podana kot argumenti, in kot rezultat vrne produkt.

Skladnja

PRODUCT(število1; število2; ...; število30)

Število1 do 30 je največ 30 argumentov, katerih produkt želimo izračunati.

PRODUCT vrne število1 * število2 * število3 * ...

Primer

=PRODUCT(2;3;4) vrne 24.

SUMSQ

Če želite izračunati vsoto kvadratov števil (vse kvadrate argumentov), jih vnesite v tekstovno polje.

Skladnja

SUMSQ(število1; število2; ...; število30)

Število1 do 30 je največ 30 argumentov, katerih vsoto kvadratov želimo izračunati.

Primer

Če v besedilne okvire številka 1; 2 in 3 vnesete števila 2; 3 in 4, je rezultat 29.

MOD

Vrne ostanek pri deljenju prvega celega števila z drugim.

Skladnja

MOD(deljenec; delitelj)

Za celoštevilčne argumente ta funkcija vrne deljenca po modulu delitelja, to je ostanek pri deljenju deljenca z deliteljem.

Ta funkcija je implemenirana kot deljenec - delitelj * INT(deljenec/delitelj). Ta formula vrne rezultat, če argumenti niso cela števila.

Primer

=MOD(22;3) vrne 1, ostanek pri deljenju 22 s 3.

=MOD(11,25;2,5) vrne 1,25.

QUOTIENT

Vrne celoštevilčni del operacije deljenja.

Skladnja

QUOTIENT(deljenec;delitelj)

Vrne celoštevilčni del imenovalca, deljenega s števcem.

QUOTIENT je enak INT(števec/imenovalec), le da lahko vrne napake z drugačnimi kodami napake.

Primer

=QUOTIENT(11;3) vrne 3. Ostanek 2 je izgubljen.

RADIANS

Stopinje pretvori v radiane.

Skladnja

RADIANS(število)

Število je kot v stopinjah, ki bo pretvorjen v radiane.

Primer

=RADIANS(90) vrne 1,5707963267949, kar je PI/2 z natančnostjo modula Calc.

ROUND

Zaokroži število na določeno število decimalnih mest.

Skladnja

ROUND(število; števec)

Vrna število, zaokroženo na števec decimalnih mest. Če števec izpustite ali ima vrednost nič, funkcija zaokroži na najbližje celo število. Če je števec negativen, funkcija zaokroži na najbližjih 10, 100, 1000 itn.

Ta funkcija zaokroži na najbližje število. Poglejte si tudi ROUNDDOWN in ROUNDUP.

Primer

=ROUND(2,348;2) vrne 2,35

=ROUND(-32,4834;3) vrne -32,483. Če želite videti izpisana vsa decimalna mesta, spremenite oblikovanje celice.

=ROUND(2,348;0) vrne 2.

=ROUND(2,5) vrne 3.

=ROUND(987,65;-2) vrne 1000.

ROUNDDOWN

Zaokroži število navzdol, proti nič, z določeno natančnostjo.

Skladnja

ROUNDDOWN(število; števec)

Vrne število, zaokroženo navzdol (proti nič) na števec decimalnih mest. Če števec izpustite ali ima vrednost nič, funkcija zaokroži na celoštevilčno vrednost. Če je števec negativno število, funkcija zaokroži navzdol na naslednjih 10, 100, 1000 itn.

Ta funkcija zaokroži proti nič. Poglejte si tudi ROUNDUP in ROUND.

Primer

=ROUNDDOWN(1,234;2) vrne 1,23.

=ROUNDDOWN(45,67;0) vrne 45.

=ROUNDDOWN(-45,67) vrne -45.

=ROUNDDOWN(987,65;-2) vrne 900.

COUNTIF

Vrne število celic, ki znotraj obsega celic izpolnjujejo določen pogoj.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v Orodja – Možnosti – LibreOffice Calc – Izračuni.

Skladnja

COUNTIF(obseg; pogoji)

Obseg je obseg, v katerem želimo uporabiti pogoje.

Pogoji vsebuje pogoje v obliki števila, izraza ali znakovnega niza. Ti pogoji določajo, katere celice se upoštevajo. Iskano besedilo lahko vnesete tudi v obliki regularnega izraza, npr. b.* za vse besede, ki se začnejo s črko b. Lahko označite tudi obseg celic, ki vsebuje iskalne pogoje. Če iščete črkovno besedilo, ga postavite v dvojne navednice.

Primer

A1:A10 je obseg celic, ki vsebuje števila od 2000 do 2009. Celica B1 vsebuje število 2006. V celico B2 vnesite formulo:

=COUNTIF(A1:A10;2006) – vrne 1

=COUNTIF(A1:A10;B1) – vrne 1

=COUNTIF(A1:A10;">=2006") - vrne 4

=COUNTIF(A1:A10;"<"&B1) – če B1 vsebuje 2006, vrne 6

=COUNTIF(A1:A10;C2), kjer celica C2 vsebuje besedilo >2006, prešteje število celic na območju A1:A10, ki so večje od 2006

Če želite prešteti samo negativna števila, uporabite =COUNTIF(A1:A10;"<0")

ROUNDUP

Zaokroži številko navzgor, stran od nič, na določeno natančnost.

Skladnja

ROUNDUP(število; števec)

Vrne število, zaokroženo navzgor (stran od nič) na števec decimalnih mest. Če števec izpustite ali ima vrednost nič, funkcija zaokroži na celoštevilčno vrednost. Če je števec negativno število, funkcija zaokroži navzdol na naslednje 10, 100, 1000 itn.

Ta funkcija zaokroži stran od nič. Poglejte si tudi ROUNDDOWN in ROUND.

Primer

=ROUNDUP(1,1111;2) vrne 1,12.

=ROUNDUP(1,2345;1) vrne 1,3.

=ROUNDUP(45,67;0) vrne 46.

=ROUNDUP(-45,67) vrne -46.

=ROUNDUP(987,65;-2) vrne 1000.

SIN

Vrne sinus podanega kota (v radianih).

Skladnja

SIN(število)

Vrne (trigonometrični) sinus števila, to je kot v radianih.

Če želite vrnjeno vrednost sinusa kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=SIN(PI()/2) vrne 1, kar je sinus PI/2 radianov.

=SIN(RADIANS(30)) vrne 0,5, sinus 30 stopinj.

SINH

Vrne hiperbolični sinus števila.

Skladnja

SINH(število)

Vrne hiperbolični sinus števila.

Primer

=SINH(0) vrne 0, kar je hiperbolični sinus 0.

SUM

Sešteje vsa števila v obsegu celic.

Skladnja

SUM(število1; število2; ...; število30)

Število 1 do števila 30 je največ 30 argumentov, katerih vsoto želimo izračunati.

Primer

Če v besedilne okvire 1; 2 in 3 vnesete števila 2; 3 in 4, je rezultat 9.

=SUM(A1;A3;B5) izračuna vsoto treh celic. =SUM (A1:E10) izračuna vsoto vseh celic v obsegu celic od A1 do E10.

Pogoji, med seboj povezani z AND, se lahko uporabijo s funkcijo SUM() na naslednji način:

Primer predpostavke: V tabelo ste vnesli račun. Stolpec A vsebuje datum računa, stolpec B pa zneske. Želite formulo, s katero bi lahko izračunali skupni znesek za le določen mesec, npr. le za obdobje >=2008-01-01 do <2008-02-01. Datumi obsegajo vrednosti A1:A40, zneski pa B1:B40. C1 vsebuje začetni datum (2008-01-01) računov, ki smo jih upoštevali, C2, ki vsebuje datum 2008-02-01, pa ni več vključen.

Vnesite naslednjo formulo kot matrično formulo:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Če želite to formulo vnesti kot matrično, pritisnite tipke dvigalka+krmilka+vnašalka, namesto da bi pritisnili le vnašalko, s čimer bi zaprli formulo. Formula se bo v oklepajih prikazala v vrstici Formula.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Formula temelji na dejstvu, da je rezultat primerjave 1, če je pogoj dosežen, in 0, če ni dosežen. Posamezen rezultat primerjave bo obravnavan kot polje in bo uporabljen v množenju matrike, na koncu bodo posamezne vrednosti seštete in podale rezultat – matriko.

SUMIF

Doda celice, ki so določene z danimi pogoji. Ta funkcija se uporablja za pregledovanje obsega, kadar iščete določeno vrednost.

Iskanje podpira regularne izraze. Vnesete lahko npr. »vse.*«, da najdete prvo mesto, kjer se nahaja »vse«, in kateremu sledi karkoli. Če želite iskati besedilo, ki je tudi običajen izraz, morate pred vsak znak vnesi znak \. Samodejno vrednotenje regularnega izraza lahko vklopite in izklopite v Orodja – Možnosti – LibreOffice Calc – Izračuni.

Skladnja

SUMIF(obseg; pogoji; obseg_vsote)

Obseg je obseg, v katerem želimo uporabiti pogoje.

Pogoji je celica, v kateri so prikazani iskalni pogoji, ali iskalni pogoji sami. Če so pogoji zapisani v formuli, morajo biti podani v dvojnih narekovajih.

Obseg_vsote je obseg, katerega vrednosti so seštete. Če ta parameter ni naveden, se seštejejo vrednosti v obsegu.

Note.png SUMIF podpira operatorja konkatenacije sklicev (~) le kot parameter pogoj, pa še to le, če ni podan neobvezni parameter obseg_vsote.

Primer

Če želite sešteti le negativna števila: =SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:10) – sešteje vrednosti v obsegu B1:B10 pod pogojem, da so ustrezne vrednosti v obsegu A1:A10 večje od 0.

Glejte tudi COUNTIF() za več primerov, ki jih lahko uporabite s funkcijo SUMIF().

TAN

Vrne tangens danega kota (v radianih).

Skladnja

TAN(število)

Vrne (trigonometrični) tangens števila, kot v radianih.

Če želite vrnjeno vrednost tangensa kota v stopinjah, uporabite funkcijo RADIANS.

Primer

=TAN(PI()/4) vrne 1, kar je tangens PI/4 radianov.

=TAN(RADIANS(45)) vrne 1, tangens 45 stopinj.

TANH

Vrne hiperbolični tangens števila.

Skladnja

TANH(število)

Vrne hiperbolični tangens števila.

Primer

=TANH(0) vrne 0, hiperbolični tangens 0.

SUBTOTAL

Izračuna delne vsote.Če obseg delne vsote že vsebuje, te v nadaljnih izračunih niso uporabljene. To funkcijo uporabite s samodejnimi filtri, če želite, da se upoštevajo le izbrani podatki.

Skladnja

SUBTOTAL(funkcija; obseg)

Funkcija je število, ki predstavlja eno od naslednjih funkcij:

Funkcija index Funkcija
1 AVERAGE
2 COUNT
3 COUNTA
4 MAX
5 MIN
6 PRODUCT
7 STDEV
8 STDEVP
9 SUM
10 VAR
11 VARP

Obseg je obseg celic, ki so vključene vanj.

Primer

Imate tabelo v celičnem obsegu A1:B5, ki vsebujejo mesta v stolpcu A in vzporedne številke v stolpcu B. Uporabili ste samodejni filter, tako da vidite le vrste, ki vsebujejo mesto Hamburg. Želite videti vsoto prikazanih številk, ki je le delna vsota izbranih vrst. V tem primeru je pravilna formula naslednja:

=SUBTOTAL(9;B2:B5)

EUROCONVERT

Pretvarja med vrednostmi v starih evropskih nacionalnih valutah in evrih.

Skladnja

EUROCONVERT(vrednost; "iz_valute"; "v_valuto", polna_natančnost, triangularna_natančnost)

Vrednost je količina denarnih enot valute za pretvorbo.

Iz_valute in v_valuto sta denarni enoti za pretvorbo iz prve v drugo. To mora biti besedilo, ki je uradna kratica valute (npr. »EUR« ali »SIT«). Menjalni tečaj (prikazan v evrih) je določila Evropska komisija.

Polna_natančnost je neobvezen parameter. Če je izpuščen ali False, je rezultat zaokrožen glede na decimalke parametra v_valuto. Če je polna_natančnost True, rezultat ni zaokrožen.

Triangularna_natančnost je neobvezen parameter. Če je triangularna_natančnost podana in je >=3, je vmesni rezultat triangularne konverzije (valuta1,EUR,valuta2) zaokrožen na to natančnost. Če je triangularna_natančnost izpuščena, vmesni rezultat ni zaokrožen. Tudi če je v_valuto enako »EUR«, je triangularna_natančnost uporabljena, kot da je triangulacija potrebna in da je bila pretvorba iz EUR v EUR izvršena.

Primeri

=EUROCONVERT(100;"SIT";"EUR") pretvori 100 slovenskih tolarjev v evre.

=EUROCONVERT(100;"EUR";"DEM") pretvori 100 evrov v nemške marke.

ODD

Zaokroži pozitivno število navzgor na najbližje liho celo število in negativno število navzdol na najbližje liho celo število.

Skladnja

ODD(število)

Vrne število, zaokroženo na naslednje višje liho celo število, stran od nič.

Primer

=ODD(1,2) vrne 3.

=ODD(1) vrne 1.

=ODD(0) vrne 1.

=ODD(-3,1) vrne -5.

ABS

Vrne absolutno vrednost števila.

Skladnja

ABS(število)

Število je število, katerega absolutno vrednost želimo izračunati. Absolutna vrednost števila je njegova vrednost brez predznaka +/-.

Primer

=ABS(-56) vrne 56.

=ABS(12) vrne 12.

=ABS(0) vrne 0.


Related Topics

Funkcije modula Calc po kategorijah v okviru wiki-pomoči LibreOffice