Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Funcions matemàtiques

From LibreOffice Help
Jump to: navigation, search

Aquesta categoria conté les funcions matemàtiques del Calc. Per obrir l'Auxiliar de funcions, trieu Insereix - Funció.

Contents

CONVERTEIX

Converteix un valor d'una unitat de mesura en una altra. Els factors de conversió es mostren en una llista a la configuració.

Anteriorment, la llista de factors de conversió incloïen les monedes antigues europees i l'euro (vegeu els exemples següents). És recomanable utilitzar la funció nova CONVERSIOEURO per convertir aquestes monedes.

Sintaxi

CONVERTEIX(Valor;"Text";"Text")

Exemple

=CONVERTEIX(100;"ATS";"EUR") retorna el valor en euros de 100 xílings austríacs.

=CONVERTEIX(100;"EUR";"DEM") converteix 100 euros en marcs alemanys.

ARRODMULTINF.PRECIS

Rounds a number down to the nearest multiple of Significance, regardless of sign of Significance

Sintaxi

ARRODMULTINF.PRECIS(Nombre; Importància)

Nombre és el nombre que s'ha d'arrodonir a la baixa.

Importància és el valor al múltiple del qual s'ha d'arrodonir a la baixa el nombre.

Exemple

=ARRODMULTINF.PRECIS( -11;-2) retorna -12

ARRODMULTINF

Arrodoneix un nombre a la baixa cap al múltiple més proper d'Importància.

Sintaxi

ARRODMULTINF(Nombre; Importància; Mode)

Nombre és el nombre que s'ha d'arrodonir a la baixa.

Importància és el valor al múltiple del qual s'ha d'arrodonir a la baixa el nombre.

Mode és un valor opcional. Si s'indica el valor Mode i no és igual a zero, i si Nombre i Importància són negatius, s'arrodoneix en funció del valor absolut del nombre. Quan s'exporta al MS Excel, s'ignora aquest paràmetre perquè l'Excel no reconeix cap tercer paràmetre.

Warning.png Si els paràmetres Nombre i Importància són negatius i el valor Mode és igual a zero o no s'indica, els resultats del LibreOffice i de l'Excel seran diferents després de l'exportació. Si exporteu el full de càlcul a l'Excel, utilitzeu Mode=1 per veure els mateixos resultats a l'Excel i al Calc.

Exemple

=ARRODMULTINF( -11;-2) retorna -12.

=ARRODMULTINF( -11;-2;0) retorna -12.

=ARRODMULTINF( -11;-2;1) retorna -10.

SIGNE

Retorna el signe d'un nombre. Retorna 1 si el nombre és positiu, -1 si és negatiu i 0 si és zero.

Sintaxi

SIGNE(Nombre)

Nombre és el nombre del qual es determinarà el signe.

Exemple

=SIGNE(3,4) retorna 1.

=SIGNE(-4,5) retorna -1.

ARRODM

Retorna un nombre arrodonit al múltiple més proper d'un altre nombre.

Sintaxi

ARRODM(Nombre; Múltiple)

Retorna el Nombre arrodonit al múltiple més proper de Múltiple.

Una implementació alternativa seria Múltiple * ARROD(Nombre/Múltiple).

Exemple

=ARRODM(15,5;3) retorna 15, ja que 15,5 és més proper a 15 (= 3*5) que a 18 (= 3*6).

=ARRODM(1.4;0,5) retorna 1,5 (= 0,5*3).

CSCH

Retorna la cosecant hiperbòlica d'un nombre.

Sintaxi

CSCH(Nombre)

Retorna la cosecant hiperbòlica d'un nombre.

Exemple

=CSCH(1) retorna aproximadament 0,8509181282, la cosecant hiperbòlica d'1.

SECH

Retorna la secant hiperbòlica d'un nombre.

Sintaxi

SECH(Nombre)

Retorna la secant hiperbòlica d'un nombre.

Exemple

=SECH(0) retorna 1, la secant hiperbòlica de 0.

CSC

Retorna la cosecant de l'angle indicat (en radians). La cosecant d'un angle és equivalent a 1 dividit entre el sinus d'aquest angle

Sintaxi

CSC(Nombre)

Retorna la cosecant (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la cosecant d'un angle en graus, utilitzeu la funció RADIANS.

Exemples

=CSC(PI()/4) retorna aproximadament 1,4142135624, la inversa del sinus de PI/4 radians.

=CSC(RADIANS(30)) retorna 2, la cosecant de 30 graus.

SEC

Retorna la secant de l'angle indicat (en radians). La secant d'un angle és equivalent a 1 dividit entre el cosinus d'aquest angle

Sintaxi

SEC(Nombre)

Retorna la secant (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la secant d'un angle en graus, utilitzeu la funció RADIANS.

Exemples

=SEC(PI()/4) retorna aproximadament 1,4142135624, la inversa del cosinus de PI/4 radians.

=SEC(RADIANS(60)) retorna 2, la secant de 60 graus.

COMPTABUIDES

Retorna el nombre de cel·les buides.

Sintaxi

COMPTABUIDES(Interval)

Retorna el nombre de cel·les buides que hi ha a l'interval de cel·les Interval.

Exemple

=COMPTABUIDES(A1:B2) retorna 4 si les cel·les A1, A2, B1 i B2 són buides.

ACOS

Retorna el cosinus trigonomètric invers d'un nombre.

Sintaxi

ACOS(Nombre)

Aquesta funció retorna el cosinus trigonomètric invers de Nombre, és a dir, l'angle (en radians) el cosinus del qual és Nombre. L'angle que es retorna es troba entre 0 i PI.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Exemple

=ACOS(-1) retorna 3,14159265358979 (PI radians).

=GRAUS(ACOS(0,5)) retorna 60. El cosinus de 60 graus és 0,5.

ACOSH

Retorna el cosinus hiperbòlic invers d'un nombre.

Sintaxi

ACOSH(Nombre)

Aquesta funció retorna el cosinus hiperbòlic invers de Nombre, és a dir, el nombre el cosinus hiperbòlic del qual és Nombre.

El nombre ha de ser més gran o igual a 1.

Exemple

=ACOSH(1) retorna 0.

=ACOSH(COSH(4)) retorna 4.

ARRELQ

Retorna l'arrel quadrada positiva d'un nombre.

Sintaxi

ARRELQ(Nombre)

Retorna l'arrel quadrada positiva de Nombre.

El nombre ha de ser positiu.

Exemple

=ARRELQ(16) retorna 4.

=ARRELQ(-16) retorna l'error: l'argument no és vàlid.

ACOT

Retorna la cotangent inversa (l'arc cotangent) del nombre donat.

Sintaxi

ACOT(Nombre)

Aquesta funció retorna la cotangent trigonomètrica inversa de Nombre, és a dir, l'angle (en radians) la cotangent del qual és Nombre. L'angle que es retorna es troba entre 0 i PI.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Exemple

=ACOT(1) retorna 0,785398163397448 (PI/4 radians).

=GRAUS(ACOT(1)) retorna 45. La tangent de 45 graus és 1.

ACOTH

Retorna la cotangent hiperbòlica inversa del nombre indicat.

Sintaxi

ACOTH(Nombre)

Aquesta funció retorna la cotangent hiperbòlica inversa de Nombre, que és el nombre la cotangent hiperbòlica del qual és Nombre.

Si el nombre es troba entre -1 i 1 (inclosos), la funció retorna un error.

Exemple

=ACOTH(1,1) retorna la cotangent hiperbòlica inversa d'1,1; aproximadament, 1,52226.

ASIN

Retorna el sinus trigonomètric invers d'un nombre.

Sintaxi

ASIN(Nombre)

Aquesta funció retorna el sinus trigonomètric invers de Nombre, és a dir, l'angle (en radians) el sinus del qual és Nombre. L'angle que es retorna es troba entre -PI/2 i +PI/2.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Exemple

=ASIN(0) retorna 0.

=ASIN(1) retorna 1,5707963267949 (PI/2 radians).

=GRAUS(ASIN(0,5)) retorna 30. El sinus de 30 graus és 0,5.

ASINH

Retorna el sinus hiperbòlic invers d'un nombre.

Sintaxi

ASINH(Nombre)

Aquesta funció retorna el sinus hiperbòlic invers de Nombre, que és el nombre el sinus hiperbòlic del qual és Nombre.

Exemple

=ASINH(-90) retorna aproximadament -5,1929877.

=ASINH(SINH(4)) retorna 4.

ATAN

Retorna la tangent trigonomètrica inversa d'un nombre.

Sintaxi

ATAN(Nombre)

Aquesta funció retorna la tangent trigonomètrica inversa de Nombre, que és l'angle (en radians) la tangent del qual és Nombre. L'angle que es retorna és entre -PI/2 i PI/2.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Exemple

=ATAN(1) retorna 0,785398163397448 (PI/4 radians).

=GRAUS(ATAN(1)) retorna 45. La tangent de 45 graus és 1.

ATAN2

Retorna la tangent trigonomètrica inversa de les coordenades x i y que s'han indicat.

Sintaxi

ATAN2(NombreX; NombreY)

NombreX és el valor de la coordenada x.

NombreY és el valor de la coordenada y.

ATAN2 retorna la tangent trigonomètrica inversa, és a dir, l'angle (en radians) entre l'eix x i una línia des del punt NombreX, NombreY a l'origen. L'angle que es retorna es troba entre -PI i PI.

Per calcular l'angle en graus, utilitzeu la funció GRAUS.

Exemple

=ATAN2(20;20) retorna 0,785398163397448 (PI/4 radians).

=GRAUS(ATAN2(12,3;12,3)) retorna 45. La tangent de 45 graus és 1.

ATANH

Retorna la tangent hiperbòlica inversa d'un nombre.

Sintaxi

ATANH(Nombre)

Aquesta funció retorna la tangent hiperbòlica inversa de Nombre, és a dir, el nombre la tangent hiperbòlica del qual és Nombre.

El nombre ha de complir la condició -1 < nombre < 1.

Exemple

=ATANH(0) retorna 0.

COS

Retorna el cosinus de l'angle que s'ha indicat (en radians).

Sintaxi

COS(Nombre)

Retorna el cosinus (trigonomètric) de Nombre, l'angle en radians.

Per calcular el cosinus d'un angle en graus, utilitzeu la funció RADIANS.

Exemples

=COS(PI()/2) retorna 0, el cosinus de PI/2 radians.

=COS(RADIANS(60)) retorna 0,5, el cosinus de 60 graus.

COSH

Retorna el cosinus hiperbòlic d'un nombre.

Sintaxi

COSH(Nombre)

Retorna el cosinus hiperbòlic d'un Nombre.

Exemple

=COSH(0) retorna 1, el cosinus hiperbòlic de 0.

COT

Retorna la cotangent de l'angle indicat (en radians).

Sintaxi

COT(Nombre)

Retorna la cotangent (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la cotangent d'un angle en graus, utilitzeu la funció RADIANS.

La cotangent d'un angle és equivalent a 1 dividit entre la tangent d'aquest angle.

Exemples:

=COT(PI()/4) retorna 1, la cotangent de PI/4 radians.

=COT(RADIANS(45)) retorna 1, la cotangent de 45 graus.

ARRELQPI

Retorna l'arrel quadrada de (PI vegades un nombre).

Sintaxi

ARRELQPI(Nombre)

Retorna l'arrel quadrada positiva de (PI multiplicat per Nombre).

Això equival a ARRELQ(PI()*Nombre).

Exemple

=ARRELQPI(2) retorna l'arrel quadrada de (2PI), aproximadament 2,506628.

COTH

Retorna la cotangent hiperbòlica d'un nombre donat (angle).

Sintaxi

COTH(Nombre)

Retorna la cotangent hiperbòlica d'un Nombre.

Exemple

=COTH(1) retorna la cotangent hiperbòlica d'1, aproximadament 1,3130.

GRAUS

Converteix radians a graus.

Sintaxi

GRAUS(Nombre)

Nombre és l'angle en radians que s'ha de convertir en graus.

Exemple

=GRAUS(PI()) retorna 180 graus.

EXP

Retorna e elevada a la potència d'un nombre. La constant e té un valor aproximat de 2,71828182845904.

Sintaxi

EXP(Nombre)

Nombre és la potència a la qual s'eleva e.

Exemple

=EXP(1) retorna 2,71828182845904, la constant matemàtica e a la precisió del Calc.

FACT

Retorna el factorial d'un nombre.

Sintaxi

FACT(Nombre)

Retorna Nombre!, el factorial de Nombre, calculat com a 1*2*3*4* ... * Nombre.

=FACT(0) retorna 1 per definició.

El factorial d'un nombre negatiu retorna l'error "L'argument no és vàlid".

Exemple

=FACT(3) retorna 6.

=FACT(0) retorna 1.

ENT

Arrodoneix un nombre a la baixa a l'enter més proper.

Sintaxi

ENT(Nombre)

Retorna el Nombre arrodonit a la baixa cap a l'enter més proper.

Els nombres negatius s'arrodoneixen a l'enter inferior.

Exemple

=ENT(5,7) retorna 5.

=ENT(-1,3) retorna -2.

PARELL

Arrodoneix un nombre positiu cap a l'enter parell superior i un nombre negatiu cap a l'enter parell inferior.

Sintaxi

PARELL(Nombre)

Retorna Nombre arrodonit cap a l'enter parell superior, allunyat de zero.

Exemples

=PARELL(2,3) retorna 4.

=PARELL(2) retorna 2.

=PARELL(0) retorna 0.

=PARELL(-0,5) retorna -2.

MCD

Retorna el màxim comú divisor de dos enters o més.

El màxim comú divisor és l'enter positiu més gran que divideix, sense residu, cadascun dels enters indicats.

Sintaxi

MCD(Enter1; Enter2; ...; Enter30)

Enter1 a 30 són fins a 30 enters dels quals s'ha de calcular el màxim comú divisor.

Exemple

=MCD(16;32;24) dóna el resultat 8 perquè 8 és el nombre més gran que pot dividir 16, 24 i 32 sense residu.

=MCD(B1:B3) on les cel·les B1, B2 i B3 contenen 9, 12 i 9 dóna 3.

MCD_ADD

El resultat és el màxim comú divisor d'una llista de nombres.

Note.png Les funcions el nom de les quals acaba amb _ADD retornen els mateixos resultats que les funcions corresponents del Microsoft Excel. Per obtenir resultats basats en els estàndards internacionals, utilitzeu les funcions que no acaben amb _ADD. Per exemple, la funció NUMSETMANA calcula el número de setmana d'una data determinada d'acord amb l'estàndard internacional ISO 8601, mentre que NUMSETMANA_ADD retorna el mateix número de setmana que el Microsoft Excel.

Sintaxi

MCD_ADD(Nombre(s))

Nombre(s) és una llista de fins a 30 nombres.

Exemple

=MCD_ADD(5;15;25) retorna 5.

ESPARELL

Retorna CERT si el valor és un enter parell, o FALS si el valor és senar.

Sintaxi

ESPARELL(Valor)

Valor és el valor que s'ha de comprovar.

Si Valor no és un enter, s'ignoren tots els dígits situats després del punt decimal. També s'ignora el signe de Valor.

Exemple

=ESPARELL(48) retorna CERT.

=ESPARELL(33) retorna FALS.

=ESPARELL(0) retorna CERT.

=ESPARELL(-2,1) retorna CERT.

=ESPARELL(3,999) retorna FALS.

ESSENAR

Retorna CERT si el valor és senar; si el nombre és parell, retorna FALS.

Sintaxi

ESSENAR(Valor)

Valor és el valor que s'ha de comprovar.

Si Valor no és un enter, s'ignoren tots els dígits situats després del punt decimal. També s'ignora el signe de Valor.

Exemple

=ESSENAR(33) retorna CERT.

=ESSENAR(48) retorna FALS.

=ESSENAR(3,999) retorna CERT.

=ESSENAR(-3,1) retorna CERT.

ALEATENTRE

Retorna un nombre enter aleatori dins d'un interval determinat.

Sintaxi

ALEATENTRE(Inferior; Superior)

Retorna un nombre enter aleatori entre els enters Inferior i Superior (inclosos).

Aquesta funció genera un nombre aleatori nou cada vegada que el Calc recalcula. Per forçar el Calc perquè recalculi de manera manual, premeu Maj+Ctrl+F9.

Per generar nombres aleatoris que no es tornin a calcular, copieu les cel·les que contenen aquesta funció i utilitzeu Edita - Enganxament especial (amb les opcions Enganxa-ho tot i Fórmules desactivades, i l'opció Nombres activada).

Exemple

=ALEATENTRE(20;30) retorna un enter entre 20 i 30.

MCM

Retorna el mínim comú múltiple d'un enter o més d'un.

Sintaxi

MCM(Enter1; Enter2; ...; Enter30)

Enter1 a 30 són fins a 30 enters dels quals s'ha de calcular el mínim comú múltiple.

Exemple

Si introduïu els nombres 512, 1024 i 2000 en els quadres de text Enter 1, 2 i 3, el resultat serà 128.000.

MCM_ADD

El resultat d'aquesta funció és el mínim comú múltiple d'una llista de nombres.

Note.png Les funcions el nom de les quals acaba amb _ADD retornen els mateixos resultats que les funcions corresponents del Microsoft Excel. Per obtenir resultats basats en els estàndards internacionals, utilitzeu les funcions que no acaben amb _ADD. Per exemple, la funció NUMSETMANA calcula el número de setmana d'una data determinada d'acord amb l'estàndard internacional ISO 8601, mentre que NUMSETMANA_ADD retorna el mateix número de setmana que el Microsoft Excel.

Sintaxi

MCM_ADD(Nombre(s))

Nombre(s) és una llista de fins a 30 nombres.

Exemple

=MCM_ADD(5;15;25) retorna 75.

COMBINAT

Retorna el nombre de combinacions per a elements sense repetició.

Sintaxi

COMBINAT(Comptatge1; Comptatge2)

Comptatge1 és el nombre d'elements del conjunt.

Comptatge2 és el nombre d'elements que s'han de triar del conjunt.

COMBINAT retorna el nombre de maneres ordenades de triar aquests elements. Per exemple, si hi ha 3 elements A, B i C en un conjunt, podeu triar 2 elements de tres maneres diferents: AB, AC i BC.

COMBINAT implementa la fórmula següent: Comptatge1!/(Comptatge2!*(Comptatge1-Comptatge2)!).

Exemple

=COMBINAT(3;2) retorna 3.

COMBINATA

Retorna el nombre de combinacions d'un subconjunt d'elements, incloses les repeticions.

Sintaxi

COMBINATA(Comptatge1; Comptatge2)

Comptatge1 és el nombre d'elements del conjunt.

Comptatge2 és el nombre d'elements que s'han de triar del conjunt.

COMBINATA retorna el nombre de maneres úniques de triar aquests elements, on l'ordre de tria és irrellevant i es permet la repetició d'elements. Per exemple, si hi ha 3 elements A, B i C en un conjunt, podeu triar 2 elements de sis maneres diferents: AA, AB, AC, BB, BC i CC.

COMBINATA implementa la fórmula següent: (Comptatge1+Comptatge2-1)! / (Comptatge2!(Comptatge1-1)!)

Exemple

=COMBINATA(3;2) retorna 6.

TRUNCA

Trunca un nombre mitjançant l'eliminació dels decimals.

Sintaxi

TRUNCA(Nombre; Comptatge)

Retorna el Nombre amb, com a màxim, els decimals de Comptatge. Els decimals que sobren s'eliminen, independentment del signe que tinguin.

TRUNCA(Nombre; 0) es comporta com ENT(Nombre) amb els nombres positius, però arrodoneix cap a zero els nombres negatius.

Warning.png El nombre de decimals visibles del resultat s'indica a Eines - Opcions - LibreOffice Calc - Càlcul.

Exemple

=TRUNCA(1,239;2) retorna 1,23. El 9 es perd.

=TRUNCA(-1,234999;3) retorna -1,234. Tots els 9 es perden.

LN

Retorna el logaritme natural a partir de la constant e d'un nombre. La constant e té un valor aproximat de 2,71828182845904.

Sintaxi

LN(Nombre)

Nombre és el valor del qual s'ha de calcular el logaritme natural.

Exemple

=LN(3) retorna el logaritme natural de 3 (aproximadament 1,0986).

=LN(EXP(321)) retorna 321.

LOG

Retorna el logaritme d'un nombre a la base indicada.

Sintaxi

LOG(Nombre; Base)

Nombre és el valor el logaritme del qual s'ha de calcular.

Base (opcional) és la base per al càlcul del logaritme. Si s'omet, s'utilitzarà la base 10.

Exemple

=LOG(10;3) retorna el logaritme en base 3 de 10 (aproximadament 2,0959).

=LOG(7^4;7) retorna 4.

LOG10

Retorna el logaritme de base-10 d'un nombre.

Sintaxi

LOG10(Nombre)

Retorna el logaritme en base 10 de Nombre.

Exemple

=LOG10(5) retorna el logaritme en base 10 de 5 (aproximadament 0,69897).

ARRODMULTSUP.ISO

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

Sintaxi

ARRODMULTSUP.ISO(Nombre; Importància)

Nombre (necessari) és el nombre que s'ha d'arrodonir a l'alça.

Importància (opcional) és el nombre al múltiple del qual s'ha d'arrodonir a l'alça el valor.

Exemple

=ARRODMULTSUP.ISO(-11;-2) retorna -10

ARRODMULTSUP.PRECIS

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

Sintaxi

ARRODMULTSUP.PRECIS(Nombre;Precisió)

Nombre (necessari) és el nombre que s'ha d'arrodonir a l'alça.

Importància (opcional) és el nombre al múltiple del qual s'ha d'arrodonir a l'alça el valor.

Exemple

=ARRODMULTSUP.PRECIS(-11;-2) retorna -10

ARRODMULTSUP

Arrodoneix un nombre cap al múltiple més proper d'Importància.

Sintaxi

ARRODMULTSUP(Nombre; Importància; Mode)

Nombre és el nombre que s'ha d'arrodonir a l'alça.

Importància és el nombre al múltiple del qual s'ha d'arrodonir a l'alça el valor.

Mode és un valor opcional. Si s'indica el valor Mode i no és igual a zero, i si Nombre i Importància són negatius, s'arrodoneix en funció del valor absolut del nombre. Quan s'exporta al MS Excel, s'ignora aquest paràmetre perquè l'Excel no reconeix cap tercer paràmetre.

Warning.png Si els paràmetres Nombre i Importància són negatius i el valor Mode és igual a zero o no s'indica, els resultats del LibreOffice i de l'Excel seran diferents quan s'hagi completat la importació. Si exporteu el full de càlcul a l'Excel, utilitzeu Mode=1 per veure els mateixos resultats a l'Excel i al Calc.

Exemple

=ARRODMULTSUP(-11;-2) retorna -10.

=ARRODMULTSUP(-11;-2;0) retorna -10.

=ARRODMULTSUP(-11;-2;1) retorna -12.

PI

Retorna 3,14159265358979, el valor de la constant matemàtica PI amb 14 decimals.

Sintaxi

PI()

Exemple

=PI() retorna 3,14159265358979.

ALEAT

Retorna un nombre aleatori entre 0 i 1.

Sintaxi

ALEAT()

Aquesta funció genera un nombre aleatori nou cada vegada que el Calc recalcula. Per a forçar manualment que el Calc recalculi, premeu F9.

Per generar nombres aleatoris que no es tornin a calcular, copieu les cel·les que continguin =ALEAT() i utilitzeu Edita - Enganxament especial (amb les opcions Enganxa-ho tot i Fórmules desactivades, i l'opció Nombres activada).

Exemple

=ALEAT() retorna un nombre aleatori entre 0 i 1.

MULTINOMIAL

Retorna el factorial de la suma dels arguments dividida pel producte dels factorials dels arguments.

Sintaxi

MULTINOMIAL(Nombre(s))

Nombre(s) és una llista de fins a 30 nombres.

Exemple

=MULTINOMIAL(F11:H11) retorna 1260, si F11 a H11 contenen els valors 2, 3 i 4. Aquest resultat correspon a la fórmula =(2+3+4)! / (2!*3!*4!).

POTENCIA

Retorna un nombre elevat a un altre nombre.

Sintaxi

POTENCIA(Base; Exponent)

Retorna la Base elevada a la potència que s'indica a Exponent.

Podeu obtenir el mateix resultat si utilitzeu l'operador d'exponent ^:

Base^Exponent

Exemple

=POTENCIA(4;3) retorna 64, que és 4 elevat a la potència de 3.

=4^3 també retorna la potència de 4 elevat a 3.

SUMASERIES

Suma els primers termes d'una sèrie de potències.

SUMASERIES(x;n;m;coeficients) = coeficient_1*x^n + coeficient_2*x^(n+m) + coeficient_3*x^(n+2m) +...+ coeficient_i*x^(n+(i-1)m)

Sintaxi

SUMASERIES(X; N; M; Coeficients)

X és el valor d'entrada de la sèrie de potències.

N és la potència inicial.

M és la potència a la qual s'eleva N.

Coeficients és una sèrie de coeficients. La suma de sèries s'amplia una secció per a cada coeficient.

PRODUCTE

Multiplica tots els nombres que s'han indicat com a arguments i en retorna el producte.

Sintaxi

PRODUCTE(Nombre1; Nombre2; ...; Nombre30)

Nombre1 fins a 30 són fins a 30 arguments el producte dels quals s'ha de calcular.

PRODUCTE retorna nombre1 * nombre2 * nombre3 * ...

Exemple

=PRODUCTE(2;3;4) retorna 24.

SUMAQUAD

Si voleu calcular la suma dels quadrats dels nombres (el total dels quals correspondrà als quadrats dels arguments), introduïu-los en els camps de text.

Sintaxi

SUMAQUAD(Nombre1; Nombre2; ...; Nombre30)

Nombre1 a 30 són fins a 30 arguments dels quals s'ha de calcular la suma dels quadrats.

Exemple

Si introduïu els nombres 2, 3 i 4 en els quadres de text Nombre 1, 2 i 3, es retornarà 29 com a resultat.

MOD

Retorna el residu quan es divideix un enter per un altre.

Sintaxi

MOD(Dividend; Divisor)

Per als arguments enters, aquesta funció retorna el residu quan el Dividend es divideix pel Divisor.

Aquesta funció s'implementa Dividend - Divisor * ENT(Dividend/Divisor), i aquesta fórmula dóna el resultat si els arguments no són enters.

Exemple

=MOD(22;3) retorna 1, el residu quan es divideix 22 entre 3.

=MOD(11,25;2,5) retorna 1,25.

QUOCIENT

Retorna la part entera d'una divisió.

Sintaxi

QUOCIENT(Numerador; Denominador)

Retorna la part entera de Numerador dividida entre Denominador.

QUOCIENT és equivalent a ENT(Numerador/Denominador), però pot ser que mostri errors amb codis d'error diferents.

Exemple

=QUOCIENT(11;3) retorna 3. El residu de 2 es perd.

RADIANS

Converteix graus a radians.

Sintaxi

RADIANS(Nombre)

Nombre és l'angle en graus que s'ha de convertir en radians.

Exemple

=RADIANS(90) retorna 1,5707963267949, que és PI/2 segons la precisió del Calc.

ARROD

Arrodoneix un nombre a un nombre determinat de xifres decimals.

Sintaxi

ARROD(Nombre; Comptatge)

Retorna Nombre arrodonit a les xifres decimals de Comptatge. Si Comptatge s'omet o és zero, s'arrodoneix la funció a l'enter més proper. Si Comptatge és negatiu, la funció s'arrodoneix fins al proper 10, 100, 1000, etcètera.

Aquesta funció arrodoneix al nombre més proper. Vegeu ARRODAVALL i ARRODAMUNT per veure funcions alternatives.

Exemple

=ARROD(2.348;2) retorna 2,35.

=ARROD(-32,4834;3) retorna -32,483. Canvieu el format de la cel·la per veure tots els decimals.

=ARROD(2,348;0) retorna 2.

=ARROD(2,5) retorna 3.

=ARROD(987,65;-2) retorna 1000.

ARRODAVALL

Arrodoneix un nombre cap avall, cap a zero, a una precisió determinada.

Sintaxi

ARRODAVALL(Nombre; Comptatge)

Retorna el Nombre arrodonit a la baixa (cap a zero) amb les xifres decimals de Comptatge. Si Comptatge s'omet o és zero, la funció arrodoneix a la baixa fins a un enter. Si Comptatge és negatiu, la funció arrodoneix a la baixa fins al proper 10, 100, 1000, etcètera.

Aquesta funció arrodoneix a zero. Vegeu ARRODAMUNT i ARROD per veure funcions alternatives.

Exemple

=ARRODAVALL(1,234;2) retorna 1,23.

=ARRODAVALL(45,67;0) retorna 45.

=ARRODAVALL(-45,67) retorna -45.

=ARRODAVALL(987,65;-2) retorna 900.

COMPTASI

Retorna el nombre de cel·les que compleixen uns criteris determinats en un interval de cel·les.

La cerca permet l'ús d'expressions regulars. Per exemple, podeu introduir "tot.*" per trobar la primera aparició de la cadena "tot" seguida per qualssevol caràcters. Si voleu cercar un text que també és una expressió regular, cal que precediu cada caràcter amb el caràcter \. Podeu habilitar o inhabilitar l'avaluació automàtica de les expressions regulars des del menú Eines - Opcions - LibreOffice Calc - Càlcul.

Sintaxi

COMPTASI(Interval; Criteris)

Interval és l'interval de cel·les on s'han d'aplicar els criteris.

Criteris indica els criteris en forma de nombre, d'expressió o de cadena de caràcters. Els criteris determinen quines cel·les es compten. També podeu introduir un text de cerca en forma d'expressió regular, com ara b.* per a totes les paraules que comencin amb b. Igualment, podeu indicar un interval de cel·les que contingui el criteri de cerca. Si cerqueu un text literal, poseu el text entre cometes dobles.

Exemple

A1:A10 és un interval de cel·les que conté els nombres entre el 2000 i el 2009. La cel·la B1 conté el nombre 2006. A la cel·la B2 introduïu una fórmula:

=COMPTASI(A1:A10;2006): retorna 1.

=COMPTASI(A1:A10;B1): retorna 1.

=COMPTASI(A1:A10;">=2006"): retorna 4.

=COMPTASI(A1:A10;"<"&B1): quan B1 conté 2006, la funció retorna 6.

=COMPTASI(A1:A10;C2) on la cel·la C2 conté el text >2006 compta el nombre de cel·les de l'interval A1:A10 que són >2006.

Per comptar només els nombres negatius: =COMPTASI(A1:A10;"<0")

ARRODAMUNT

Arrodoneix un nombre a l'alça, allunyat de zero, amb una precisió determinada.

Sintaxi

ARRODAMUNT(Nombre; Comptatge)

Retorna el Nombre arrodonit a l'alça (allunyat de zero) amb les xifres decimals de Comptatge. Si Comptatge s'omet o és zero, la funció arrodoneix a un enter. Si Comptatge és negatiu, la funció arrodoneix a l'alça fins al proper 10, 100, 1000, etcètera.

Aquesta funció s'allunya del zero en arrodonir. Vegeu ARRODAVALL i ARROD per veure funcions alternatives.

Exemple

=ARRODAMUNT(1,1111;2) retorna 1,12.

=ARRODAMUNT(1,2345;1) retorna 1,3.

=ARRODAMUNT(45,67;0) retorna 46.

=ARRODAMUNT(-45,67) retorna -46.

=ARRODAMUNT(987,65;-2) retorna 1000.

SIN

Retorna el sinus de l'angle que s'ha indicat (en radians).

Sintaxi

SIN(Nombre)

Retorna el sinus (trigonomètric) de Nombre, l'angle en radians.

Per calcular el sinus d'un angle en graus, utilitzeu la funció RADIANS.

Exemple

=SIN(PI()/2) retorna 1, el sinus de PI/2 radians.

=SIN(RADIANS(30)) retorna 0,5, el sinus de 30 graus.

SINH

Retorna el sinus hiperbòlic d'un nombre.

Sintaxi

SINH(Nombre)

Retorna el sinus hiperbòlic d'un Nombre.

Exemple

=SINH(0) retorna 0, el sinus hiperbòlic de 0.

SUMA

Suma tots els nombres d'un interval de cel·les.

Sintaxi

SUMA(Nombre1; Nombre2; ...; Nombre30)

Nombre1 a Nombre30 són fins a 30 arguments dels quals s'ha de calcular la suma.

Exemple

Si introduïu els nombres 2, 3 i 4 en els quadres de text Nombre 1, 2 i 3, es retornarà 9 com a resultat.

=SUMA(A1;A3;B5) calcula la suma de les tres cel·les. =SUMA (A1:E10) calcula la suma de totes les cel·les situades en l'interval d'A1 a E10.

Les condicions enllaçades amb I poden utilitzar-se amb la funció SUMA() de la manera següent:

Exemple hipotètic: heu introduït factures en una taula. La columna A conté el valor de data de la factura i la columna B, els imports. Voleu trobar una fórmula que pugueu utilitzar per calcular el total de tots els imports d'un mes determinat, p. ex., només l'import del període >=01-01-2008 a <01-02-2008. L'interval dels valors de dates és A1:A40; l'interval que conté els imports que s'han de totalitzar és B1:B40. C1 conté la data d'inici, 01-01-2008, de les factures que s'han d'incloure; C2 conté la data, 01-02-2008, que ja no s'inclou.

Introduïu la fórmula següent com una fórmula matricial:

=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Per introduir-ho com a fórmula matricial, heu de prémer les tecles Maj+Ctrl+Retorn en comptes de prémer només la tecla Retorn per tancar la fórmula. La fórmula es mostrarà llavors a la barra Fórmula, tancada entre claus.

{=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

La fórmula es basa en el fet que el resultat d'una comparació és 1 si es compleix el criteri de cerca i 0 si no es compleix. Els resultats de la comparació individual es tractaran com una matriu i s'utilitzaran en una multiplicació matricial; tot seguit, es totalitzaran els valors individuals per donar la matriu del resultat.

SUMASI

Suma les cel·les que s'han indicat segons uns criteris determinats. Aquesta funció s'utilitza per cercar un valor determinat en un interval.

La cerca permet l'ús d'expressions regulars. Per exemple, podeu introduir "tot.*" per trobar la primera aparició de la cadena "tot" seguida per qualssevol caràcters. Si voleu cercar un text que també és una expressió regular, cal que precediu cada caràcter amb el caràcter \. Podeu habilitar o inhabilitar l'avaluació automàtica de les expressions regulars des del menú Eines - Opcions - LibreOffice Calc - Càlcul.

Sintaxi

SUMASI(Interval; Criteris; IntervalDeSuma)

Interval és l'interval de cel·les on s'han d'aplicar els criteris.

Criteris és la cel·la on es mostra el criteri de cerca, o el mateix criteri. Si s'escriu el criteri en la fórmula, s'ha de posar entre cometes dobles.

IntervalDeSuma és l'interval a partir del qual se sumen els valors. Si no s'ha indicat el paràmetre, se sumen els valors de l'Interval.

Note.png SUMASI només admet l'operador de concatenació de referència (~) en el paràmetre Criteris, i només si no s'indica el paràmetre opcional IntervalDeSuma.

Exemple

Per sumar només els nombres negatius: =SUMASI(A1:A10;"<0").

=SUMASI(A1:A10;">0";B1:10): suma els valors de l'interval B1:B10 només si els valors corresponents de l'interval A1:A10 són >0.

Vegeu COMPTASI() per veure altres exemples de sintaxi que podeu utilitzar amb la funció SUMASI().

TAN

Retorna la tangent de l'angle indicat (en radians).

Sintaxi

TAN(Nombre)

Retorna la tangent (trigonomètrica) de Nombre, l'angle en radians.

Per calcular la tangent d'un angle en graus, utilitzeu la funció RADIANS.

Exemple

=TAN(PI()/4) retorna 1, la tangent de PI/4 radians.

=TAN(RADIANS(45)) retorna 1, la tangent de 45 graus.

TANH

Retorna la tangent hiperbòlica d'un nombre.

Sintaxi

TANH(Nombre)

Retorna la tangent hiperbòlica d'un Nombre.

Exemple

=TANH(0) retorna 0, la tangent hiperbòlica de 0.

SUBTOTAL

Calcula subtotals. Si un interval ja conté subtotals, no s'utilitzen per fer altres càlculs. Utilitzeu aquesta funció amb els filtres automàtics per tenir en compte només els registres filtrats.

Sintaxi

SUBTOTAL(Funció; Interval)

Funció és un nombre que representa una de les funcions següents:

Índex de funcions Funció
1 MITJANA
2 COMPTA
3 COMPTAA
4 MAX
5 MIN
6 PRODUCTE
7 DESVEST
8 DESVESTP
9 SUMA
10 VAR
11 VARP

Interval és l'interval les cel·les del qual s'inclouen.

Exemple

Teniu una taula a l'interval de cel·les A1:B5 que conté ciutats a la columna A i xifres relacionades a la columna B. Heu utilitzat un Filtre automàtic per veure només les files que contenen la ciutat d'Hamburg. Voleu veure la suma de les xifres que es mostren, és a dir, només el subtotal de les files filtrades. En aquest cas, la fórmula correcta és la següent:

=SUBTOTAL(9;B2:B5)

CONVERSIOEURO

Converteix les antigues monedes nacionals europees en euros, i viceversa.

Sintaxi

CONVERSIOEURO(Valor; "Moneda_origen"; "Moneda_destí", Màxima_precisió, Precisió_triangulació)

Valor és la quantitat de la moneda que s'ha de convertir.

Moneda_origen és la unitat monetària que s'ha de convertir; Moneda_destí és la unitat monetària en què s'ha de convertir la primera. L'abreviatura de la moneda ha de ser text (per exemple, "EUR"). Les taxes (que es mostren en euros) les va establir la Comissió Europea.

Màxima_precisió és opcional. Si s'omet o és Fals, el resultat s'arrodoneix segons els decimals de la Moneda_destí. Si Màxima_precisió és Cert, el resultat no s'arrodoneix.

Precisió_triangulació és opcional. Si s'indica la Precisió_triangulació i és >=3, el resultat intermedi d'una conversió triangular (moneda1,EUR,moneda2) s'arrodoneix a aquesta precisió. Si s'omet la Precisió_triangulació, el resultat intermedi no s'arrodoneix. A més, si la Moneda_destí és "EUR", la Precisió_triangulació s'utilitza com si es necessités la triangulació i s'apliqués la conversió d'EUR a EUR.

Exemples

=CONVERSIOEURO(100;"ATS";"EUR") converteix 100 xílings austríacs en euros.

=CONVERSIOEURO(100;"EUR";"DEM") converteix 100 euros en marcs alemanys.

SENAR

Arrodoneix un nombre positiu a l'alça cap a l'enter senar més proper i un nombre negatiu a la baixa cap a l'enter senar més proper.

Sintaxi

SENAR(Nombre)

Retorna Nombre arrodonit a l'alça cap a l'enter senar més proper, allunyat de zero.

Exemple

=SENAR(1,2) retorna 3.

=SENAR(1) retorna 1.

=SENAR(0) retorna 1.

=SENAR(-3,1) retorna -5.

ABS

Retorna el valor absolut d'un nombre.

Sintaxi

ABS(Nombre)

Nombre és el nombre del qual s'ha de calcular el valor absolut. El valor absolut d'un nombre és el seu valor sense el signe +/-.

Exemple

=ABS(-56) retorna 56.

=ABS(12) retorna 12.

=ABS(0) retorna 0.


Related Topics

Funcions del Calc per categoria a la wiki d'ajuda del LibreOffice