Warning: This Help page is relevant to LibreOffice up to version 6.0.
For updated Help pages, visit https://help.libreoffice.org.

Funkcje macierzowe

From LibreOffice Help
Jump to: navigation, search

W tej kategorii znajdują się funkcje macierzowe.

Co to jest macierz

Macierz jest połączonym zakresem komórek arkusza zawierającym wartości. Kwadratowy zakres komórek składający się z 3 wierszy i 3 kolumn jest nazywany macierzą 3 x 3:

A B C
1 7 31 33
2 95 17 2
3 5 10 50

Najmniejszą możliwą macierzą jest macierz 1 x 2 lub 2 x 1 składająca się z dwóch przyległych komórek.

Co to jest formuła macierzowa

Formuła macierzowa to formuła, w której są obliczane poszczególne wartości w zakresie komórek. W odróżnieniu od innych formuł w formule macierzowej jednocześnie obliczana jest nie jedna, ale wiele wartości.

Formuła macierzowa nie tylko oblicza wiele wartości, ale może także zwracać wiele wyników. Wynikiem formuły macierzowej jest także macierz.

Aby w powyższej tabeli dokonać mnożenia indywidualnych komórek przez 10, nie trzeba stosować osobnej formuły dla każdej indywidualnej komórki lub wartości. Zamiast tego wystarczy skorzystać z prostej formuły tablicowej. Zaznacz w innym miejscu arkusza zakres o wymiarze 3 x 3 komórki, wpisz formułę =10*A1:C3, po czym potwierdź tę formułę za pomocą kombinacji klawiszy Ctrl + Shift + Enter. Wynikiem jest macierz 3 x 3, w której pojedyncze wartości w zakresie komórek (A1:C3) zostały pomnożone przez wartość 10.

W odwołaniu do zakresu (macierzy), oprócz mnożenia, można użyć także innych operatorów. Program LibreOffice Calc pozwala na korzystanie z operatorów dodawania (+), odejmowania (-), mnożenia (*), dzielenia (/), potęgowania (^), iloczynu logicznego (&) i porównania (=, <>, <, >, <=, >=). Operatory mogą służyć do obliczania poszczególnych wartości w zakresie komórek i w przypadku wprowadzenia formuły macierzowej zwracają wynik w postaci macierzy.

Podczas zmiany operatorów porównania w formule macierzowej puste komórki podlegają tym samym zasadom, co w przypadku pojedynczych porównań, czyli mogą być reprezentowane przez liczbę 0 lub ciąg pusty. W związku z tym obie formuły macierzowe: {=A1:A2=""} i {=A1:A2=0} zwracają 1-kolumnową i 2-wierszową macierz z komórkami zawierającymi wartość PRAWDA, jeśli komórki A1 i A2 są puste.

Kiedy używa się formuł macierzowych

Formuł macierzowych używa się w celu powtórzenia obliczeń dla różnych wartości. Późniejsza zmiana metody obliczeń wymaga jedynie aktualizacji formuły macierzowej. Aby dodać formułę macierzową, należy zaznaczyć cały zakres komórek, a następnie dokonać odpowiedniej zmiany w formule macierzowej.

W przypadku obliczania wielu wartości formuły macierzowe pozwalają także oszczędzić miejsce, ponieważ nie wymagają dużej ilości pamięci. Oprócz tego macierze są bardzo ważnym narzędziem w przypadku skomplikowanych obliczeń, ponieważ w obliczeniach można uwzględnić wiele zakresów komórek. Program LibreOffice posiada różne funkcje do przeprowadzania obliczeń na macierzach, miedzy innymi funkcję MACIERZ.ILOCZYN służącą do mnożenia dwóch macierzy i funkcję SUMA.ILOCZYNÓW obliczającą iloczyny skalarne dwóch macierzy.

Korzystanie z formuł macierzowych w programie LibreOffice Calc

Można także utworzyć "normalną" formułę, w której zakres komórek, taki jak parametry, oznacza formułę macierzową. Wynik jest uzyskiwany z przecięcia zakresu odwołania i wierszy lub kolumn zawierających formułę. Jeśli nie istnieje takie przecięcie lub zakres w przecięciu obejmuje kilka wierszy lub kolumn, zostanie wyświetlony komunikat o błędzie #WARTOŚĆ! Poniższy rysunek przedstawia omawianą koncepcję:

Tworzenie formuł macierzowych

W przypadku tworzenia formuły macierzowej za pomocą Kreatora funkcji za każdym razem należy zaznaczyć pole wyboru Macierz, dzięki czemu wyniki są zwracane w postaci macierzy. W przeciwnym razie zostanie zwrócony wynik funkcji wyłącznie dla wartości w lewym górnym rogu macierzy.

Jeżeli formuła tablicowa wprowadzana jest bezpośrednio do komórki, należy użyć kombinacji klawiszy Shift + Ctrl + Enter, zamiast samego klawisza Enter. Tylko wówczas formuła będzie formułą tablicową.

Note.png Formuły macierzowe w programie LibreOffice Calc są wyświetlane w klamrach. Jednakże nie można utworzyć formuły macierzowej poprzez ręczne wprowadzenie klamer.

Komórki w macierzy wynikowej są automatycznie chronione przed zmianami, Możliwa jest jednak edycja i kopiowanie formuły macierzowej przez zaznaczenie całego zakresu komórek.

Korzystanie z wewnętrznych stałych tablicowych w formułach

Program Calc obsługuje wewnętrzne stałe macierzowe/tablicowe w formułach. Wewnętrzna tablica znajduje się w nawiasach klamrowych „{” i „}”. Elementy mogą być liczbami (w tym liczbami ujemnymi), stałymi logicznymi (PRAWDA, FAŁSZ) lub ciągami literałów. Wyrażenia nie będące stałymi nie są dozwolone. Tablice mogą być wprowadzane w jednym lub kilku wierszach oraz w jednej lub kilku kolumnach. Wszystkie wiersze muszą składać się z tej samej liczby elementów, podobnie wszystkie kolumny muszą składać się z tej samej liczby elementów.

Separator kolumn (oddzielający elementy w jednym wierszu) to średnik (;). Separator wierszy to symbol potoku „|”. Separatory są niezależne od języka i ustawień regionalnych.

Tablice nie mogą być zagnieżdżone.

Przykłady:

={1;2;3}

Tablica składająca się z jednego wiersza zawierającego trzy liczby 1, 2 i 3.

Aby do tej macierzy wprowadzić wartości stałe, należy zaznaczyć trzy komórki w wierszu, a następnie wpisać formułę =(1;2;3), korzystając z nawiasów okrągłych i średników, po czym nacisnąć klawisze Ctrl + Shift + Enter.

={1;2;3|4;5;6}

Tablica składająca się z dwóch wierszy i trzech wartości w każdym wierszu.

={0;1;2|FALSE;TRUE;"two"}

Mieszana tablica danych.

=SIN({1;2;3})

Wprowadzona jako formuła macierzowa zwraca wynik trzech obliczeń SIN z argumentami 1, 2 i 3.

Edycja formuł macierzowych

  1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową. Aby zaznaczyć całą macierz, umieść kursor wewnątrz zakresu macierzy, po czym naciśnij klawisze Ctrl + /, przy czym klawisz / jest znakiem dzielenia umieszczonym na klawiaturze numerycznej.
  2. Innym sposobem jest naciśnięcie klawisza F2 lub ustawienie kursora w wierszu wprowadzania. Obie powyższe czynności pozwalają na edycję formuły.
  3. Po wprowadzeniu zmian naciśnij klawisze Ctrl + Shift + Enter.
Tip.png Części macierzy mogą być odrębnie formatowane, można na przykład zmienić kolor czcionki. W tym celu należy wybrać zakres komórek, a następnie zmienić żądany atrybut.

Kopiowanie formuł macierzowych

  1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową.
  2. Naciśnij klawisz F2 lub umieść kursor w wierszu wprowadzania.
  3. Skopiuj formułę do wiersza wprowadzania, naciskając klawisze Ctrl + C.
  4. Zaznacz zakres komórek, gdzie ma zostać wstawiona formuła macierzowa, a następnie naciśnij klawisz F2 lub umieść kursor w wierszu wprowadzania.
  5. W zaznaczonym obszarze wklej formułę za pomocą klawiszy Ctrl + V, po czym potwierdź ją, naciskając kombinację klawiszy Ctrl + Shift + Enter. Zaznaczony zakres zawiera teraz formułę tablicową.

Dostosowanie zakresu komórek

Aby edytować macierz wynikową, należy wykonać poniższe czynności:

  1. Zaznacz zakres komórek lub macierz zawierającą formułę macierzową.
  2. Poniżej zaznaczenia, po prawej stronie znajduje się mała ikona pozwalająca na zwiększenie lub zmniejszenie zakresu za pomocą myszy.
Note.png Dostosowanie zakresu macierzy nie powoduje dostosowania formuły macierzowej. Zmianie podlega wyłącznie zakres wyświetlanych wyników.

Trzymając przyciśnięty klawisz Ctrl, możesz w danym zakresie tworzyć kopię formuły macierzystej.

Warunkowe obliczenia macierzy

Warunkowe obliczenie macierzy jest macierzą lub formułą macierzową, która zawiera funkcję JEŻELI() lub WYBIERZ(). Argument warunkowy w formule jest odwołaniem do obszaru lub wynikiem macierzy.

W poniższym przykładzie zapis ">0" w formule {=JEŻELI(A1:A3>0;"tak";"nie")} dotyczy każdej komórki w zakresie A1:A3, a wynik jest kopiowany do odpowiedniej komórki.

A B (formuła) B (wynik)
1 1 {=JEŻELI(A1:A3>0;"tak";"nie")} tak
2 0 {=JEŻELI(A1:A3>0;"tak";"nie")} nie
3 1 {=JEŻELI(A1:A3>0;"tak";"nie")} tak

Poniższe funkcje służą do wymuszonej obsługi macierzy: WSP.KORELACJI, KOWARIANCJA, REGLINX, TEST.F, ODCIĘTA, WYZNACZNIK MACIERZY, MACIERZ.ODW, MACIERZ.ILOCZYN, WYST.NAJCZĘŚCIEJ, PEARSON, PRAWDPD, R.KWADRAT, NACHYLENIE, REGBŁSTD, SUMA.ILOCZYNÓW, SUMA.X2.M.Y2, SUMA.X2.P.Y2, SUMA.XMY.2, TEST.T Użycie odwołań do obszarów jako argumentów powyższych funkcji powoduje, że zachowują się one jak funkcje macierzowe. Poniższa tabela przedstawia przykład wymuszonej obsługi macierzy:

A B (formuła) B (wynik) C (wymuszona formuła macierzowa) C (wynik)
1 1 =A1:A2+1 2 =SUMA.ILOCZYNÓW(A1:A2+1) 5
2 2 =A1:A2+1 3 =SUMA.ILOCZYNÓW(A1:A2+1) 5
3 =A1:A2+1 #WARTOŚĆ =SUMA.ILOCZYNÓW(A1:A2+1) 5

TRANSPONUJ

Transponuje wiersze macierzy z jej kolumnami.

Składnia

TRANSPONUJ(macierz)

Macierz oznacza macierz, którą należy przetransponować.

Szczegółowe informacje znajdują się na górze strony.

Przykład

W arkuszu kalkulacyjnym zaznacz zakres, w którym ma być wpisana macierz transponowana. Jeżeli macierz pierwotna posiada n wierszy i m kolumn, zaznaczony zakres musi mieć przynajmniej m wierszy i n kolumn. Następnie wpisz bezpośrednio formułę, zaznacz obszar pierwotny i naciśnij kombinację klawiszy Shift + Ctrl + Enter. Możesz także wywołać Kreatora funkcji i zaznaczyć pole wyboru Macierz. Macierz transponowana zostanie wyświetlona w zaznaczonym obszarze docelowym. Macierz ta jest automatycznie chroniona przed zmianami.

REGLINP

Zwraca tabelę ze statystykami prostej linii, która najlepiej pasuje do zestawu danych.

Składnia

LINEST(dane_Y; dane_X; Typ_liniowy; Parametry)

Dane_Y to pojedynczy wiersz lub kolumna z danymi określającymi współrzędne Y w zestawie punktów danych.

Dane_X to odpowiadający pojedynczy wiersz lub kolumna z danymi określającymi współrzędne X w zestawie punktów danych. Jeżeli argumentdane_X zostanie pominięty, arkusz przyjmie domyślne wartości 1, 2, 3, ..., n. Jeżeli dostępnych jest kilka zestawów zmiennych, argument dane_X może być zakresem z wieloma odpowiadającymi wierszami lub kolumnami.

Funkcja REGLINP odnajduje prostą wyrażoną wzorem y = a + bx, która najdokładniej pasuje do danych. W tym celu wykorzystuje mechanizm regresji liniowej (metodę "najmniejszych kwadratów"). W przypadku kilku zestawów zmiennych prosta wyrażona jest wzorem y = a + bx1 + bx2 ... + bnxn.

Jeżeli argument typ_liniowy przyjmie wartość FAŁSZ, spowoduje to wymuszenie przejścia znalezionej prostej przez początek układu współrzędnych (stała a przyjmie wartość zero; prosta będzie wyrażona wzorem y = bx). Jeżeli argument typ_liniowy zostanie pominięty, przyjmie on domyślną wartość PRAWDA (nie będzie wymuszenia przejścia przez początek układu współrzędnych).

Jeżeli argument parametry zostanie pominięty lub przyjmie wartość FAŁSZ, zostanie zwrócony jedynie górny wiersz tabeli ze statystyką. Jeżeli argument ten przyjmie wartość PRAWDA, zostanie zwrócona cała tabela.

Funkcja REGLINP zwraca tabelę (macierz) ze statystyką analogiczną do poniższej i musi być wprowadzana jako formuła tablicowa (na przykład za pomocą klawiszy Ctrl + Shift + Enter zamiast samego klawisza Enter).

W funkcjach programu LibreOffice można nie podawać parametrów oznaczonych jako "opcjonalnych", tylko jeśli za nimi nie występują inne parametry. Na przykład w funkcji o czterech parametrach, w której dwa ostatnie parametry są oznaczone jako "opcjonalne", można nie podawać parametru 4 lub parametrów 3 i 4, ale nie można nie podawać tylko parametru 3.

Szczegółowe informacje znajdują się na górze strony.

Przykład

Funkcja ta zwraca macierz i obsługiwana jest w taki sam sposób, w jaki obsługiwane są pozostałe funkcje tablicowe. Zaznacz obszar odpowiedzi, a następnie funkcji. Zaznacz obszar argumentu dane_Y. W razie potrzeby możesz wprowadzić pozostałe argumenty. Zaznacz pole wyboru Macierz, a następnie kliknij przycisk OK.

Wartości zwrócone przez program (przy argumencie parametry = 0) pokażą przynajmniej nachylenie krzywej regresji i jej punkt przecięcia z osią Y. Jeżeli argument parametry ma wartość inną niż 0, zostaną wyświetlone inne wyniki.

Pozostałe wyniki funkcji REGLINP

Przykłady:

A B C D E F G
1 x1 x2 y Wartość REGLINP
2 4 7 100 4,17 -3,48 82,33
3 5 9 105 5,46 10,96 9,35
4 6 11 104 0,87 5,06 #BRAK
5 7 12 108 13,21 4 #BRAK
6 8 15 111 675,45 102,26 #BRAK
7 9 17 120
8 10 19 133

Kolumna A zawiera kilka wartości X1, kolumna B zawiera wartości X2, a kolumna C - wartości Y. Powyższe wartości już zostały wprowadzone do arkusza kalkulacyjnego. Zaznacz zakres E2:G6 i uruchom Kreatora funkcji. W celu wprowadzenia funkcji REGLINP należy zaznaczyć pole wyboru Macierz w Kreatorze funkcji. Następnie zaznacz na arkuszu kalkulacyjnym następujące wartości (lub wprowadź je za pomocą klawiatury):

Dane_Y to C2:C8

Dane_X to A2:B8

Typ_liniowy oraz parametry ustawione na wartość 1.

Po kliknięciu przycisku OK program LibreOffice Calc wypełnia powyższą tabelę przedstawionymi w niej wartościami funkcji REGLINP.

Formuła zapisana w pasku Formuła odnosi się do każdej komórki macierzy REGLINP {=REGLINP(C2:C8;A2:B8;1;1)}

Znaczenie obliczonych wartości funkcji REGLINP jest następujące:

E2 i F2: Nachylenie m krzywej regresji y=b+m*x dla wartości x1 i x2. Wartości są podane w odwrotnej kolejności, wartość E2 oznacza nachylenie dla x2, a F2 dla x1.

G2: Przecięcie b z osią y.

E3 i F3: Błąd standardowy wartości nachylenia.

G3: Błąd standardowy przecięcia.

E4: R.KWADRAT

F4: Błąd standardowy regresji obliczonej z wartości Y.

E5: Wartość F obliczona na podstawie analizy wariancji.

F5: Stopień swobody obliczony na podstawie analizy wariancji.

E6: Suma kwadratów odchyleń wartości Y obliczonych na podstawie ich średniej liniowej.

F6: Suma kwadratów odchyleń wartości Y obliczonej na podstawie podanych wartości Y.

Szczegółowe informacje znajdują się na górze strony.

REGEXPP

Funkcja wyznacza dopasowanie wprowadzonych danych w postaci wykładniczej krzywej regresji (y=b*m^x).

Składnia

REGEXPP(dane_Y; dane_X; typ_funkcji; parametry)

Dane_Y oznaczają macierz danych Y.

Dane_X (parametr opcjonalny) oznaczają macierz danych X.

Typ_funkcji (parametr opcjonalny). Jeśli typ_funkcji = 0, zostanie obliczona funkcja w formie y = m^x. W przeciwnym razie zostaną obliczone funkcje y = b*m^x.

Parametry (parametr opcjonalny). Jeśli parametr=0, zostanie obliczony wyłącznie współczynnik regresji,

W funkcjach programu LibreOffice można nie podawać parametrów oznaczonych jako "opcjonalnych", tylko jeśli za nimi nie występują inne parametry. Na przykład w funkcji o czterech parametrach, w której dwa ostatnie parametry są oznaczone jako "opcjonalne", można nie podawać parametru 4 lub parametrów 3 i 4, ale nie można nie podawać tylko parametru 3.

Szczegółowe informacje znajdują się na górze strony.

Przykład

Zobacz REGLINP. Suma kwadratów nie zostanie jednak obliczona.

SUMA.ILOCZYNÓW

Mnoży odpowiadające sobie elementy w podanych macierzach i zwraca sumę tych iloczynów.

Składnia

SUMA.ILOCZYNÓW(macierz_1; macierz_2...macierz_30)

Macierz_1, macierz_2...macierz_30 oznaczają macierze, dla których należy pomnożyć ich odpowiadające sobie elementy.

Na liście argumentów musi znajdować się co najmniej jedna macierz. W przypadku tylko jednej macierzy sumowane są jej wszystkie elementy.

Przykład

A B C D
1 2 3 4 5
2 6 7 8 9
3 10 11 12 13

=SUMA.ILOCZYNÓW(A1:B3;C1:D3) zwraca wartość 397.

Obliczenia: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Funkcja SUMA.ILOCZYNÓW pozwala na obliczenie iloczynu skalarnego dwóch wektorów.

Note.png Funkcja SUMA.ILOCZYNÓW zwraca jedną liczbę, nie ma potrzeby wprowadzania jej w postaci funkcji macierzowej.

Szczegółowe informacje znajdują się na górze strony.

SUMA.X2.M.Y2

Zwraca sumę różnic kwadratów odpowiadających sobie wartości dwóch macierzy.

Składnia

SUMA.X2.M.Y2(macierz_X; macierz_Y)

Macierz_X oznacza pierwszą macierz, której elementy mają być podniesione do kwadratu i dodane.

Macierz_Y oznacza drugą macierz, której elementy mają być podniesione do kwadratu i odjęte.

Szczegółowe informacje znajdują się na górze strony.

SUMA.X2.P.Y2

Zwraca sumę sum kwadratów odpowiadających sobie wartości dwóch macierzy.

Składnia

SUMA.X2.P.Y2(macierz_X; macierz_Y)

Macierz_X oznacza pierwszą macierz, której elementy mają być podniesione do kwadratu i dodane.

Macierz_Y oznacza drugą macierz, której elementy mają być podniesione do kwadratu i dodane.

Szczegółowe informacje znajdują się na górze strony.

SUMA.XMY.2

Dodaje kwadraty wariancji pomiędzy odpowiadającymi sobie elementami dwóch macierzy.

Składnia

SUMA.XMY.2(macierz_X; macierz_Y)

Macierz_X oznacza pierwszą macierz, której elementy mają być odjęte i podniesione do kwadratu.

Macierz_Y oznacza drugą macierz, której elementy mają być odjęte i podniesione do kwadratu.

Szczegółowe informacje znajdują się na górze strony.

REGLINW

Zwraca wartości regresji liniowej.

Składnia

REGLINW(dane_Y; dane_X; nowe_dane_X; typ_liniowy)

Dane_Y oznaczają macierz danych Y.

Dane_X (parametr opcjonalny) oznaczają macierz danych X.

Nowe_dane_X (parametr opcjonalny) oznaczają macierz danych X używanych do ponownego obliczenia wartości.

Typ_liniowy (parametr opcjonalny). Jeśli typ_liniowy = 0, obliczane linie przechodzą przez punkt zerowy. W przeciwnym razie zostaną obliczone także linie przesunięte. Domyślnie typ_liniowy <> 0.

W funkcjach programu LibreOffice można nie podawać parametrów oznaczonych jako "opcjonalnych", tylko jeśli za nimi nie występują inne parametry. Na przykład w funkcji o czterech parametrach, w której dwa ostatnie parametry są oznaczone jako "opcjonalne", można nie podawać parametru 4 lub parametrów 3 i 4, ale nie można nie podawać tylko parametru 3.

Szczegółowe informacje znajdują się na górze strony.

Przykład

Zaznacz zakres arkusza kalkulacyjnego zawierający dane regresji. Wybierz funkcję. Wprowadź dane wyjściowe lub zaznacz je myszą. Zaznacz pole wyboru Macierz, a następnie kliknij przycisk OK. Zostaną wyświetlone dane regresji obliczone na podstawie podanych parametrów.

MUNIT

Zwraca kwadratową macierz unitarną określonego rozmiaru. Macierz unitarna jest macierzą kwadratową o elementach na głównej przekątnej równych 1 i wszystkich pozostałych elementach równych 0.

Składnia

MUNIT(wymiary)

Wymiary oznaczają rozmiar jednostki macierzy.

Note.png Ogólne wprowadzenie do kategorii funkcji Macierz można znaleźć na górze tej strony.

Przykład

Zaznacz kwadratowy obszar na arkuszu, na przykład od A1 do E5.

Bez usuwania zaznaczenia wybierz funkcję MUNIT. Zaznacz pole wyboru Macierz. Wprowadź żądane wymiary jednostki macierzy, w tym przypadku 5, a następnie kliknij przycisk OK.

Możesz także w ostatniej komórce zaznaczonego obszaru wprowadzić formułę =Jedn.Macierzy(5), po czym nacisnąć kombinację klawiszy Shift + Ctrl + Enter.

W zakresie A1:E5 zostanie utworzona macierz unitarna.

Szczegółowe informacje znajdują się na górze strony.

CZĘSTOŚĆ

Określa rozkład częstości w macierzy jednokolumnowej. Wartość domyślna i liczba przedziałów lub klas służą do obliczenia, ile wartości znajduje się w poszczególnych przedziałach.

Składnia

CZĘSTOŚĆ(dane; klasy)

Dane określają macierz lub odwołanie do zestawu obliczanych wartości.

Klasy oznaczają macierz zestawu klas.

Note.png Ogólne wprowadzenie do kategorii funkcji Macierz można znaleźć na górze tej strony.

Przykład

W poniższej tabeli kolumna A zawiera nieposortowane wyniki pomiarów. Kolumna B zawiera górne granice poszczególnych klas, na które należy podzielić kolumnę A. Zgodnie z granicą określoną w komórce B1 funkcja CZĘSTOŚĆ zwraca liczbę wartości pomiarów mniejszych lub równych 5. Granica w komórce B2 wynosi 10, w związku z czym funkcja CZĘSTOŚĆ zwraca drugi wynik oznaczający liczbę wartości pomiarów większych od 5 lub większych lub równych 10. Tekst ">25" wprowadzony w komórce B6 ma znaczenie wyłącznie informacyjne.

A B C
1 12 5 1
2 8 10 3
3 24 15 2
4 11 20 3
5 5 25 1
6 20 >25 1
7 16
8 9
9 7
10 16
11 33

Zaznacz zakres obejmujący pojedynczą kolumnę, w której należy wprowadzić częstość wartości, które są większe od górnej granicy klasy. Należy zaznaczyć o jedno pole więcej niż górna granica klasy. W odniesieniu do tego przykładu zaznacz zakres C1:C6. W Kreatorze funkcji wybierz funkcję CZĘSTOŚĆ. Zaznacz zakres wyników pomiarów (A1:A11) jako parametr Dane, a następnie zaznacz kolumnę Klasy zawierającą granice klas (B1:B6). Zaznacz pole wyboru Macierz i kliknij przycisk OK. We wstępnie zaznaczonym zakresie C1:C6 zostaną wyświetlone wyniki funkcji częstości.

Szczegółowe informacje znajdują się na górze strony.

WYZNACZNIK.MACIERZY

Zwraca wyznacznik macierzy. Funkcja zwraca wartość w bieżącej komórce; nie jest wymagane zdefiniowanie zakresu.

Składnia

WYZNACZNIK.MACIERZY(macierz)

Macierz oznacza macierz kwadratową, dla której należy obliczyć wyznacznik.

Note.png Ogólne wprowadzenie do kategorii funkcji Macierz znajduje się na górze tej strony.

Szczegółowe informacje znajdują się na górze strony.

MACIERZ.ODW

Zwraca macierz odwrotną.

Składnia

MACIERZ.ODW(macierz)

Macierz oznacza macierz kwadratową, którą należy odwrócić.

Szczegółowe informacje znajdują się na górze strony.

Przykład

Zaznacz macierz, a następnie wybierz funkcję MACIERZ.ODW. Zaznacz macierz wyjściową, zaznacz pole Macierz, a następnie kliknij przycisk OK.

MACIERZ.ILOCZYN

Wyznacza iloczyn dwóch macierzy. Liczba kolumn pierwszej macierzy musi być równa liczbie wierszy drugiej macierzy. Macierz kwadratowa charakteryzuje się równą liczbą wierszy i kolumn.

Składnia

MACIERZ.ILOCZYN(macierz; macierz)

Macierz na pierwszej pozycji oznacza pierwszą macierz używaną do obliczenia iloczynu.

Macierz na drugiej pozycji oznacza drugą macierz o tej samej liczbie wierszy.

Note.png Szczegółowe informacje znajdują się na górze strony.

Przykład

Zaznacz kwadratowy zakres komórek. Wybierz funkcję MACIERZ.ILOCZYN. Zaznacz pierwszą Macierz, a następnie zaznacz drugą Macierz. Korzystając z Kreatora funkcji, zaznacz pole wyboru Macierz. Kliknij przycisk OK. W zakresie zaznaczonym na początku zostanie wyświetlona macierz wynikowa.

REGEXPW

Wyznacza punkty regresji wykładniczej w macierzy.

Składnia

REGEXPW(dane_Y; dane_X; nowe_Dane_X; typ_funkcji)

Dane_Y oznaczają macierz danych Y.

Dane_X (parametr opcjonalny) oznaczają macierz danych X.

Nowe_dane_X (parametr opcjonalny) oznaczają macierz danych X używanych do ponownego obliczenia wartości.

Typ_funkcji (parametr opcjonalny). Jeśli typ_funkcji = 0, zostanie obliczona funkcja w formie y = m^x. W przeciwnym razie zostaną obliczone funkcje y = b*m^x.

W funkcjach programu LibreOffice można nie podawać parametrów oznaczonych jako "opcjonalnych", tylko jeśli za nimi nie występują inne parametry. Na przykład w funkcji o czterech parametrach, w której dwa ostatnie parametry są oznaczone jako "opcjonalne", można nie podawać parametru 4 lub parametrów 3 i 4, ale nie można nie podawać tylko parametru 3.

Szczegółowe informacje znajdują się na górze strony.

Przykład

Funkcja zwraca macierz i jest obsługiwana w taki sam sposób, jak inne funkcje macierzowe. Zaznacz zakres, w którym ma zostać wyświetlony wynik, a następnie wybierz funkcję. Zaznacz Dane_Y. Wprowadź pozostałe parametry, zaznacz pole wyboru Macierz, a następnie kliknij przycisk OK.


Related Topics

Funkcje arkusza Calc na stronie Wiki OpenOffice.org