Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Kategorie Mathematik

From LibreOffice Help
Jump to navigation Jump to search

Diese Kategorie enthält mathematische Funktionen. Wählen Sie Einfügen - Funktion, um das Fenster Funktionsautopilot aufzurufen.

UMRECHNEN

Rechnet den Wert von einer Maßeinheit in eine andere Maßeinheit um. Die Umrechnungsfaktoren sind in einer Konfigurationsliste abgelegt.

Die Umrechnungsliste enthielt die früheren europäischen Währungen und den Euro (siehe Beispiele). Wir empfehlen die neue Funktion EUROUMRECHNEN zu verwenden, um diese Währungen umzurechnen.

Syntax

UMRECHNEN(Wert;"Text";"Text")

Beispiel

=UMRECHNEN(100;"ATS";"EUR") ergibt den Wert von 100 österreichischen Schilling in Euro .

=UMRECHNEN(100;"EUR";"DEM") rechnet 100 Euros in Deutsche Mark um.

UNTERGRENZE

Rundet eine Zahl auf das nächste Vielfache der Schrittweite ab.

Syntax

UNTERGRENZE(Zahl; Schrittweite; Modus)

Zahl ist die Zahl, die abgerundet werden soll.

Schrittweite ist der Wert, auf dessen Vielfaches die Zahl abgerundet wird.

Modus ist ein optionaler Wert. Wenn der gegebene Moduswert nicht gleich null ist und wenn Zahl und Schrittweite negativ sind, erfolgt eine Rundung ausgehend vom absoluten Wert der Zahl. Dieser Parameter wird beim Exportieren nach MS Excel ignoriert, da Excel keinen dritten Parameter kennt.

Warning.png Wenn die beiden Parameter Zahl und Schrittweite negativ sind und der Moduswert gleich null oder nicht angegeben ist, unterscheiden sich die Ergebnisse in LibreOffice und Excel, nachdem der Export abgeschlossen wurde. Wenn Sie das Tabellendokument nach Excel exportieren, verwenden Sie Modus=1, um in Excel dieselben Ergebnisse wie in Calc zu erhalten.

Beispiel

=UNTERGRENZE( -11;-2) ergibt -12

=UNTERGRENZE( -11;-2;0) ergibt -12

=UNTERGRENZE( -11;-2;1) ergibt -10

VORZEICHEN

Liefert das Vorzeichen einer Zahl. Liefert eine 1 wenn die Zahl positiv ist, -1 wenn sie negativ ist und 0 wenn sie Null ist.

Syntax

VORZEICHEN(Zahl)

Zahl ist die Zahl, deren Vorzeichen bestimmt werden soll.

Beispiel

=VORZEICHEN(3,4) ergibt 1.

=VORZEICHEN(-4,5) ergibt -1.

VRUNDEN

Rundet eine Zahl auf das nächste ganzzahlige Vielfache einer anderen Zahl.

Syntax

VRUNDEN(Zahl;Vielfaches)

Rundet Zahl auf das nächste Vielfache von Vielfaches.

Eine alternative Umsetzung ist Vielfaches * RUNDEN(Zahl/Vielfaches).

Beispiel

=VRUNDEN(15,5;3) ergibt 15, da 15,5 dichter an 15 (= 3*5) liegt als an 18 (= 3*6).

=VRUNDEN(1,4;0,5) ergibt 1,5 (= 0,5*3).

ANZAHLLEEREZELLEN

Gibt die Anzahl der leeren Zellen zurück.

Syntax

ANZAHLLEEREZELLEN(Bereich)

Gibt die Anzahl der leeren Zellen im Zellbereich Bereich zurück.

Beispiel

=ANZAHLLEEREZELLEN(A1:B2) ergibt 4, wenn die Zellen A1, A2, B1 und B2 leer sind.

ARCCOS

Berechnet den Arkuskosinus einer Zahl.

Syntax

ARCCOS(Zahl)

Diese Funktion gibt den Arkuskosinus von Zahl zurück, d. h. den Winkel (im Bogenmaß), dessen Kosinus Zahl ist. Der zurückgegebene Winkel liegt zwischen 0 und PI.

Um den Winkel in Grad zu erhalten, verwenden Sie die DEG-Funktion.

Beispiel

=ARCCOS(-1) ergibt 3,14159265358979 (PI/4 Bogenmaß).

=DEG(ARCCOS(0,5)) ergibt 60. Der Kosinus von 60 Grad ist 0,5.

ARCCOSHYP

Berechnet den inversen Hyperbelkosinus (hyperbolischer Kosinus) einer Zahl.

Syntax

ARCCOSHYP(Zahl)

Diese Funktion gibt den inversen Hyperbelkosinus (hyperbolischer Kosinus) von Zahl zurück, d. h. die Zahl, deren Hyperbelkosinus Zahl ist.

Zahl muss größer als oder gleich 1 sein.

Beispiel

=ARCCOSHYP(1) ergibt 0.

=ARCCOSHYP(COSHYP(4)) ergibt 4.

WURZEL

Berechnet die positive Quadratwurzel einer Zahl.

Syntax

WURZEL(Zahl)

Berechnet die positive Quadratwurzel von Zahl.

Zahl muss positiv sein.

Beispiel

=WURZEL(16) ergibt 4.

=WURZEL(-16) gibt den Fehler Ungültiges Argument zurück.

ARCCOT

Berechnet den inversen Kotangens (den Arkuskotangens) der gegebenen Zahl.

Syntax

ARCCOT(Zahl)

Diese Funktion gibt den inversen trigonometrischen Kotangens von Zahl zurück, d. h. den Winkel (im Bogenmaß), dessen Kotangens Zahl ist. Der zurückgegebene Winkel liegt zwischen 0 und PI.

Um den Winkel in Grad zu erhalten, verwenden Sie die DEG-Funktion.

Beispiel

=ARCCOT(1) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=DEG(ARCCOT(1)) ergibt 45. Der Tangens von 45 Grad ist 1.

ARCCOTHYP

Berechnet den Areakotangens (inverser hyperbolischer Kotangens) einer Zahl.

Syntax

ARCCOTHYP(Zahl)

Diese Funktion gibt den inversen hyperbolischen Kotangens von Zahl zurück, d. h. die Zahl, deren hyperbolischer Kotangens Zahl ist.

Ein Fehler tritt auf, wenn Zahl zwischen -1 und einschließlich 1 liegt.

Beispiel

=ARCCOTHYP(1,1) ergibt einen inversen hyperbolischen Kotangens von 1,1, etwa 1,52226.

ARCSIN

Berechnet den Arkussinus einer Zahl.

Syntax

ARCSIN(Zahl)

Diese Funktion gibt den Arkussinus von Zahl zurück, d. h. den Winkel (im Bogenmaß), dessen Sinus Zahl ist. Der zurückgegebene Winkel liegt zwischen -PI/2 und +PI/2.

Um den Winkel in Grad zu erhalten, verwenden Sie die DEG-Funktion.

Beispiel

=ARCSIN(0) ergibt 0.

=ARCSIN(1) ergibt 1,5707963267949 (PI/2 Bogenmaß).

=DEG(ARCSIN(0,5)) ergibt 30. Der Sinus von 30 Grad ist 0,5.

ARCSINHYP

Berechnet den inversen Hyperbelsinus einer Zahl.

Syntax

ARCSINHYP(Zahl)

Diese Funktion gibt den inversen Hyperbelsinus von Zahl zurück, d. h. die Zahl, deren Hyperbelsinus Zahl ist.

Beispiel

=ARCSINHYP(-90) ergibt etwa -5,1929877.

=ARCSINHYP(SINHYP(4)) ergibt 4.

ARCTAN

Berechnet den Arkustangens einer Zahl.

Syntax

ARCTAN(Zahl)

Diese Funktion gibt den Arkustangens von Zahl zurück, d. h. den Winkel (im Bogenmaß), dessen Tangente Zahl ist. Der zurückgegebene Winkel liegt zwischen -PI/2 und PI/2.

Um den Winkel in Grad zu erhalten, verwenden Sie die DEG-Funktion.

Beispiel

=ARCTAN(1) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=DEG(ARCTAN(1)) ergibt 45. Der Tangens von 45 Grad ist 1.

ARCTAN2

Gibt den Arkustangens der angegebenen X- und Y-Koordinaten zurück.

Syntax

ARCTAN2(ZahlX; ZahlY)

ZahlX ist der Wert der X-Koordinate.

ZahlY ist der Wert der Y-Koordinate.

ARCTAN2 gibt den Arkustangens zurück, d. h. den Winkel (im Bogenmaß) zwischen der X-Achse und einer Linie vom Punkt ZahlX, ZahlY zum Ausgangspunkt. Der zurückgegebene Winkel liegt zwischen -PI und PI.

Um den Winkel in Grad zu erhalten, verwenden Sie die DEG-Funktion.

Beispiel

=ARCTAN2(20;20) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=DEG(ARCTAN2(12,3;12,3)) ergibt 45. Der Tangens von 45 Grad ist 1.

ARCTANHYP

Berechnet den Areatangens (inverser hyperbolischer Tangens) einer Zahl.

Syntax

ARCTANHYP(Zahl)

Diese Funktion gibt den Areatangens (inverser hyperbolischer Tangens) von Zahl zurück, d. h. die Zahl, deren hyperbolischer Tangens Zahl ist.

Zahl muss die Bedingung -1 < Zahl < 1 erfüllen.

Beispiel

=ARCTANHYP(0) ergibt 0.

COS

Liefert den Konsinus des gegebenen Winkels (im Bogenmaß).

Syntax

COS(Zahl)

Liefert den (trigonometrischen) Kosinus von Zahl, dem Winkel im Bogenmaß.

Um den Kosinus eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die RAD-Funktion.

Beispiele

=COS(PI()/2) ergibt 0, den Kosinus von PI/2 Bogenmaß.

=COS(RAD(60)) ergibt 0,5, den Kosinus von 60 Grad.

COSHYP

Berechnet den Hyperbelkosinus einer Zahl.

Syntax

COSHYP(Zahl)

Berechnet den Hyperbelkosinus von Zahl.

Beispiel

=COSHYP(0) ergibt 1, den hyperbolischen Kosinus von 0.

COT

Berechnet den Kotangens des (im Bogenmaß) angegebenen Winkels.

Syntax

COT(Zahl)

Liefert den (trigonometrischen) Kotangens von Zahl, dem Winkel im Bogenmaß.

Um den Kotangens eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die RAD-Funktion.

Der Kotangens eines Winkels ist gleich 1 dividiert durch den Tangens desselben Winkels.

Beispiele:

=COT(PI()/4) ergibt 1, den Kotangens von PI/4 Bogenmaß.

=COT(RAD(45)) ergibt 1, den Kotangens von 45 Grad.

WURZELPI

Berechnet die Quadratwurzel einer mit PI multiplizierten Zahl.

Syntax

WURZELPI(Zahl)

Berechnet die positive Quadratwurzel einer mit PI multiplizierten Zahl.

Dies entspricht WURZEL(PI()*Zahl).

Beispiel

=WURZELPI(2) gibt die Quadratwurzel von (2PI) zurück, etwa 2,506628.

COTHYP

Berechnet den Hyperbelkotangens (hyperbolischer Kotangens) einer Zahl (Winkel).

Syntax

COTHYP(Zahl)

Berechnet den hyperbolischen Kotangens von Zahl.

Beispiel

=COTHYP(1) ergibt den hyperbolischen Kotangens von 1, etwa 1,3130.

DEG

Rechnet Bogenmaß (Radiant) in Grad um.

Syntax

DEG(Zahl)

Zahl ist der Winkel im Bogenmaß, der in Grad umgewandelt werden soll.

Beispiel

=DEG(PI()) ergibt 180 Grad.

EXP

Berechnet aus der eingegebenen Zahl den Exponent zur Basis e. Die Konstante e hat den ungefähren Wert 2,71828182845904.

Syntax

EXP(Zahl)

Potenz ist die Hochzahl, mit der e potenziert wird.

Beispiel

=EXP(1) ergibt 2,71828182845904, die mathematische Konstante e für die Genauigkeit von Calc.

FAKULTÄT

Berechnet die Fakultät einer Zahl.

Syntax

FAKULTÄT(Zahl)

Gibt Zahl! zurück, die Fakultät von Zahl, berechnet als 1*2*3*4* ... * Zahl.

=FAKULTÄT(0) ergibt per Definition 1.

Die Fakultät einer negativen Zahl liefert den Fehler "Ungültiges Argument".

Beispiel

=FAKULTÄT(3) ergibt 6.

=FAKULTÄT(0) ergibt 1

GANZZAHL

Die im Textfeld eingegebenen Zahl wird auf die nächst kleinere ganze Zahl abgerundet.

Syntax

GANZZAHL(Zahl)

Gibt Zahl zurück, abgerundet auf die nächste kleinere Ganzzahl.

Negative Zahlen werden zur nächsten ganzen Zahl abgerundet.

Beispiel

=GANZZAHL(5,7) ergibt 5.

=GANZZAHL(-1,3) ergibt -2.

GERADE

Rundet eine positive Zahl auf die nächste Ganzzahl auf und eine negative Zahl auf die nächste Ganzzahl ab.

Syntax

GERADE(Zahl)

Gibt Zahl zurück, gerundet auf die nächste gerade Ganzzahl, weg von Null.

Beispiele

=GERADE(2,3) ergibt 4.

=GERADE(2) ergibt 2.

=GERADE(0) ergibt 0.

=GERADE(-0,5) ergibt -2.

GGT

Berechnet den größten gemeinsamen Teiler von zwei oder mehr Ganzzahlen.

Der größte gemeinsame Teiler ist die größte positive ganze Zahl, die durch die sich jede der angegebenen ganzen Zahlen ohne einen Rest teilen lassen.

Syntax

GGT(Ganzzahl 1; Ganzzahl 2; ...; Ganzzahl 30)

Ganzzahl 1 bis 30 sind bis zu 30 Ganzzahlen, deren größter gemeinsamer Teiler berechnet werden soll.

Beispiel

=GGT(16;32;24) ergibt 8, weil 8 die größte Zahl ist, mit der 16, 24 und 32 ohne Rest geteilt werden kann.

=GGT(B1:B3) ergibt 3, wenn die Zellen B1, B2, B3 9, 12, 9 enthalten.

GGT_ADD

Das Ergebnis ist der größte gemeinsame Teiler einer Liste von Zahlen.

Note.png Die Funktionen, deren Namen mit _ADD enden, geben dieselben Ergebnisse zurück wie die entsprechenden Microsoft Excel-Funktionen. Verwenden Sie die Funktionen ohne _ADD, um Ergebnisse zu erhalten, die auf internationalen Standards basieren. So berechnet beispielsweise die Funktion KALENDERWOCHE die Wochennummer eines angegebenen Datums, basierend auf dem internationalen Standard ISO 8601, während KALENDERWOCHE_ADD dieselbe Wochennummer zurückgibt wie Microsoft Excel.

Syntax

GGT_ADD(Zahl(en))

Zahl(en) ist eine Liste von bis zu 30 Zahlen.

Beispiel

=GGT_ADD(5;15;25) ergibt 5.

ISTGERADE

Liefert WAHR, wenn der Wert eine gerade Ganzzahl ist und FALSCH, wenn er ungerade ist.

Syntax

ISTGERADE(Wert)

Wert ist der zu prüfende Wert.

Wenn Wert keine Ganzzahl ist, werden Ziffern nach dem Dezimalkomma ignoriert. Das Vorzeichen von Wert wird ebenfalls ignoriert.

Beispiel

=ISTGERADE(48) gibt WAHR zurück.

=ISTGERADE(33) gibt FALSCH zurück.

=ISTGERADE(0) ergibt WAHR.

=ISTGERADE(-2,1) gibt WAHR zurück

=ISTGERADE(3,999) gibt FALSCH zurück.

ISTUNGERADE

Liefert WAHR, wenn der Wert eine ungerade Ganzzahl ist und FALSCH, wenn er gerade ist.

Syntax

ISTUNGERADE(Wert)

Wert ist der zu prüfende Wert.

Wenn Wert keine Ganzzahl ist, werden Ziffern nach dem Dezimalkomma ignoriert. Das Vorzeichen von Wert wird ebenfalls ignoriert.

Beispiel

=ISTUNGERADE(33) gibt WAHR zurück

=ISTUNGERADE(48) ergibt FALSCH.

=ISTUNGERADE(3,999) gibt WAHR zurück

=ISTUNGERADE(-3,1) gibt WAHR zurück

ZUFALLSBEREICH

Liefert eine ganze Zufallszahl aus einem festgelegten Bereich.

Syntax

ZUFALLSBEREICH(Kleinste Zahl; Größte Zahl)

Gibt eine ganze Zufallszahl zwischen den Ganzzahlen Kleinste Zahl und Größte Zahl (einschließlich beide Zahlen).

Diese Funktion erzeugt jedes mal, wenn Calc neu berechnet, neue Zufallszahlen. Um die Neuberechnung in Calc zu erzwingen, drücken Sie Umschalt+Strg+F9.

Um Zufallszahlen zu generieren, die nie neu berechnet werden, kopieren Sie Zellen, in denen diese Funktion enthalten ist, und verwenden Bearbeiten - Inhalt einfügen (wobei Alles einfügen und Formeln nicht aktiviert sein darf und Zahlen aktiviert sein muss).

Beispiel

=ZUFALLSBEREICH(20;30) gibt eine Ganzzahl zwischen 20 und 30 zurück.

KGV

Berechnet das kleinste gemeinsame Vielfache von zwei oder mehr Ganzzahlen.

Syntax

KGV(Ganzzahl 1; Ganzzahl 2; ...; Ganzzahl 30)

Ganzzahl 1 bis 30 sind bis zu 30 Ganzzahlen, deren kleinstes gemeinsames Vielfaches berechnet werden soll.

Beispiel

Wenn Sie die Zahlen 512;1024 und 2000 in die Textfelder "Ganzzahl 1;2 und 3" eingeben, wird 128000 als Ergebnis zurückgegeben.

KGV_ADD

Das Ergebnis ist das kleinste gemeinsame Vielfache einer Liste von Zahlen.

Note.png Die Funktionen, deren Namen mit _ADD enden, geben dieselben Ergebnisse zurück wie die entsprechenden Microsoft Excel-Funktionen. Verwenden Sie die Funktionen ohne _ADD, um Ergebnisse zu erhalten, die auf internationalen Standards basieren. So berechnet beispielsweise die Funktion KALENDERWOCHE die Wochennummer eines angegebenen Datums, basierend auf dem internationalen Standard ISO 8601, während KALENDERWOCHE_ADD dieselbe Wochennummer zurückgibt wie Microsoft Excel.

Syntax

KGV_ADD(Zahl(en))

Zahl(en) ist eine Liste von bis zu 30 Zahlen.

Beispiel

=KGV_ADD(5;15;25) ergibt 75.

KOMBINATIONEN

Gibt die Anzahl von Kombinationen für Elemente ohne Wiederholung zurück.

Syntax

KOMBINATIONEN(Count1; Count2)

Count1 ist die Anzahl von Elementen in der Gruppe.

Count2 ist die Anzahl von Elementen, die aus der Gruppe ausgewählt werden.

KOMBINATIONEN gibt die geordneten Möglichkeiten zur Auswahl diese Elemente zurück. Wenn beispielsweise 3 Elemente A, B und C in einer Gruppe zusammengefasst sind, haben Sie 3 verschiedene Möglichkeiten, um 2 Elemente auszuwählen, nämlich AB, AC und BC.

KOMBINATIONEN führt folgende Formel aus: Count1!/(Count2!*(Count1-Count2)!)

Beispiel

=KOMBINATIONEN(3;2) ergibt 3.

KOMBINATIONEN2

Gibt die Anzahl von Kombinationen einer Teilmenge von Elementen einschließlich Wiederholung zurück.

Syntax

KOMBINATIONEN2(Count1; Count2)

Count1 ist die Anzahl von Elementen in der Gruppe.

Count2 ist die Anzahl von Elementen, die aus der Gruppe ausgewählt werden.

KOMBINATIONEN2 gibt die Anzahl von eindeutigen Möglichkeiten zur Auswahl dieser Elemente zurück, wobei die Reihenfolge der Auswahl irrelevant ist. Wenn beispielweise 3 Elemente A,B und C in einer Gruppe zusammengefasst sind, haben Sie 6 Möglichkeiten, um 2 Elemente auszuwählen, nämlich AA, AB, AC, BB, BC und CC.

KOMBINATIONEN2 führt folgende Formel aus: (Count1+Count2-1)! / (Count2!(Count1-1)!)

Beispiel

=KOMBINATIONEN(3;2) ergibt 6.

KÜRZEN

Kürzt eine Zahl durch das Entfernen von Dezimalstellen.

Syntax

KÜRZEN(Zahl; Count)

Gibt Zahl zurück, mit den möglichen durch Count definierten Dezimalstellen. Überschüssige Dezimalstellen werden einfach entfernt, ungeachtet des Vorzeichens.

KÜRZEN(Zahl; 0) verhält sich wie GANZZAHL(Zahl) bei positiven Zahlen, bei negativen Zahlen wird jedoch in Richtung Null gerundet.

Warning.png Die sichbaren Dezimalstellen eines Ergebnisses können Sie unter Extras - Optionen... - LibreOffice Calc - Berechnen einstellen.

Beispiel

=KÜRZEN(1,239;2) ergibt 1,23. Die 9 wird nicht angezeigt.

=KÜRZEN(-1,234999;3) ergibt -1,234. Die Neunen werden nicht angezeigt.

LN

Aus dem eingegebenen Wert wird der natürliche Logarithmus zur Basis e berechnet. Die Konstante e hat den ungefähren Wert 2,71828182845904.

Syntax

LN(Zahl)

Zahl ist der Wert, dessen natürlicher Logarithmus berechnet werden soll.

Beispiel

=LN(3) ergibt den natürlichen Logarithmus von 3 (etwa 1,0986).

=LN(EXP(321)) ergibt 321.

LOG

Berechnet den Logarithmus zu einer angegebenen Basis.

Syntax

LOG(Zahl; Basis)

Zahl ist der Wert, dessen Logarithmus berechnet werden soll.

Basis (optional) ist die Basis des Logarithmus. Wenn dieser Parameter fehlt, wird als Basis 10 angenommen

Beispiel

=LOG(10;3) ergibt den Logarithmus zur Basis 3 von 10 (etwa 2,0959).

=LOG(7^4;7) ergibt 4.

LOG10

Aus dem im Textfeld eingegebenen Wert wird der Logarithmus zur Basis 10 berechnet.

Syntax

LOG10(Zahl)

Aus Zahl wird der Logarithmus zur Basis 10 berechnet.

Beispiel

=LOG10(5) ergibt den Logarithmus zur Basis 10 von 5 (etwa 0,69897).

OBERGRENZE

Rundet eine Zahl auf das nächste Vielfache der Schrittweite auf.

Syntax

OBERGRENZE(Zahl; Schrittweite; Modus)

Zahl ist die Zahl, die aufgerundet werden soll.

Schrittweite ist die Zahl, auf deren Vielfaches der Wert aufgerundet wird.

Modus ist ein optionaler Wert. Wenn der gegebene Moduswert nicht gleich null ist und wenn Zahl und Schrittweite negativ sind, erfolgt eine Rundung ausgehend vom absoluten Wert von Zahl. Dieser Parameter wird beim Exportieren nach MS Excel ignoriert, da Excel keinen dritten Parameter kennt.

Warning.png Wenn die beiden Parameter Zahl und Schrittweite negativ sind und der Moduswert gleich null oder nicht angegeben ist, unterscheiden sich die Ergebnisse in LibreOffice und Excel, nachdem der Import abgeschlossen wurde. Wenn Sie das Tabellendokument nach Excel exportieren, verwenden Sie Modus=1, um in Excel dieselben Ergebnisse wie in Calc zu erhalten.

Beispiel

=OBERGRENZE(-11;-2) ergibt -10

=OBERGRENZE(-11;-2;0) ergibt -10

=OBERGRENZE(-11;-2;1) ergibt -12

PI

Gibt 3,14159265358979 zurück, der Wert der mathematischen Konstanten PI mit 14 Dezimalstellen.

Syntax

PI()

Beispiel

=PI() ergibt 3,14159265358979.

ZUFALLSZAHL

Mit dieser Funktion können Sie sich eine Zufallszahl aus dem Bereich 0 bis 1 erzeugen lassen.

Syntax

ZUFALLSZAHL()

Diese Funktion erzeugt jedes mal, wenn Calc neu berechnet, neue Zufallszahlen. Um die Neuberechnung in Calc zu erzwingen, drücken Sie Umschalt+Strg+F9.

Um Zufallszahlen zu generieren, die nie neu berechnet werden, kopieren Sie Zellen, in denen =ZUFALLSZAHL() enthalten ist, und verwenden Bearbeiten - Inhalt einfügen (wobei Alles einfügen und Formeln nicht aktiviert sein darf und Zahlen aktiviert sein muss).

Beispiel

=ZUFALLSZAHL() gibt eine Zufallszahl zwischen 0 und 1 zurück.

POLYNOMIAL

Ergibt die Fakultät der Summe der Argumente geteilt durch das Produkt der Fakultäten der Argumente.

Syntax

POLYNOMIAL(Zahl(en))

Zahl(en) ist eine Liste von bis zu 30 Zahlen.

Beispiel

=POLYNOMIAL(F11:H11) ergibt 1260, wenn in F11 bis H11 die Werte 2, 3 und 4 enthalten sind. Dies entspricht der Formel =(2+3+4)! / (2!*3!*4!)

POTENZ

Ergibt die Zahl hoch einer anderen Zahl.

Syntax

POTENZ(Basis; Exponent)

Ergibt Basis hoch Exponent.

Das gleiche Resultat wird erzielt, wenn man den Exponentialoperator ^ verwendet:

Basis^Exponent

Beispiel

=POTENZ(4;3) ergibt 64, also 4 hoch 3.

=4^3 ergibt auch 4 hoch 3.

POTENZREIHE

Summiert die ersten Glieder einer Potenzreihe.

POTENZREIHE(X;N;M;Koeffizienten) = Koeffizient_1*X^N + Koeffizient_2*X^(N+M) + Koeffizient_3*X^(N+2M) +...+ Koeffizient_i*X^(N+(i-1)M)

Syntax

POTENZREIHE(X; N; M; Koeffizienten)

X ist der Eingabewert für die Potenzenfolge.

N ist der Anfangsexponent

M ist das Inkrement zur Erhöhung von N.

Koeffizienten ist eine Reihe von Koeffizienten. Für jeden Koeffizienten wird die Reihensumme um einen Abschnitt erweitert.

PRODUKT

Multipliziert alle als Argumente eingegebenen Zahlen und liefert das Produkt.

Syntax

PRODUKT(Zahl 1; Zahl 2; ...; Zahl 30)

Zahl 1 bis 30 sind bis zu 30 Argumente, deren Produkt berechnet werden soll.

PRODUKT berechnet Zahl 1* Zahl 2 * Zahl 3*...

Beispiel

=PRODUKT(2;3;4) ergibt 24.

QUADRATESUMME

Möchten Sie aus Zahlen eine Quadratesumme berechnen (Summierung der Quadrate der Argumente), so geben Sie diese in die Textfelder ein.

Syntax

QUADRATSUMME(Zahl 1; Zahl 2; ...; Zahl 30)

Zahl 1 bis 30 sind bis zu 30 Argumente, deren Quadratsumme berechnet werden soll.

Beispiel

Wenn Sie die Zahlen 2;3 und 4 in die Textfelder "Zahl 1;2 und 3" eingeben, wird 29 als Ergebnis zurückgegeben.

REST

Berechnet den Restwert bei einer Division einer Ganzzahl durch eine andere.

Syntax

REST(Divident; Divisor)

Bei ganzzahligen Argumenten gibt diese Funktion Dividend Modulo Divisor zurück, d. h. den Rest, wenn der Dividend durch den Divisor geteilt wird.

Diese Funktion wird als Dividend - Divisor * GANZZAHL(Dividend/Divisor) ausgeführt, und diese Formel berechnet das Ergebnis, wenn die Argumente keine Ganzzahlen sind.

Beispiel

=REST(22;3) ergibt 1, den Rest der Division von 22 durch 3.

=REST(11,25;2,5) ergibt 1,25.

QUOTIENT

Gibt den ganzzahligen Teil einer Division zurück.

Syntax

QUOTIENT(Zähler; Nenner)

Gibt den ganzzahligen Teil der Division von Zähler geteilt durch Nenner zurück.

QUOTIENT ist gleich zu GANZZAHL(Zähler/Nenner, außer, dass gegebenenfalls andere Fehlercodes gemeldet werden.

Beispiel

=QUOTIENT(11;3) ergibt 3. Der Rest 2 wird nicht angezeigt.

RAD

Aus der im Textfeld eingegebenen Gradzahl wird das Bogenmaß berechnet.

Syntax

RAD(Zahl)

Zahl ist der Winkel in Grad, der in Bogenmaß umgewandelt werden soll.

Beispiel

=RAD(90) ergibt 1,5707963267949, d. h. PI/2 für die Genauigkeit von Calc.

RUNDEN

Rundet eine Zahl auf eine festgelegte Anzahl von Nachkommastellen.

Syntax

RUNDEN(Zahl; Count)

Gibt Zahl zurück, gerundet auf die durch Count definierten Dezimalstellen. Wenn Count weggelassen wird oder null ist, rundet die Funktion auf die nächste Ganzzahl. Wenn Count negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 usw.

Diese Funktion rundet auf die nächstgelegene Zahl. Für Alternativen siehe ABRUNDEN und AUFRUNDEN.

Beispiel

=RUNDEN(2,348;2) ergibt 2,35.

=RUNDEN(-32,4834;3) ergibt -32,483. Ändern Sie das Zellenformat, um alle Dezimalzahlen anzuzeigen.

=RUNDEN(2,348;0) ergibt 2.

=RUNDEN(2,5) ergibt 3.

=RUNDEN(987,65;-2) ergibt 1000.

ABRUNDEN

Rundet eine Zahl gegen Null mit einer bestimmten Genauigkeit ab.

Syntax

ABRUNDEN(Zahl; Count)

Gibt Zahl zurück, abgerundet (Richtung Null) auf durch Count definierte Dezimalstellen. Wenn Count weggelassen wird oder null ist, rundet die Funktion auf eine Ganzzahl ab. Wenn Count negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 usw. ab.

Diese Funktion rundet Richtung Null ab. Für Alternativen sehen sie auch AUFRUNDEN und RUNDEN.

Beispiel

=ABRUNDEN(1,234;2) ergibt 1,23.

=ABRUNDEN(45,67;0) ergibt 45.

=ABRUNDEN(-45,67) ergibt -45.

=ABRUNDEN(987,65;-2) ergibt 900.

ZÄHLENWENN

Hiermit geben Sie die Anzahl der Zellen in einem Zellbereich zurück, die ein bestimmtes Kriterium erfüllen.

Die Suche unterstützt reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendein Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in Extras - Optionen - LibreOffice Calc - Berechnen ein und ausschalten.

Syntax

ZÄHLENWENN(Bereich; Kriterien)

Bereich ist der Bereich, auf den die Kriterien angewendet werden sollen.

Kriterien zeigt die Kriterien in Form einer Zahl, eines Ausdrucks oder einer Zeichenkette an. Diese Kriterien bestimmen, welche Zellen gezählt werden. Sie können auch einen Suchtext in Form eines regulären Ausdrucks eingeben, z. B. b.* für alle Wörter, die mit b beginnen. Sie können auch einen Zellbereich angeben, in dem das Suchkriterium enthalten ist. Wenn Sie nach Literaltext suchen, schließen Sie den Text in doppelten Anführungsstrichen ein.

Beispiel

A1:A10 ist ein Zellbereich, der die Zahlen 2000 bis 2009 enthält. Die Zelle B1 enthält die Zahl 2006. In Zelle B2 geben Sie eine Formel ein:

=ZÄHLENWENN(A1:A10;2006) ergibt 1.

=ZÄHLENWENN(A1:A10;B1) ergibt 1.

=ZÄHLENWENN(A1:A10;">=2006") ergibt 3.

=ZÄHLENWENN(A1:A10;"<"&B1) - wenn in B1 2006 enthalten ist, wird 6 zurückgegeben

=ZÄHLENWENN(A1:A10;C2) zählt die Anzahl von Zellen im Bereich A1:A10, wenn Zelle C2 den Text >2006 enthält. Das Ergebnis ist >2006

So zählen Sie ausschließlich negative Zahlen: =ZÄHLENWENN(A1:A10;"<0")

AUFRUNDEN

Rundet eine von Null verschiedene Zahl mit einer festgelegten Genauigkeit auf.

Syntax

AUFRUNDEN(Zahl; Count)

Gibt Zahl zurück, aufgerundet (weg von Null) auf Dezimalstellen, die durch Count definiert sind. Wenn Count weggelassen wird oder null ist, rundet die Funktion auf eine Ganzzahl auf. Wenn Count negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 usw. auf.

Diese Funktion rundet von Null weg. Für Alternativen siehe ABRUNDEN und RUNDEN.

Beispiel

=AUFRUNDEN(1,1111;2) ergibt 1,12.

=AUFRUNDEN(1,2345;1) ergibt 1,3.

=AUFRUNDEN(45,67;0) ergibt 46.

=AUFRUNDEN(-45,67) ergibt -46.

=AUFRUNDEN(987,65;-2) ergibt 1000.

SIN

Berechnet den Sinus eines gegebenen Winkels (im Bogenmaß (rad)).

Syntax

SIN(Zahl)

Berechnet den (trigonometrischen) Sinus von Zahl, den Winkel im Bogenmaß.

Um den Sinus eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die RAD-Funktion.

Beispiel

=SIN(PI()/2) ergibt 1, den Sinus von PI/2 Bogenmaß.

=SIN(RAD(30)) ergibt 0,5, den Sinus von 30 Grad.

SINHYP

Berechnet den Hyperbelsinus (hyperbolischer Sinus) einer Zahl.

Syntax

SINHYP(Zahl)

Berechnet den Hyperbelsinus von Zahl.

Beispiel

=SINHYP(0) ergibt 0, den Hyperbelsinus von 0.

SUMME

Summiert alle Zahlen eines Zellbereichs.

Syntax

SUMME(Zahl 1; Zahl 2; ...; Zahl 30)

Zahl 1 bis Zahl 30 sind bis zu 30 Argumente, deren Summe berechnet werden soll.

Beispiel

Wenn Sie die Zahlen 2;3 und 4 in die Textfelder "Zahl 1;2 und 3" eingeben, wird 9 als Ergebnis zurückgegeben.

=SUMME(A1;A3;B5) berechnet die Summe der drei Zellen. =SUMME (A1:E10) berechnet die Summe aller Zellen im Bereich A1 bis E10.

In SUMME()-Funktionen können UND-Verknüpfungen wie folgt eingesetzt werden:

Annahme (Beispiel): Sie habe Rechnungen in eine Tabelle eingegeben. Spalte A enthält den Datumswert der Rechnung, Spalte B die Beträge. Sie möchten eine Formel verwenden, mit der Sie die Summe aller Beträge für einen bestimmten Monat berechnen können, z. B. den Betrag für den Zeitraum >=1.1.2008 bis <1.2.2008. Der Bereich mit den Datumswerten umfasst A1:A40, der Bereich mit den zusammenzurechnenden Beträgen umfasst B1:B40. C1 enthält das Anfangsdatum 1.1.2008 der einzubeziehenden Rechnungen, und C2 enthält das Datum 1.2.2008, das nicht mehr einbezogen wird.

Geben Sie die folgende Formel als Matrixformel ein:

=SUMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Um diese Formel als eine Matrixformel einzugeben, schließen Sie sie nicht einfach durch Drücken der Eingabetaste ab, sondern beenden den Befehl mit Umschalt + Strg+Eingabetaste. Die Formel in der Formelleiste wird daraufhin in geschweifte Klammern gesetzt.

{=SUMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Die Formel basiert auf der Tatsache, dass das Ergebnis eines Vergleichs 1 ist, wenn das Kriterium erfüllt ist, und 0, wenn das Kriterium nicht erfüllt ist. Die einzelnen Vergleichsergebnisse werden als Matrix behandelt und in der Matrixmultiplikation verwendet, und abschließend werden die einzelnen Werte zusammengerechnet, woraus sich die Ergebnismatrix ergibt.

SUMMEWENN

Möchten Sie eine Summierung der Argumente nur wenn bestimmte Bedingungen erfüllt sind, geben Sie den Bereich, die Kriterien und optional den Summenbereich ein. Diese Funktion können Sie anwenden, um einen Bereich nach einem bestimmten Wert zu durchsuchen.

Die Suche unterstützt reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendein Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in Extras - Optionen - LibreOffice Calc - Berechnen ein und ausschalten.

Syntax

SUMMEWENN(Bereich; Kriterien; Summierbereich)

Bereich ist der Bereich, auf den die Kriterien angewendet werden sollen.

Kriterien ist die Zelle, in der das Suchkriterium angegeben ist, oder das Suchkriterium selbst. Das Kriterium wird in die Formel eingefügt und muss in doppelten Anführungszeichen stehen.

Summierbereich ist der Bereich, aus dem Werte summiert werden. Wenn dieser Parameter nicht angegeben ist, werden die im Bereich gefundenen Werte summiert.

Note.png SUMMEWENN unterstützt den Bezugsverkettungsoperator (~) nur im Parameter Kriterien, und nur, wenn der optionale Parameter Summierbereich nicht angegeben ist.

Beispiel

Summieren ausschließlich negativer Zahlen: =SUMMEWENN(A1:A10;"<0")

=SUMMEWENN(A1:A10;">0";B1:10) summiert nur Werte aus dem Bereich B1:B10, wenn die entsprechenden Werte im Bereich A1:A10 größer als 0 sind.

Weitere Syntaxbeispiele für die Funktion SUMMEWENN() finden Sie unter ZÄHLENWENN().

TAN

Berechnet den Tangens des gegebenen Winkels (im Bogenmaß).

Syntax

TAN(Zahl)

Berechnet den (trigonometrischen) Tangens von Zahl, den Winkel im Bogenmaß.

Um den Tangens eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die RAD-Funktion.

Beispiel

=TAN(PI()/4) ergibt 1, den Tangens von PI/4 Bogenmaß.

=TAN(RAD(45)) ergibt 1, den Tangens von 45 Grad.

TANHYP

Berechnet den Hyperbeltangens (hyperbolischer Tangens) einer Zahl.

Syntax

TANHYP(Zahl)

Berechnet den hyperbolischen Tangens von Zahl.

Beispiel

=TANHYP(0) ergibt 0, den hyperbolischen Tangens von 0.

TEILERGEBNIS

Berechnet Teilergebnisse. Sollte ein Bereich bereits Teilergebnisse enthalten, werden diese nicht in die weitere Berechnung einbezogen. Verwenden Sie diese Funktion gemeinsam mit AutoFiltern, damit nur die gefilterten Datensätze berücksichtigt werden.

Syntax

TEILERGEBNIS(Funktion; Bereich)

Funktion ist eine Zahl, die für eine der folgenden Funktionen steht:

Funktionsindex Funktion
1 MITTELWERT
2 ANZAHL
3 ANZAHL2
4 MAX
5 MIN
6 PRODUKT
7 STABW
8 STABWN
9 SUMME
10 VARIANZ
11 VARIANZEN

Bereich ist der Bereich, dessen Zellen berücksichtigt werden.

Beispiel

Gegeben sei eine über den Zellbereich A1:B5 ausgedehnte Tabelle mit Städten in Spalte A und Begleitzahlen in Spalte B. Sie haben einen AutoFilter angewendet, der nur die Zeilen anzeigt, in welchen die Stadt Hamburg enthalten ist. Nun möchten Sie die Summe der angezeigten Zahlen ermitteln, also ein Teilergebnis für die gefilterten Zeilen. In diesem Fall lautet die richtige Formel:

=TEILERGEBNIS(9;B2:B5)

EUROUMRECHNEN

Rechnet ehemalige europäische nationale Währungen nach Euro und von Euro um.

Syntax

EUROUMRECHNEN(Wert;"Ausgangwährung";"Zielwährung";Volle Genauigkeit;Zwischenergebnis-Genauigkeit)

Wert ist der Betrag der umzurechnenden Währung.

Ausgangswährung und Zielwährung sind die Währungseinheiten, aus denen bzw. in die umgerechnet wird. Diese müssen aus einem Text bestehen, der eine offizielle Abkürzung der Währung ist (zum Beispiel "EUR"). Die (pro Euro angezeigten) Währungskurse wurden von der Europäischen Kommission festgelegt.

Volle Genauigkeit ist ein optionaler Parameter. Wenn er fehlt oder FALSCH ist, wird das Resultat auf die, der Zielwährung entsprechende Stellenanzahl gerundet. Wenn Volle Genauigkeit WAHR ist, wird das Ergebnis nicht gerundet.

Zwischenergebnis-Genauigkeit ist ein optionaler Parameter. Wenn die Zwischenergebnis-Genauigkeit angeben und >=3 ist, wird das Zwischenergebnis Umwandlung (Währung1, EUR, Währung2) auf diese Genauigkeit gerundet. Wenn Zwischenergebnis-Genauigkeit fehlt wird das Zwischenergebnis nicht gerundet, auch wenn die Zielwährung "EUR" ist.

Beispiele

=EUROUMRECHNEN(100;"ATS";"EUR") rechnet 100 Schilling in Euro um.

=EUROUMRECHNEN(100;"EUR";"DEM") rechnet 100 Euro in Deutsche Mark um.

UNGERADE

Rundet eine positive Zahl auf die nächste ungerade Ganzzahl auf und eine negative Zahl auf die nächste ungerade Ganzzahl ab.

Syntax

UNGERADE(Zahl)

Gibt Zahl zurück, gerundet auf die nächste ungerade Ganzzahl, weg von Null.

Beispiel

=UNGERADE(1,2) ergibt 3.

=UNGERADE(1) ergibt 1.

=UNGERADE(0) ergibt 1.

=UNGERADE(-3,1) ergibt -5.

ABS

Hier können Sie den Absolutwert einer Zahl berechnen.

Syntax

ABS(Zahl)

Zahl ist die Zahl, von der der Betrag errechnet werden soll. Der Betrag einer Zahl ist ihr Wert ohne +/- Zeichen.

Beispiel

=ABS(-56) ergibt 56.

=ABS(12) ergibt 12.

=ABS(0) ergibt 0


Related Topics

Calc Funktionen im OpenOffice.org Wiki