Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Математически функции

From LibreOffice Help
Jump to: navigation, search

Тази категория съдържа математическите функции в Calc. За да отворите помощника за функции, изберете Вмъкване - Функция.

Contents

CONVERT

Преобразува стойност от една мерна единица в друга. Коефициентите за преобразуване са дадени в списък в конфигурацията.

До определен момент списъкът с коефициенти за преобразуване включваше старите европейски валути и еврото (вижте долните примери). Препоръчваме ви за преобразуване на тези валути да използвате новата функция EUROCONVERT.

Синтаксис

CONVERT(стойност; "текст"; "текст")

Пример

=EUROCONVERT(100;"ATS";"EUR") преобразува 100 австрийски шилинга в евро.

=CONVERT(100;"EUR";"DEM") преобразува 100 евро в германски марки.

FLOOR.PRECISE

Закръглява число нагоре до най-близкото кратно на Стъпка, независимо от знака на Стъпка

Синтаксис

FLOOR.PRECISE(Число; Стъпка)

Число е числото, което да бъде закръглено надолу.

Стъпка е стойността, до чието кратно трябва да се закръгли числото.

Пример

=FLOOR.PRECISE(-11;-2) връща -12

FLOOR

Закръглява число надолу до най-близкото кратно на дадено число.

Синтаксис

FLOOR(Число; Стъпка; Режим)

Число е числото, което да бъде закръглено надолу.

Стъпка е стойността, до чието кратно трябва да се закръгли числото.

Режим е незадължителна стойност. Ако тя е подадена и различна от нула и ако числото и стъпката са отрицателни, закръгляването ще е базирано на абсолютната стойност на числото. Този параметър се игнорира при експортиране към MS Excel, тъй като Excel не поддържа трети параметър.

Warning.png Ако и двата параметъра Число и Стъпка са отрицателни и Режим е нула или пропуснат, резултатът в LibreOffice и Excel ще се различава след експортирането. Ако експортирате електронната таблица към Excel, използвайте Режим=1, за да видите еднакви резултати в Excel и Calc.

Пример

=FLOOR(-11;-2) връща -12

=FLOOR(-11;-2;0) връща -12

=FLOOR(-11;-2;1) връща -10

SIGN

Връща знака на число: 1, ако числото е положително, -1, ако е отрицателно, и 0, ако е нула.

Синтаксис

SIGN(Число)

Число е числото, чийто знак да бъде определен.

Пример

=SIGN(3,4) връща 1.

=SIGN(-4,5) връща -1.

MROUND

Връща число, закръглено до най-близкото кратно на друго число.

Синтаксис

MROUND(Число; Стъпка)

Връща Число, закръглено до най-близкото кратно на Стъпка.

Алтернативна реализация на същото изчисление е Стъпка * ROUND(Число / Стъпка).

Пример

=MROUND(15,5;3) връща 15, тъй като 15,5 е по-близо до 15 (= 3*5), отколкото до 18 (= 3*6).

=MROUND(1,4;0,5) връща 1,5 (= 0,5*3).

CSCH

Връща хиперболичния косеканс на число.

Синтаксис

CSCH(Число)

Връща хиперболичния косеканс на Число.

Пример

=CSCH(1) връща приблизително 0,8509181282, хиперболичният косеканс на 1.

SECH

Връща хиперболичния секанс на число.

Синтаксис

SECH(Число)

Връща хиперболичния секанс на Число.

Пример

=SECH(0) връща 1, хиперболичният секанс на 0.

CSC

Връща косеканса на дадения ъгъл в радиани. Косекансът на ъгъл е равен на единица върху синуса му.

Синтаксис

CSC(Число)

Връща косеканса на Число, ъгълът трябва да е в радиани.

За да получите косеканса на ъгъл в градуси, използвайте функцията RADIANS.

Примери

=CSC(PI()/4) връща приблизително 1,4142135624, реципрочното на синус от PI/4 радиана.

=CSC(RADIANS(30)) връща 2, косекансът на 30 градуса.

SEC

Връща секанса на дадения ъгъл в радиани. Секансът на ъгъл е равен на единица върху косинуса му.

Синтаксис

SEC(Число)

Връща секанса на Число, ъгълът трябва да е в радиани.

За да получите секанса на ъгъл в градуси, използвайте функцията RADIANS.

Примери

=SEC(PI()/4) връща приблизително 1,4142135624, реципрочното на косинус от PI/4 радиана.

=SEC(RADIANS(60)) връща 2, секансът на 60 градуса.

COUNTBLANK

Връща броя на празните клетки.

Синтаксис

COUNTBLANK

Връща броя на празните клетки в областта от клетки Област.

Пример

=COUNTBLANK(A1:B2) връща 4, ако клетките A1, A2, B1 и B2 са празни.

ACOS

Връща аркускосинуса (обратния косинус) на число.

Синтаксис

ACOS(Число)

Тази функция връща аркускосинуса на Число, т.е. ъгъла в радиани, чийто косинус е Число. Връщаният ъгъл е между 0 и пи.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ACOS(-1) връща 3,14159265358979 (пи радиана)

=DEGREES(ACOS(0,5)) връща 60. Косинусът на 60 градуса е 0,5.

ACOSH

Връща обратния хиперболичен косинус на число.

Синтаксис

ACOSH(Число)

Тази функция връща обратния хиперболичен косинус на Число, т.е. числото, чийто хиперболичен косинус е Число.

Числото трябва да е по-голямо или равно на 1.

Пример

=DELTA(1;2) връща 0.

=ACOSH(COSH(4)) връща 4.

SQRT

Връща положителния квадратен корен на число.

Синтаксис

SQRT(Число)

Връща положителния квадратен корен на Число.

Числото трябва да е положително.

Пример

=SQRT(16) връща 4.

=SQRT(-16) връща грешка от типа невалиден аргумент.

ACOT

Връща аркускотангенса (обратния котангенс) на даденото число.

Синтаксис

ACOT(Число)

Тази функция връща аркускотангенса на Число, т.е. ъгъла в радиани, чийто котангенс е Число. Връщаният ъгъл е между 0 и пи.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ACOT(1) връща 0,785398163397448 (PI/4 радиана).

=DEGREES(ACOT(1)) връща 45. Тангенсът на 45 градуса е 1.

ACOTH

Връща обратния хиперболичен котангенс на даденото число.

Синтаксис

ACOTH(Число)

Тази функция връща обратния хиперболичен котангенс на Число, т.е. числото, чийто хиперболичен котангенс е Число.

Ако числото е между -1 и 1 включително, възниква грешка.

Пример

=ACOTH(1,1) връща обратния хиперболичен котангенс на 1,1, приблизително 1,52226.

ASIN

Връща аркуссинуса (обратния синус) на число.

Синтаксис

ASIN(Число)

Тази функция връща аркуссинуса на Число, т.е. ъгъла в радиани, чийто синус е Число. Връщаният ъгъл е между 0 и пи.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ASIN(0) връща 0.

=ASIN(1) връща 1,5707963267949 (PI/2 радиана).

=DEGREES(ASIN(0.5)) връща 30. Синусът на 30 градуса е 0,5.

ASINH

Връща обратния хиперболичен синус на число.

Синтаксис

ASINH(Число)

Тази функция връща обратния хиперболичен синус на Число, т.е. числото, чийто хиперболичен синус е Число.

Пример

=ASINH(-90) връща приблизително -5,1929877.

=ASINH(SINH(4)) връща 4.

ATAN

Връща аркустангенса (обратния тангенс) на число.

Синтаксис

ATAN(Число)

Тази функция връща аркустангенса на Число, т.е. ъгъла в радиани, чийто тангенс е Число. Връщаният ъгъл е между -PI/2 и PI/2.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ATAN(1) връща 0,785398163397448 (PI/4 радиана).

=DEGREES(ATAN(1)) връща 45. Тангенсът на 45 градуса е 1.

ATAN2

Връща аркустангенса (обратния тангенс) по зададени координати x и y.

Синтаксис

ATAN2(X; Y)

ЧислоX е стойността на координатата x.

ЧислоY е стойността на координатата y.

ATAN2 връща аркустангенса (обратния тангенс), т.е. ъгъла в радиани между оста x и правата през точката (X, Y) и началото. Връщаният ъгъл е между -PI и PI.

За да получите ъгъла в градуси, използвайте функцията DEGREES.

Пример

=ATAN2(20;20) връща 0,785398163397448 (пи/4 радиана).

=DEGREES(ATAN2(12,3;12,3)) връща 45. Тангенсът на 45 градуса е 1.

ATANH

Връща обратния хиперболичен тангенс на число.

Синтаксис

ATANH(Число)

Тази функция връща обратния хиперболичен тангенс на Число, т.е. числото, чийто хиперболичен тангенс е Число.

Числото трябва да бъде в отворения интервал (-1; 1).

Пример

=ATANH(0) връща 0.

COS

Връща косинуса на дадения ъгъл в радиани.

Синтаксис

COS(Число)

Връща косинуса на Число, ъгълът трябва да е в радиани.

За да получите косинуса на ъгъл в градуси, използвайте функцията RADIANS.

Примери

=COS(PI()/2) връща 0, косинусът на PI/2 радиана.

=COS(RADIANS(60)) връща 0,5, косинусът на 60 градуса.

COSH

Връща хиперболичния косинус на число.

Синтаксис

COSH(Число)

Връща хиперболичния косинус на Число.

Пример

=COSH(0) връща 1, хиперболичния косинус на 0.

COT

Връща котангенса на дадения ъгъл в радиани.

Синтаксис

COT(Число)

Връща котангенса на Число, ъгълът трябва да е в радиани.

За да получите котангенса на ъгъл в градуси, използвайте функцията RADIANS.

Котангенсът на ъгъл е равен на единица върху тангенса му.

Примери

=COT(PI()/4) връща 1, котангенсът на PI/4 радиана.

=COT(RADIANS(45)) връща 1, котангенсът на 45 градуса.

SQRTPI

Връща квадратния корен на пи, умножено по число.

Синтаксис

SQRTPI(Число)

Връща положителния квадратен корен на произведението на пи с Число.

Това е еквивалентно на SQRT(PI()*Число).

Пример

=SQRTPI(2) връща квадратния корен на 2*пи, приблизително 2,506628.

COTGH

Връща хиперболичния котангенс на дадено число (ъгъл).

Синтаксис

COTH(Число)

Връща хипербличния котангенс на Число.

Пример

=COTH(1) връща хиперболичния котангенс на 1, приблизително 1,3130.

DEGREES

Преобразува радиани в градуси.

Синтаксис

DEGREES(Число)

Число е ъгълът в радиани, който да бъде преобразуван в градуси.

Пример

=DEGREES(PI()) връща 180 градуса.

EXP

Връща e на степен дадено число. Константата e е приблизително равна на 2,71828182845904.

Синтаксис

EXP(Число)

Число е степента, на която да бъде повдигнато e.

Пример

=EXP(1) връща 2,71828182845904, математическата константа e с точността на Calc.

FACT

Връща факториела на число.

Синтаксис

FACT(Число)

Връща Число!, факториела на Число, който е равен на 1*2*3*4*…*Число.

=FACT(0) връща 1 по дефиниция.

Факториел от отрицателно число предизвиква грешка от типа „невалиден аргумент“.

Пример

=FACT(3) връща 6.

=FACT(0) връща 1.

INT

Закръглява число надолу до най-близкото цяло число.

Синтаксис

INT(Число)

Връща Число, закръглено надолу до най-близкото цяло число.

Отрицателните числа се закръгляват надолу до съответните цели числа под тях.

Пример

=INT(5,7) връща 5.

=INT(-1,3) връща -2.

EVEN

Закръглява положително число нагоре до следващото четно цяло число и отрицателно число – надолу до следващото четно цяло число.

Синтаксис

EVEN(Число)

Връща Число, закръглено нагоре до следващото четно цяло число, в посока обратно на нулата.

Примери

=EVEN(2,3) връща 4.

=EVEN(2) връща 2.

=EVEN(0) връща 0.

=EVEN(-0,5) връща -2.

GCD

Връща най-големия общ делител на две или повече цели числа.

Най-големият общ делител е най-голямото положително цяло число, което дели без остатък всяко от дадените цели числа.

Синтаксис

GCD(ЦялоЧисло1; ЦялоЧисло2; …; ЦялоЧисло30)

ЦялоЧисло1…30 са не повече от 30 цели числа, чийто най-голям общ делител да бъде изчислен.

Пример

=GCD(16;32;24) дава резултат 8, тъй като 8 е най-голямото число, делящо 16, 24 и 32 без остатък.

=GCD(B1:B3), ако клетките B1, B2 и B3 съдържат9, 12 и 9, дава 3.

GCD_ADD

Резултатът е най-големият общ делител на списък от числа.

Note.png Функциите, чиито имена завършват с _ADD, връщат същите резултати като съответните функции на Microsoft Excel. Използвайте функциите без _ADD, за да получите резултати, базирани на международните стандарти. Например функцията WEEKNUM изчислява номера на седмицата на дадена дата според международния стандарт ISO 6801, докато WEEKNUM_ADD връща същия номер на седмица като Microsoft Excel.

Синтаксис

GCD_ADD(Числа)

Числа е списък от не повече от 30 числа.

Пример

=GCD_ADD(5;15;25) връща 5.

ISEVEN

Връща TRUE, ако стойността е четно цяло число, и FALSE, ако стойността е нечетна.

Синтаксис

ISODD(Стойност)

Стойност е стойността, която да бъде проверена.

Ако стойността не е цяло число, цифрите след десетичната запетая се игнорират. Знакът на числото също се пренебрегва.

Пример

=ISEVEN(48) връща TRUE

=ISREF(4) връща FALSE

=ISEVEN(0) връща TRUE

=ISEVEN(-2,1) връща TRUE

=ISEVEN(3,999) връща FALSE

ISODD

Връща TRUE, ако стойността е нечетна, и FALSE, ако е четна.

Синтаксис

ISODD(Стойност)

Стойност е стойността, която да бъде проверена.

Ако стойността не е цяло число, цифрите след десетичната запетая се игнорират. Знакът на числото също се пренебрегва.

Пример

=ISODD(33) връща TRUE

=ISREF(4) връща FALSE

=ISODD(3,999) връща TRUE

=ISODD(-3,1) връща TRUE

RANDBETWEEN

Връща случайно цяло число в зададен диапазон.

Синтаксис

RANDBETWEEN(ДолнаГраница; ГорнаГраница)

Връща случайно цяло число между целите числа ДолнаГраница и ГорнаГраница (включително).

Тази функция връща ново случайно число всеки път, когато Calc изчислява наново. За да наложите ръчно преизчисляване в Calc, натиснете Shift+Ctrl+F9.

За да се генерират случайни числа, които никога не се преизчисляват, копирайте клетките, съдържащи тази функция, и използвайте Редактиране - Специално вмъкване (като Вмъкване - всичко и Формули не са отметнати, а Числа е отметнато).

Пример

=RANDBETWEEN(20;30) връща цяло число между 20 и 30.

LCM

Returns the least common multiple of one or more integers.

Синтаксис

LCM(ЦялоЧисло1; ЦялоЧисло2; …; ЦялоЧисло30)

ЦялоЧисло1…30 са не повече от 30 цели числа, чието най-малко общо кратно да бъде изчислено.

Пример

Ако въведете числата 512, 1024 и 2000 в полетата ЦялоЧисло 1, 2 и 3, ще получите резултат 128000.

LCM_ADD

Резултатът е най-малкото общо кратно на списък от числа.

Note.png Функциите, чиито имена завършват с _ADD, връщат същите резултати като съответните функции на Microsoft Excel. Използвайте функциите без _ADD, за да получите резултати, базирани на международните стандарти. Например функцията WEEKNUM изчислява номера на седмицата на дадена дата според международния стандарт ISO 6801, докато WEEKNUM_ADD връща същия номер на седмица като Microsoft Excel.

Синтаксис

LCM_ADD(Числа)

Числа е списък от не повече от 30 числа.

Пример

=LCM_ADD(5;15;25) връща 75.

COMBIN

Връща броя на комбинациите за елементи без повторение.

Синтаксис

COMBIN(Брой1; Брой2)

Брой1 е броят на елементите в множеството.

Брой2 е броят избирани елементи от множеството.

COMBIN връща броя на начините, по които могат да се изберат даден брой елементи. Например, ако множеството се състои от трите елемента А, Б и В, можете да изберете два елемента по три различни начина: АБ, БВ и АВ.

COMBIN реализира формулата Брой1! / (Брой2! * (Брой1 - Брой2)!)

Пример

=COMBIN(3;2) връща 3.

COMBINA

Връща броя на комбинациите от избрани елементи с повторения.

Синтаксис

COMBINA(Брой1; Брой2)

Брой1 е броят на елементите в множеството.

Брой2 е броят избирани елементи от множеството.

COMBINA връща броя различни начини да се изберат даден брой елементи независимо от реда им, като е разрешено повтаряне на елементи. Например за множество от трите елемента А, Б и В можете да изберете два елемента по шест различни начина: АА, АБ, ББ, БВ, ВВ, и АВ.

COMBINA реализира формулата (Брой1 + Брой2 - 1)! / (Брой2! (Брой1 - 1)!)

Пример

=COMBINA(3;2) връща 6.

TRUNC

Отрязва число, премахвайки дробни позиции.

Синтаксис

TRUNC(Число; Брой)

Връща Число с не повече от Брой дробни позиции. Излишните разреди се премахват независимо от знака.

TRUNC(Число; 0) се държи като INT(Число) за положителни числа, но закръгля в посока към нулата за отрицателни числа.

Warning.png Видимите дробни позиции в резултата се задават в Инструменти - Настройки - LibreOffice Calc - Изчисляване.

Пример

=TRUNC(1,239;2) връща 1,23. Разредът със стойност 9 се изгубва.

=TRUNC(-1,234999;3) връща -1,234. Всички деветки се изгубват.

LN

Връща натуралния логаритъм (с основа e) на число. Константата e има стойност приблизително 2,71828182845904.

Синтаксис

LN(Число)

Число е стойността, чийто натурален логаритъм да се изчисли.

Пример

=LN(3) връща натуралния логаритъм на 3 (приблизително 1,0986).

=LN(EXP(321)) връща 321.

LOG

Връща логаритъма на число при зададена основа.

Синтаксис

LOG(Число; Основа)

Число е стойността, чийто логаритъм да се изчисли.

Основа е основата на логаритъма.

Пример

=LOG(10;3) връща логаритъма на 10 при основа 3 (приблизително 2,0959).

=LOG(7^4;7) връща 4.

LOG10

Връща десетичния логаритъм на число.

Синтаксис

LOG10(Число)

Връща десетичния логаритъм на Число.

Пример

=LOG10(5) връща десетичния логаритъм на 5 (приблизително 0,69897).

ISO.CEILING

Закръглява число нагоре до най-близкото кратно на Стъпка, независимо от знака на Стъпка

Синтаксис

ISO.CEILING(Число; Стъпка; Режим)

Число (задължителен) е числото, което да бъде закръглено нагоре.

Стъпка (незадължителен) е числото, до чието кратно трябва да бъде закръглена стойността.

Пример

=ISO.CEILING(-11;-2) връща -10

CEILING.PRECISE

Закръглява число нагоре до най-близкото кратно на Стъпка, независимо от знака на Стъпка

Синтаксис

CEILING.PRECISE(Число; Стъпка)

Число (задължителен) е числото, което да бъде закръглено нагоре.

Стъпка (незадължителен) е числото, до чието кратно трябва да бъде закръглена стойността.

Пример

=CEILING.PRECISE(-11;-2) връща -10

CEILING

Закръглява число нагоре до най-близкото кратно на дадено число.

Синтаксис

CEILING(Число; Стъпка; Режим)

Число е числото, което да бъде закръглено нагоре.

Стъпка е числото, до чието кратно трябва да бъде закръглена стойността.

Режим е незадължителна стойност. Ако тя е подадена и различна от нула и ако числото и стъпката са отрицателни, закръгляването ще е базирано на абсолютната стойност на числото. Този параметър се игнорира при експортиране към MS Excel, тъй като Excel не поддържа трети параметър.

Warning.png Ако и двата параметъра Число и Стъпка са отрицателни и Режим е нула или пропуснат, резултатът в LibreOffice и Excel ще се различава след импортирането. Ако експортирате електронната таблица към Excel, използвайте Режим=1, за да видите еднакви резултати в Excel и Calc.

Пример

=CEILING(-11;-2) връща -10

=CEILING(-11;-2;0) връща -10

=CEILING(-11;-2;1) връща -12

PI

Връща 3,14159265358979, стойността на математическата константа пи с точност до 14 дробни позиции.

Синтаксис

PI()

Пример

=PI() връща 3,14159265358979.

RAND

Връща случайно число между 0 и 1.

Синтаксис

RAND()

Тази функция дава ново случайно число всеки път, когато Calc преизчислява. За да предизвикате преизчисляване ръчно, натиснете F9.

За да се генерират случайни числа, които никога не се преизчисляват, копирайте клетките, съдържащи =RAND(), и използвайте Редактиране - Специално вмъкване (като Вмъкване - всичко и Формули не са отметнати, а Числа е отметнато).

Пример

=RAND() връща случайно число между 0 и 1.

MULTINOMIAL

Връща факториела на сумата на аргументите, разделен на произведението от факториелите на аргументите.

Синтаксис

MULTINOMIAL(Числа)

Числа е списък от не повече от 30 числа.

Пример

=MULTINOMIAL(F11:H11) връща 1260, ако клетките от F11 до H11 съдържат стойностите 2, 3 и 4. Това съответства на формулата =(2+3+4)! / (2!*3!*4!).

POWER

Връща число, повдигнато на степен.

Синтаксис

POWER(Основа; Степен)

Връща Основа, повдигната на Степен.

Същият резултат може да се постигне чрез операцията степенуване ^:

Основа^Степен

Пример

=POWER(4;3) връща 64, което е 4 на степен 3.

=4^3 също връща 4 на степен 3.

SERIESSUM

Сумира първите членове на степенен ред.

SERIESSUM(x; n; m; коефициенти) = коефициент_1*x^n + коефициент_2*x^(n+m) + коефициент_3*x^(n+2m) +...+ коефициент_i*x^(n+(i-1)m)

Синтаксис

SERIESSUM(X; N; M; Коефициенти)

X е стойността, за която се изчислява степенният ред.

N е началната степен.

M е стъпката за увеличаване на N.

Коефициенти е редица от коефициенти. На всеки коефициент съответства по един член в сумата на реда.

PRODUCT

Умножава всички подадени като аргументи числа и връща произведението.

Синтаксис

PRODUCT(Число1; Число2; …; Число30)

Число1…30 са не повече от 30 аргумента, чието произведение да бъде изчислено.

PRODUCT връща число1 * число2 * число3 * ...

Пример

=PRODUCT(2;3;4) връща 24.

SUMSQ

Ако искате да изчислите сумата на квадратите на числа, подадени като аргументи, въведете ги в текстовите полета.

Синтаксис

SUMSQ(Число1; Число2; …; Число30)

Число1…30 са не повече от 30 аргумента, сумата на чиито квадрати да бъде изчислена.

Пример

Ако въведете числата 2, 3 и 4 в текстовите полета Число 1, 2 и 3 ще получите резултат 29.

MOD

Връща остатъка от деление на едно цяло число на друго.

Синтаксис

MOD(Делимо; Делител)

За целочислени аргументи тази функция връща остатъка от делението на Делимо на Делител.

Тази функция е реализирана като Делимо - Делител * INT(Делимо / Делител) и формулата дава резултат и ако аргументите не са цели числа.

Пример

=MOD(22;3) връща 1, остатъкът при деление на 22 на 3.

=MOD(11,25;2,5) връща 1,25.

QUOTIENT

Връща целочислената част от резултата при деление.

Синтаксис

QUOTIENT(Числител; Знаменател)

Връща цялата част от частното на Числител и Знаменател.

QUOTIENT е еквивалентна на INT(Числител / Знаменател), но може да предизвика грешки с други кодове.

Пример

=QUOTIENT(11;3) връща 3. Остатъкът 2 се загубва.

RADIANS

Преобразува градуси в радиани.

Синтаксис

RADIANS(Число)

Число е ъгълът в градуси, който да бъде преобразуван в радиани.

Пример

=RADIANS(90) връща 1,5707963267949, което е пи/2 с точността на Calc.

ROUND

Закръглява число до зададен брой дробни позиции.

Синтаксис

ROUND(Число; Брой)

Връща Число, закръглено до Брой дробни позиции. Ако броят е пропуснат или нула, функцията закръглява до най-близкото цяло число. Ако броят е отрицателен, функцията закръглява до най-близкото кратно на 10, 100, 1000 и т.н.

Тази функция закръглява до най-близкото число. За алтернативи вижте ROUNDDOWN и ROUNDUP.

Пример

=ROUND(2,348;2) връща 2,35

=ROUND(-32,4834;3) връща -32,483. Променете формата на клетката, за да видите всички дробни позиции.

=ROUND(2,348;0) връща 2.

=ROUND(2,5) връща 3.

=ROUND(987,65;-2) връща 1000.

ROUNDDOWN

Закръглява число в посока надолу към нулата до зададена точност.

Синтаксис

ROUNDDOWN(Число; Брой)

Връща Число, закръглено надолу (към нулата) до Брой дробни позиции. Ако броят е пропуснат или нула, функцията закръглява надолу до цяло число. Ако броят е отрицателен, функцията закръглява надолу до следващото кратно на 10, 100, 1000 и т.н.

Тази функция закръглява към нулата. За алтернативи вижте ROUNDUP и ROUND.

Пример

=ROUNDDOWN(1,234;2) връща 1,23.

=ROUNDDOWN(45,67;0) връща 45.

=ROUNDDOWN(-45,67) връща -45.

=ROUNDDOWN(987,65;-2) връща 900.

COUNTIF

Връща броя на клетките от дадена област, които удовлетворяват определен критерий.

Търсенето поддържа регулярни изрази. Например, можете да въведете „всички.*“, за да намерите първото срещане на „всички“, последвано от произволни знаци. Ако желаете да търсите текст, който сам по себе си е регулярен израз, трябва да поставите наклонена черта \ пред всеки знак. Можете да включвате и изключвате автоматичното изчисляване на регулярни изрази чрез Инструменти - Настройки - LibreOffice Calc - Изчисляване.

Синтаксис

COUNTIF(Област; Критерий)

Област е областта, върху която да се приложат критериите.

Критерий задава критерия под формата на число, израз или знаков низ. Той определя кои клетки да бъдат преброени. Можете да въведете и текст за търсене във вид на регулярен израз, например б.* за всички думи, започващи с „б“. Можете да посочите и област от клетки, която съдържа критерия за търсене. Ако търсите непосредствено зададен текст, заградете го с двойни кавички.

Пример

A1:A10 е област от клетки, съдържащи числата от 2000 до 2009. Клетката B1 съдържа числото 2006. В клетката B2 въведете формулата:

=COUNTIF(A1:A10;2006) връща 1

=COUNTIF(A1:A10;B1) връща 1

=COUNTIF(A1:A10;">=2006") връща 4

=COUNTIF(A1:A10;"<"&B1) – ако B1 съдържа 2006, резултатът е 6

=COUNTIF(A1:A10;C2), ако C2 съдържа текста >2006, преброява клетките в областта A1:A10 със стойности, по-големи от 2006

За да преброите само отрицателните числа: =COUNTIF(A1:A10;"<0")

ROUNDUP

Закръглява число нагоре, в посока обратна на нулата, до зададена точност.

Синтаксис

ROUNDUP(Число; Брой)

Връща Число, закръглено нагоре (в посока обратно на нулата) до Брой дробни позиции. Ако броят е пропуснат или нула, функцията закръглява нагоре до цяло число. Ако броят е отрицателен, функцията закръглява нагоре до следващото кратно на 10, 100, 1000 и т.н.

Тази функция закръглява в посока, обратна на нулата. За алтернативи вижте ROUNDDOWN и ROUND.

Пример

=ROUNDUP(1,1111;2) връща 1,12.

=ROUNDUP(1,2345;1) връща 1,3.

=ROUNDUP(45,67;0) връща 46.

=ROUNDUP(-45,67) връща -46.

=ROUNDUP(987,65;-2) връща 1000.

SIN

Връща синуса на дадения ъгъл в радиани.

Синтаксис

SIN(Число)

Връща синуса на Число, ъгълът трябва да е в радиани.

За да получите синуса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=SIN(PI()/2) връща 1, синусът на пи/2 радиана.

=SIN(RADIANS(30)) връща 0,5, синусът на 30 градуса.

SINH

Връща хиперболичния синус на число.

Синтаксис

SINH(Число)

Връща хиперболичния синус на Число.

Пример

=SINH(0) връща 0, хиперболичният синус на 0.

SUM

Сумира всички числа в област от клетки.

Синтаксис

SUM(Число1; Число2; …; Число30)

Число1…30 са не повече от 30 аргумента, чиято сума да бъде изчислена.

Пример

Ако въведете числата 2, 3 и 4 в полетата Число 1, 2 и 3, ще получите резултат 9.

=SUM(A1;A3;B5) изчислява сумата на три клетки. =SUM (A1:E10) изчислява сумата на всички клетки в областта от A1 до E10.

Условия, свързани с AND, могат да се използват с функцията SUM() по следния начин:

Да приемем, че сте въвели фактури в таблица. Колоната A съдържа датата, а B – количествата. Необходима ви е формула, с която да изчислите общата сума на количествата за даден месец, например само в периода от >=2008-01-01 до <2008-02-01. Областта с датите е A1:A40, а с количествата за сумиране – B1:B40. Клетката C1 съдържа най-ранната дата на желаните фактури, 2008-01-01, а C2 – най-късната дата, 2008-02-01.

Въведете следната формула като формула за масив:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

За да въведете формула за масив, трябва да натиснете комбинацията Shift+ Ctrl+Enter вместо просто Enter, когато завършвате формулата. След това формулата ще се покаже оградена с фигурни скоби в лентата Формула.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Формулата се базира на факта, че резултатът от сравнение е 1, ако условието е изпълнено, и 0 в противен случай. Отделните резултати от сравненията се третират като масив и се използват в матрично умножение. Накрая отделните стойности се сумират, за да се получи резултатната матрица.

SUMIF

Сумира клетките, отговарящи на зададен критерий. Чрез тази функция можете да пресеете областта, търсейки конкретни стойности.

Търсенето поддържа регулярни изрази. Например, можете да въведете „всички.*“, за да намерите първото срещане на „всички“, последвано от произволни знаци. Ако желаете да търсите текст, който сам по себе си е регулярен израз, трябва да поставите наклонена черта \ пред всеки знак. Можете да включвате и изключвате автоматичното изчисляване на регулярни изрази чрез Инструменти - Настройки - LibreOffice Calc - Изчисляване.

Синтаксис

SUMIF(Област; Критерии; ОблСум)

Област е областта, върху която да се приложат критериите.

Критерии е самото условие за търсене или клетката, която го съдържа. Ако критериите са изписани във формулата, трябва да бъдат заградени с двойни кавички.

ОблСум е областта, от която се сумират стойности. Ако този параметър е пропуснат, се сумират стойностите от параметъра Област.

Note.png SUMIF поддържа операцията слепване на обръщения (~) само в параметъра Критерии и само ако незадължителният параметър Област е пропуснат.

Пример

За да сумирате само отрицателни числа: =SUMIF(A1:A10; "<0")

=SUMIF(A1:A10;">0";B1:10) - сумира стойностите от областта B1:B10 само ако съответните стойности от областта A1:A10 са по-големи от 0.

При COUNTIF() ще намерите още примери за синтаксиса, който може да се използва със SUMIF().

TAN

Връща тангенса на дадения ъгъл в радиани.

Синтаксис

TAN(Число)

Връща тангенса на Число, ъгълът трябва да е в радиани.

За да получите тангенса на ъгъл в градуси, използвайте функцията RADIANS.

Пример

=TAN(PI()/4) връща 1, тангенсът на пи/4 радиана.

=TAN(RADIANS(45)) връща 1, тангенсът на 45 градуса.

TANH

Връща хиперболичния тангенс на число.

Синтаксис

TANH(Число)

Връща хиперболичния тангенс на Число.

Пример

=TANH(0) връща 0, хиперболичният тангенс на 0.

SUBTOTAL

Изчислява междинни суми. Ако областта вече съдържа междинни суми, те не се включват в по-нататъшните изчисления. Използвайте тази функция заедно с автофилтър, за да обработите само филтрираните записи.

Синтаксис

SUBTOTAL(Функция; Област)

Функция е число, което означава една от следващите функции:

Индекс Функция
1 AVERAGE
2 COUNT
3 COUNTA
4 MAX
5 MIN
6 PRODUCT
7 STDEV
8 STDEVP
9 SUM
10 VAR
11 VARP

Област е областта, чиито клетки са включени.

Пример

В областта A1:B5 има таблица, съдържаща имена на градове в колоната A и съответни числа в колоната B. Използвали сте автофилтър, така че виждате само редовете с град Пловдив. Искате да видите сумата на показаните числа, т.е. само междинната сума за филтрираните редове. В този случай правилната формула е:

=SUBTOTAL(9;B2:B5)

EUROCONVERT

Преобразува между стари европейски парични единици и евро и обратно.

Синтаксис

EUROCONVERT(Стойност; "Валута1"; "Валута2", ПълнаТочност, МеждТочност)

Стойност е паричната сума, която да бъде преобразувана.

От_валута и Към_валута са паричните единици, между които да се преобразува. Те трябва да представляват текстове – официалните обозначения на валутите (например "EUR"). Курсовете (спрямо евро) са определени от Европейската комисия.

Пълна_точност не е задължителен. Ако се пропусне или има стойност False, резултатът се закръгля според дробните позиции за Валута2. Ако е True, резултатът не се закръгля.

Межд_точност не е задължителен. Ако е зададен и има стойност >=3, междинният резултат при двойно преобразуване (Валута1, EUR, Валута2) се закръглява до тази точност. Ако е пропуснат, междинният резултат не се закръглява. Освен това, ако Валута2 е "EUR", МеждТочност се използва все едно, че е необходимо двойно преобразуване и се прилага преобразуване от EUR към EUR.

Примери

=EUROCONVERT(100;"ATS";"EUR") преобразува 100 австрийски шилинга в евро.

=EUROCONVERT(100;"EUR";"DEM") преобразува 100 евро в германски марки.

ODD

Закръглява положително число нагоре до най-близкото нечетно цяло число, а отрицателно – надолу към най-близкото нечетно цяло число.

Синтаксис

ODD(Число)

Връща Число, закръглено до следващото нечетно цяло число в посока обратно на нулата.

Пример

=ODD(1,2) връща 3.

=ODD(1) връща 1.

=ODD(0) връща 1.

=ODD(-3,1) връща -5.

ABS

Връща абсолютната стойност на число.

Синтаксис

ABS(Число)

Число е числото, чиято абсолютна стойност да бъде изчислена. Абсолютната стойност на число е стойността му без знака +/-.

Пример

=ABS(-56) връща 56.

=ABS(12) връща 12.

=ABS(0) връща 0.


Related Topics

Функции на Calc по категории в WikiHelp сайта на LibreOffice