Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

빈 셀 처리

From LibreOffice Help
Jump to navigation Jump to search

이 소프트웨어의 이전 버전에서는 빈 셀의 처리가 일부 문맥에서는 숫자 0으로, 다른 곳에서는 빈 문자열로 강제 설정되었습니다. 그리고 =A1=0과 =A1="" 같은 직접 비교는 예외로 처리되었습니다. 이와 같은 경우에는 A1이 비었을 경우 모두 TRUE 값을 갖게 됩니다. 이러한 처리는 계속 유지되어, =VLOOKUP(...)=0과 =VLOOKUP(...)=""의 경우 빈 셀이 결과값으로 반환될 경우 TRUE 값을 갖습니다.

빈 셀에 대한 단순 참조는 숫자 0으로 표시되지만 숫자 형식일 필요는 없습니다. 따라서 참조하는 셀과의 비교도 예상대로 동작합니다.

다음 예제에서는, A1 에는 숫자, B1 은 빈 셀, C1 에는 B1 에 대한 참조가 포함되어 있습니다.

A1: 1 B1: <비어있음> C1: =B1 (0으로 표시)

=B1=0 => TRUE

=B1="" => TRUE

=C1=0 => TRUE

=C1="" => TRUE (이전값은 FALSE)

=ISNUMBER(B1) => FALSE

=ISNUMBER(C1) => FALSE (이전값은 TRUE)

=ISNUMBER(VLOOKUP(1;A1:C1;2)) => FALSE (B1)

=ISNUMBER(VLOOKUP(1;A1:C1;3)) => FALSE (C1, 이전값은 TRUE)

=ISTEXT(B1) => FALSE

=ISTEXT(C1) => FALSE

=ISTEXT(VLOOKUP(1;A1:C1;2)) => FALSE (B1, 이전값은 TRUE)

=ISTEXT(VLOOKUP(1;A1:C1;3)) => FALSE (C1)

=ISBLANK(B1) => TRUE

=ISBLANK(C1) => FALSE

=ISBLANK(VLOOKUP(1;A1:C1;2)) => TRUE (B1, 이전값은 FALSE)

=ISBLANK(VLOOKUP(1;A1:C1;3)) => FALSE (C1)

Note.png Microsoft Excel 은 빈 셀이나 빈 결과를 갖는 수식 셀에 대한 참조 결과가 항상 숫자로 반환됩니다. 예제:

A1: <비어있음>

B1: =A1 => 0 으로 표시. 단, 이는 빈 셀에 대한 참조일뿐입니다.

=ISNUMBER(A1) => FALSE

=ISTEXT(A1) => FALSE

=A1=0 => TRUE

=A1="" => TRUE

=ISNUMBER(B1) => FALSE (MS-Excel: TRUE)

=ISTEXT(B1) => FALSE

=B1=0 => TRUE

=B1="" => TRUE (MS-Excel: FALSE)

C1: =VLOOKUP(...) 에 빈 셀이 올 경우, 결과 => 빈 셀로 표시(MS-Excel: 0으로 표시)

=ISNUMBER(VLOOKUP(...)) => FALSE

=ISTEXT(VLOOKUP(...)) => FALSE

=ISNUMBER(C1) => FALSE (MS-Excel: TRUE)

=ISTEXT(C1) => FALSE