Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Afhandelen van lege cellen

From LibreOffice Help
Jump to navigation Jump to search

In oudere versies van de software werden lege cellen in sommige contexten gedwongen tot een numerieke 0 en in andere tot een lege tekenreeks, behalve in een directe vergelijking waar =A1=0 en =A1="" beide resulteerden naar WAAR als A1 leeg was. Leeg zijn wordt nu geërfd totdat het gebruikt wordt, dus zowel =VERT.ZOEKEN(...)=0 en =VERT.ZOEKEN(...)="" geven WAAR als het opzoeken resulteert in een lege cel die wordt teruggegeven.

Een eenvoudige verwijzing naar een lege cel wordt nog steeds weergegeven als een numerieke 0 maar is niet meer noodzakelijkerwijze van het type numeriek, dus werken ook vergelijkingen met de cel waarnaar verwezen wordt zoals verwacht.

Voor de volgende voorbeelden bevat A1 een getal, B1 is leeg en C1 bevat de verwijzing naar B1:

A1: 1 B1: <leeg> C1: =B1 (geeft 0 weer)

=B1=0 => WAAR

=B1="" => WAAR

=C1=0 => WAAR

=C1="" => WAAR (was eerder ONWAAR)

=ISGETAL(B1) => ONWAAR

=ISGETAL(C1) => ONWAAR (was eerder WAAR)

=ISGETAL(VERT.ZOEKEN(1;A1:C1;2)) => ONWAAR (B1)

=ISGETAL(VERT.ZOEKEN(1;A1:C1;3)) => ONWAAR (C1, was eerder WAAR)

=ISTEKST(B1) => ONWAAR

=ISTEKST(C1) => ONWAAR

=ISTEKST(VERT.ZOEKEN(1;A1:C1;2)) => ONWAAR (B1, was eerder WAAR)

=ISTEKST(VERT.ZOEKEN(1;A1:C1;3)) => ONWAAR (C1)

=ISLEEG(B1) => WAAR

=ISLEEG(C1) => ONWAAR

=ISLEEG(VERT.ZOEKEN(1;A1:C1;2)) => WAAR (B1, was eerder ONWAAR)

=ISLEEG(VERT.ZOEKEN(1;A1:C1;3)) => ONWAAR (C1)

Note.png Merk op dat Microsoft Excel zich anders gedraagt en altijd een getal teruggeeft als resultaat van een verwijzing naar een lege cel of een formulecel met het resultaat van een lege cel. Bijvoorbeeld:

A1: <empty>

B1: =A1 => geeft 0 weer, maar is slechts een verwijzing naar een lege cel

=ISGETAL(A1) => ONWAAR

=ISTEKST(A1) => ONWAAR

=A1=0 => WAAR

=A1="" => WAAR

=ISGETAL(B1) => ONWAAR (MS-Excel: WAAR)

=ISTEKST(B1) => ONWAAR

=B1=0 => WAAR

=B1="" => WAAR (MS-Excel: ONWAAR)

C1: =VERT.ZOEKEN(...) met leeg celresultaat => geeft leeg weer (MS-Excel: geeft 0 weer)

=ISGETAL(VERT.ZOEKEN(...)) => ONWAAR

=ISTEKST(VERT.ZOEKEN(...)) => ONWAAR

=ISGETAL(C1) => ONWAAR (MS-Excel: WAAR)

=ISTEKST(C1) => ONWAAR