Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Funciones matemátiques

From LibreOffice Help
Jump to: navigation, search

Esta categoría contién les funciones matemátiques de Calc. el Asistente pa funciones, escueya Inxertar - Función.

Contents

CONVERTIR

Convierte un valor d'una unidá de midida a otra. Los factores de conversión apurrir nuna llista na configuración.

Nel so momentu, la llista de factores de conversión incluyía les monedes europees heredaes y l'euru (ver los exemplos de siguío). Encamiéntase utilizar la nueva función EUROCONVERT pa convertir estes monedes.

Sintaxis

CONVERTIR(valor;"testu";"testu")

Exemplu

=CONVERTIR(100;"ATS";"EUR") devuelve'l valor n'euros de 100 chelines austríacos.

=CONVERTIR(100;"EUR";"DEM") convierte 100 euros en marcos alemanes.

FLOOR.PRECISE

Rounds a number down to the nearest multiple of Significance, regardless of sign of Significance

Syntax

FLOOR.PRECISE(Number; Significance)

Number is the number that is to be rounded down.

Significance is the value to whose multiple the number is to be rounded down.

Example

=FLOOR.PRECISE( -11;-2) returns -12

MÚLTIPLU.INFERIOR

Arredondia un númberu escontra baxo hasta'l múltiplu de cifra significativa más próximu.

Sintaxis

MÚLTIPLU.INFERIOR(númberu; cifra_significativa; mou)

Númberu ye la cifra que se debe arredondiar escontra baxo.

cifra_significativa ye'l númberu que'l so valor de múltiplu tien d'arredondiase escontra baxo.

Mou ye un valor opcional. Si apúrrese'l valor Mou y nun ye igual a cero, y si el so Númberu y cifra significativa son negativos, l'arredondio efeutuar según el valor absolutu del númberu. Esti parámetru omitir al esportase a MS Excel, yá que dichu programa nun conoz nengún tercer parámetru.

Warning.png Si ambos parámetro Númberu y Cifra significatica son negativos, y si el valor Mou ye igual a cero o nun ta especificáu, les resultancies en LibreOffice Calc y Excel van ser distintes depués d'esportar. Si esporta la fueya de cálculu a Excel, use Mou=1 pa ver les mesmes resultancies en Excel como en Calc.

Exemplu

=MÚLTIPLU.INFERIOR( -11;-2) devuelve -12.

=MÚLTIPLU.INFERIOR( -11;-2;0) devuelve -12.

=MÚLTIPLU.INFERIOR( -11;-2;1) devuelve -10.

SIGNU

Devuelve'l signu d'un númberu. La función devuelve como resultáu 1 si'l signu ye positivu y -1 si ye negativu. Si'l númberu ye cero, la función devuelve tamién un cero.

Sintaxis

SIGNU(Númberu)

Númberu ye'l númberu que'l so signu tien de determinase.

Exemplu

=SIGNU(3.4) devuelve 1.

=SIGNU(-4.5) devuelve -1.

REDOND.MULT

La resultancia ye'l múltiplu enteru más próximu del númberu.

Sintaxis

REDOND.MULT(Númberu; Múltiplu)

Devuelve Númberu arrondáu al multiplo mas cercanu a Múltiplu.

Una implementación alternativa va ser Múltiplu * REDOND(Númberu/Multiplo).

Exemplu

=REDOND.MULT(15,5;3) devuelve 15, yá que 15,5 ta más cercanu a 15 (= 3*5) qu'a 18 (= 3*6).

=REDOND.MULT(1.4;0.5) da como resultáu 1,5 (= 0,5*3).

CSCH

Devuelve la cosecante hiperbólica d'un númberu.

Sintaxis

CSCH(Númberu)

Devuelve la cosecante hiperbólica de Númberu.

Exemplu

=CSCH(1) devuelve aproximadamente 0.8509181282, la cosecante hiperbólica de 1.

SECH

Devuelve la secante hiperbólica d'un númberu.

Sintaxis

SECH(Númberu)

Devuelve la secante hiperbólica del Númberu.

Exemplu

=SECH(0) devuelve 1, la secante hiperbólica de 0.

CSC

Devuelve la cosecante d'un ángulu dau (en radianes). La cosecante d'un ángulu equival a 1 dividíu pol senu d'esi ángulu

Sintaxis

CSC(Númberu)

Devuelve la cosecante (trigonométrica) de Númberu, l'ángulu en radianes.

Pa devolver la cosecante d'un ángulu en graos, usa la función RADIANES.

Exemplos

=CSC(PI()/4) devuelve aproximadamente 1.4142135624, l'inversu del senu de PI/4 radianes.

=CSC(RADIANS(30)) devuelve 2, la cosecante de 30 graos.

SEC

Devuelve la secante del ángulu dau (en radianes). La secante d'un ángulu ye equivalente a 1 dividíu pol cosenu d'esi ángulu

Sintaxis

SEC(Númberu)

Devuelve la secante (trigonométrica) de Númberu, l'ángulu en radianes.

Pa devolver el senu d'un ángulu en graos, usa la función RADIANS.

Exemplos

=SEC(PI()/4) devuelve aproximadamente 1.4142135624, l'inversu del cosenu de PI/4 radianes.

=SEC(RADIANS(60)) devuelve 2, la secante de 60 graos.

CUNTAR.BLANCO

Devuelve'l númberu de caxelles baleres.

Sintaxis

CUNTAR.BLANCO(Rangu)

Devuelve'l númberu de caxelles baleres nel rangu de caxellesRangu.

Exemplu

=CUNTAR.BLANCO(A1:B2) devuelve 4 si les caxelles A1, A2, B1 y B2 tán baleres.

ACOS

Devuelve la inversa del cosenu trigonométricu d'un númberu.

Sintaxis

ACOS(Númberu)

_Esta función devuelve la inversa del cosenu trigonométricu del Númberu, que ye l'ángulu (en radianes) que'l so cosenu ye Númberu. L'ángulu devueltu esta ente 0 y PI.

Pa volver l'ángulu en graos, use la función GRAOS.

Exemplu

=ACOS(-1) devuelve 3,14159265358979 (PI radianes).

=GRAOS(ACOS(0,5)) devuelve 60. El cosenu de 60 graos ye 0,5.

ACOSH

Devuelve l'inversu del cosenu hiperbólicu d'un númberu.

Sintaxis

ACOSH(Númberu)

Esta función devuelve l'inversu del cosenu hiperbólicu de Númberu, que ye'l númberu que'l so cosenu hiperbólicu ye Númberu.

Númberu tien de ser mas o igual que 1.

Exemplu

=ACOSH(1) devuelve 0.

=ACOSH(COSH(4)) devuelve 4.

RAIGAÑU

Devuelve'l raigañu cuadráu positiva d'un númberu. El númberu tien de ser positivu.

Sintaxis

RAIGAÑU(Númberu)

Devuelve'l raigañu cuadráu positiva de Númberu.

El númberu tien de ser positivu.

Exemplu

=RAIGAÑU(16) devuelve 4.

=RAIZ(-16) devuelve un fallu de argumentu non válidu.

ACOT

Devuelve l'inversu de la cotanxente del númberu especificáu.

Sintaxis

ACOT(Númberu)

Esta función devuelv()y la cotanxente trigonométrica inversa del Númberu, que ye l'ángulu (en radianes) que'l so númberu ye cotanxente. L'ángulu que devuelve ta ente 0 y PI.

Pa volver l'ángulu en graos, use la función GRAOS.

Exemplu

=ACOT(1) devuelve 0,785398163397448 (PI/4 radianes).

=GRAOS(ACOT(1)) devuelve 45. La tanxente de 45 graos ye 1.

ACOTH

Devuelve l'inversu de la cotanxente hiperbólica del númberu especificáu.

Sintaxis

ACOTH(Númberu)

Esta función devuelve la inversa de la cotanxente hiperbólica de Númberu, que ye'l númberu que la so cotanxente hiperbólica ye Númberu.

Una resultancia da fallu si Númberu esta ente -1 y 1, dambos inclusive.

Exemplu

=ACOTH(1.1) devuelve la cotanxente hiperbólica inversa de 1,1, aprosimao 1,52226.

ASENO

Devuelve la inversa del senu trigonométricu d'un númberu.

Sintaxis

ASENO(Númberu)

Esta función devuelve'l senu trigonométricu inversu del Númberu, que ye l'ángulu (en radianes) que'l so senu ye'l Númberu. L'ángulu que s'amuesa ta ente -PI/2 y +PI/2.

Pa volver l'ángulu en graos, use la función GRAOS.

Exemplu

=ASENO(0) devuelve 0.

=ASENO(1) devuelve 1,5707963267949 (PI/2 radianes).

=GRAOS(ASENO(0,5)) devuelve 30. El senu de 30 graos ye 0,5.

ASENOH

Devuelve'l senu hiperbólicu inversu d'un númberu.

Sintaxis

ASENOH(Númberu)

Esta función devuelve'l senu hiperbólicu inversu del Númberu, que ye'l númberu que'l so senu hiperbólicu ye el númberu.

Exemplu

=ASENOH(-90) da como resultáu aprosimao -5,1929877.

=ASENOH(SENOH(4)) devuelve 4.

ARREYEN

Devuelve la inversa de la tanxente trigonométrica d'un númberu.

Sintaxis

ARREYEN(Númberu)

Esta función devuelve la tanxente trigonométrica inversa del Númberu, que ye l'ángulu (en radianes) que la so tanxente ye'l númberu. L'ángulu amuesa ta ente -PI/2 y PI/2.

Pa volver l'ángulu en graos, use la función GRAOS.

Exemplu

=ARREYEN(1) devuelve 0,785398163397448 (PI/4 radianes).

=GRAOS(ARREYEN(1)) devuelve 45. La tanxente de 45 graos ye 1.

ARREYEN2

Devuelve la inversa de la tanxente trigonométrica de les coordenaes x y y especificaes.

Sintaxis

ARREYEN2(NúmberuX; NúmberuY)

NúmberuX ye'l valor de la coordenada x.

NúmberuY ye'l valor de la coordenada y.

ARREYEN2 devuelve la tanxente trigonométrica inversa, que ye, l'ángulu (en radianes) ente la exa X y una llinia dende'l puntu NúmberuX, NúmberuY al orixe.L'ángulu qu'amuesa ta ente -PI y PI.

Pa volver l'ángulu en graos, use la función GRAOS.

Exemplu

=ARREYEN2(20;20) devuelve 0,785398163397448 (PI/4 radianes).

=GRAOS(ARREYEN2(12,3;12,3)) devuelve 45. La tanxente de 45 graos ye 1.

ATANH

Devuelve la tanxente hiperbólica inversa d'un númberu.

Sintaxis

ATANH(Númberu)

Esta función devuelve la inversa de la tanxente hiperbólica del Númberu, que ye'l númberu que la so tanxente hiperbólica ye Númberu.

El númberu tien d'obedecer a la condición -1 < númberu < 1.

Exemplu

=ATANH(0) devuelve 0.

COS

Devuelve'l cosenu del númberu (ángulu) especificáu.

Sintaxis

COS(Númberu)

Númberu ye'l valor que'l so cosenu tien de calculase.

To return the cosine of an angle in degrees, use the RADIANS function.

Exemplos

=COSENU(PI()/2) devuelve 0, el cosenu de PI/2 radianes.

=COSENU(RADIANES(60)) devuelve 0,5, el cosenu de 60 graos.

COSH

Devuelve'l cosenu hiperbólicu d'un númberu.

Sintaxis

COSH(Númberu)

Númberu ye'l valor que'l so cosenu hiperbólicu tien de calculase.

Exemplu

=COSH(0) devuelve 1, el cosenu hiperbólicu de 0.

COT

Devuelve la cotanxente del ángulu especificáu.

Sintaxis

COT(Númberu)

Númberu ye'l valor que la so cotanxente tien de calculase.

Pa tornar la cotanxente d'un angulo en graos, usa la función de RADIANES.

The cotangent of an angle is equivalent to 1 divided by the tangent of that angle.

Exemplu:

=COT(PI()/4) devuelve 1, la cotanxente de PI/4 radianes.

=COT(RADIANES(45)) devuelve 1, la cotanxente de 45 graos.

RAIZ2PI

Devuelve'l raigañu cuadráu d'un númberu multiplicáu por pi.

Sintaxis

RAIZ2PI(Númberu)

Devuelve'l raigañu cuadráu positiva de (PI multiplicáu pol Númberu).

Esto ye equivalente aRAIGAÑU(PI()*Númberu).

Exemplu

=RAIZ2PI(2) devuelve'l raigañu cuadráu de (2PI), aprosimao 2,506628.

COTH

Devuelve la cotanxente hiperbólica d'un númberu (ángulu) especificáu.

Sintaxis

COTH(Númberu)

Númberu ye'l valor que'l so cotanxente hiperbólica tien de calculase.

Exemplu

=COTH(1) devuelve la cotanxente hiperbólica de 1, aprosimao 1,3130.

GRAOS

Convierte radianes en graos.

Sintaxis

GRAOS(númberu)

Númberu ye l'ángulu en radianes que se va convertir a graos.

Exemplu

=GRAOS(PI()) da como resultáu 180 graos.

EXP

Devuelve la resultancia d'alzar un númberu a una potencia. La constante y tien un valor averáu de 2,71828182845904.

Sintaxis

EXP(Númberu)

Númberu ye la potencia a la que se va alzar el númberu y.

Exemplu

=EXP(1) devuelve 2,71828182845904, la constante matemática y cola precisión de Calc.

FACT

Devuelve'l factorial d'un númberu. FACT(0) devuelve 1. FACT(n) devuelve 1*2*3*4* ... *n.

Sintaxis

FACT(Númberu)

Devuelve Númberu!, el factorial de Númberu, calculáu como 1*2*3*4* ... * Númberu.

=FACT(0) devuelve 1 por definición.

El valor d'un númberu negativu devuelve l'erru "argumentu inválidu".

Exemplu

=FACT(3) devuelve 6.

=FACT(0) devuelve 1.

ENTERU

Arredondia un númberu escontra baxo hasta l'enteru más próximu.

Sintaxis

ENTERU(Númberu)

Devuelve el Númberu arrondáu al enteru mas cercanu.

Los númberos negativos arredondiar al enteru inferior.

Exemplu

=ENTERU(5.7) devuelve 5.

=ENTERU(-1,3) devuelve -2.

ARREDONDIA.PAR

Arredondia un númberu positivu escontra riba hasta l'enteru par más próximu y un númberu negativu escontra baxo hasta l'enteru par más próximu.

Sintaxis

ARREDONDIA.PAR(Númberu)

Devuelve Númberu arrondáu al siguiente enteru par, llueñe de cero.

Exemplos

=ARREDONDIA.PAR(2.3) devuelve 4.

=ARREDONDIA.PAR(2) devuelve 2.

=ARREDONDIA.PAR(0) devuelve 0.

=ARREDONDIA.PAR(-0.5) devuelve -2.

M.C.D

Devuelve'l máximu común divisor de dos o más enteros.

El máximu común divisor ye l'enteru positivu más grande qu'estrema, ensin restu, cada unu de los enteros dados.

Sintaxis

GCD(Enteru1; Enteru2; ...; Enteru30)

Enteros de 1 a 30 son hasta 30 númberos enteros de los que tien de calculase'l máximu común divisor.

Exemplu

=M.C.D(16;32;24) da 8 como resultancia, porque 8 ye'l mayor númberu que pue estremar 16, 24 y 32 ensin restu.

=M.C.D.(B1:B3) onde les caxelles B1, B2, B3 contienen 9, 12, 9 da como resultáu 3.

M.C.D_ADD

La resultancia ye'l máximu común divisor d'una llista de númberos.

Note.png Les funciones que'l so nome termina con _ADD devuelven el mesmu resultáu que les funciones correspondientes de Microsoft Excel. Utilice les funciones ensin _ADD pa llograr resultancies basaes n'estándares internacionales. Por exemplu, la función SEM.DEL.AÑU calcula'l númberu de selmana d'una fecha concreta basándose nel estándar internacional ISO 6801, ente que SEM.DEL.AÑU_ADD devuelve'l mesmu númberu de selmana que Microsoft Excel.

Sintaxis

GGT_ADD(Númberu(s))

Númberu(s) ye una llista d'hasta 30 númberos.

Exemplu

=MCD_ADD(5;15;25) devuelve 5.

ESPAR

Devuelve VERDADERU si'l valor ye un enteru par, y FALSU si ye impar.

Sintaxis

ESPAR(Valor)

Valor ye'l valor que se debe verificar.

Si'l valor nun ye un enteru cualquier díxitu dempués del puntu decimal ignórase. El signu de valor tamién ye ignoráu.

Exemplu

=ESPAR(48) devuelve VERDADERU.

=ESPAR(33) devuelve FALSU.

=ESPAR(0) devuelve VERDADERU.

=ESPAR(-2.1) devuelve VERDADERU.

=ESPAR(3,999) devuelve FALSU.

ESIMPAR

Devuelve VERDADERU si'l valor ye impar, y FALSU si ye par.

Sintaxis

ESIMPAR(Valor)

Valor ye'l valor que se debe verificar.

Si'l valor nun ye un enteru cualquier díxitu dempués del puntu decimal ignórase. El signu de valor tamién ye ignoráu.

Exemplu

=ESIMPAR(33) devuelve VERDADERU.

=ESIMPAR(48) devuelve FALSU.

=ESIMPAR(3.999) devuelve VERDADERU.

=ESIMPAR(-3.1) devuelve VERDADERU.

ALEATORIU.ENTE

Devuelve un númberu enteru al debalu dientro d'un intervalu determináu,

Sintaxis

ALEATORIU.ENTE (menor; mayor)

Devuelve un enteru de númberos aleatorios ente enterosInferior y Cimeru (dambos inclusive).

Esta función xenera un nuevu númberu aleatoriu cada vez que Calc vuelve calcular. Pa forzar a Calc a que vuelva calcular manualmente, calque Mayús+Ctrl+F9.

Pa xenerar númberos aleatorios que nunca recalcular, copie'l conteníu de les caxelles d'esta funció, y use Editar - Pegáu especial (with Apegar too y Fórmules non marcaes y Númberos marcaos).

Exemplu

=ALEATORIU.ENTE(20;30) devuelve un enteru ente 20 y 30.

M.C.M

Devuelve'l mínimu común múltiplu d'unu o más enteros.

Sintaxis

M.C.M(Enteru1; Enteru2; ...; Enteru30)

Enteros de 1 a 30 son númberos hasta 30 númberos enteros de los que tien de calculase'l mínimu común múltiplu.

Exemplu

Si ingresa los númberos 512;1024 y 2000 nel cuadru de testu 1;2 y 3, 128000 va devolvese como resultáu.

MCM_ADD

La resultancia ye'l mínimu común múltiplu d'una llista de númberos.

Note.png Les funciones que'l so nome termina con _ADD devuelven el mesmu resultáu que les funciones correspondientes de Microsoft Excel. Utilice les funciones ensin _ADD pa llograr resultancies basaes n'estándares internacionales. Por exemplu, la función SEM.DEL.AÑU calcula'l númberu de selmana d'una fecha concreta basándose nel estándar internacional ISO 6801, ente que SEM.DEL.AÑU_ADD devuelve'l mesmu númberu de selmana que Microsoft Excel.

Sintaxis

MCM_ADD(Númberu(s))

Númberu(s) ye una llista d'hasta 30 númberos.

Exemplu

=MCM_ADD(5;15;25) devuelve 75.

COMBINAR

Devuelve'l númberu de combinaciones pa un númberu determináu d'oxetos ensin repeticiones.

Sintaxis

COMBINAR(Cuntar1; Cuntar2)

Cuntar1 ye'l númberu d'elementos nel conxuntu.

Cuntar2 ye'l númberu d'elementos qu'escoyer nel conxuntu.

COMBINAR devuelve'l númberu de maneres d'escoyer esos elementos. Por exemplu si hai 3 elementos A, B y C nun conxuntu, pue escoyer 2 elementos de 3 distintes maneres: AB, AC y BC.

COMBINAR aplica la siguiente fórmula: Cuntar1!/(Cuntar2!*(Cuntar1-Cuntar2)!)

Exemplu

=COMBINAR(3;2) devuelve 3.

COMBINAR2

Devuelve'l númberu de combinaciones pa un númberu determináu d'oxetos incluyendo les repeticiones.

Sintaxis

COMBINAR(Cuntar1; Cuntar2)

Cuntar1 ye'l númberu d'elementos nel conxuntu.

Cuntar2 ye'l númberu d'elementos qu'escoyer nel conxuntu.

COMBINATA devuelve la cantidá de maneres úniques d'escoyer esos elementos, onde l'orde d'elección ye irrelevante. Por exemplu, si hai 3 elementos A, B y C nun conxuntu, puen escoyer 2 elementos de 6 maneres distintes: AA, AB, AC, BB, BC y CC.

COMBINAR aplica la siguiente fórmula: (Cuntar1+Cuntar2-1)!/(Cuntar2!(Cuntar1-1)!)

Exemplu

=COMBINA(3;2) devuelve 6.

ATAYAR

Trunca un númberu desaniciando llugares decimales.

Sintaxis

ATAYAR(Númberu; Cuenta)

Devuelve el Númberu siquier Cuntar espacios decimales. L'escesu de decimales son desaniciaos, independientemente del so signu.

ATAYAR(Númberu; 0) pórtase como ENTERU(Númberu) pa los númberos positivos, pero na práctica arredondia escontra cero pa los númberos negativos.

Warning.png La cantidá de decimales visibles de la resultancia especificar en Ferramientes - Opciones - LibreOffice Calc - Calcular.

Exemplu

=ATAYAR(1,239;2) devuelve 1,23. El 9 piérdese.

=ATAYAR(-1.234999;3) devuelve -1.234. Piérdense tolos 9.

LN

Devuelve'l llogaritmu natural basándose na constante y d'un númberu. La constante y tien un valor averáu de 2.71828182845904.

Sintaxis

LN(Númberu)

Númberu ye'l valor que'l so llogaritmu natural tien de calculase.

Exemplu

=LN(3) devuelve'l llogaritmu natural de 3 (aprosimao 1,0986).

=LN(EXP(321)) devuelve 321.

LOG

Devuelve'l llogaritmu d'un númberu na base especificada.

Sintaxis

LOG(Númberu; Base)

Númberu ye'l valor que'l so llogaritmu tien de calculase.

Base (opcional) ye la base emplegada pal cálculu del llogaritmu. Si omítese, asumir la base 10.

Exemplu

=LOG(10;3) devuelve'l llogaritmu con base 3 de 10 (aprosimao 2,0959).

=LOG(7^4;7) devuelve 4.

LOG10

Devuelve'l llogaritmu en base 10 d'un númberu.

Sintaxis

LOG10(Númberu)

Devuelve'l llogaritmu en base 10 d'un Númberu.

Exemplu

=LOG10(5) devuelve'l llogaritmu en base 10 de 5 (aprosimao 0,69897).

ISO.CEILING

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

Syntax

ISO.CEILING(Number; Significance)

Number (required) is the number that is to be rounded up.

Significance (optional) is the number to whose multiple the value is to be rounded up.

Example

=ISO.CEILING(-11;-2) returns -10

CEILING.PRECISE

Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance

Syntax

CEILING.PRECISE(Number; Significance)

Number (required) is the number that is to be rounded up.

Significance (optional) is the number to whose multiple the value is to be rounded up.

Example

=CEILING.PRECISE(-11;-2) returns -10

MÚLTIPLU.SUPERIOR

Arredondia un númberu escontra riba hasta'l múltiplu de cifra significativa más próxima.

Sintaxis

MÚLTIPLU.CIMERU(Númberu; Cifra significativa; Mou)

Númberu ye la cifra que se debe arredondiar.

cifra_significativa ye'l númberu que'l so valor de múltiplu tien d'arredondiase escontra riba.

Mou ye un valor opcional. Si apúrrese'l valor Mou y nun ye igual a cero, y el so Númberu y cifra significativa son negativos, l'arredondio efeutuar según el valor absolutu del númberu. Esti parámetru omitir al esportase a MS Excel, yá que dichu programa nun conoz nengún tercer parámetru.

Warning.png Si ambos parámetro Númberu y Cifra significativa son negativos y el valor Mou ye igual a cero o nun ye dáu, la resultancia en LibreOffice y Excel va ser distinta entós que la importación completárase. Si esporta la fueya de cálculu pa Excel, use Mou=1 pa ver la mesma resultancia en Excel como en Calc.

Exemplu

=MÚLTIPLU.CIMERU(-11;-2) devuelve -10.

=MÚLTIPLU.CIMERU(-11;-2;0) devuelve -10.

=MÚLTIPLU.CIMERU(-11;-2;1) devuelve -12.

PI

Devuelve 3,14159265358979, el valor de la constante matemática PI en 14 decimales.

Sintaxis

PI()

Exemplu

=PI() devuelve 3,14159265358979.

ALEATORIU

Devuelve un númberu aleatoriu ente 0 y 1.

Sintaxis

ALEATORIU( )

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

Pa xenerar númberos aleatorios que nunca recalcular, copie'l conteníu de cada caxella ALEATORIU(), y use Editar - Pegáu especial (with Apegar too y Fórmules non marcaes y Númberos marcaos).

Exemplu

=ALEATORIU() da como resultáu un númberu aleatoriu ente 0 y 1.

MULTINOMIAL

Devuelve'l factorial de la suma de los argumentos estremáu pol productu de los factoriales de los argumentos.

Sintaxis

MULTINOMIAL(Númberu(s))

Númberu(s) ye una llista d'hasta 30 númberos.

Exemplu

=MULTINOMIAL(F11:H11) devuelve 1260, si F11 a H11 contién los valores 2, 3 y 4. Esto correspuende a la fórmula =(2+3+4) / (2!*3!*4!)

POTENCIA

Devuelve la resultancia d'alzar un númberu a una potencia.

Sintaxis

POTENCIA(Base; Esponente)

Devuelve la Base alzada a la potencia del Esponente.

The same result may be achieved by using the exponentiation operator ^:

Base^Esponente

Exemplu

=POTENCIA(4;3) devuelve 64, que ye 4 a la 3.ª potencia.

=4^3 tamién devuelve 4 pa la potencia de 3.

SUMA SERIES

Suma'l primera termino d'una serie de potencies.

SUMA SERIES(x;n;m;coeficientes) = coeficiente_1*x^n + coeficiente_2*x^(n+m) + coeficiente_3*x^(n+2m) +...+ coeficiente_i*x^(n+(i-1)m)

Sintaxis

SUMA.SERIES(X; N; M; Coeficientes)

X ye'l valor d'entrada pa la serie de potencies.

N ye la primer potencia.

M ye la medría p'aumentar N.

Coeficientes ye una serie de coeficientes. Pa cada coeficiente, la suma de la serie ampliar nuna seición.

PRODUCTU

Multiplica tolos númberos indicaos como argumentos y devuelve el productu.

Sintaxis

PRODUCTU(Númberu1; Númberu2; ...; Númberu30)

Númberu1 a 30 son hasta 30 argumentos que'l so productu dir a calcular.

PRODUCTU devuelve númberu1 * númberu2 * númberu3 * ...

Exemplu

=PRODUCTU(2;3;4) devuelve 24.

SUMA.CUADRAOS

Pa llograr la suma de cuadraos de dellos númberos (suma de los cuadraos de los argumentos), introduza lo siguiente nos campos de testu.

Sintaxis

SUMA.CUADRAOS(Númberu1; Númberu2; ...; Númberu30)

Númberu1 a 30 son hasta 30 argumentos que la so suma de los cuadraos va calculase.

Exemplu

Si ingresa los númberos 2; 3 y 4 nel cuadru de testu 1; 2 y 3, 29 va devolvese como resulado.

BORRAFA

Permite calcular la borrafa d'una división por un númberu.

Sintaxis

BORRAFA(Dividendu; Divisor)

Los argumentos enteros pa esta función devuelven Dividendu per Divisor, que ye cuando'l remanente Dividendu estremar por Divisor.

Esta función ye implementada como Dividendu - Divisor * ENTERU(Dividendu/Divisor) , y esta fórmula da los resultaos si l'argumentu nun ye un enteru.

Exemplu

=BORRAFA(22;3) devuelve 1, el restu cuando 22 estremar por 3.

=BORRAFA(11,25;2,5) devuelve 1,25

COCIENTE

Devuelve la parte entera d'una división.

Sintaxis

COCIENTE(Numberador; Denominador)

Devuelve la parte entera del Numberador estremáu pol Denominador.

COCIENTE ye equivalente a ENTERU(numberador/denominador), sacante que pueda reportar fallos con distintos códigos de fallu.

Exemplu

=COCIENTE(11;3) devuelve 3. El restu de 2 piérdese.

RADIANES

Convierte graos en radianes.

Sintaxis

RADIANES(Númberu)

Númberu ye l'ángulu en graos que se va convertir a radianes.

Exemplu

=RADIANES(90) da como resultáu 1,5707963267949, que ye PI/2 na precisión de Calc.

ARREDONDIAR

Devuelve un númberu arrondáu hasta una cantidá determinada de decimales.

Sintaxis

ARREDONDIAR(Númberu; Cuntar)

Devuelve el Númberu arrondáu a Cuntar posiciones decimales. Si Cuntar omítese o ye cero, la función arredondia al enteru más cercanu. Si Cuntar ye negativu, la función arredondia a 10, 100, 1000, etc., más cercanu.

This function rounds to the nearest number. See ROUNDDOWN and ROUNDUP for alternatives.

Exemplu

=ARREDONDIAR(2,348;2) devuelve 2,35.

=ARREDONDIAR(-32.4834;3) devuelve -32.483. Camude'l formatu de la caxella pa ver tolos decimales.

=ARREDONDIAR(2,348;0) devuelve 2.

=ARREDONDIAR(2,5) devuelve 3.

=ARREDONDIAR(987,65;-2) devuelve 1.000.

ARREDONDIAR.MENOS

Arredondia un númberu escontra baxo, escontra cero.

Sintaxis

ARREDONDIAR.MENOS(Númberu; Cuntar)

Devuelve el Númberu arredondiáu escontra baxo (escontra cero) pa Cuntarespacios decimales. Si Cuntar ye omitíu o ye cero, la función arredondia al enteru más cercanu escontra baxo. Si Cuntar ye negativu, la función arredondia escontra baxo al más cercanu 10, 100, 1000, etc.

This function rounds towards zero. See ROUNDUP and ROUND for alternatives.

Exemplu

=ARREDONDIAR.MENOS(1,234;2) devuelve 1,23.

=ARREDONDIAR.MENOS(45.67;0) devuelve 45.

=ARREDONDIAR.MENOS(-45,67) devuelve -45.

=ARREDONDIAR.MENOS(987.65;-2) devuelve 900.

CUNTAR.SI

Devuelve'l númberu de caxelles que cumplen determinaos criterios.

La busca almite espresiones regulares. Pue escribir "tou.*", por exemplu, pa guetar la primer apaición de "tou" siguíu por cualesquier combinación de caráuteres. Si deseya guetar un testu que seya de la mesma una espresión regular, cada caráuter tien de dir precedíu col caráuter \ (barra invertida). Pue activar y desactivar la evaluación automática d'espresiones regulares en Ferramientes - Opciones - LibreOffice Calc - Calcular.

Sintaxis

CUNTAR.SI(Rangu; Criteriu)

Rangu ye l'área na que se van aplicar los criterios.

Criterios indica los criterios en forma de númberu, espresión o cadena de caráuteres. Estos criterios determinen les caxelles que se cunten. Un criteriu de busca pue formulase como una espresión regular, por exemplu "b.*" pa toles pallabres qu'empiecen por "b". Tamién ye posible indicar un rangu de caxelles que contenga un criteriu de busca. Si busca testu lliteral, delimite el testu con comines dobles.

Exemplu

A1:A10 ye un rangu de caxella que contienen los númberos 2000 a 2009. Caxella B1 contién el númberu 2006. Na caxella B2, ingresa una fórmula:

=CUNTAR.SI(A1:A10;2006) da como resultáu 1.

=CUNTAR.SI(A1:A10;B1) da como resultáu 1.

=CUNTAR.SI(A1:A10;">=2006") da como resultáu 4.

=CUNTAR.SI(A1:A10;"<"&B1); cuando B1 contién 2006, devuelve 6.

=CUNTAR.SI(A1:A10;C2) onde la caxella C2 contién el testu >2006 cunta'l númberu de caxelles nel área A1:A10, que son >2006.

Pa cuntar namái númberos negativos: =CUNTAR.SI(A1:A10;"<0")

ARREDONDIAR.MAS

Devuelve un númberu arrondáu escontra riba hasta'l númberu especificáu de decimales.

Sintaxis

ARREDONDIAR.MAS(Númberu; Cuntar)

Devuelve el Númberu arredondiáu escontra riba (llueñe dende'l cero) pa Cuntar espacios decimales. Si Cuntar ye omitíu o ye cero, la función arredondia escontra riba a un enteru. Si Cuntar ye negativu, la función arredondia escontra riba, al siguiente 10, 100, 1000, etc.

This function rounds away from zero. See ROUNDDOWN and ROUND for alternatives.

Exemplu

=ARREDONDIAR.MAS(1.1111;2) devuelve 1.12.

=ARREDONDIAR.MAS(1,2345;1) devuelve 1,3.

=ARREDONDIAR.MAS(45,67;0) devuelve 46.

=ARREDONDIAR.MAS(-45.67) devuelve -46.

=ARREDONDIAR.MAS(987.65;-2) devuelve 1.000.

SENU

Devuelve'l senu del númberu (ángulu) especificáu.

Sintaxis

SENU(Númberu)

Devuelve'l senu (trigonométricu) del Númberu, l'ángulu en radianes.

To return the sine of an angle in degrees, use the RADIANS function.

Exemplu

=SENU(PI()/2) devuelve 1, el senu de PI/2 radianes.

=SENU(RADIANES(30)) da como resultáu 0,5, el senu de 30 graos.

SENOH

Devuelve'l senu hiperbólicu d'un númberu.

Sintaxis

SENOH(Númberu)

Devuelve'l senu hiperbólicu del Númberu.

Exemplu

=SENOH(0) devuelve 0, el senu hiperbólicu de 0.

SUMA

Suma tolos númberos d'una área de caxelles.

Sintaxis

SUMA(Númberu1; Númberu2; ...; Númberu30)

Númberu de 1 a 30 son hasta 30 argumentos que la so suma va calculase.

Exemplu

Si ingresa los númberos2; 3 y 4 na caxa de testu 1; 2 y 3, 9 va ser devueltu como la resultancia.

=SUMA(A1;A3;B5) calcula la suma de los trés caxelles. =SUMA (A1:Y10) calcula la suma de toles caxelles nel rangu d'A1 a Y10.

Les condiciones xuníes por aciu Y puen utilizase xuntu cola función SUMA() d'esta forma:

Exemplu hipotéticu: Introdució factures nuna tabla. La columna A contién el valor de fecha de la factura, na columna B importar. Quier atopar una fórmula que pue utilizar pa devolver el total de toles sumes namái pa un determináu mes, por exemplu, namái la cantidá pal períodu >= 2008-01-01 a <2008-02-01. El rangu de valores a la fecha toma A1:A40, el rangu que contién importar que se totalizaron ye B1:B40. C1 contién la fecha d'entamu, 2008-01-01, de les factures que s'han d'incluyir y C2 la fecha, 2008 -02-01, que yá nun ta incluyíu.

Escriba la fórmula siguiente como fórmula de matriz:

=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Pa escribila como fórmula de matriz, tien de calcar les tecles Mayús + Control + Intro pa zarrar la fórmula, en llugar de calcar solamente Intro. La fórmula apaez ente llaves na barra de fórmules.

{=SUMA((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Formular ye basada nel fechu de que la resultancia d'una comparanza ye 1 si'l criteriu ye conocíu y 0 si'l criteriu nun ye conocíu. La comparanza de resultancies individuales va ser tratada como un arreglu y utilizaos na matriz de multiplicación, y a la fin los valores individuales sumar pa dar la resultancia matriz.

SUMAR.SI

Amiesta les caxelles especificaes por un criteriu determináu. Esta función usar pa guetar nuna área un determináu valor.

La busca almite espresiones regulares. Pue escribir "tou.*", por exemplu, pa guetar la primer apaición de "tou" siguíu por cualesquier combinación de caráuteres. Si deseya guetar un testu que seya de la mesma una espresión regular, cada caráuter tien de dir precedíu col caráuter \ (barra invertida). Pue activar y desactivar la evaluación automática d'espresiones regulares en Ferramientes - Opciones - LibreOffice Calc - Calcular.

Sintaxis

SUMAR.SI(Rangu; Criteriu; Suma de Rangu)

Rangu ye l'área na que se van aplicar los criterios.

Criterios ye la caxella en que s'amuesa'l criteriu de busca, o ye'l criteriu de busca en sí. Si un criteriu escribir na fórmula, tien de quedar llindáu por comines dobles.

Rangu de suma ye l'área dende'l que se suman los valores. Si esti parámetru nun s'indicó, sumir los valores atopaos nel rangu.

Note.png SUMAR.SI soporta l'operador de concatenación () solamente nel parámetru de Criteriu, y si el Rangu de suma nun ta definíu.

Exemplu

Pa sumar namái númberos negativos: =SUMAR.SI(A1:A10;"<0")

=SUMAR.SI(A1:A10;">0";B1:10) suma los valores del área B1:B10 namái si los valores correspondientes nel área A1:A10 son >0.

Consulte CUNTAR.SI() pa llograr más exemplos de sintaxis que puedan utilizase con SUMAR.SI().

TAN

Devuelve la tanxente del ángulu especificáu.

Sintaxis

TAN(Númberu)

Devuelve la tanxente (trigonemétrica) del Númberu, l'ángulu en radianes

To return the tangent of an angle in degrees, use the RADIANS function.

Exemplu

=TAN(PI()/4) devuelve 1, la tanxente de PI/4 radianes.

=TAN(RADIANES(45)) devuelve 1, la tanxente de 45 graos.

TANH

Devuelve la tanxente hiperbólica d'un númberu.

Sintaxis

TANH(Númberu)

Devuelve la tanxente hiperbólica del Númberu.

Exemplu

=TANH(0) devuelve 0, la tanxente hiperbólica de 0.

SUBTOTAL

Calcula subtotales. Si una área yá contién subtotales, éstos nun s'utilicen n'otros cálculos. Utilice esta función en combinación colos filtros automáticos pa tener en cuenta namái los rexistros peñeraos.

Sintaxis

SUBTOTAL(Función; Rangu)

Función ye un númberu que representa una de les siguientes funciones:

Índiz de funciones Función
1 PROMEDIU
2 CUNTAR
3 CUNTARA
4 MÁX
5 MÍN
6 PRODUCTU
7 DESVEST
8 DESVESTP
9 SUMA
10 VAR
11 VARP

Área ye l'área que les sos caxelles tán incluyíes.

Exemplu

La área de caxelles A1:B5 contién una tabla con ciudaes na columna A y cifres rellacionaes na columna B. Utilizó un Filtru automáticu pa ver namái les fileres que contienen la ciudá de Hamburgo. Deseya ver la suma de les cifres amosaes; esto ye, el subtotal de les fileres peñeraes. En tal casu, la fórmula correcta va ser:

=SUBTOTAL(9;B2:B5)

EUROCONVERT

Convierte ente les monedes nacionales europees antigües y los euros.

Sintaxis

EUROCONVERT(Valor; "De_moneda"; "A_moneda", precisión_completa, precisión_triangulación)

Valor ye la cantidá de moneda que se va a convertir.

De_moneda y A_moneda son les unidaes monetaries que se van convertir respectivamente. Tienen De ser testu, l'abreviatura oficial de la moneda (por exemplu, "EUR"). La Comisión Europea estableció los tipos de cambéu (amosaos por Euru).

Precisión_completa ye opcional. Si omítese o ye Falsu, la resultancia arredondiar según los decimales de la moneda de destín. Si Precisión_completa ye Verdaderu, la resultancia nun s'arredondia.

Precisión_triangulación ye opcional. Si apúrrese Precisión_triangulación y >=3, la resultancia entemedia d'una conversión triangular (moneda1,EUR,moneda2) arredondiar a dicha precisión. Si omítese Precisión_triangulación, la resultancia entemedia nun s'arredondia. Amás si A moneda ye "EUR", Precisión_triangulación utilízase como si precisara la triangulación y aplicárase la conversión de EUR a EUR.

Exemplos

=EUROCONVERT(100;"ATS";"EUR") convierte 100 chelines austríacos a euros.

=EUROCONVERT(100;"EUR";"DEM") convierte 100 euros a marcos alemanes.

ARREDONDIA.IMPAR

Arredondia un númberu positivu escontra riba hasta l'enteru impar más próximu siguiente y un númberu negativu escontra baxo hasta l'enteru impar más próximu.

Sintaxis

ARREDONDIA.IMPAR(Númberu)

Devuelve el Númberu arrondáu pal próximu enteru impar, llueñe del cero.

Exemplu

=ARREDONDIA.IMPAR(1.2) devuelve 3.

=ARREDONDIA.IMPAR(1) devuelve 1.

=ARREDONDIA.IMPAR(0) devuelve 1.

=ARREDONDIA.IMPAR(-3.1) devuelve -5.

ABS

Devuelve'l valor absolutu d'un númberu.

Sintaxis

ABS(Númberu)

Númberu ye'l valor que'l so valor absolutu tien de calculase. El valor absolutu d'un númberu ye'l so valor ensin el signu +/-.

Exemplu

=ABS(-56) devuelve 56.

=ABS(12) devuelve 12.

=ABS(0) devuelve 0.


Related Topics

Funciones de Calc por categoría na WikiAyuda de LibreOffice