Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Fonctions mathématiques

From LibreOffice Help
Jump to: navigation, search

Cette catégorie contient les fonctions mathématiques de Calc. Pour ouvrir l'assistant Fonctions, choisissez Insertion - Fonction.

Contents

CONVERTIR

Convertit une valeur d'une unité de mesure en une autre unité de mesure. Les facteurs de conversion sont donnés dans une liste dans la configuration.

À un moment, la liste de facteurs de conversion incluait les monnaies anciennes européennes et l'Euro (voir les exemples ci-dessous). Nous vous suggérons d'utiliser la nouvelle fonction EUROCONVERT pour convertir ces monnaies.

Syntaxe

CONVERTIR(valeur;"texte";"texte")

Exemple

=CONVERTIR(100;"ATS";"EUR") renvoie la valeur en Euro de 100 shillings autrichiens.

=CONVERTIR(100;"EUR";"DEM") convertit 100 Euros en marks allemands.

PLANCHER.PRECIS

Arrondit un nombre par valeur inférieure au plus proche multiple de la précision, quelque soit le signe de la précision

Syntaxe

PLANCHER.PRECIS(Nombre ; Précision)

nombre est le nombre devant être arrondi.

Précision est la valeur au multiple de laquelle le nombre doit être arrondi par valeur inférieure.

Exemple

=PLANCHER.PRECIS(-11;-2) renvoie -12

PLANCHER

Arrondit un nombre au multiple significatif inférieur le plus proche.

Syntaxe

PLANCHER(nombre;précision;mode)

nombre est le nombre devant être arrondi.

précision est la valeur vers le multiple de laquelle le nombre est arrondi.

mode est une valeur facultative. Si la valeur mode est donnée et différente de zéro, et si nombre et précision sont négatifs, l'arrondi est donné en se basant sur la valeur absolue du nombre. Ce paramètre est ignoré lors de l'export vers MS Excel car Excel ne connaît pas de troisième paramètre.

Warning.png Si les deux paramètres nombre et précision sont négatifs et si la valeur mode est égale à zéro ou n'est pas spécifiée, alors les résultats dans LibreOffice Calc et Excel différeront après l'export. Si vous exportez la feuille de calcul vers Excel, utilisez mode=1 pour afficher les mêmes résultats dans Excel et dans Calc.

Exemple

=PLANCHER(-11;-2) renvoie -12

=PLANCHER(-11;-2;0) renvoie -12

=PLANCHER(-11;-2;1) renvoie -10

SIGNE

Renvoie le signe d'un nombre. Renvoie 1 si le nombre est positif, -1 si négatif et 0 si zéro.

Syntaxe

SIGNE(nombre)

nombre est le nombre dont le signe doit être déterminé.

Exemple

=SIGNE(3,4) renvoie 1.

=SIGNE(-4,5) renvoie -1.

ARRONDI.AU.MULTIPLE

Le résultat obtenu est le multiple entier le plus proche du nombre.

Syntaxe

ARRONDI.AU.MULTIPLE(nombre;multiple)

renvoie un nombre arrondit au multiple le plus proche de multiple.

Une implémentation alternative serait Multiple * ARRONDI(nombre/multiple).

Exemple

=ARRONDI.AU.MULTIPLE(15,5;3) renvoie 15, car 15,5 est plus près de 15 (= 3*5) que de 18 (= 3*6).

=ARRONDI.AU.MULTIPLE(1,4;0,5) renvoie 1,5 (= 0,5*3).

CSCH

Renvoie la cosécante hyperbolique d'un nombre.

Syntaxe

CSCH(nombre)

Renvoie la cosécante hyperbolique de nombre.

Exemple

=CSCH(1) renvoie approximativement 0,8509181282, la cosécante hyperbolique de 1.

SECH

Renvoie la sécante hyperbolique d'un nombre.

Syntaxe

SECH(nombre)

Renvoie la sécante hyperbolique de nombre.

Exemple

=SECH(0) renvoie 1, la sécante hyperbolique de 0.

CSC

Renvoie la cosécante de l'angle donné (en radians). La cosécante d'un angle est équivalente à 1 divisé par le sinus de cet angle

Syntaxe

CSC(nombre)

Renvoie la cosécante (trigonométrique) de nombre, l'angle en radians.

Pour renvoyer la cosécante d'un angle en degrés, utilisez la fonction RADIANS.

Exemples

=CSC(PI()/4) renvoie approximativement 1,4142135624, l'inverse du sinus de PI/4 radians.

=CSC(RADIANS(30)) renvoie 2, la cosécante de 30 degrés.

SEC

Renvoie la sécante d'un angle donné (en radians). La sécante d'un angle est équivalent à 1 divisé par le cosinus de cet angle

Syntaxe

SEC(nombre)

Renvoie la sécante (trigonométrique) de nombre, l'angle en radians.

Pour renvoyer la sécante d'un angle en degrés, utilisez la fonction RADIANS.

Exemples

=SEC(PI()/4) renvoie approximativement 1.4142135624, l'inverse du cosinus de PI/4 radians.

=SEC(RADIANS(60)) renvoie 2, la sécante de 60 degrés.

NB.VIDE

Renvoie le nombre de cellules vides.

Syntaxe

NB.VIDE(plage)

Renvoie le nombre de cellules vides dans la plage de cellule plage.

Exemple

=NB.VIDE(A1:B2) renvoie 4 si les cellules A1, A2, B1 et B2 sont toutes vides.

ACOS

Renvoie le cosinus trigonométrique inverse d'un nombre.

Syntaxe

ACOS(nombre)

Cette fonction renvoie le cosinus trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont le cosinus est nombre. L'angle renvoyé est entre 0 et PI.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

Exemple

=ACOS(-1) renvoie 3,14159265358979 (PI radians)

=DEGRES(ACOS(0,5)) renvoie 60. Le cosinus de 60 degrés est 0,5.

ACOSH

Renvoie le cosinus hyperbolique inverse d'un nombre.

Syntaxe

ACOSH(nombre)

La fonction renvoie le cosinus hyperbolique inverse de nombre, c'est à dire le nombre dont le cosinus hyperbolique est nombre.

Nombre doit être supérieur ou égal à 1.

Exemple

=ACOSH(1) renvoie 0.

=ACOSH(COSH(4)) renvoie 4.

RACINE

Renvoie la racine carrée positive d'un nombre.

Syntaxe

RACINE(nombre)

Renvoie la racine carrée positive de nombre.

nombre doit être positif.

Exemple

=RACINE(16) renvoie 4.

=RACINE(-16) renvoie une erreur argument invalide.

ACOT

Renvoie la cotangente inverse (l'arc cotangente) d'un nombre donné.

Syntaxe

ACOT(nombre)

Cette fonction renvoie la cotangente trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont la cotangente est nombre. L'angle renvoyé est entre 0 et PI.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

Exemple

=ACOT(1) renvoie 0,785398163397448 (PI/4 radians).

=DEGRES(ACOT(1)) renvoie 45. La tangente de 45 degrés est 1.

ACOTH

Renvoie la cotangente hyperbolique inverse du nombre donné.

Syntaxe

ACOTH(nombre)

Cette fonction renvoie la cotangente hyperbolique inverse de nombre, c'est à dire le nombre dont la cotangente hyperbolique est nombre.

Il résulte une erreur si le nombre est compris entre -1 et 1 inclus.

Exemple

=ACOTH(1,1) renvoie la cotangente hyperbolique inverse de 1,1, approximativement 1,52226.

ASIN

Renvoie le sinus trigonométrique inverse d'un nombre.

Syntaxe

ASIN(nombre)

Cette fonction renvoie le sinus trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont le sinus est nombre. L'angle renvoyé est entre -PI/2 et + PI/2.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

Exemple

=ASIN(0) renvoie 0.

=ASIN(1) renvoie 1,5707963267949 (PI/2 radians).

=DEGRES(ASIN(0,5)) renvoie 30. Le sinus de 30 degrés est 0,5.

ASINH

Renvoie le sinus hyperbolique inverse d'un nombre.

Syntaxe

ASINH(nombre)

Cette fonction renvoie le sinus hyperbolique inverse de nombre, c'est à dire le nombre dont le sinus hyperbolique est nombre.

Exemple

=ASINH(-90) renvoie approximativement -5,1929877.

=ASINH(SINH(4)) renvoie 4.

ATAN

Renvoie la tangente trigonométrique inverse d'un nombre.

Syntaxe

ATAN(nombre)

Cette fonction renvoie la tangente trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont la tangente est nombre. L'angle renvoyé est entre -PI/2 et PI/2.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

Exemple

=ATAN(1) renvoie 0,785398163397448 (PI/4 radians).

=DEGRES(ATAN(1)) renvoie 45. La tangente de 45 degrés est 1.

ATAN2

Renvoie la tangente trigonométrique inverse des coordonnées x et y spécifiées.

Syntaxe

ATAN2(nombre_X;nombre_Y)

nombreX est la valeur de la coordonnée x.

nombreY représente la valeur des coordonnées y.

ATAN2 renvoie la tangente trigonométrique inverse, c'est à dire l'angle (en radians) entre l'axe x et une ligne du point nombre_X, nombre_Y à l'origine. L'angle renvoyé est entre -PI et PI.

Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.

Exemple

=ATAN2(20;20) renvoie 0,785398163397448 (PI/4 radians).

=DEGRES(ATAN2(12,3;12,3)) renvoie 45. La tangente de 45 degrés est 1.

ATANH

Renvoie la tangente hyperbolique inverse d'un nombre.

Syntaxe

ATANH(nombre)

Cette fonction renvoie la tangente hyperbolique inverse de nombre, c'est à dire le nombre dont la tangente hyperbolique est nombre.

Le nombre doit obéir à la condition -1 < nombre < 1.

Exemple

=ATANH(0) renvoie 0.

COS

Renvoie le cosinus de l'angle donné (en radians).

Syntaxe

COS(nombre)

nombre est la valeur dont le cosinus est à calculer, l'angle en radians.

Pour renvoyer le cosinus d'un angle en degrés, utilisez la fonction RADIANS.

Exemples

=COS(PI()/2) renvoie 0, le cosinus de radians PI/2.

=COS(RADIANS(60)) renvoie 0,5, le cosinus de 60 degrés.

COSH

Renvoie le cosinus hyperbolique d'un nombre.

Syntaxe

COSH(nombre)

Renvoie le cosinus hyperbolique de nombre.

Exemple

=COSH(0) renvoie 1, le cosinus hyperbolique de 0.

COT

Renvoie la cotangente de l'angle donné (en radians).

Syntaxe

COT(nombre)

Renvoie la cotangente (trigonométrique) de nombre, l'angle est en radians.

Pour renvoyer la cotangente d'un angle en degrés, utilisez la fonction RADIANS.

La cotangente d'un angle est équivalente à 1 divisé par la tangente de cet angle.

Exemples :

=COT(PI()/4) renvoie 1, la cotangente de PI/4 radians.

=COT(RADIANS(45)) renvoie 1, la cotangente de 45 degrés.

RACINE.PI

Renvoie la racine carrée d'un nombre*PI.

Syntaxe

RACINE.PI(nombre)

Renvoie la racine carrée positive de (PI multiplié par nombre).

C'est l'équivalent de RACINE(PI()*nombre).

Exemple

=RACINE.PI(2) renvoie la racine carrée de (2PI), approximativement 2,506628.

COTH

Renvoie la cotangente hyperbolique d'un nombre donné (angle).

Syntaxe

COTH(nombre)

Renvoie la cotangente hyperbolique de nombre.

Exemple

=COTH(1) renvoie la cotangente hyperbolique de 1, approximativement 1,3130.

DEGRES

Convertit les radians en degrés.

Syntaxe

DEGRES(nombre)

nombre est l'angle en radians à convertir en degrés.

Exemple

=DEGRES(PI()) renvoie 180 degrés.

EXP

Renvoie e élevé à la puissance d'un nombre. La constante e a une valeur approximative de 2,71828182845904.

Syntaxe

EXP(nombre)

nombre est la puissance à laquelle e doit être élevé.

Exemple

=EXP(1) renvoie 2,71828182845904, la constante mathématique e à la précision de Calc.

FACT

Renvoie la factorielle d'un nombre.

Syntaxe

FACT(nombre)

Renvoie nombre!, la factorielle de nombre, calculée comme 1*2*3*4*...*nombre.

=FACT(0) renvoie 1 par définition.

La factorielle d'un nombre négatif renvoie l'erreur "argument invalide".

Exemple

=FACT(3) renvoie 6.

=FACT(0) renvoie 1.

ENT

Arrondit un nombre à l'entier immédiatement inférieur.

Syntaxe

ENT(nombre)

Renvoie nombre arrondi au nombre entier inférieur le plus proche.

Les nombres négatifs sont arrondis au nombre entier inférieur.

Exemple

=ENT(5,7) renvoie 5.

=ENT(-1,3) renvoie -2.

PAIR

Arrondit un nombre positif au nombre entier pair supérieur le plus proche et un nombre négatif au nombre entier pair inférieur le plus proche.

Syntaxe

PAIR(nombre)

Renvoie le nombre arrondi au plus proche nombre entier pair supérieur, éloigné de zéro.

Exemples

=PAIR(2,3) renvoie 4.

=PAIR(2) renvoie 2.

=PAIR(0) renvoie 0.

=PAIR(-0,5) renvoie -2.

PGCD

Renvoie le plus grand diviseur commun de plusieurs nombres entiers.

Le plus grand diviseur commun est l'entier positif le plus grand permettant de diviser sans reste chacun des entiers donnés.

Syntaxe

PGCD(nombre_entier_1;nombre_entier_2;...;nombre_entier_30)

nombre_entier1 à 30 représente jusqu'à 30 nombres entiers dont le plus grand diviseur commun doit être calculé.

Exemple

=PGCD(16;32;24) donne 8 comme résultat, parce que 8 est le plus grand nombre qui peut diviser 16, 24 et 32 sans reste.

=PGCD(B1:B3) où les cellules B1, B2, B3 contiennent 9, 12, 9 renvoie 3.

PGCD_ADD

Renvoie le plus grand diviseur commun d'une liste de nombres.

Note.png Les fonctions dont les noms se terminent par _ADD renvoient les mêmes résultats que les fonctions Microsoft Excel correspondantes. Pour obtenir des résultats conformes aux normes internationales, utilisez des fonctions sans _ADD. Par exemple, la fonction NO.SEMAINE calcule le numéro de la semaine d'une date donnée conformément à la norme internationale ISO 8601, alors que la fonction NO.SEMAINE_ADD renvoie le même numéro de semaine que Microsoft Excel.

Syntaxe

PGCD_ADD(nombre(s))

nombre(s) est une liste contenant jusqu'à 30 nombres.

Exemple

=PGCD_ADD(5;15;25) renvoie 5.

EST.PAIR

Renvoie VRAI si la valeur est un nombre entier pair ou FAUX si la valeur est impaire.

Syntaxe

ESTPAIR(valeur)

valeur est la valeur devant être vérifiée.

Si la valeur n'est pas un entier, tous les chiffres après le séparateur de décimales sont ignorés. Le signe de la valeur est également ignoré.

Exemple

=EST.PAIR(48) renvoie VRAI

=EST.PAIR(33) renvoie FAUX

=EST.PAIR(0) renvoie VRAI

=EST.PAIR(-2,1) renvoie VRAI

=EST.PAIR(3,999) renvoie FAUX

EST.IMPAIR

Renvoie VRAI si la valeur est impaire ou FAUX si le nombre est pair.

Syntaxe

EST.IMPAIR(valeur)

valeur est la valeur devant être vérifiée.

Si la valeur n'est pas un entier, tous les chiffres après le séparateur de décimales sont ignorés. Le signe de la valeur est également ignoré.

Exemple

=EST.IMPAIR(33) renvoie VRAI

=EST.IMPAIR(48) renvoie FAUX

=EST.IMPAIR(3,999) renvoie VRAI

=EST.IMPAIR(-3,1) renvoie VRAI

ALEA.ENTRE.BORNES

Renvoie un nombre entier aléatoire compris dans une plage spécifiée.

Syntaxe

ALEA.ENTRE.BORNES(minimum;maximum)

Renvoie un nombre entier aléatoire entre les nombres entiers minimum et maximum (tous deux inclusifs).

Cette fonction produit un nouveau nombre aléatoire chaque fois que Calc recalcule. Pour forcer Calc à recalculer manuellement, appuyez sur Maj+Ctrl+F9.

Pour générer des nombres aléatoires qui ne sont jamais recalculés, copiez les cellules contenant cette fonction et utilisez Édition - Collage spécial (avec Tout coller et Formules non cochées et Nombres coché).

Exemple

=ALEA.ENTRE.BORNES(20;30) renvoie un nombre entier entre 20 et 30.

PPCM

Renvoie le plus petit multiple commun d'un ou de plusieurs nombres entiers.

Syntaxe

PPCM(nombre_entier_1;nombre_entier_2;...;nombre_entier_30)

nombre_entier1 à 30 représente jusqu'à 30 nombres entiers dont le plus petit commun multiple doit être calculé.

Exemple

Si vous saisissez les nombres 512;1024 et 2000 dans les zones de textes de nombres entiers 1;2 et 3, 128000 sera le résultat renvoyé.

PPCM_ADD

Le résultat est le plus petit multiple commun d'une liste de nombres.

Note.png Les fonctions dont les noms se terminent par _ADD renvoient les mêmes résultats que les fonctions Microsoft Excel correspondantes. Pour obtenir des résultats conformes aux normes internationales, utilisez des fonctions sans _ADD. Par exemple, la fonction NO.SEMAINE calcule le numéro de la semaine d'une date donnée conformément à la norme internationale ISO 8601, alors que la fonction NO.SEMAINE_ADD renvoie le même numéro de semaine que Microsoft Excel.

Syntaxe

PPCM_ADD(nombre(s))

nombre(s) est une liste contenant jusqu'à 30 nombres.

Exemple

=PPCM_ADD(5;15;25) renvoie 75.

COMBIN

Renvoie le nombre de combinaisons pour des éléments sans répétition.

Syntaxe

COMBIN(nombre_1;nombre_2)

nombre_1 est le nombre d'éléments dans l'ensemble.

nombre_2 est le nombre d'éléments à choisir dans l'ensemble.

COMBIN renvoie le nombre de façon ordonné de choisir ces éléments. Par exemple, s'il y a 3 éléments A, B et C dans un ensemble, vous pouvez choisir 2 éléments de 3 façons différentes : AB, AC et BC.

COMBIN implémente la formule : nombre1!/(nombre2!*(nombre1-nombre2)!)

Exemple

=COMBIN(3;2) renvoie 3.

COMBINA

Renvoie le nombre de combinaisons pour un sous ensemble d'éléments incluant les répétitions.

Syntaxe

COMBINA(nombre_1;nombre_2)

nombre_1 est le nombre d'éléments dans l'ensemble.

nombre_2 est le nombre d'éléments à choisir dans l'ensemble.

COMBINA renvoie le nombre de façons uniques de choisir ces éléments, où l'ordre du choix est sans importance et les répétions d'éléments sont autorisées. Par exemple, s'il y a 3 éléments A, B et C dans un ensemble, vous pouvez choisir 2 éléments de 6 façons différentes, nommément : AA, AB, AC, BB, BC et CC.

COMBINA implémente la formule : (nombre1+nombre2-1)!/(nombre2!(nombre1-1)!)

Exemple

=COMBINA(3;2) renvoie 6.

TRONQUE

Tronque un nombre en supprimant ses décimales.

Syntaxe

TRONQUE(nombre;nombre)

Renvoie le nombre avec tout au plus le nombre de décimales. Les décimales en plus sont simplement supprimées, sans tenir compte du signe.

TRONQUE(nombre;0) se comporte comme ENT(nombre) pour les nombres positifs, mais arrondit effectivement autour de zéro pour les nombres négatifs.

Warning.png Le nombre de décimal visible du résultat est spécifié dans Outils - Options - LibreOffice Calc - Calcul.

Exemple

=TRONQUE(1,239;2) renvoie 1,23. Le 9 est perdu.

=TRONQUE(-1,234999;3) renvoie -1,234. Tous les 9 sont perdus.

LN

Renvoie le logarithme népérien d'un nombre, basé sur la constante e. La constante e a une valeur approximative de 2,71828182845904.

Syntaxe

LN(nombre)

nombre est la valeur dont vous souhaitez calculer le logarithme népérien.

Exemple

=LN(3) renvoie le logarithme népérien de 3 (approximativement 1,0986).

=LN(EXP(321)) renvoie 321.

LOG

Donne le logarithme d'un nombre dans la base spécifiée.

Syntaxe

LOG(nombre;base)

nombre correspond à la valeur dont le logarithme est à calculer.

base (falcultatif) est la base pour le calcul du logarithme. Si omis, c'est la Base 10 qui est supposée.

Exemple

=LOG(10;3) renvoie le logarithme de base 3 de 10 (approximativement 2,0959).

=LOG(7^4;7) renvoie 4.

LOG10

Renvoie le logarithme en base 10 d'un nombre.

Syntaxe

LOG10(nombre)

Renvoie le logarithme en base 10 du nombre.

Exemple

=LOG10(5) renvoie le logarithme en base 10 de 5 (approximativement 0,69897).

ISO.PLAFOND

Arrondit un nombre au plus proche multiple de la précision par valeur supérieure, quelque soit le signe de la précision

Syntaxe

ISO.PLAFOND(Nombre ; Précision)

Nombre (requis) est le nombre à arrondir par valeur supérieure.

Précision (optionel) est la valeur au multiple de laquelle le nombre doit être arrondi.

Exemple

=ISO.PLAFOND(-11;-2) renvoie -10

PLAFOND.PRECIS

Arrondit un nombre au multiple de la précision le plus proche, quelque que soit le signe de la précision

Syntaxe

PLAFOND.PRECIS(Nombre ; Précision)

Nombre (requis) est le nombre qui doit être arrondi.

Précision (optionel) est la valeur au multiple de laquelle le nombre doit être arrondi par valeur supérieure.

Exemple

=PLAFOND.PRECIS(-11;-2) renvoie -10

PLAFOND

Arrondit un nombre au multiple de la précision supérieur le plus proche.

Syntaxe

PLAFOND(nombre;précision;mode)

nombre correspond au nombre à arrondir.

précision est la valeur au multiple de laquelle le nombre doit être arrondi par valeur supérieure.

mode est une valeur facultative. Si la valeur de mode est donnée et différente de zéro, et si le nombre et la précision sont négatifs, alors l'arrondi est fait en se basant sur la valeur absolue du nombre. Ce paramètre est ignoré lors de l'export vers MS Excel car Excel ne connaît pas de troisième paramètre.

Warning.png Si le nombre et la précision sont négatifs et que la valeur mode est égale à 0 ou n'est pas donnée, les résultats de LibreOffice et Excel diffèreront après l'import. Si vous exportez un classeur vers Excel, utilisez mode=1 pour avoir les mêmes résultats dans Excel et dans Calc.

Exemple

=PLAFOND(-11;-2) renvoie -10

=PLAFOND(-11;-2;0) renvoie -10

=PLAFOND(-11;-2;1) renvoie -12

PI

Renvoie 3,14159265358979, la valeur de la constante mathématique PI à 14 décimales.

Syntaxe

PI()

Exemple

=PI() renvoie 3,14159265358979.

ALEA

Renvoie un nombre aléatoire compris entre 0 et 1.

Syntaxe

ALEA()

Cette fonction produit un nouveau nombre aléatoire à chaque fois que Calc recalculer. Pour forcer Calc à recalculer manuellement, appuyez sur F9.

Pour générer un nombre aléatoire qui n'est jamais recalculé, copiez les cellules contenant =ALEA() et utilisez Édition - Collage spécial (avec Tout coller et Formules non cochés et Nombres coché).

Exemple

=ALEA() renvoie un nombre entre 0 et 1.

MULTINOMIALE

Renvoie la factorielle de la somme des arguments divisée par le produit des factorielles des arguments.

Syntaxe

MULTINOMIALE(nombre(s))

nombre(s) est une liste contenant jusqu'à 30 nombres.

Exemple

=MULTINOMIALE(F11:H11) renvoie 1260, si F11 à H11 contiennent les valeurs 2, 3 et 4. Cela correspond à la formule =(2+3+4)!/(2!*3!*4!)

PUISSANCE

Renvoie un nombre élevé à un autre nombre.

Syntaxe

PUISSANCE (base; exposant)

Renvoie la base élevée à la puissance de exposant.

On obtiendra le même résultat en utilisant l'opérateur d'exposant ^ :

base^exposant

Exemple

=PUISSANCE(4;3) renvoie 64, qui correspond à 4 à la puissance 3.

=4^3 renvoie aussi 4 à la puissance 3.

SOMME.SERIES

Additionne les premiers termes d'une série de puissances

SOMME.SERIES(x;n;m;coefficients) = coefficient_1*x^n + coefficient_2*x^(n+m) + coefficient_3*x^(n+2m) +...+ coefficient_i*x^(n+(i-1)m)

Syntaxe

SOMME.SERIES(x;n;m;coefficients)

x est la valeur de saisie de la série de puissances.

n est la puissance initiale

m est l'incrément pour augmenter n

coefficients est une série de coefficients. Pour chaque coefficient, la somme des séries est étendue d'une section.

PRODUIT

Donne le produit de la multiplication de tous les nombres donnés comme arguments.

Syntaxe

PRODUIT(nombre_1;nombre_2;...;nombre_30)

nombre1 à 30 représente jusqu'à 30 arguments dont le produit doit être calculé.

PRODUIT renvoie nombre1 * nombre2 * nombre3 * ...

Exemple

=PRODUIT(2;3;4) renvoie 24.

SOMME.CARRES

Si vous souhaitez calculer la somme des carrés de ces nombres (dont le total correspondra aux carrés des arguments), saisissez-les dans les champs de texte.

Syntaxe

SOMMES.CARRES(nombre_1;nombre_2;...;nombre_30)

nombre_1 à 30 représente jusqu'à 30 arguments dont la somme des carrés doit être calculée.

Exemple

Si vous saisissez les nombres 2 ; 3 et 4 dans les zones de texte nombre 1; 2 et 3, 29 est le résultat renvoyé.

MOD

Renvoie le reste après la division d'un nombre.

Syntaxe

MOD(dividende;diviseur)

Pour les arguments de nombres entiers, cette fonction renvoie le dividende modulo le diviseur, c'est à dire le reste quand le dividende est divisé par le diviseur.

Cette fonction est implémentée comme dividende - diviseur * ENT(dividende/diviseur) , et cette formule donne un résultat même si les arguments ne sont pas des nombres entiers.

Exemple

=MOD(22;3) renvoie 1, le reste quand 22 est divisé par 3.

=MOD(11,25;2,5) renvoie 1,25.

QUOTIENT

Renvoie la partie entière d'une division.

Syntaxe

QUOTIENT(numérateur; dénominateurr)

Renvoie la partie du nombre entier du numérateur divisé par le dénominateur.

QUOTIENT est équivalent à ENT(numérateur/dénominateur), excepté qu'il peut renvoyer des erreurs avec des codes différents.

Exemple

=QUOTIENT(11;3) renvoie 3. Le reste 2 est perdu.

RADIANS

Convertit les degrés en radians.

Syntaxe

RADIANS(nombre)

nombre est l'angle en degrés à convertir en radians.

Exemple

=RADIANS(90) renvoie 1,5707963267949, qui est PI/2 à la précision de Calc.

ARRONDI

Arrondit un nombre à un nombre donné de décimales.

Syntaxe

ARRONDI(nombre;nombre)

Renvoie le nombre arrondi au nombre de décimales. Si le nombre est omis ou est zéro, la fonction arrondit au nombre entier le plus proche. Si le nombre est négatif, la fonction arrondit au plus proche de 10, 100, 1000, etc.

Cette fonction arrondit au nombre le plus proche. Voir ARRONDI.INF and ARRONDI.SUP pour des alternatives.

Exemple

=ARRONDI(2,348;2) renvoie 2,35

=ARRONDI(-32,4834;3) renvoie -32,483. Modifiez le format de la cellule pour afficher toutes les décimales.

=ARRONDI(2,348;0) renvoie 2.

=ARRONDI(2,5) renvoie 3.

=ARRONDI(987,65;-2) renvoie 1 000.

ARRONDI.INF

Arrondit, vers zéro, un nombre à une précision donnée.

Syntaxe

ARRONDI.INF(nombre;nb_décimales)

Renvoie le nombre arrondi par valeur inférieure (vers zéro) à nb_décimales décimales. Si nb_décimales est omis ou est zéro, la fonction arrondit au nombre entier inférieur. Si nb_décimales est négatif, la fonction arrondit par valeur inférieure au plus proche de 10, 100, 1000, etc.

Cette fonction arrondit vers zéro. Voir ARRONDI.SUP et ARRONDI pour des alternatives.

Exemple

=ARRONDI.INF(1,234;2) renvoie 1,23.

=ARRONDI.INF(45,67;0) renvoie 45.

=ARRONDI.INF(-45,67) renvoie -45.

=ARRONDI.INF(987,65;-2) renvoie 900.

NB.SI

Indique le nombre de cellules répondant à certains critères dans une plage de cellules donnée.

La fonction de recherche prend en charge les expressions régulières. Vous pouvez, par exemple, taper "tout.*" afin de rechercher la première occurrence de "tout" suivie d'un caractère. Si vous souhaitez rechercher un texte qui constitue également une expression régulière, vous devez insérer deux barres obliques inversées \ avant chaque caractère. Vous pouvez activer et désactiver l'évaluation automatique des expressions régulières dans Outils - Options - LibreOffice Calc - Calculer.

Syntaxe

NB.SI(plage;critère)

plage est la plage de cellules à laquelle les critères doivent être appliqués.

critère indique le critère sous la forme d'un nombre, d'une expression ou d'une chaîne de caractères. Ces critères déterminent quelles cellules sont comptées. Vous pouvez également saisir un texte de recherche sous la forme d'une expression régulière, i.e. b.* pour tous les mots commençant par b. Vous pouvez également indiquer une plage de cellules qui contient le critère de recherche. Si vous cherchez du texte littéral, entourez-le de guillemets doubles.

Exemple

A1:A10 est une plage de cellules contenant les nombres 2000 à 2009. La cellule B1 contient le nombre 2006. Dans la cellule B2, saisissez la formule :

=NB.SI(A1:A10;2006) - cela renvoie 1

=NB.SI(A1:A10;B1) - cela renvoie 1

=NB.SI(A1:A10;">=2006") - cela renvoie 4

=NB.SI(A1:A10;"<"&B1) - quand B1 contient 2006, cela renvoie 6

=NB.SI(A1:A10;C2) où la cellule C2 contient le texte >2006 compte le nombre de cellules dans la plage A1:A10 qui sont >2006

Pour compter uniquement des valeurs négatives : =NB.SI(A1:A10;"<0")

ARRONDI.SUP

Arrondit un nombre par valeur supérieure au nombre de décimales spécifié.

Syntaxe

ARRONDI.SUP(nombre;nb_décimales)

Renvoie le nombre arrondi par valeur supérieure (partant de zéro) à nb_décimales décimales. Si le nombre est omis ou est nul, la fonction arrondit au nombre entier supérieur. Si nb_décimales est négatif, la fonction arrondit par valeur supérieure au plus proche de 10, 100, 1 000, etc.

Cette fonction arrondit en s'éloignant de zéro. Voir ARRONDI.INF ET ARRONDI pour des alternatives.

Exemple

=ARRONDI.SUP(1,1111;2) renvoie 1,12.

=ARRONDI.SUP(1,2345;1) renvoie 1,3.

=ARRONDI.SUP(45,67;0) renvoie 46.

=ARRONDI.SUP(-45,67) renvoie -46.

=ARRONDI.SUP(987,65;-2) renvoie 1 000.

SIN

Renvoie le sinus du nombre donné (angle).

Syntaxe

SIN(nombre)

Renvoie le sinus (trigonométrique) de nombre, l'angle est en radians.

Pour renvoyer le sinus d'un angle en degrés, utilisez la fonction RADIANS.

Exemple

=SIN(PI()/2) renvoie 1, le sinus de PI/2 radians.

=SIN(RADIANS(30)) renvoie 0,5, le sinus de 30 degrés.

SINH

Renvoie le sinus hyperbolique d'un nombre.

Syntaxe

SINH(nombre)

Renvoie le sinus hyperbolique de Nombre.

Exemple

=SINH(0) renvoie 0, le sinus hyperbolique de 0.

SOMME

Additionne tous les nombres d'une plage de cellules.

Syntaxe

SOMME(nombre_1;nombre_2;...;nombre_30)

nombre_1 à nombre30 représente jusqu'à 30 arguments dont la somme doit être calculée.

Exemple

Si vous saisissez les nombres 2 ; 3 et 4 dans la zone de texte nombre 1 ; 2 et 3, 9 sera le résultat renvoyé.

=SOMME(A1;A3;B5) calcule la somme des trois cellules. =SOMME(A1:E10) calcule la somme de toutes les cellules de la plage A1 à E10.

Avec la fonction SOMME(), vous pouvez utiliser des conditions reliées par ET de la manière suivante :

Par exemple : vous avez saisi des factures dans une table. La colonne A contient la valeur de date de la facture, la colonne B contient le montant. Vous souhaitez trouver une formule que vous pourrez utiliser pour renvoyer le total des montants uniquement pour un mois spécifique, i.e. seul le montant pour la période du 2008-01-01 inclus au 2008-02-01 exclus. La plage des valeurs de date est A1:A40, la plage contenant les montants devant être totalisés est B1:B40. C1 contient la date de départ, 2008-01-01, des factures qui doivent être incluses et C2 la date,2008-02-01, qui n'est plus incluse.

Saisissez la formule de matrice suivante :

=SOMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Pour que la formule soit bien interprétée comme une formule de matrice, vous devez la saisir en appuyant sur les touches Maj+Ctrl+Entrée, et non simplement en appuyant sur la touche Entrée. La formule s'affiche alors entre accolades dans la barre de formule.

{=SOMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

La formule est basée sur le fait que le résultat d'une comparaison est 1 si le critère est rencontré et 0 s'il ne l'est pas. Les résultats de la comparaison individuelle seront traités comme une matrice et utilisés dans la multiplication matricielle et, à la fin, les valeurs individuelles seront totalisées pour donner la matrice de résultat.

SOMME.SI

Ajoute les cellules spécifiées par un critère donné. Vous pouvez utiliser cette fonction pour rechercher une valeur donnée dans une plage.

La fonction de recherche prend en charge les expressions régulières. Vous pouvez, par exemple, taper "tout.*" afin de rechercher la première occurrence de "tout" suivie d'un caractère. Si vous souhaitez rechercher un texte qui constitue également une expression régulière, vous devez insérer deux barres obliques inversées \ avant chaque caractère. Vous pouvez activer et désactiver l'évaluation automatique des expressions régulières dans Outils - Options - LibreOffice Calc - Calculer.

Syntaxe

SOMME.SI(plage;critère;plage_de_somme)

plage est la plage de cellules à laquelle les critères doivent être appliqués.

critère correspond à la cellule dans laquelle s'affiche le critère de recherche, ou au critère lui-même. Si le critère est écrit dans la formule, il doit être délimité par des guillemets.

plage_de_somme est la plage à partir de laquelle les valeurs sont additionnées. Si ce paramètre n'a pas été indiqué, les valeurs trouvées dans la plage sont additionnées.

Note.png SOMME.SI prend en charge l'opérateur de concaténation de référence (~) seulement dans le paramètre critère et seulement si le paramètre facultatif plage_somme n'est pas donné.

Exemple

Pour additionner uniquement des valeurs négatives : =SOMME.SI(A1:A10;"<0")

=SOMME.SI(A1:A10;">0";B1:10) - additionne les valeurs de la plage B1:B10 seulement si les valeurs correspondantes dans la plage A1:A10 sont >0.

Pour des exemples de syntaxe supplémentaires utilisables avec SOMME.SI(), voir NB.SI().

TAN

Renvoie la tangente de l'angle donné (en radians).

Syntaxe

TAN(nombre)

Renvoie la tangente (trigonométrique) de Nombre, l'angle est en radians.

Pour renvoyer la tangente d'un angle en degrés, utilisez la fonction RADIANS.

Exemple

=TAN(PI()/4) renvoie 1, la tangente de PI/4 radians.

=TAN(RADIANS(45)) renvoie 1, la tangente de 45 degrés.

TANH

Renvoie la tangente hyperbolique d'un nombre.

Syntaxe

TANH(nombre)

Renvoie la tangente hyperbolique de Nombre.

Exemple

=TANH(0) renvoie 0, la tangente hyperbolique de 0.

SOUS.TOTAL

Calcule les sous-totaux. Si une plage donnée contient déjà des sous-totaux, ceux-ci ne sont pas utilisés pour des calculs ultérieurs. Pour que le calcul ne porte que sur les enregistrements filtrés, associez cette fonction aux AutoFiltres.

Syntaxe

SOUS.TOTAL(fonction;plage)

fonction est un nombre qui représente l'une des fonctions suivantes :

Index de fonctions Fonction
1 MOYENNE
2 NB
3 NBVAL
4 MAX
5 MIN
6 PRODUIT
7 ECARTYPE
8 ECARTYPEP
9 SOMME
10 VAR
11 VAR.P

plage correspond à la plage dont les cellules sont incluses.

Exemple

Les cellules A1:B5 affichent un tableau répertoriant des villes dans la colonne A et des chiffres dans la colonne B. Vous appliquez un AutoFiltre vous permettant de ne visualiser que les lignes citant la ville de Hambourg. Vous souhaitez obtenir la somme des chiffres affichés, c'est-à-dire uniquement le sous-total des lignes après filtrage. Vous devez alors saisir la formule suivante :

=SOUS.TOTAL(9;B2:B5)

EUROCONVERT

Cette fonction convertit les anciennes monnaies nationales européennes de et vers l'Euro.

Syntaxe

EUROCONVERT(Valeur;"de_monnaie";"en_monnaie",précision_complète,précision_triangulation)

valeur est le montant de la monnaie à convertir.

de_monnaie et en_monnaie sont les unités monétaires à convertir de et en respectivement. Cela doit être du texte, l'abréviation officielle de la monnaie (par exemple "EUR"). Le taux de conversion (affiché en euro) a été fixé par la Commission Européenne.

Précision_complète est facultatif. Si omis ou faux, le résultat est arrondi en fonction des décimales de En monnaie. Si Précision_complète est vrai, le résultat n'est pas arrondi.

Précision_triangulation est facultatif. Si Précision_triangulation est donné et >=3, le résultat intermédiaire d'une conversion triangulaire (monnaie1,EUR,monnaie2) est arrondi à cette précision. Si Précision_triangulation est omis, le résultat intermédiaire n'est pas arrondi. De même, si la monnaie est "EUR", Précision_triangulation est utilisé comme si la triangulation était nécessaire et la conversion de EUR en EUR était appliquée.

Exemples

=EUROCONVERT(100;"ATS";"EUR") convertit 100 shillings autrichiens en euros.

=EUROCONVERT(100;"EUR";"DEM") convertit 100 euros en marks allemands.

IMPAIR

Arrondit un nombre positif au nombre entier impair supérieur le plus proche, et un nombre négatif au nombre entier impair inférieur le plus proche.

Syntaxe

IMPAIR(nombre)

Renvoie le nombre arrondi au plus proche nombre entier impair supérieur, éloigné de zéro.

Exemple

=IMPAIR(1,2) renvoie 3.

=IMPAIR(1) renvoie 1.

=IMPAIR(0) renvoie 1.

=IMPAIR(-3,1) renvoie -5.

ABS

Renvoie la valeur absolue d'un nombre.

Syntaxe

ABS(nombre)

nombre est le nombre dont la valeur absolue est à calculer. La valeur absolue d'un nombre est sa valeur sans le signe +/-.

Exemple

=ABS(-56) renvoie 56.

=ABS(12) renvoie 12.

=ABS(0) renvoie 0.


Related Topics

Fonctions Calc par catégories dans le wiki de l'aide LibreOffice