Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Processamento de células vazias

From LibreOffice Help
Jump to navigation Jump to search

Em versões mais antigas do software, as células vazias eram obrigadas a devolver 0 numérico em alguns contextos e uma cadeia vazia noutros, excepto na comparação directa em que =A1=0 e =A1="" resultavam ambas em VERDADEIRO se A1 estivesse vazia. Uma célula vazia é herdada até ser utilizada e, como tal, =PROCV(...)=0 e =PROCV(...)="" devolvem VERDADEIRO se a procura teve como resultado a devolução de uma célula vazia.

Uma referência simples a uma célula vazia é apresentada como 0 numérico, mas já não é necessariamente do tipo numérico; como tal, também as comparações com a célula de referência funcionam do modo previsto.

Para os exemplos apresentados em seguida, A1 contém um número, B1 está vazia, C1 contém a referência a B1:

A1: 1 B1: <empty> C1: =B1 (apresenta 0)

=B1=0 => VERDADEIRO

=B1="" => VERDADEIRO

=C1=0 => VERDADEIRO

=C1="" => VERDADEIRO (anteriormente era FALSO)

=É.NÚM(B1) => FALSO

=É.NÚM(C1) => FALSO (anteriormente era VERDADEIRO)

=É.NÚM(PROCV(1;A1:C1;2)) => FALSO (B1)

=É.NÚM(PROCV(1;A1:C1;3)) => FALSO (C1, anteriormente era VERDADEIRO)

=É.TEXTO(B1) => FALSO

=É.TEXTO(C1) => FALSO

=É.TEXTO(PROCV(1;A1:C1;2)) => FALSO (B1, anteriormente era VERDADEIRO)

=É.TEXTO(PROCV(1;A1:C1;3)) => FALSO (C1)

=É.CÉL.VAZIA(B1) => VERDADEIRO

=É.CÉL.VAZIA(C1) => FALSO

=É.CÉL.VAZIA(PROCV(1;A1:C1;2)) => VERDADEIRO (B1, anteriormente era FALSO)

=É.CÉL.VAZIA(PROCV(1;A1:C1;3)) => FALSO (C1)

Note.png Repare que o Microsoft Excel tem um comportamento diferente e devolve sempre um número como resultado de uma referência a uma célula vazia ou uma célula de fórmula com o resultado de uma célula vazia. Por exemplo:

A1: <empty>

B1: =A1 => apresenta 0, mas corresponde apenas a uma referência a uma célula vazia

=É.NÚM(A1) => FALSO

=É.TEXTO(A1) => FALSO

=A1=0 => VERDADEIRO

=A1="" => VERDADEIRO

=É.NÚM(B1) => FALSO (MS-Excel: VERDADEIRO)

=É.TEXTO(B1) => FALSO

=B1=0 => VERDADEIRO

=B1="" => VERDADEIRO (MS-Excel: FALSO)

C1: =PROCV(...) com resultado de célula vazia => apresenta uma célula vazia (MS-Excel: apresenta 0)

=É.NÚM(PROCV(...)) => FALSO

=É.TEXTO(PROCV(...)) => FALSO

=É.NÚM(C1) => FALSO (MS-Excel: VERDADEIRO)

=É.TEXTO(C1) => FALSO