Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Tratar células vazias

From LibreOffice Help
Jump to navigation Jump to search

Em versões antigas do software, as células vazias eram forçadas a serem numericamente iguais a zero em alguns contextos e a serem uma cadeia de caracteres vazia em outros, exceto em comparações diretas, onde =A1=0 e =A1="" ambas resultavam em VERDADEIRO se A1 fosse vazia. Agora a propriedade vazia é herdada até sua utilização, de forma que ambos =PROCV(...)=0 e =PROCV(...)="" retornam VERDADEIRO se a procura resultar em uma célula vazia.

Uma simples referência a uma célula vazia é ainda exibida como 0 numérico mas não é mais necessariamente de tipo numérico. Assim, comparações com a célula referenciada funcionam normalmente.

Para os exemplos que seguem, A1 contém um número, B1 está vazia, C1 contém uma referência a B1:

A1: 1 B1: \<vazia\> C1: =B1 (exibe 0)

=B1=0 => VERDADEIRO

=B1="" => VERDADEIRO

=C1=0 => VERDADEIRO

=C1="" => VERDADEIRO (anteriormente era FALSO)

=ÉNUM(B1) => FALSO

=ÉNUM(C1) => FALSO (anteriormente era VERDADEIRO)

=ÉNUM(PROCV(1;A1:C1;2)) => FALSO (B1)

=ÉNUM(PROCV(1;A1:C1;3)) => FALSO (C1, anteriormente era VERDADEIRO)

=ÉTEXTO(B1) => FALSO

=ÉTEXTO(C1) => FALSO

=ÉTEXTO(PROCV(1;A1:C1;2)) => FALSO (B1, anteriormente era VERDADEIRO)

=ÉTEXTO(PROCV(1;A1:C1;3)) => FALSO (C1)

=ÉCEL.VAZIA(B1) => VERDADEIRO

=ÉCEL.VAZIA(C1) => FALSO

=ÉCEL.VAZIA(PROCV(1;A1:C1;2)) => VERDADEIRO (B1, anteriormente era FALSO)

=ÉCEL.VAZIA(PROCV(1;A1:C1;3)) => FALSO (C1)

Note.png Note que o Microsoft Excel se comporta de forma diferente e sempre retorna um número como resultado de uma referência a uma célula vazia ou a uma célula de fórmula que resulte em uma célula vazia. Por exemplo:

A1: \<vazia\>

B1: =A1 => exibe 0, mas é só uma referência a uma célula vazia

=ÉNUM(A1) => FALSO

=ÉTEXTO(A1) => FALSO

=A1=0 => VERDADEIRO

=A1="" => VERDADEIRO

=ÉNUM(B1) => FALSO (MS-Excel: VERDADEIRO)

=ÉTEXTO(B1) => FALSO

=B1=0 => VERDADEIRO

=B1="" => VERDADEIRO (MS-Excel: FALSO)

C1: =PROCV(...) resultando em uma célula vazia => exibe vazia (MS-Excel: exibe 0)

=ÉNUM(PROCV(...)) => FALSO

=ÉTEXTO(PROCV(...)) => FALSO

=ÉNUM(C1) => FALSO (MS-Excel: VERDADEIRO)

=ÉTEXTO(C1) => FALSO